tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 cmake_minimum_required(VERSION 2.8.6)
   7
   8 find_package(Java 1.7)
   9 include(UseJava)
  10
  11 # Rules to build libsimgrid-java
  12 #
  13 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  14 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
  15 if (CMAKE_VERSION VERSION_LESS "2.8.8")
  16   include_directories(${JNI_INCLUDE_DIRS})
  17
  18   message("[Java] Try to workaround missing feature in older CMake. You should better update CMake to version 2.8.8 or above.")
  19   get_directory_property(CHECK_INCLUDES INCLUDE_DIRECTORIES)
  20 else()
  21   get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  22   if (COMMON_INCLUDES)
  23     set_target_properties(simgrid-java PROPERTIES
  24       INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  25   else()
  26     set_target_properties(simgrid-java PROPERTIES
  27       INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  28   endif()
  29
  30   get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  31 endif()
  32 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  33
  34 target_link_libraries(simgrid-java simgrid)
  35
  36
  37 if(WIN32)
  38   exec_program("java -d32 -version"
  39                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  40   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  41   if(${POSITION} GREATER -1)
  42     message("POTENTIAL ERROR: Java JVM needs to be 32 bits to be able to run with Simgrid on Windows for now")
  43   endif()
  44
  45   set_target_properties(simgrid-java PROPERTIES
  46     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
  47   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  48   message(STATUS "pexports: ${PEXPORTS_PATH}")
  49   if(PEXPORTS_PATH)
  50     add_custom_command(TARGET simgrid-java POST_BUILD
  51       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/simgrid-java.dll > ${CMAKE_BINARY_DIR}/lib/simgrid-java.def)
  52   endif(PEXPORTS_PATH)
  53 endif()
  54
  55 # Rules to build simgrid.jar
  56 #
  57
  58 ## Files to include in simgrid.jar
  59 ##
  60 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  61 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  62 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  63
  64 set(LIBSIMGRID_SO
  65   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  66 set(LIBSIMGRID_JAVA_SO
  67   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  68 set(LIBSURF_JAVA_SO
  69   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  70
  71 ## Here is how to build simgrid.jar
  72 ##
  73 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  74   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  75   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  76 else()
  77   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  78 endif()
  79
  80 add_custom_command(
  81   TARGET simgrid-java_jar POST_BUILD
  82   COMMENT "Add the documentation into simgrid.jar..."
  83   DEPENDS ${MANIFEST_IN_FILE}
  84           ${CMAKE_HOME_DIRECTORY}/COPYING
  85           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  86           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  87           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  88
  89   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  90   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  91   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  92
  93   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.surf org.simgrid.trace
  94
  95   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc -C ${CMAKE_HOME_DIRECTORY} COPYING ChangeLog ChangeLog.SimGrid-java LICENSE-LGPL-2.1
  96   )
  97
  98 ###
  99 ### Pack the java libraries into the jarfile if asked to do so
 100 ###
 101
 102 if(enable_lib_in_jar)
 103   find_program(STRIP_COMMAND strip)
 104   if(NOT STRIP_COMMAND)
 105     set(STRIP_COMMAND "cmake -E echo (strip not found)")
 106   endif()
 107
 108   set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
 109   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
 110     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/x86)
 111   endif()
 112   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 113        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 114     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/amd64)
 115   endif()
 116
 117   add_custom_command(
 118     TARGET simgrid-java_jar POST_BUILD
 119     COMMENT "Add the native libs into simgrid.jar..."
 120     DEPENDS simgrid-java
 121             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 122             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 123             ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
 124
 125     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 126     COMMAND ${CMAKE_COMMAND} -E make_directory                                     ${JAVA_NATIVE_PATH}
 127     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}
 128     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}
 129     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}    ${JAVA_NATIVE_PATH}
 130
 131     # strip seems to fail on Mac on binaries that are already stripped.
 132     # It then spits: "symbols referenced by indirect symbol table entries that can't be stripped"
 133     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}      || true
 134     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO} || true
 135     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSURF_JAVA_SO}    || true
 136
 137     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 138     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 139
 140     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 141     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 142     )
 143   if(MINGW)
 144     find_library(WINPTHREAD_DLL
 145       NAME winpthread winpthread-1
 146       PATHS C:\\MinGW C:\\MinGW64 C:\\MinGW\\bin C:\\MinGW64\\bin
 147     )
 148     add_custom_command(
 149       TARGET simgrid-java_jar POST_BUILD
 150       COMMENT "Add the MinGW libs into simgrid.jar..."
 151       DEPENDS ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 152
 153       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 154       COMMAND ${CMAKE_COMMAND} -E make_directory          ${JAVA_NATIVE_PATH}
 155       COMMAND ${CMAKE_COMMAND} -E copy ${WINPTHREAD_DLL}  ${JAVA_NATIVE_PATH}
 156
 157       COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 158       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 159     )
 160   endif(MINGW)
 161 endif(enable_lib_in_jar)
 162
 163 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 164
 165 if(enable_maintainer_mode)
 166   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 167   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 168
 169   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 170
 171   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 172   swig_link_libraries(surf-java simgrid)
 173 else()
 174   add_library(surf-java SHARED ${JSURF_C_SRC})
 175   target_link_libraries(surf-java simgrid)
 176 endif()
 177
 178 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 179 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 180
 181 add_dependencies(simgrid-java surf-java)
 182 add_dependencies(simgrid-java_jar surf-java)
 183
 184 if(WIN32)
 185   set_target_properties(surf-java PROPERTIES
 186     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
 187   if(PEXPORTS_PATH)
 188     add_custom_command(TARGET surf-java POST_BUILD
 189       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/surf-java.dll > ${CMAKE_BINARY_DIR}/lib/surf-java.def)
 190   endif(PEXPORTS_PATH)
 191 endif()