tools/cmake/UnitTesting.cmake

   1 # This file is in charge of the unit testing in SimGrid.
   2 # See http://simgrid.gforge.inria.fr/simgrid/3.13/doc/inside_tests.html#inside_tests_add_units
   3
   4 # To register a file containing unit tests, simply add it to
   5 # FILES_CONTAINING_UNITTESTS and have a pleasant day.
   6
   7 set(FILES_CONTAINING_UNITTESTS
   8   src/xbt/cunit.cpp
   9   src/xbt/ex.cpp
  10   src/xbt/dynar.cpp
  11   src/xbt/dict.cpp
  12   src/xbt/xbt_str.cpp
  13   src/xbt/config.cpp
  14 )
  15
  16 if(SIMGRID_HAVE_MC)
  17   set(FILES_CONTAINING_UNITTESTS ${FILES_CONTAINING_UNITTESTS}
  18       src/mc/PageStore.cpp
  19       src/mc/mc_snapshot.cpp
  20   )
  21 endif()
  22
  23 ####  Nothing to change below this line to add a new tested file
  24 ################################################################
  25
  26 foreach(file ${FILES_CONTAINING_UNITTESTS})
  27   get_filename_component(basename ${file} NAME_WE)
  28   get_filename_component(ext ${file} EXT)
  29   set(EXTRACTED_TEST_SOURCE_FILES ${EXTRACTED_TEST_SOURCE_FILES} ${CMAKE_CURRENT_BINARY_DIR}/src/${basename}_unit${ext})
  30 endforeach()
  31
  32 set(EXTRACTED_TEST_SOURCE_FILES ${EXTRACTED_TEST_SOURCE_FILES} ${CMAKE_CURRENT_BINARY_DIR}/src/simgrid_units_main.c)
  33
  34 set_source_files_properties(${EXTRACTED_TEST_SOURCE_FILES} PROPERTIES GENERATED true)
  35
  36 ADD_CUSTOM_COMMAND(
  37   OUTPUT  ${EXTRACTED_TEST_SOURCE_FILES}
  38   DEPENDS ${CMAKE_HOME_DIRECTORY}/tools/sg_unit_extractor.pl ${FILES_CONTAINING_UNITTESTS}
  39   COMMENT "Generating *_units files for testall..."
  40
  41   WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}
  42   COMMAND           ${CMAKE_COMMAND} -E remove -f ${EXTRACTED_TEST_SOURCE_FILES}
  43   COMMAND           chmod +x ${CMAKE_HOME_DIRECTORY}/tools/sg_unit_extractor.pl
  44   COMMAND           ${CMAKE_HOME_DIRECTORY}/tools/sg_unit_extractor.pl --root=src/ --outdir=${CMAKE_CURRENT_BINARY_DIR}/src/ ${FILES_CONTAINING_UNITTESTS}
  45 )
  46
  47 add_executable       (testall ${EXTRACTED_TEST_SOURCE_FILES})
  48 target_link_libraries(testall simgrid)
  49 set_property(
  50     TARGET testall
  51     APPEND PROPERTY
  52            INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}"
  53            )
  54