tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 find_package(Java 1.7 REQUIRED)
   7 include(UseJava)
   8
   9 # Rules to build libsimgrid-java
  10 #
  11 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  12 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
  13
  14 get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  15 if (COMMON_INCLUDES)
  16   set_target_properties(simgrid-java PROPERTIES
  17     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  18 else()
  19   set_target_properties(simgrid-java PROPERTIES
  20     INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  21 endif()
  22
  23 get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  24 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  25
  26 target_link_libraries(simgrid-java simgrid)
  27
  28
  29 if(WIN32)
  30   exec_program("java -d32 -version" OUTPUT_VARIABLE IS_32_BITS_JVM)
  31   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  32   if(NOT ${POSITION} GREATER -1)
  33     message(fatal_error "SimGrid can only use Java 64 bits")
  34   endif()
  35 endif()
  36
  37 # Rules to build simgrid.jar
  38 #
  39
  40 ## Files to include in simgrid.jar
  41 ##
  42 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  43 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  44 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  45
  46 set(LIBSIMGRID_SO
  47   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  48 set(LIBSIMGRID_JAVA_SO
  49   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  50 set(LIBSURF_JAVA_SO
  51   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  52
  53 ## Here is how to build simgrid.jar
  54 ##
  55 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  56   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  57   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  58 else()
  59   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  60 endif()
  61
  62 add_custom_command(
  63   TARGET simgrid-java_jar POST_BUILD
  64   COMMENT "Add the documentation into simgrid.jar..."
  65   DEPENDS ${MANIFEST_IN_FILE}
  66           ${CMAKE_HOME_DIRECTORY}/COPYING
  67           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  68           ${CMAKE_HOME_DIRECTORY}/NEWS
  69           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  70           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  71
  72   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  73   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  74   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  75
  76   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.surf org.simgrid.trace
  77
  78   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc -C ${CMAKE_HOME_DIRECTORY} COPYING ChangeLog ChangeLog.SimGrid-java LICENSE-LGPL-2.1 NEWS
  79   )
  80
  81 ###
  82 ### Pack the java libraries into the jarfile if asked to do so
  83 ###
  84
  85 if(enable_lib_in_jar)
  86   find_program(STRIP_COMMAND strip)
  87   mark_as_advanced(STRIP_COMMAND)
  88   if(NOT STRIP_COMMAND)
  89     set(STRIP_COMMAND "cmake -E echo (strip not found)")
  90   endif()
  91   set(SG_SYSTEM_NAME ${CMAKE_SYSTEM_NAME})
  92
  93   if(${SG_SYSTEM_NAME} MATCHES "kFreeBSD")
  94     set(SG_SYSTEM_NAME GNU/kFreeBSD)
  95   endif()
  96
  97   set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
  98   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
  99     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/x86)
 100   endif()
 101   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 102        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 103     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/amd64)
 104   endif()
 105   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "armv7l")
 106     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/arm) # Default arm (soft-float ABI)
 107   endif()
 108
 109   add_custom_command(
 110     TARGET simgrid-java_jar POST_BUILD
 111     COMMENT "Add the native libs into simgrid.jar..."
 112     DEPENDS simgrid-java
 113             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 114             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 115             ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
 116
 117     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 118     COMMAND ${CMAKE_COMMAND} -E make_directory                                     ${JAVA_NATIVE_PATH}
 119     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}
 120     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}
 121     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}    ${JAVA_NATIVE_PATH}
 122
 123     # strip seems to fail on Mac on binaries that are already stripped.
 124     # It then spits: "symbols referenced by indirect symbol table entries that can't be stripped"
 125     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}      || true
 126     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO} || true
 127     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSURF_JAVA_SO}    || true
 128
 129     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 130     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 131
 132     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 133     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 134     )
 135   if(MINGW)
 136     find_library(WINPTHREAD_DLL
 137       NAME winpthread winpthread-1
 138       PATHS C:\\MinGW C:\\MinGW64 C:\\MinGW\\bin C:\\MinGW64\\bin
 139     )
 140     add_custom_command(
 141       TARGET simgrid-java_jar POST_BUILD
 142       COMMENT "Add the MinGW libs into simgrid.jar..."
 143       DEPENDS ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 144
 145       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 146       COMMAND ${CMAKE_COMMAND} -E make_directory          ${JAVA_NATIVE_PATH}
 147       COMMAND ${CMAKE_COMMAND} -E copy ${WINPTHREAD_DLL}  ${JAVA_NATIVE_PATH}
 148
 149       COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 150       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 151     )
 152   endif(MINGW)
 153 endif(enable_lib_in_jar)
 154
 155 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 156
 157 if(SWIG_FOUND)
 158   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 159   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 160
 161   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 162
 163   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 164   swig_link_libraries(surf-java simgrid)
 165 else()
 166   add_library(surf-java SHARED ${JSURF_C_SRC})
 167   target_link_libraries(surf-java simgrid)
 168 endif()
 169
 170 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 171 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 172
 173 add_dependencies(simgrid-java surf-java)
 174 add_dependencies(simgrid-java_jar surf-java)
 175