Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
c38cac7f3a5254c83e7d360dc4e88b8e5cc27b15
[simgrid.git] / tools / cmake / GCCFlags.cmake
1 ##
2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
3 ##
4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
5 ##
6 ##   These flags do break some classical CMake tests, so you don't
7 ##   want to do so before the very end of the configuration.
8 ## 
9 ##   Other compiler flags (C/C++ standard version) are tested and set
10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
11
12 set(warnCFLAGS "")
13 set(optCFLAGS "")
14 set(warnCXXFLAGS "")
15
16 if(enable_compile_warnings)
17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
18   if(CMAKE_COMPILER_IS_GNUCC AND (NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS "5.0")))
19     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
20   endif()
21   if(CMAKE_C_COMPILER_ID MATCHES "Clang|GCC")
22     set(warnCFLAGS "${warnCFLAGS} -Wno-format-nonliteral")
23   endif()
24   if(CMAKE_COMPILER_IS_GNUCC)
25     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
26   endif()
27
28   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
29   if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0")))
30     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
31   endif()
32   if(CMAKE_CXX_COMPILER_ID MATCHES "Clang|GCC")
33     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-format-nonliteral")
34   endif()
35   if(CMAKE_COMPILER_IS_GNUCXX)
36     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
37   endif()
38   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
39     # don't care about class that become struct, avoid issue of empty C structs
40     # size (coming from libunwind.h)
41     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
42   endif()
43
44   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
45     # ignore remark  #1418: external function definition with no prior declaration
46     # 3179: deprecated conversion of string literal to char* (should be const char*)
47     # 191: type qualifier is meaningless on cast type
48     set(warnCXXFLAGS "${warnCXXFLAGS} -wd1418 -wd191 -wd3179")
49   endif()
50
51   # the one specific to C but refused by C++
52   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes") 
53
54   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
55     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
56   endif()
57   if(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
58     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
59   endif()
60   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
61 endif()
62
63 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
64 if(enable_compile_warnings AND enable_debug)
65   set(warnCFLAGS "${warnCFLAGS} -Werror")
66   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
67 endif()
68
69 # Activate the warnings on #if FOOBAR when FOOBAR has no value
70 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
71 if(enable_maintainer_mode)
72   set(warnCFLAGS "${warnCFLAGS} -Wundef")
73   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
74 endif()
75
76 # Se the optimisation flags
77 # NOTE, we should CMAKE_BUILD_TYPE for this
78 if(enable_compile_optimizations)
79   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
80 else()
81   set(optCFLAGS "-O0 ")
82 endif()
83 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
84     AND (NOT enable_model-checking))
85   # This is redundant (already in -03):
86   set(optCFLAGS "${optCFLAGS} -finline-functions ")
87 endif()
88
89 # Do not leak the current directory into the binaries
90 if(CMAKE_COMPILER_IS_GNUCC)
91   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
92     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
93   if(RESULT EQUAL 0)
94     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
95   else()
96     message(WARNING "Failed to find relative source directory. Using \".\".")
97     set(RELATIVE_SOURCE_DIR ".")
98   endif()
99   set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}")
100 endif()
101
102 # Configure LTO
103 # NOTE, cmake 3.0 has a INTERPROCEDURAL_OPTIMIZATION target
104 #       property for this (http://www.cmake.org/cmake/help/v3.0/prop_tgt/INTERPROCEDURAL_OPTIMIZATION.html)
105 if(enable_lto) # User wants LTO. Try if we can do that
106   set(enable_lto OFF)
107   if(enable_compile_optimizations
108       AND CMAKE_COMPILER_IS_GNUCC
109       AND (NOT enable_model-checking))
110     # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
111     #   We are experiencing assertion failures even with 4.8 on MinGW.
112     #   Push the support forward: will see if 4.9 works when we test it.
113     #
114     # On Linux, we got the following with GCC 4.8.4 on Centos and Ubuntu
115     #    lto1: internal compiler error: in output_die, at dwarf2out.c:8478
116     #    Please submit a full bug report, with preprocessed source if appropriate.
117     # So instead, we push the support forward
118
119     if ( (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
120          AND (LINKER_VERSION VERSION_GREATER "2.22"))
121       set(enable_lto ON)
122     endif()
123   endif()
124   if(enable_lto)
125     message(STATUS "LTO seems usable.")
126   else()
127     if(NOT enable_compile_optimizations)
128       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
129     else() 
130       if(enable_model-checking)
131         message(STATUS "LTO disabled when compiling with model-checking.")
132       else()
133         message(STATUS "LTO does not seem usable -- try updating your build chain.")
134       endif() 
135     endif()
136   endif()
137 else()
138   message(STATUS "LTO disabled on the command line.")
139 endif()
140 if(enable_lto) # User wants LTO, and it seems usable. Go for it
141   set(optCFLAGS "${optCFLAGS} -flto ")
142   # See https://gcc.gnu.org/wiki/LinkTimeOptimizationFAQ#ar.2C_nm_and_ranlib:
143   # "Since version 4.9 gcc produces slim object files that only contain
144   # the intermediate representation. In order to handle archives of
145   # these objects you have to use the gcc wrappers:
146   # gcc-ar, gcc-nm and gcc-ranlib."
147   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
148       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
149     set (CMAKE_AR gcc-ar)
150     set (CMAKE_RANLIB gcc-ranlib)
151   endif()
152 endif()
153
154 if(enable_model-checking AND enable_compile_optimizations)
155   # Forget it, do not optimize the code (because it confuses the MC):
156   set(optCFLAGS "-O0 ")
157   # But you can still optimize this:
158   foreach(s
159       src/kernel/lmm/fair_bottleneck.cpp src/kernel/lmm/lagrange.cpp src/kernel/lmm/maxmin.cpp
160       src/xbt/mmalloc/mm.c
161       src/xbt/log.c src/xbt/xbt_log_appender_file.c
162       src/xbt/xbt_log_layout_format.c src/xbt/xbt_log_layout_simple.c
163       src/xbt/dict.cpp src/xbt/dict_elm.c src/xbt/dict_cursor.c
164       src/xbt/dynar.cpp
165       src/xbt/xbt_str.cpp src/xbt/snprintf.c
166       src/xbt/xbt_os_time.c src/xbt/xbt_os_thread.c
167       src/xbt/backtrace_linux.cpp
168       ${MC_SRC_BASE} ${MC_SRC})
169       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
170        if(CMAKE_COMPILER_IS_GNUCC)
171          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
172       endif()
173       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
174   endforeach()
175 endif()
176
177 if(NOT enable_debug)
178   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
179   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
180 endif()
181
182 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
183 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
184
185 # Try to make Mac a bit more complient to open source standards
186 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
187   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
188 endif()
189
190 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
191 if(enable_ns3)
192   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")  
193 endif()
194
195 set(TESH_OPTION "")
196 if(enable_coverage)
197   find_program(GCOV_PATH gcov)
198   if(GCOV_PATH)
199     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
200     set(COVERAGE_EXTRA_FLAGS "-l -p")
201     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
202     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
203     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
204     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
205     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
206     add_definitions(-fprofile-arcs -ftest-coverage)
207   endif()
208 endif()
209
210 if(enable_address_sanitizer)
211     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
212     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
213     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
214     set(TESH_OPTION --enable-sanitizers)
215     try_compile(HAVE_SANITIZE_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
216     try_compile(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
217       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
218 else()
219     set(HAVE_SANITIZE_ADDRESS FALSE CACHE INTERNAL "")
220     set(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
221 endif()
222
223 if(enable_thread_sanitizer)
224     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
225     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
226     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
227 endif()
228
229 if(enable_undefined_sanitizer)
230     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
231     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
232     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
233 endif()
234
235 if(NOT $ENV{CFLAGS} STREQUAL "")
236   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
237   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
238 endif()
239
240 if(NOT $ENV{CXXFLAGS} STREQUAL "")
241   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
242   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
243 endif()
244
245 if(NOT $ENV{LDFLAGS} STREQUAL "")
246   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
247   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
248 endif()
249
250 if(MINGW)
251   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
252   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
253   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
254   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
255   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
256   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
257   
258   # JNI searches for stdcalls
259   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
260   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
261   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
262   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
263   
264   # Specify the data model that we are using (yeah it may help Java)
265   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
266     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
267     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
268   else()
269     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
270     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
271   endif()  
272 endif()