examples/cpp/CMakeLists.txt

   1 # Regular examples: with only one source and tested with all factories by default
   2 #################################################################################
   3 ### Define the examples' specificities
   4
   5 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   6                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   7                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   8 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
   9 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  10                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  11                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  12                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  13
  14 set(_actor-stacksize_factories "^thread") # Threads ignore modifications of the stack size
  15
  16 # The maestro-set example only works for threads and when not using windows.
  17 set(_maestro-set_factories "thread")
  18 if(WIN32)
  19   set(_maestro-set_disable 1)
  20 endif()
  21
  22 if(SIMGRID_HAVE_MC)
  23   # These tests timeout with threads, maybe because of dwarf parsing? not sure
  24   foreach(example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  25      set(_${example}_factories "^thread") # Timeout
  26      add_dependencies(tests-mc s4u-${example})
  27   endforeach()
  28
  29   if(HAVE_C_STACK_CLEANER)
  30     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  31     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  32     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  33     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-on)
  34
  35     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  36     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  37     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  38     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-off)
  39   endif()
  40
  41   # Model-checking liveness
  42   if(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64)
  43     # liveness model-checking works only on 64bits (for now ...)
  44     set(_mc-bugged1-liveness_factories "ucontext")
  45     add_dependencies(tests-mc s4u-mc-bugged1-liveness)
  46     set(_mc-bugged2-liveness_factories "ucontext")
  47
  48     # This example never ends, disable it for now
  49     set(_mc-bugged2-liveness_disable 1)
  50
  51     ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
  52                                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  53                                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
  54                                                        ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
  55     IF(HAVE_C_STACK_CLEANER)
  56       add_dependencies(tests-mc s4u-mc-bugged1-liveness-stack-cleaner)
  57       # This test checks if the stack cleaner is making a difference:
  58       ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
  59                                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/
  60                                                      ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
  61     ENDIF()
  62   else()
  63     set(_mc-bugged1-liveness_disable 1)
  64     set(_mc-bugged2-liveness_disable 1)
  65   endif()
  66
  67   if(enable_coverage)
  68     foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
  69       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
  70     endforeach()
  71     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
  72   endif()
  73
  74 else()
  75   foreach (example mc-bugged1 mc-bugged2  mc-centralized-mutex mc-failing-assert mc-electric-fence
  76                    mc-bugged1-liveness mc-bugged2-liveness)
  77     set(_${example}_disable 1)
  78   endforeach()
  79 endif()
  80
  81 if (SIMGRID_HAVE_MC)
  82   # Hijack some regular tests to run them on top of the MC
  83   foreach (example synchro-barrier synchro-mutex synchro-semaphore)
  84     set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-mc-${example}.tesh)
  85
  86     ADD_TESH(s4u-mc-${example}
  87              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  88              --setenv libdir=${CMAKE_BINARY_DIR}/lib
  89              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  90              --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
  91              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  92              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-mc-${example}.tesh)
  93
  94     add_dependencies(tests-mc s4u-${example})
  95   endforeach()
  96
  97   # Dependency on the regular tests
  98   foreach(example mc-centralized-mutex)
  99     add_dependencies(tests-mc s4u-${example})
 100   endforeach()
 101 endif()
 102
 103
 104 if(NOT HAVE_GRAPHVIZ)
 105   set(_dag-from-dot_disable 1)
 106 endif()
 107
 108 if(NOT SIMGRID_HAVE_NS3)
 109   foreach (example network-ns3 network-ns3-wifi)
 110     set(_${example}_disable 1)
 111   endforeach()
 112 endif()
 113
 114 # Deal with each example
 115
 116 foreach (example activity-testany activity-waitany
 117                  actor-create actor-daemon actor-exiting actor-join actor-kill
 118                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
 119                  app-bittorrent app-chainsend app-token-ring
 120                  comm-pingpong comm-ready comm-serialize comm-suspend comm-testany comm-wait comm-waitany comm-waitall comm-waituntil
 121                  comm-dependent comm-host2host comm-failure comm-throttling
 122                  cloud-capping cloud-migration cloud-simple
 123                  dag-comm dag-from-dax dag-from-dot dag-failure dag-io dag-scheduling dag-simple
 124                  dht-chord dht-kademlia
 125                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
 126                  engine-filtering engine-run-partial
 127                  exec-async exec-basic exec-dvfs exec-remote exec-waitany exec-waitfor exec-dependent exec-unassigned
 128                  exec-ptask-multicore exec-ptask-multicore-latency exec-cpu-nonlinear exec-cpu-factors exec-failure exec-threads
 129                  maestro-set
 130                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-bugged2-liveness mc-centralized-mutex mc-electric-fence mc-failing-assert
 131                  network-ns3 network-ns3-wifi network-wifi
 132                  io-async io-priority io-degradation io-file-system io-file-remote io-disk-raw io-dependent
 133                  platform-failures platform-profile platform-properties
 134                  plugin-host-load plugin-link-load plugin-prodcons
 135                  replay-comm replay-io
 136                  routing-get-clusters
 137                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore
 138                  clusters-multicpu network-factors network-nonlinear)
 139
 140   # Use default source file unless specified otherwise
 141   if(NOT DEFINED _${example}_sources)
 142     set(_${example}_sources ${example}/s4u-${example}.cpp)
 143   endif()
 144
 145   if(NOT DEFINED _${example}_disable)
 146     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
 147     add_dependencies     (tests s4u-${example})
 148     add_dependencies     (s4u-${example} platf_cpp)
 149     target_link_libraries(s4u-${example} simgrid)
 150     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 151
 152     # Use default factories unless specified otherwise
 153     if(NOT DEFINED _${example}_factories)
 154       set(_${example}_factories "*")
 155     endif()
 156 #    message("Factories of ${example}: ${_${example}_factories}")
 157
 158     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 159                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 160                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 161                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 162                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 163                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 164                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 165   else()
 166     message(STATUS "Example ${example} disabled, thus not compiled.")
 167     unset(_${example}_disable)
 168   endif()
 169
 170   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 171   foreach(file ${_${example}_sources})
 172     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 173   endforeach()
 174
 175   unset(_${example}_factories)
 176   unset(_${example}_sources)
 177 endforeach()
 178
 179
 180 # Specific examples
 181 ###################
 182
 183 # MASTERWORKERS EXAMPLE
 184 foreach(variant fun class)
 185   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 186   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 187   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 188   add_dependencies(tests s4u-app-masterworkers-${variant})
 189
 190   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 191 endforeach()
 192 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 193
 194 # The tests the parallel variant of of DHTs
 195
 196 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 197   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 198   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 199   set(parallel-factories "^ucontext")
 200 else()
 201   set(parallel-factories "*")
 202 endif()
 203
 204 foreach(example app-bittorrent app-masterworkers
 205                 dht-chord dht-kademlia
 206                 )
 207   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 208                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 209                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 210                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 211                                              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 212 endforeach()
 213
 214 # Examples not accepting factories
 215 ##################################
 216
 217 foreach (example exec-ptask trace-categories trace-masterworkers trace-platform trace-process-migration
 218                  trace-host-user-variables trace-link-user-variables trace-route-user-variables)
 219   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 220   target_link_libraries(s4u-${example} simgrid)
 221   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 222   add_dependencies(tests s4u-${example})
 223
 224   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 225   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 226
 227   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 228                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 229                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 230                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 231                           ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 232 endforeach()
 233
 234 if (NOT enable_memcheck AND NOT WIN32)
 235   ADD_TESH(debug-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/comm-pingpong
 236                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 237                             ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh)
 238 endif()
 239
 240 # Add all extra files to the archive
 241 ####################################
 242 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp        PARENT_SCOPE)
 243 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh
 244                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh
 245                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh  PARENT_SCOPE)
 246 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 247                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 248                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 249                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 250                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-scheduling/Montage_25.xml
 251                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 252                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 253                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 254                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 255                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 256                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 257                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 258                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 259                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 260                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 261                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 262                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 263                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 264                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 265 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 266                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 267                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness
 268                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged2-liveness/promela_bugged2_liveness PARENT_SCOPE)
 269 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/simple_dax_with_cycle.xml
 270                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/smalldax.xml
 271                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag.dot
 272                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag_with_cycle.dot
 273                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 274                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 275                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 276                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)