configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal])
  48
  49 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  50 AC_FUNC_SNPRINTF
  51 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  52 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  53 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  54 # we don't use those:
  55 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
  56 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
  57
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_CONST
  61 AC_C_INLINE
  62 AC_TYPE_SIZE_T
  63
  64 ###################################
  65 ## SimGrid and GRAS specific checks
  66 ##
  67
  68 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  69 # Check architecture signature begin
  70 GRAS_ARCH
  71 # Check architecture signature end
  72 GRAS_CHECK_STRUCT_COMPACTION
  73
  74
  75 dnl ##
  76 dnl ##  CONTEXT IMPLEMENTATION
  77 dnl ##
  78
  79 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  80
  81 dnl #
  82 dnl #  1. determine possibilities
  83 dnl #
  84
  85 dnl #  check for MCSC method
  86 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  87
  88 dnl #  check for pthread method
  89 AC_CHECK_HEADERS([pthread.h])
  90 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  91
  92 dnl #
  93 dnl #  2. make a general decision
  94 dnl #
  95
  96 if test ".$mcsc" = .yes; then
  97    mcsc=yes
  98 elif test ".$pthread" = .yes; then
  99    pthread=yes
 100 else
 101     ac_header=windows.h
 102     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 103     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 104       windows_context=yes
 105     else
 106       AC_ERROR([no appropriate backend found])
 107     fi
 108 fi
 109
 110 dnl #
 111 dnl #  3. allow decision to be overridden by user
 112 dnl #
 113
 114 AC_MSG_CHECKING(what kind of backend should we use)
 115
 116 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 117
 118 AC_ARG_WITH(context,
 119   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 120   with_context=auto)
 121
 122 if test "x$with_context$mcsc" = "xucontextno" ; then
 123   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 124 fi
 125
 126 case $with_context in
 127  ucontext) ;;
 128  pthread) ;;
 129  windows) ;;
 130  auto) with_context=ucontext;;
 131  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 132 esac
 133
 134 if test "x$with_context" = "xucontext" ; then
 135   if test ".$mcsc" = .yes; then
 136     AC_MSG_RESULT(found working ucontext. Great!)
 137     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 138   else
 139     if test ".$windows_context" = .yes ; then
 140       AC_MSG_RESULT(use windows context portability layer.)
 141       with_context=windows
 142     else
 143       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 144       with_context=pthread
 145     fi
 146   fi
 147 fi
 148
 149 if test "x$with_context" = "xpthread"; then
 150   AC_CHECK_HEADERS([pthread.h])
 151   AC_CHECK_LIB(pthread,pthread_create,,
 152     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
 153   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 154   AC_MSG_RESULT(You have pthreads. Let's use them.)
 155 fi
 156
 157 dnl #
 158 dnl #  4. determine a few additional details
 159 dnl #
 160
 161 if test "x$with_context" = "xucontext" ; then
 162 dnl #  direction of stack grow
 163   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 164   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 165       PTH_STACK_GROWTH="down"
 166   else
 167       PTH_STACK_GROWTH="up"
 168   fi
 169   AC_SUBST(PTH_STACK_GROWTH)
 170
 171   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 172 fi
 173
 174 #########################################
 175 ## Check for libraries extra-dependencies
 176 ##
 177
 178 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 179 SIMGRID_DEP=""
 180 AC_SUBST([SIMGRID_DEP])
 181
 182 GRAS_DEP=""
 183 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 184 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 185
 186 AC_MSG_CHECKING(for extra dependencies of libgras)
 187 case $host_os in
 188   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
 189 esac
 190
 191 if test "x$GRAS_DEP" = x; then
 192    AC_MSG_RESULT(none)
 193 else
 194    AC_MSG_RESULT($GRAS_DEP)
 195 fi
 196 AC_SUBST([GRAS_DEP])
 197
 198 ##############################################
 199 ## Enhance maintainer mode and SUBST variables
 200 ## (must be placed after any compilation tests since our overprotective flags
 201 ##  let some tests fail)
 202
 203 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 204 # Next line is modified by sed when building gramine source tree
 205 gramine_mode=no
 206 if test x$gramine_mode = xyes
 207 then
 208   USE_MAINTAINER_MODE=no
 209 fi
 210 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 211
 212
 213 AM_MAINTAINER_MODE
 214 if test x$USE_MAINTAINER_MODE = xyes
 215 then
 216    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 217    enable_compile_warnings=yes
 218 fi
 219 SG_COMPILE_FLAGS
 220
 221 AC_SUBST(CFLAGS)
 222 AC_SUBST(CPPFLAGS)
 223 AC_SUBST(LDFLAGS)
 224 AC_SUBST([abs_builddir])
 225 AC_SUBST([abs_srcdir])
 226 AC_SUBST([abs_top_builddir])
 227 AC_SUBST([abs_top_srcdir])
 228
 229 #####################
 230 ## Check for programs
 231 ##
 232
 233 SG_CONFIGURE_PART(Check for programs...)
 234 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 235 WARNING="This file is generated, do not edit"
 236 AC_SUBST(WARNING)
 237
 238
 239 # Can we rebuild the parsers?
 240 # We really want flex and refuse other lex. So, the parser is portable and
 241 # does not induce extra lib dependency
 242 AC_PROG_FLEX(2.5.30)
 243
 244 # Can we rebuild the xml-lexers from the XML specification?
 245 # if not, simply touch the flex source files (which are distributed in
 246 #  tarballs even if generated by flexml) and hope for the best.
 247 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 248 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 249
 250 if test x$USE_MAINTAINER_MODE = xyes
 251 then
 252    # Check for doxygen when in maintainer mode since dist* targets fail
 253    # without it
 254    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 255    if test x$DOXYGEN = x ; then
 256      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 257    fi
 258 fi
 259
 260 # Can we extract really usable backtraces? (also need the popen function)
 261 AC_PATH_PROG(ADDR2LINE, addr2line)
 262 if test x$ADDR2LINE != x ; then
 263   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 264 fi
 265
 266 AC_SUBST(ac_configure_args)
 267 # Can we make status line about the compilation result?
 268 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 269 if test x$MD5SUM != xno ; then
 270   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 271                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 272 else
 273   build_version="no_md5sum_binary"
 274 fi
 275 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 276 AC_SUBST(build_id)
 277
 278 ###################
 279 ## Makes the output
 280 ##
 281
 282
 283 #
 284 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 285 #  src/amok/Makefile
 286
 287 SG_CONFIGURE_PART(Generating files...)
 288
 289 # Core of the libraries
 290
 291 AC_CONFIG_FILES([
 292   Makefile
 293   include/Makefile
 294   src/Makefile
 295   src/ucontext_stack.h
 296 ])
 297
 298 # Tools being embeeded in gramine (stub generator)
 299 AC_CONFIG_FILES([
 300   tools/Makefile
 301     tools/gras/Makefile
 302 ])
 303
 304 # GRAMINE_CUT_BEGIN
 305
 306 # Tools NOT being embeeded in gramine
 307 AC_CONFIG_FILES([
 308   tools/graspe-slave
 309 ],[
 310     for file in                                                 \
 311      tools/graspe-slave           tools/graspe-master           \
 312     ; do                                                        \
 313       test -e $file && chmod +x $file;                          \
 314     done
 315 ])
 316
 317 # Testsuite
 318
 319 AC_CONFIG_FILES([
 320   testsuite/Makefile
 321   testsuite/run_tests
 322   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 323 ],[
 324     for file in                                                 \
 325      testsuite/run_tests                                        \
 326      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 327     ; do                                                        \
 328       test -e $file && chmod +x $file;                          \
 329     done
 330 ])
 331
 332 # Documentation
 333 AC_CONFIG_FILES([
 334   doc/Makefile
 335   doc/Doxyfile
 336 ])
 337
 338 # Examples
 339
 340 AC_CONFIG_FILES([
 341   examples/Makefile
 342     examples/msg/Makefile           examples/msg/run_msg_test
 343     examples/simdag/Makefile        examples/simdag/test_simdag
 344     examples/gras/Makefile
 345       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 346       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 347       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 348       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 349       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 350       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 351       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 352       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 353
 354       examples/gras/p2p/Makefile
 355       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 356       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 357
 358     examples/amok/Makefile
 359       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 360       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 361 ],[
 362     for file in                                                 \
 363      \
 364      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 365      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 366      \
 367      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 368      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 369      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 370      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 371      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 372      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 373      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 374      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 375      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 376      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 377      examples/msg/run_msg_test                                  \
 378      examples/simdag/test_simdag                                \
 379     ; do                                                        \
 380       test -e $file && chmod +x $file;                          \
 381     done
 382 ])
 383
 384 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 385 #    examples/gras/pastry/test_sg
 386
 387
 388
 389 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 390 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 391
 392
 393 # GRAMINE_CUT_END
 394
 395 AC_OUTPUT
 396
 397 echo "
 398
 399 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 400
 401         Compiler:        ${CC} (version: ${GCC_VERSION})
 402
 403         CFlags:          ${CFLAGS}
 404         CPPFlags:        ${CPPFLAGS}
 405         LDFlags:         ${LDFLAGS}
 406
 407         Context backend: ${with_context}
 408 "
 409
 410 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 411   echo "WARNING:"
 412   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 413   echo "WARNING: You may want to enable this by specifying:"
 414   echo "WARNING:"
 415   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 416   echo "WARNING:"
 417 fi
 418 echo $build_id > stamp.configure
 419
 420 exit 0;