tools/cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3 ###############################
   4 # Declare the library content #
   5 ###############################
   6
   7 # Actually declare our libraries
   8 add_library(simgrid SHARED ${simgrid_sources})
   9 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  10
  11 if(enable_ust)
  12   ADD_DEPENDENCIES(simgrid simgrid_ust)
  13 endif()
  14
  15 add_dependencies(simgrid maintainer_files)
  16
  17 if(enable_model-checking)
  18   add_executable(simgrid-mc ${MC_SIMGRID_MC_SRC})
  19   target_link_libraries(simgrid-mc simgrid)
  20   set_target_properties(simgrid-mc
  21     PROPERTIES
  22       RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
  23 endif()
  24
  25 # Compute the dependencies of SimGrid
  26 #####################################
  27 set(SIMGRID_DEP "-lm")
  28 if (HAVE_BOOST_CONTEXT)
  29   set(SIMGRID_DEP "${SIMGRID_DEP} ${Boost_CONTEXT_LIBRARY}")
  30 endif()
  31
  32 if(HAVE_PTHREAD AND ${CONTEXT_THREADS} AND NOT APPLE)
  33   # Clang on recent Mac OS X is not happy about -pthread.
  34   SET(SIMGRID_DEP "${SIMGRID_DEP} -pthread")
  35 endif()
  36
  37 if(HAVE_LUA)
  38   ADD_CUSTOM_TARGET(link_simgrid_lua ALL
  39     DEPENDS     simgrid
  40     ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
  41     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
  42     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
  43     )
  44   add_custom_command(
  45     OUTPUT      ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
  46     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
  47     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
  48     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
  49     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/lua/
  50     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} #for test
  51
  52     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
  53     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/msg/masterslave/
  54     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} #for test
  55
  56     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
  57     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/simdag/
  58     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} #for test
  59     )
  60   SET(SIMGRID_DEP "${SIMGRID_DEP} ${LUA_LIBRARY} -ldl")
  61 endif()
  62
  63 if(HAVE_GRAPHVIZ)
  64   if(HAVE_CGRAPH_LIB)
  65     SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
  66   else()
  67     if(HAVE_AGRAPH_LIB)
  68       SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
  69     endif()
  70   endif()
  71 endif()
  72
  73 if(HAVE_LIBSIGC++)
  74   SET(SIMGRID_DEP "${SIMGRID_DEP} -lsigc-2.0")
  75   add_definitions(-DLIBSIGC)
  76   set(SIMGRID_HAVE_LIBSIG 1)
  77 endif()
  78
  79 if(HAVE_MC)
  80   # The availability of libunwind was checked in CompleteInFiles.cmake
  81   #   (that includes FindLibunwind.cmake), so simply load it now.
  82
  83   SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind -lunwind-ptrace")
  84
  85   # Same for libdw
  86   SET(SIMGRID_DEP "${SIMGRID_DEP} -ldw")
  87   # This supposes that the host machine is either an AMD or a X86.
  88   # This is deeply wrong, and should be fixed by manually loading -lunwind-PLAT (FIXME)
  89   if(PROCESSOR_x86_64)
  90     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86_64")
  91   else()
  92     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86")
  93   endif()
  94 endif()
  95
  96 if(MMALLOC_WANT_OVERRIDE_LEGACY AND HAVE_GNU_LD)
  97   SET(SIMGRID_DEP "${SIMGRID_DEP} ${DL_LIBRARY}")
  98 endif()
  99
 100 if(HAVE_NS3)
 101   SET(SIMGRID_DEP "${SIMGRID_DEP} -lns${NS3_VERSION}-core -lns${NS3_VERSION}-csma -lns${NS3_VERSION}-point-to-point -lns${NS3_VERSION}-internet -lns${NS3_VERSION}-applications")
 102 endif()
 103
 104 if(HAVE_POSIX_GETTIME)
 105   SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
 106 endif()
 107
 108 if(HAVE_BACKTRACE_IN_LIBEXECINFO)
 109   SET(SIMGRID_DEP "${SIMGRID_DEP} -lexecinfo")
 110 endif(HAVE_BACKTRACE_IN_LIBEXECINFO)
 111
 112 # Dependencies from USR
 113 ###################################
 114 if(enable_ust)
 115   set(SIMGRID_DEP "${SIMGRID_DEP} -llttng-ust")
 116 endif()
 117
 118 # Compute the dependencies of SMPI
 119 ##################################
 120 if(enable_smpi AND APPLE)
 121   set(SIMGRID_DEP "${SIMGRID_DEP} -Wl,-U -Wl,_smpi_simulated_main")
 122 endif()
 123
 124 target_link_libraries(simgrid   ${SIMGRID_DEP})
 125
 126 # Dependencies from maintainer mode
 127 ###################################
 128 if(enable_maintainer_mode AND PYTHON_EXE)
 129   add_dependencies(simgrid simcalls_generated_src)
 130 endif()
 131 if(enable_maintainer_mode AND BISON_EXE AND LEX_EXE)
 132   add_dependencies(simgrid automaton_generated_src)
 133 endif()