Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Document the introduction of RPC into GRAS, and the relevant API change
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.0.2-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15
16 AM_INIT_AUTOMAKE(gnu)
17 AC_CONFIG_MACRO_DIR(acmacro) 
18 ACLOCAL="$ACLOCAL -I acmacro"
19 AC_PROG_LIBTOOL
20
21 ###############
22 ## System checks
23 ##
24 SG_CONFIGURE_PART(System checks...)
25 AC_PROG_CC(xlC gcc cc)
26 AM_SANITY_CHECK
27 AC_PROG_MAKE_SET
28 AC_CHECK_PRINTF_NULL
29 AC_CHECK_VA_COPY
30
31 # Checks for header files.
32 AC_HEADER_STDC
33 AC_HEADER_TIME
34 AC_CHECK_HEADERS([sys/socket.h \
35                   sys/stat.h \
36                   windows.h winsock.h winsock2.h \
37                   sys/time.h \
38                   errno.h unistd.h \
39                   execinfo.h])
40 AC_CHECK_FUNCS([gettimeofday usleep \
41                 getdtablesize \
42                 sysconf\
43                 readv])
44                 
45 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
46 AC_FUNC_SNPRINTF
47 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
48 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
49 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
50 # we don't use those:
51 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
52 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
53
54
55 # Checks for typedefs, structures, and compiler characteristics.
56 AC_C_CONST
57 AC_C_INLINE
58 AC_TYPE_SIZE_T
59
60 ###################################
61 ## SimGrid and GRAS specific checks
62 ##
63
64 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
65 # Check architecture signature begin
66 GRAS_ARCH
67 # Check architecture signature end
68 GRAS_CHECK_STRUCT_COMPACTION
69
70
71 dnl ##
72 dnl ##  CONTEXT IMPLEMENTATION
73 dnl ##
74
75 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
76
77 dnl #
78 dnl #  1. determine possibilities
79 dnl #
80
81 dnl #  check for MCSC method
82 AC_MSG_CHECKING(on top of what can we build the contexts)
83 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
84 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
85 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
86
87 dnl #  check for pthread method
88 AC_CHECK_HEADERS([pthread.h])
89 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
90
91 dnl #
92 dnl #  2. make a general decision
93 dnl #
94
95 if test ".$mcsc" = .yes; then
96    mcsc=yes
97 elif test ".$pthread" = .yes; then
98    pthread=yes
99 else
100     ac_header=windows.h
101     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
102     if test `eval echo '${'$as_ac_Header'}'` = yes; then
103       windows_context=yes
104     else
105       AC_ERROR([no appropriate backend found])
106     fi
107 fi
108
109 dnl #
110 dnl #  3. allow decision to be overridden by user
111 dnl #
112
113 AC_MSG_CHECKING(what kind of backend should we use)
114 AC_ARG_WITH(context,
115   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
116   with_context=auto)
117 case $with_context in
118  ucontext) ;;
119  pthread) ;;
120  windows) ;;
121  auto) with_context=ucontext;;
122  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
123 esac
124
125 if test "x$with_context" = "xucontext" ; then
126   if test ".$mcsc" = .yes; then
127     AC_MSG_RESULT(found working ucontext. Great!)
128     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
129   else
130     if test ".$windows_context" = .yes ; then
131       AC_MSG_RESULT(use windows context portability layer.)
132       with_context=windows
133     else
134       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
135       with_context=pthread
136     fi
137   fi
138 fi
139
140 if test "x$with_context" = "xpthread"; then
141   AC_CHECK_HEADERS([pthread.h])
142   AC_CHECK_LIB(pthread,pthread_create,,
143     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
144   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
145   AC_MSG_RESULT(You have pthreads. Let's use them.)
146 fi
147
148 dnl #
149 dnl #  4. determine a few additional details
150 dnl #
151
152 if test "x$with_context" = "xucontext" ; then
153 dnl #  direction of stack grow
154   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
155   if test ".$ac_cv_check_stackgrowth" = ".down"; then
156       PTH_STACK_GROWTH="down"
157   else
158       PTH_STACK_GROWTH="up"
159   fi
160   AC_SUBST(PTH_STACK_GROWTH)
161   
162   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
163 fi
164
165 #########################################
166 ## Check for libraries extra-dependencies
167 ##
168
169 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
170 SIMGRID_DEP=""
171 AC_SUBST([SIMGRID_DEP])
172
173 GRAS_DEP=""
174 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
175 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
176
177 AC_MSG_CHECKING(for extra dependencies of libgras)
178 case $host_os in
179   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
180 esac
181            
182 if test "x$GRAS_DEP" = x; then 
183    AC_MSG_RESULT(none)
184 else
185    AC_MSG_RESULT($GRAS_DEP)
186 fi
187 AC_SUBST([GRAS_DEP])
188
189 ##############################################
190 ## Enhance maintainer mode and SUBST variables
191 ## (must be placed after any compilation tests since our overprotective flags
192 ##  let some tests fail)
193
194 AM_MAINTAINER_MODE
195 if test x$USE_MAINTAINER_MODE = xyes 
196 then
197    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
198    enable_compile_warnings=yes   
199 fi
200 SG_COMPILE_FLAGS
201
202 AC_SUBST(CFLAGS)
203 AC_SUBST(CPPFLAGS)
204 AC_SUBST(LDFLAGS)
205
206 #####################
207 ## Check for programs
208 ##
209
210 SG_CONFIGURE_PART(Check for programs...)
211 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
212 WARNING="This file is generated, do not edit"
213 AC_SUBST(WARNING)
214
215 # Can we rebuild the parsers?
216 # We really want flex and refuse other lex. So, the parser is portable and
217 # does not induce extra lib dependency
218 AC_PROG_FLEX(2.5.30)
219                 
220 # Can we rebuild the xml-lexers from the XML specification?
221 # if not, simply touch the flex source files (which are distributed in
222 #  tarballs even if generated by flexml) and hope for the best.
223 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
224 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
225
226 if test x$USE_MAINTAINER_MODE = xyes 
227 then
228    # Check for doxygen when in maintainer mode since dist* targets fail
229    # without it
230    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
231    if test x$DOXYGEN = x ; then 
232      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
233    fi
234 fi
235
236 ###################
237 ## Makes the output
238 ##
239
240
241 #
242 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
243 #  src/amok/Makefile
244
245 SG_CONFIGURE_PART(Generating files...)
246 AC_CONFIG_FILES([
247   Makefile
248   include/Makefile
249   src/Makefile
250   src/ucontext_stack.h
251   examples/Makefile 
252     examples/msg/Makefile           examples/msg/run_msg_test
253     examples/gras/Makefile 
254       examples/gras/ping/Makefile   examples/gras/ping/test_sg  examples/gras/ping/test_rl
255       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg   examples/gras/rpc/test_rl
256       examples/gras/timer/Makefile  examples/gras/timer/test_sg examples/gras/timer/test_rl
257       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
258       examples/gras/tokenS/Makefile examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl
259       examples/gras/mmrpc/Makefile examples/gras/mmrpc/test_sg examples/gras/mmrpc/test_rl
260
261       examples/gras/p2p/Makefile
262       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
263       
264     examples/amok/Makefile       
265       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
266   doc/Makefile
267     doc/Doxyfile
268   tools/graspe-slave            tools/Makefile
269     tools/gras/Makefile
270   testsuite/Makefile
271   testsuite/run_tests    
272   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
273 ],[
274     for file in                                                 \
275      testsuite/run_tests                                        \
276      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
277      tools/graspe-slave           tools/graspe-master           \
278      \
279      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
280      \
281      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
282      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl    \
283      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
284      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
285      examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl  \
286      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
287      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
288      examples/msg/run_msg_test                                  \
289     ; do                                                        \
290       test -e $file && chmod +x $file;                          \
291     done
292 ])
293
294
295 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
296 #    examples/gras/pastry/test_sg   
297
298
299
300 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
301 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
302
303
304
305 AC_OUTPUT
306
307 echo "
308
309 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
310
311         Compiler:        ${CC} (version: ${GCC_VERSION})
312         
313         CFlags:          ${CFLAGS}
314         LDFlags:         ${LDFLAGS}
315
316         Context backend: ${with_context}
317 "
318
319 exit 0;