tools/cmake/Tests.cmake

   1 IF(enable_smpi AND NOT WIN32)
   2   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicc)
   3   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicxx)
   4   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpiff)
   5   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpif90)
   6   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpirun)
   7 ENDIF()
   8
   9 SET(TESH_OPTION "--ignore-jenkins")
  10 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
  11
  12 IF(enable_memcheck)
  13   INCLUDE(FindValgrind)
  14
  15   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  16     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  17     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  18
  19     set(TESH_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  20     set(TESH_WRAPPER ${TESH_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  21     if(enable_memcheck_xml)
  22       SET(TESH_WRAPPER ${TESH_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  23     endif()
  24
  25 #    message(STATUS "tesh wrapper: ${TESH_WRAPPER}")
  26
  27     mark_as_advanced(TESH_WRAPPER)
  28   else()
  29     set(enable_memcheck false)
  30     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  31   endif()
  32 ENDIF()
  33 SET(TESH_WRAPPER_UNBOXED "${TESH_WRAPPER}")
  34 SEPARATE_ARGUMENTS(TESH_WRAPPER_UNBOXED)
  35
  36 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  37 # default to posix for these tests if futexes are not supported
  38 IF(NOT HAVE_FUTEX_H)
  39   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  40 ENDIF()
  41
  42 MACRO(ADD_TESH NAME)
  43   SET(ARGT ${ARGV})
  44   LIST(REMOVE_AT ARGT 0)
  45   IF(WIN32)
  46     STRING(REPLACE "§" "\;" ARGT "${ARGT}")
  47   ENDIF()
  48   if(TESH_WRAPPER)
  49     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${TESH_WRAPPER}" ${TESH_OPTION} ${ARGT})
  50   else()
  51     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  52   endif()
  53 ENDMACRO()
  54
  55 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  56   SET(ARGR ${ARGV})
  57   LIST(REMOVE_AT ARGR 0) # remove name
  58   FOREACH(I ${FACTORIES}) # remove all factories
  59     LIST(REMOVE_AT ARGR 0)
  60   ENDFOREACH()
  61   FOREACH(FACTORY ${FACTORIES})
  62     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  63         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  64         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  65         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  66       ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  67     ENDIF()
  68   ENDFOREACH()
  69 ENDMACRO()
  70
  71 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
  72   SET(ARGR ${ARGV})
  73   LIST(REMOVE_AT ARGR 0) # remove name
  74   FOREACH(I ${FACTORIES}) # remove all factories
  75     LIST(REMOVE_AT ARGR 0)
  76   ENDFOREACH()
  77   FOREACH(FACTORY ${FACTORIES})
  78     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  79         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  80         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  81         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  82       set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
  83     endif()
  84   ENDFOREACH()
  85 ENDMACRO()
  86
  87 IF(enable_java)
  88   IF(WIN32)
  89     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/\;${CMAKE_BINARY_DIR}/teshsuite/java/\;${SIMGRID_JAR}")
  90     STRING(REPLACE "\;" "§" TESH_CLASSPATH "${TESH_CLASSPATH}")
  91   ELSE()
  92     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/:${CMAKE_BINARY_DIR}/teshsuite/java/:${SIMGRID_JAR}")
  93   ENDIF()
  94 ENDIF()
  95
  96 # New tests should use the Catch Framework
  97 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
  98                 src/kernel/resource/profile/trace_mgr_test.cpp
  99                 src/xbt/config_test.cpp
 100                 src/xbt/dict_test.cpp
 101                 src/xbt/dynar_test.cpp
 102                 src/xbt/xbt_str_test.cpp)
 103 if (SIMGRID_HAVE_MC)
 104   set(UNIT_TESTS ${UNIT_TESTS} src/mc/sosp/mc_snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 105 else()
 106   set(EXTRA_DIST ${EXTRA_DIST} src/mc/sosp/mc_snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 107 endif()
 108
 109 add_executable       (unit-tests ${UNIT_TESTS})
 110 target_link_libraries(unit-tests simgrid)
 111 ADD_TEST(unit-tests ${CMAKE_BINARY_DIR}/unit-tests)
 112 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 113 add_dependencies(tests unit-tests)
 114 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 115
 116 unset(UNIT_TESTS)