configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal\
  48                 getline])
  49
  50 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  51 AC_FUNC_SNPRINTF
  52 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  53 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  54 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_TYPE_SIZE_T
  60
  61 ###################################
  62 ## SimGrid and GRAS specific checks
  63 ##
  64
  65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  66 # Check architecture signature begin
  67 GRAS_ARCH
  68 # Check architecture signature end
  69 GRAS_CHECK_STRUCT_COMPACTION
  70
  71
  72 dnl ##
  73 dnl ##  CONTEXT IMPLEMENTATION
  74 dnl ##
  75
  76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  77
  78 dnl #
  79 dnl #  1. determine possibilities
  80 dnl #
  81
  82 dnl #  check for MCSC method
  83 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  84
  85 dnl #  check for pthread method
  86 AC_CHECK_HEADERS([pthread.h])
  87 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  88
  89 dnl #
  90 dnl #  2. make a general decision
  91 dnl #
  92
  93 if test ".$mcsc" = .yes; then
  94    mcsc=yes
  95 elif test ".$pthread" = .yes; then
  96    pthread=yes
  97 else
  98     ac_header=windows.h
  99     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 100     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 101       windows_context=yes
 102     else
 103       AC_ERROR([no appropriate backend found])
 104     fi
 105 fi
 106
 107 dnl #
 108 dnl #  3. allow decision to be overridden by user
 109 dnl #
 110
 111 AC_MSG_CHECKING(what kind of backend should we use)
 112
 113 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 114 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 115
 116 AC_ARG_WITH(context,
 117   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 118   with_context=auto)
 119
 120 if test "x$with_context$mcsc" = "xucontextno" ; then
 121   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 122 fi
 123
 124 case $with_context in
 125  ucontext) ;;
 126  pthread) ;;
 127  pthreads) ;;
 128  windows) ;;
 129  auto) with_context=ucontext;;
 130  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 131 esac
 132
 133 if test "x$with_context" = "xucontext" ; then
 134   if test ".$mcsc" = .yes; then
 135     AC_MSG_RESULT(found working ucontext. Great!)
 136     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 137   else
 138     if test ".$windows_context" = .yes ; then
 139       AC_MSG_RESULT(use windows context portability layer.)
 140       with_context=windows
 141     else
 142       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 143       with_context=pthread
 144     fi
 145   fi
 146 fi
 147
 148 if test "x$with_context" = "xpthreads"; then
 149   with_context=pthread
 150 fi
 151 if test "x$with_context" = "xpthread"; then
 152   AC_CHECK_HEADERS([pthread.h])
 153   AC_CHECK_LIB(pthread,pthread_create,,
 154     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 155   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 156   AC_MSG_RESULT(You have pthreads. Let's use them.)
 157 fi
 158
 159 dnl #
 160 dnl #  4. determine a few additional details
 161 dnl #
 162
 163 if test "x$with_context" = "xucontext" ; then
 164 dnl #  direction of stack grow
 165   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 166   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 167       PTH_STACK_GROWTH="down"
 168   else
 169       PTH_STACK_GROWTH="up"
 170   fi
 171   AC_SUBST(PTH_STACK_GROWTH)
 172
 173   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 174 fi
 175
 176
 177 #########################################
 178 ## Build optional modules (simix)
 179 ##
 180 SG_CONFIGURE_PART(Optional modules)
 181 AC_ARG_ENABLE(simix,
 182   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
 183   enable_simix=$enableval,enable_simix=no)
 184 if test "x$enable_simix" = "xyes" ; then
 185   AC_MSG_RESULT(***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****)
 186   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
 187 else
 188   AC_MSG_RESULT(Eventually you will come to SimIX.)
 189 fi
 190 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
 191
 192 #########################################
 193 ## Build optional modules (gtnets)
 194 ##
 195 AC_ARG_WITH(gtnets,
 196   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 197   gtnets_path="$withval",gtnets_path="NO")
 198 if test "x$gtnets_path" = "xNO" ; then
 199   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 200 else
 201   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****)
 202   AC_DEFINE(USE_GTNETS, 1, [Indicates whether we should use GTNetS or not])
 203   if ! test -e $gtnets_path ; then
 204     AC_MSG_ERROR(Provided path to GTNetS include files ($gtnets_path) do not exist!)
 205   fi
 206   GTNETS_CFLAGS=-I$gtnets_path/include
 207   AC_SUBST([GTNETS_CFLAGS])
 208   GTNETS_LDFLAGS=-L$gtnets_path/lib
 209   AC_SUBST([GTNETS_LDFLAGS])
 210 fi
 211 AM_CONDITIONAL(USE_GTNETS,test "x$gtnets_path" != xNO)
 212
 213 #########################################
 214 ## Check for libraries extra-dependencies
 215 ##
 216
 217 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 218
 219 SIMGRID_DEP=""
 220 GRAS_DEP=""
 221 if test xpthread=xyes ; then
 222   # if the pthreads are usable
 223   if test "x$with_context" = "xpthread" ; then
 224     # if we use them to implement the xbt_context
 225     SIMGRID_DEP="-lpthread"
 226   fi
 227   # we need them in any case for the gras lib (which is multithreaded)
 228   GRAS_DEP="-lpthread"
 229 fi
 230
 231 AC_MSG_CHECKING(for csdp)
 232 sdp=no
 233 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 234 if test "x$csdp" = xyes; then
 235   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 236   AC_MSG_RESULT(Found working sdp library.)
 237   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 238 else
 239   AC_MSG_RESULT(Could not find any working sdp library.)
 240 fi;
 241 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 242
 243 AC_SUBST([SIMGRID_DEP])
 244
 245 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 246 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 247
 248 AC_MSG_CHECKING(for extra dependencies of libgras)
 249 case $host_os in
 250   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 251             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 252             AC_DEFINE(CONTEXT_THREADS,1);;
 253 esac
 254
 255 if test "x$GRAS_DEP" = x; then
 256    AC_MSG_RESULT(none)
 257 else
 258    AC_MSG_RESULT($GRAS_DEP)
 259 fi
 260 AC_SUBST([GRAS_DEP])
 261
 262
 263 ##############################################
 264 ## Enhance maintainer mode and SUBST variables
 265 ## (must be placed after any compilation tests since our overprotective flags
 266 ##  let some tests fail)
 267
 268 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 269 # Next line is modified by sed when building gramine source tree
 270 gramine_mode=no
 271 if test x$gramine_mode = xyes
 272 then
 273   USE_MAINTAINER_MODE=no
 274 fi
 275 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 276
 277
 278 AM_MAINTAINER_MODE
 279 if test x$USE_MAINTAINER_MODE = xyes
 280 then
 281    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 282    enable_compile_warnings=yes
 283 fi
 284 SG_COMPILE_FLAGS
 285
 286 AC_SUBST(CFLAGS)
 287 AC_SUBST(CPPFLAGS)
 288 AC_SUBST(LDFLAGS)
 289 AC_SUBST([abs_builddir])
 290 AC_SUBST([abs_srcdir])
 291 AC_SUBST([abs_top_builddir])
 292 AC_SUBST([abs_top_srcdir])
 293
 294 #####################
 295 ## Check for programs
 296 ##
 297
 298 SG_CONFIGURE_PART(Check for programs...)
 299 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 300 WARNING="This file is generated, do not edit"
 301 AC_SUBST(WARNING)
 302
 303
 304 # Can we rebuild the parsers?
 305 # We really want flex and refuse other lex. So, the parser is portable and
 306 # does not induce extra lib dependency
 307 AC_PROG_FLEX(2.5.30)
 308
 309 # Can we rebuild the xml-lexers from the XML specification?
 310 # if not, simply touch the flex source files (which are distributed in
 311 #  tarballs even if generated by flexml) and hope for the best.
 312 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 313 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 314
 315 if test x$USE_MAINTAINER_MODE = xyes
 316 then
 317    # Check for doxygen when in maintainer mode since dist* targets fail
 318    # without it
 319    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 320    if test x$DOXYGEN = x ; then
 321      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 322    fi
 323 fi
 324
 325 # Can we extract really usable backtraces? (also need the popen function)
 326 AC_PATH_PROG(ADDR2LINE, addr2line)
 327 if test x$ADDR2LINE != x ; then
 328   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 329 fi
 330
 331 AC_SUBST(ac_configure_args)
 332 # Can we make status line about the compilation result?
 333 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 334 if test x$MD5SUM != xno ; then
 335   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 336                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 337 else
 338   build_version="no_md5sum_binary"
 339 fi
 340 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 341 AC_SUBST(build_id)
 342
 343 ###################
 344 ## Makes the output
 345 ##
 346
 347
 348 #
 349 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 350 #  src/amok/Makefile
 351
 352 SG_CONFIGURE_PART(Generating files...)
 353
 354 # Core of the libraries
 355
 356 AC_CONFIG_FILES([
 357   Makefile
 358   include/Makefile
 359   src/Makefile
 360   src/ucontext_stack.h
 361 ])
 362
 363 # Tools being embeeded in gramine (stub generator)
 364 AC_CONFIG_FILES([
 365   tools/Makefile
 366     tools/gras/Makefile
 367     tools/tesh/Makefile
 368 ])
 369
 370
 371 # GRAMINE_CUT_BEGIN
 372
 373 # Tools NOT being embeeded in gramine
 374 AC_CONFIG_FILES([
 375   tools/graspe-slave
 376 ],[
 377     for file in                                                 \
 378      tools/graspe-slave           tools/graspe-master           \
 379     ; do                                                        \
 380       test -e $file && chmod +x $file;                          \
 381     done
 382 ])
 383
 384 # Testsuite
 385
 386 AC_CONFIG_FILES([
 387   testsuite/Makefile
 388   testsuite/run_tests
 389   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 390 ],[
 391     for file in                                                 \
 392      testsuite/run_tests                                        \
 393      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 394     ; do                                                        \
 395       test -e $file && chmod +x $file;                          \
 396     done
 397 ])
 398
 399 # Documentation
 400 AC_CONFIG_FILES([
 401   doc/Makefile
 402   doc/Doxyfile
 403 ])
 404
 405 # Examples
 406
 407 AC_CONFIG_FILES([
 408   examples/Makefile
 409     examples/msg/Makefile
 410     examples/simdag/Makefile        examples/simdag/test_simdag
 411     examples/gras/Makefile
 412       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 413       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 414       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 415       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 416       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 417       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 418       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 419       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 420
 421       examples/gras/p2p/Makefile
 422       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 423       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 424
 425     examples/amok/Makefile
 426       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 427       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 428 ],[
 429     for file in                                                 \
 430      \
 431      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 432      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 433      \
 434      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 435      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 436      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 437      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 438      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 439      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 440      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 441      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 442      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 443      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 444      examples/msg/run_msg_test                                  \
 445      examples/simdag/test_simdag                                \
 446     ; do                                                        \
 447       test -e $file && chmod +x $file;                          \
 448     done
 449 ])
 450
 451 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 452 #    examples/gras/pastry/test_sg
 453
 454
 455
 456 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 457 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 458
 459
 460 # GRAMINE_CUT_END
 461
 462 AC_OUTPUT
 463
 464 echo "
 465
 466 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 467
 468         Compiler:        ${CC} (version: ${GCC_VERSION})
 469
 470         CFlags:          ${CFLAGS}
 471         CPPFlags:        ${CPPFLAGS}
 472         LDFlags:         ${LDFLAGS}
 473
 474         Context backend: ${with_context}
 475 "
 476
 477 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 478   echo "WARNING:"
 479   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 480   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 481   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 482   echo "WARNING:"
 483   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 484   echo "WARNING:"
 485 fi
 486 echo $build_id > stamp.configure
 487
 488 exit 0;