Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
First try at instrumenting the action replay tool.
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.4.1],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision: 6998 $)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AC_PROG_CXX
21 AM_PROG_GCJ
22
23 dnl ########### Addition for mmalloc (to be integrated into Cmake tools)
24 AC_FUNC_MMAP
25 AC_CHECK_HEADERS(limits.h stddef.h unistd.h)
26
27 BFD_NEED_DECLARATION(sbrk)
28 BFD_NEED_DECLARATION(getpagesize)
29 dnl ########### end of addition for mmalloc
30
31 AM_INIT_AUTOMAKE([gnu -Wno-portability])
32 AC_CONFIG_MACRO_DIR(acmacro) 
33 ACLOCAL="$ACLOCAL -I acmacro"
34
35 dnl Next few lines is a hack to prevent libtool checking for F77
36 m4_undefine([AC_PROG_F77])
37 m4_defun([AC_PROG_F77],[])
38
39 dnl We do build a proper DLL when using win32
40 AC_LIBTOOL_WIN32_DLL
41 AC_PROG_LIBTOOL
42
43 SIMGRID_DEP=""
44 SMPI_DEP=""
45 GRAS_DEP=""
46
47
48 ###############
49 ## SVN version check
50 ##
51 if test -e .svn && echo $VERSION | grep -q svn; then
52   VERSION="$VERSION-r`svnversion`"
53   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
54   PACKAGE_STRING="$PACKAGE_STRING r`svnversion`"
55 else if test -e .git && echo $VERSION | grep -q svn; then
56   ver=`git log --oneline -1 | sed 's| .*||'`
57   VERSION=`echo "$VERSION-r$ver" | sed 's/svn/git/'`
58   PACKAGE_VERSION=`echo "$PACKAGE_VERSION-r$ver" | sed 's/svn/git/'`
59   PACKAGE_STRING=`echo "$PACKAGE_STRING r$ver" | sed 's/svn/git/'`
60 fi fi
61
62 ###############
63 ## System checks
64 ##
65 SG_CONFIGURE_PART([System checks...])
66 AC_PROG_CC(xlC gcc cc)
67 AM_SANITY_CHECK
68 AC_PROG_MAKE_SET
69 AC_CHECK_PRINTF_NULL
70 AC_CHECK_VA_COPY
71
72 # Checks for header files.
73 AC_HEADER_STDC
74 AC_HEADER_TIME
75 AC_CHECK_HEADERS([sys/socket.h \
76                   sys/stat.h \
77                   windows.h winsock.h winsock2.h \
78                   sys/time.h \
79                   errno.h unistd.h \
80                   execinfo.h\
81                   signal.h ])
82 AC_CHECK_FUNCS([gettimeofday usleep \
83                 getdtablesize \
84                 sysconf\
85                 readv\
86                 popen\
87                 signal])           
88   
89 dnl GNU systems before POSIX2008 need the _GNU_SOURCE definition to find getline (and simgrid does pass this)             
90 AC_MSG_CHECKING(a usable getline)
91 AC_LINK_IFELSE([
92     #define _GNU_SOURCE
93     #include <stdio.h>
94     int main(void){
95       FILE * fp;
96       char * line = NULL;
97       size_t len = 0;
98       getline(&line, &len, fp);
99     }
100   ],[
101     AC_MSG_RESULT(found)
102   ],[
103     AC_SUBST(need_getline, ["#define SIMGRID_NEED_GETLINE 1 /* enable the getline replacement*/"])
104     AC_DEFINE(SIMGRID_NEED_GETLINE, 1, enable the getline replacement)
105     AC_MSG_RESULT(not found (activating internal implementation))
106   ])
107
108 dnl AC_MSG_CHECKING(POSIX timer functions)
109 AC_CHECK_LIB(rt, [clock_gettime], [
110     AC_DEFINE(HAVE_POSIX_GETTIME, 1, POSIX timer functions were found)
111     SIMGRID_DEP="$SIMGRID_DEP -lrt"
112     GRAS_DEP="$GRAS_DEP -lrt"
113   ])
114
115 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
116 AC_FUNC_SNPRINTF
117 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
118 AC_CHECK_FUNC(  asprintf, :,[
119     AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf replacement)
120     AC_SUBST(need_asprintf, ["#define SIMGRID_NEED_ASPRINTF 1 /* enable the asprintf replacement */"]) 
121    ])
122 AC_CHECK_FUNC( vasprintf, :,[
123     AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf replacement)
124     AC_SUBST(need_vasprintf, ["#define SIMGRID_NEED_VASPRINTF 1 /*enable the vasprintf replacement */"]) 
125    ])
126
127 # Checks for typedefs, structures, and compiler characteristics.
128 AC_C_CONST
129 AC_C_INLINE
130 AC_TYPE_SIZE_T
131
132 ###################################
133 ## SimGrid and GRAS specific checks
134 ##
135
136 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
137 # Check architecture signature begin
138 GRAS_ARCH
139 # Check architecture signature end
140 GRAS_CHECK_STRUCT_COMPACTION
141
142
143 dnl ##
144 dnl ##  CONTEXT IMPLEMENTATION
145 dnl ##
146
147 SG_CONFIGURE_PART([Checking threads, contexts or assimilated...])
148
149 dnl #
150 dnl #  1. determine possibilities
151 dnl #
152
153 dnl #  check for MCSC method (ucontexts)
154 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
155
156 dnl #  check for pthread method
157 AC_CHECK_HEADERS([pthread.h])
158 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
159
160 if test x$pthread = xyes ; then
161   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
162   if test ${HAVE_SEM_INIT} = yes ; then
163      AC_MSG_CHECKING(if sem_init is compilable)
164      AC_TRY_COMPILE([#include <semaphore.h>],
165                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
166      if test ${HAVE_SEM_INIT} = yes ; then
167         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
168         AC_MSG_RESULT(yes)
169      else
170         AC_MSG_RESULT(no)
171      fi
172   fi
173   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
174   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
175      AC_MSG_CHECKING(if sem_timedwait is compilable)
176      AC_TRY_COMPILE([#include <semaphore.h>],
177                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
178      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
179         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
180         AC_MSG_RESULT(yes)
181      else
182         AC_MSG_RESULT(no)
183      fi
184   fi
185
186   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
187   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
188      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
189      AC_TRY_COMPILE([#include <pthread.h>],
190                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
191      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
192         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
193         AC_MSG_RESULT(yes)
194      else
195         AC_MSG_RESULT(no)
196      fi
197   fi
198 fi
199
200 dnl #
201 dnl #  2. make a general decision
202 dnl #
203
204 if test ".$mcsc" = .yes; then
205    # ucontext found
206    mcsc=yes
207 elif test ".$pthread" = .yes; then
208    # ucontext not found, but pthread found
209    pthread=yes
210 else
211     ac_header=windows.h
212     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
213     if test `eval echo '${'$as_ac_Header'}'` = yes; then
214       windows_context=yes
215     else
216       AC_ERROR([no appropriate backend found])
217     fi
218 fi
219 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
220
221
222 dnl #
223 dnl #  3. allow decision to be overridden by user
224 dnl #
225
226 AC_MSG_CHECKING(what kind of backend should we use)
227
228 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
229 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
230
231 AC_ARG_WITH(context,
232   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
233   with_context=auto)
234
235 if test "x$with_context$mcsc" = "xucontextno" ; then 
236   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
237 fi
238
239 case $with_context in
240  ucontext) ;;
241  pthread) ;;
242  pthreads) ;;
243  windows) ;;
244  auto) with_context=ucontext;;
245  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
246 esac
247
248 if test "x$with_context" = "xucontext" ; then
249   if test ".$mcsc" = .yes; then
250     AC_MSG_RESULT(found working ucontext. Great!)
251     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
252     AC_CHECK_HEADERS([valgrind/valgrind.h])
253   else
254     if test ".$windows_context" = .yes ; then
255       AC_MSG_RESULT(use windows context portability layer.)
256       with_context=windows
257     else
258       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
259       with_context=pthread
260     fi
261   fi
262 fi
263
264 if test "x$with_context" = "xpthread"; then
265   if test x$pthread != xyes ; then # reuse previous checks
266     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
267   fi
268   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
269   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
270 fi
271 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
272
273 dnl #
274 dnl #  4. determine a few additional details
275 dnl #
276
277 if test "x$with_context" = "xucontext" ; then
278 dnl #  direction of stack grow
279   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
280   if test ".$ac_cv_check_stackgrowth" = ".down"; then
281       PTH_STACK_GROWTH="down"
282   else
283       PTH_STACK_GROWTH="up"
284   fi
285   AC_SUBST(PTH_STACK_GROWTH)
286   
287   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
288 fi
289
290 #########################################
291 ## Check for libraries extra-dependencies
292 ##
293
294 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
295
296 if test xpthread=xyes ; then 
297   # if the pthreads are usable
298   if test "x$with_context" = "xpthread" ; then
299     # if we use them to implement the xbt_context
300     SIMGRID_DEP="$SIMGRID_DEP -lpthread"
301   fi
302   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
303   if test "x$with_context" != "xwindows" ; then
304     GRAS_DEP="$GRAS_DEP -lpthread"
305   fi
306 fi
307 AC_SEARCH_LIBS([connect],[socket],[],[],[]) # need -lsocket on solaris
308
309 #########################################
310 ## Build optional modules (gtnets)
311 ##
312 gtnets=no
313 AC_ARG_WITH(gtnets,
314   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
315   gtnets_path="$withval",gtnets_path="no")
316 if test "x$gtnets_path" = "xno" ; then
317   AC_MSG_RESULT(Eventually you will come to GTNetS.)
318 else  
319   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
320   AC_MSG_CHECKING(for gtnets)
321   AC_LANG_PUSH([C++])  
322   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
323   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
324   LDFLAGS_SAV=$LDFLAGS  
325   CPPFLAGS_SAV=$CPPFLAGS
326   CPPFLAGS+=$GTNETS_CPPFLAGS
327   LDFLAGS+=$GTNETS_LDFLAGS
328   AC_TRY_LINK([ #include <simulator.h>
329               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
330   CPPFLAGS=$CPPFLAGS_SAV
331   LDFLAGS=$LDFLAGS_SAV
332   AC_LANG_POP([C++])  
333 fi
334
335 if test "x$gtnets" = "xyes" ; then
336   AC_MSG_RESULT(Enabling GTNETS support.)
337   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
338   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
339   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
340 fi
341 AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
342
343
344
345 AC_SUBST([SIMGRID_DEP])
346 AC_SUBST([SMPI_DEP])
347
348 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
349 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
350
351 AC_MSG_CHECKING(for extra dependencies of libgras)
352 case $host_os in
353   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
354             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
355             AC_DEFINE(CONTEXT_THREADS,1);;
356 esac
357
358
359
360 if test "x$GRAS_DEP" = x; then 
361    AC_MSG_RESULT(none)
362 else
363    AC_MSG_RESULT($GRAS_DEP)
364 fi
365 AC_SUBST([GRAS_DEP])
366
367 ##############################################
368 ## Enhance maintainer mode and SUBST variables
369 ## (must be placed after any compilation tests since our overprotective flags
370 ##  let some tests fail)
371
372 # Check whether we are doing a regular build or a GRAMINE (minimal) one
373 # Next line is modified by sed when building gramine source tree
374 gramine_mode=no
375 if test x$gramine_mode = xyes
376 then
377   USE_MAINTAINER_MODE=no
378 fi
379 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
380
381 AM_MAINTAINER_MODE
382 if test x$USE_MAINTAINER_MODE = xyes 
383 then
384    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
385    force_compile_warnings=yes   
386 fi
387 SG_COMPILE_FLAGS
388
389 ##
390 ## Support for tracing instrumentation (no longer supported in autotools)
391 ##
392
393 ##
394 ## Support for the supernovae compilation mode
395 ##
396 AC_ARG_ENABLE(supernovae,
397               AS_HELP_STRING([--enable-supernovae],[Put the whole library in one compilation unit only to help gcc optimizing the code]),
398               [supernovae=$enableval],
399               [supernovae=no])
400 AM_CONDITIONAL(SUPERNOVAE_MODE, test x$supernovae != xno)
401
402 AC_SUBST([CFLAGS])
403 AC_SUBST([CPPFLAGS])
404 AC_SUBST([LDFLAGS])
405 AC_SUBST([AM_CPPFLAGS])
406 AC_SUBST([abs_builddir])
407 AC_SUBST([abs_srcdir])
408 AC_SUBST([abs_top_builddir])
409 AC_SUBST([abs_top_srcdir])
410
411 ##############################################
412 ## Specific mode for build daemons.
413 ## (they compile the SVN without having the autotools installed)
414 AC_ARG_ENABLE(botbuild,
415               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
416               botbuild=$enableval,botbuild=no)
417 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
418
419 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
420   echo "ERROR: "
421   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
422   echo "ERROR: For this, just call configure this way:"
423   echo "ERROR:"
424   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
425   echo "ERROR:"
426   exit 1
427 fi
428
429
430 SG_CONFIGURE_PART(Checking Java bindings...)
431 # Java cruft
432 AC_ARG_ENABLE(java,
433               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
434               disable_java=$enableval,disable_java=yes)
435 if test "x$disable_java" != "xyes" ; then
436    use_java="disabled by user"
437 else
438   AC_PATH_PROG([JAVAC], [javac], `which javac`)
439   AC_PATH_PROG([JAVA],  [java] , `which java`)
440   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
441   AC_CHECK_HEADERS(jni.h)
442   if test -n "$JAVAC" && test -n "$JAVA" && test -n "$JAR" && test "x$ac_cv_header_jni_h" = "xyes" ; then
443      use_java="yes"
444      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
445   else   
446      use_java="no (you may want to install the java-gcj-compat-dev package)"
447   fi
448 fi
449 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
450 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
451
452
453 SG_CONFIGURE_PART(Checking Lua bindings...)
454 AC_ARG_ENABLE(lua,
455               AS_HELP_STRING([--disable-lua], [To not compile the Lua bindings even if the tools are found]),
456               disable_lua=$enableval,disable_lua=yes)
457 if test "x$disable_lua" != "xyes" ; then
458    use_lua="disabled by user"
459 else
460   AC_CHECK_HEADERS(lualib.h)
461   if test "x$ac_cv_header_lualib_h" = "xyes" ; then
462      use_lua="yes"
463      AC_DEFINE(HAVE_LUA,1, [defines whether Lua bindings must be compiled or not])
464      SIMGRID_DEP="${SIMGRID_DEP} -ldl -llua5.1"
465   else   
466      use_lua="no (you may want to install the liblua5.1-0-dev package, or pass CFLAGS=-I/usr/include/lua5.1)"
467   fi
468 fi
469 AC_MSG_RESULT(decide whether to compile lua bindings... $use_lua)
470 AM_CONDITIONAL(HAVE_LUA,test "x$use_lua" = "xyes")
471
472 SG_CONFIGURE_PART(Checking Ruby bindings...)
473 # Ruby cruft
474 AC_ARG_ENABLE(ruby,
475               AS_HELP_STRING([--disable-ruby], [To not compile the Ruby bindings even if the tools are found]),
476               disable_ruby=$enableval,disable_ruby=yes)
477 if test "x$disable_ruby" != "xyes" ; then
478    use_ruby="disabled by user"
479 else
480   CPPFLAGS="-I/usr/lib/ruby/1.8/i486-linux/ $CPPFLAGS"
481   AC_MSG_CHECKING(checking ruby.h usability and presence)
482   AC_COMPILE_IFELSE([
483     #undef PACKAGE_NAME
484     #undef PACKAGE_TARNAME
485     #undef PACKAGE_VERSION
486     #undef PACKAGE_STRING
487     #undef PACKAGE_BUGREPORT
488     #include <ruby.h>
489   ], use_ruby=yes,use_ruby="no (Package ruby1.8-dev missing)")
490   AC_MSG_RESULT($use_ruby)
491   if test "x$use_ruby" = "xyes" ; then
492      AC_DEFINE(HAVE_RUBY,1, [defines whether Ruby bindings must be compiled or not])
493      SIMGRID_DEP="${SIMGRID_DEP} -lruby1.8"
494   else
495      AC_MSG_RESULT(Please install the ruby1.8-dev package (on debian and similar) to get ruby bindings)
496   fi
497 fi
498 AC_MSG_RESULT(decide whether to compile ruby bindings... $use_ruby)
499 AM_CONDITIONAL(HAVE_RUBY,test "x$use_ruby" = "xyes")
500
501
502 #####################
503 ## Check for programs
504 ##
505
506 SG_CONFIGURE_PART(Checking programs...)
507 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
508 WARNING="This file is generated, do not edit"
509 AC_SUBST(WARNING)
510
511
512 # Can we rebuild the parsers?
513 # We really want flex and refuse other lex. So, the parser is portable and
514 # does not induce extra lib dependency
515 AC_PROG_FLEX(2.5.30)
516                 
517 # Can we rebuild the xml-lexers from the XML specification?
518 # if not, simply touch the flex source files (which are distributed in
519 #  tarballs even if generated by flexml) and hope for the best.
520 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
521 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
522
523 # Check for doxygen when in maintainer mode which is helpful to build doc & dist
524 AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
525 AC_PATH_PROG(FIG2DEV,fig2dev,`which fig2dev`)
526 AM_CONDITIONAL(HAVE_DOXYGEN,test x$DOXYGEN != x &&
527                             test x$FIG2DEV != x)
528
529 # Can we rebuild the publication list from the bib file?
530 AC_CHECK_PROG(BIBTEX,bibtex,`which flexml`,NOTFOUND)
531 AC_CHECK_PROG(BIBTOOL,bibtool,`which bibtool`,NOTFOUND)
532 AC_CHECK_PROG(ICONV,iconv,`which iconv`,NOTFOUND)
533 AC_CHECK_PROG(BIBTEX2HTML,bibtex2html,`which bibtex2html`,NOTFOUND)
534
535 BIBTEX2HTML_VER="date"
536 if test "x$BIBTEX2HTML" != "xNOTFOUND" ; then
537    BIBTEX2HTML_VER=`$BIBTEX2HTML --help 2>&1 | grep date`
538 fi;
539
540 AC_MSG_CHECKING(whether you have the right bibtex2html and will be able to build HTML files from the bibtex file)
541 AM_CONDITIONAL(HAVE_BIBTEX2HTML,test "x$BIBTEX2HTML_VER" == "x"     &&
542                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
543                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
544                                 test "x$ICONV" != "xNOTFOUND"         )
545
546 if test "x$BIBTEX2HTML_VER" == "x"     &&
547                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
548                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
549                                 test "x$ICONV" != "xNOTFOUND"; then
550    AC_MSG_RESULT(yes)
551 else
552    AC_MSG_RESULT(no)
553 fi
554
555 # Can we extract really usable backtraces? (also need the popen function)
556 AC_PATH_PROG(ADDR2LINE, addr2line)
557 if test x$ADDR2LINE != x ; then
558   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
559 fi
560
561 AC_SUBST(ac_configure_args)
562 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
563 # Can we make status line about the compilation result?
564 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
565 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
566 AC_SUBST(build_id)
567
568 ###################
569 ## Makes the output
570 ##
571
572
573 #
574 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
575 #  src/amok/Makefile
576
577 SG_CONFIGURE_PART(Generating files...)
578
579 # Core of the libraries
580
581 AC_CONFIG_FILES([
582   Makefile
583   include/Makefile
584   include/simgrid_config.h
585   src/Makefile
586   src/context_sysv_config.h
587 ])
588
589 # Tools being embeeded in gramine (stub generator)
590 AC_CONFIG_FILES([
591   tools/Makefile
592     tools/gras/Makefile
593     tools/tesh/Makefile
594 ])
595 #    tools/tesh2/Makefile
596
597
598 # GRAMINE_CUT_BEGIN
599
600 # Tools NOT being embeeded in gramine
601 AC_CONFIG_FILES([
602   tools/graspe-slave
603 ],[
604     for file in                                                 \
605      tools/graspe-slave           tools/graspe-master           \
606      checkall                     examples/java/runtest         \
607      src/mk_supernovae.sh                                       \
608     ; do                                                        \
609       test -e $file && chmod +x $file;                          \
610     done
611 ])
612
613 # build tools && Testsuite
614
615 AC_CONFIG_FILES([  
616   buildtools/Makefile
617   testsuite/Makefile
618   testsuite/run_tests    
619 ],[
620     for file in                                                 \
621      testsuite/run_tests                                        \
622     ; do                                                        \
623       test -e $file && chmod +x $file;                          \
624     done
625 ])
626
627 # Teshsuite (testsuite using tesh)
628 AC_CONFIG_FILES([  
629   teshsuite/Makefile
630 ])
631
632 # Documentation
633 AC_CONFIG_FILES([
634   doc/Makefile
635   doc/Doxyfile
636 ])
637
638 # Examples
639
640 #      examples/gras/p2p/Makefile
641 #      examples/gras/p2p/chord/Makefile
642 #      examples/gras/p2p/can/Makefile
643
644 AC_CONFIG_FILES([
645     examples/java/Makefile
646       examples/java/basic/Makefile
647       examples/java/comm_time/Makefile
648       examples/java/suspend/Makefile
649       examples/java/ping_pong/Makefile
650 ])
651
652 AC_CONFIG_FILES([
653   examples/Makefile 
654     examples/msg/Makefile
655     examples/simdag/Makefile
656     examples/gras/Makefile
657       examples/gras/ping/Makefile   
658       examples/gras/rpc/Makefile
659       examples/gras/spawn/Makefile
660       examples/gras/synchro/Makefile
661       examples/gras/timer/Makefile
662       examples/gras/properties/Makefile
663       examples/gras/chrono/Makefile
664       examples/gras/mutual_exclusion/simple_token/Makefile
665       examples/gras/mmrpc/Makefile
666       examples/gras/pmm/Makefile
667       examples/gras/all2all/Makefile
668     examples/amok/Makefile       
669     examples/smpi/Makefile       
670 ])
671 #      examples/gras/replay/Makefile
672
673 AC_CONFIG_FILES([
674   src/smpi/smpicc
675   src/smpi/smpirun
676 ],[
677     for file in                                                 \
678       src/smpi/smpicc                                           \
679       src/smpi/smpirun                                          \
680     ; do                                                        \
681       test -e $file && chmod +x $file;                          \
682     done
683 ])
684
685 # GRAMINE_CUT_END
686
687 AC_OUTPUT
688
689 echo "
690
691 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
692
693         Compiler:        ${CC} (version: ${GCC_VERSION})
694         
695         CFlags:          ${CFLAGS}
696         CPPFlags:        ${CPPFLAGS}
697         LDFlags:         ${LDFLAGS}
698
699         Context backend: ${with_context}
700         Compile Java:    ${use_java}
701         Compile Lua:     ${use_lua}
702         Compile Ruby:    ${use_ruby}
703         
704         Maintainer mode: ${USE_MAINTAINER_MODE}
705         Supernovae mode: ${supernovae}
706
707 "
708 if test x$botbuild = xyes ; then
709   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
710   echo
711 fi
712
713 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
714   echo "WARNING: "
715   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
716   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
717   echo "WARNING:"
718   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
719   echo "WARNING:"
720 fi
721
722 echo $build_id > stamp.configure
723
724 exit 0;