examples/s4u/CMakeLists.txt

   1
   2 # Regular examples: with only one source and tested with all factories by default
   3 #################################################################################
   4 set(_actor-stacksize_factories "raw;boost;ucontext") # Threads ignore modifications of the stack size
   5
   6 foreach (example actor-create actor-daemon actor-exiting actor-join actor-kill
   7                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
   8                  app-chainsend app-pingpong app-token-ring
   9                  async-ready async-wait async-waitany async-waitall async-waituntil
  10                  comm-dependent
  11                  cloud-capping cloud-migration cloud-simple
  12                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask
  13                  engine-filtering
  14                  exec-async exec-basic exec-dvfs exec-ptask exec-remote exec-waitany exec-waitfor exec-dependent
  15                  io-async io-file-system io-file-remote io-disk-raw io-dependent
  16                  platform-failures platform-profile platform-properties
  17                  plugin-hostload
  18                  replay-comm replay-io
  19                  routing-get-clusters
  20                  synchro-barrier synchro-condition-variable synchro-mutex synchro-semaphore)
  21   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
  22   add_dependencies     (tests s4u-${example})
  23   target_link_libraries(s4u-${example} simgrid)
  24   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  25
  26   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
  27   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
  28
  29   # Use default factories unless specified otherwise
  30   if(NOT DEFINED _${example}_factories)
  31     set(_${example}_factories "thread;ucontext;raw;boost")
  32   endif()
  33 #  message("Factories of ${example}: ${_${example}_factories}")
  34
  35   ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
  36                                     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  37                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  38                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  39                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
  40
  41   unset(_${example}_factories)
  42 endforeach()
  43
  44
  45 # Model-checking examples: with only one source and tested with all factories but thread
  46 ######################################################################
  47
  48 foreach (example mc-failing-assert)
  49   if(SIMGRID_HAVE_MC)
  50     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
  51     add_dependencies     (tests s4u-${example})
  52     target_link_libraries(s4u-${example} simgrid)
  53     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  54
  55
  56     ADD_TESH_FACTORIES(s4u-${example} "ucontext;raw;boost"
  57                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  58                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  59                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  60                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
  61   endif()
  62
  63   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
  64   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
  65 endforeach()
  66
  67
  68 # Multi-files examples
  69 ######################
  70
  71 # MASTERWORKERS EXAMPLE
  72 foreach(variant fun class)
  73   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
  74   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
  75   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
  76   add_dependencies(tests s4u-app-masterworkers-${variant})
  77
  78   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
  79 endforeach()
  80 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
  81
  82 # CHORD EXAMPLE
  83 add_executable       (s4u-dht-chord EXCLUDE_FROM_ALL dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord-node.cpp)
  84 target_link_libraries(s4u-dht-chord simgrid)
  85 set_target_properties(s4u-dht-chord PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dht-chord)
  86 add_dependencies(tests s4u-dht-chord)
  87 foreach (file s4u-dht-chord.cpp s4u-dht-chord-node.cpp s4u-dht-chord.hpp)
  88   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/${file})
  89 endforeach()
  90
  91 # KADEMLIA EXAMPLE
  92 add_executable       (s4u-dht-kademlia EXCLUDE_FROM_ALL dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/node.cpp
  93                       dht-kademlia/routing_table.cpp dht-kademlia/answer.cpp)
  94 target_link_libraries(s4u-dht-kademlia simgrid)
  95 set_target_properties(s4u-dht-kademlia PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dht-kademlia)
  96 add_dependencies(tests s4u-dht-kademlia)
  97 foreach (file answer routing_table node s4u-dht-kademlia)
  98   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/${file}.cpp
  99                                      ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/${file}.hpp)
 100 endforeach()
 101 set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/message.hpp)
 102
 103 # BITTORRENT EXAMPLE
 104 add_executable       (s4u-bittorrent EXCLUDE_FROM_ALL app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-peer.cpp
 105                       app-bittorrent/s4u-tracker.cpp)
 106 target_link_libraries(s4u-bittorrent simgrid)
 107 set_target_properties(s4u-bittorrent PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-bittorrent)
 108 add_dependencies(tests s4u-bittorrent)
 109 foreach (file s4u-bittorrent s4u-peer s4u-tracker)
 110   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/${file}.cpp
 111                                      ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/${file}.hpp)
 112 endforeach()
 113
 114 # The tests of DHT, along with the parallel variant
 115
 116 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 117   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 118   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 119   set(parallel-factories "thread;raw;boost")
 120 else()
 121   set(parallel-factories "thread;ucontext;raw;boost")
 122 endif()
 123
 124 foreach(example app-bittorrent app-masterworkers
 125                 dht-chord dht-kademlia
 126                 )
 127   ADD_TESH_FACTORIES(s4u-${example} "thread;ucontext;raw;boost"
 128                                     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 129                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 130                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 131                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 132
 133   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 134                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 135                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 136                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 137                                              ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 138 endforeach()
 139
 140 # Examples not accepting factories
 141 ##################################
 142
 143 foreach (example trace-platform)
 144   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 145   target_link_libraries(s4u-${example} simgrid)
 146   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 147   add_dependencies(tests s4u-${example})
 148
 149   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 150   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 151
 152   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 153                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 154                           ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 155 endforeach()
 156
 157 if (NOT enable_memcheck AND NOT WIN32)
 158   ADD_TESH(simix-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/app-pingpong
 159                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 160                             ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh)
 161 endif()
 162
 163 # Examples accepting only thread factories
 164 ##################################
 165 foreach (example maestro-set)
 166   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 167   target_link_libraries(s4u-${example} simgrid)
 168   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 169   add_dependencies(tests s4u-${example})
 170
 171   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 172   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 173
 174   if(NOT WIN32)
 175     ADD_TESH_FACTORIES(s4u-${example} "thread" --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 176                                                --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 177                                                ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 178   else()
 179     message("Test maestro-set disabled on windows: this feature is not working")
 180   endif()
 181 endforeach()
 182
 183 # Add all extra files to the archive
 184 ####################################
 185
 186 set(examples_src  ${examples_src}                                                                          PARENT_SCOPE)
 187 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent.tesh
 188                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh
 189                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord.tesh
 190                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia.tesh
 191                   PARENT_SCOPE)
 192 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 193                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 194                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-yield/s4u-actor-yield_d.xml
 195                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 196                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 197                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-wait/s4u-async-wait_d.xml
 198                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waitany/s4u-async-waitany_d.xml
 199                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waitall/s4u-async-waitall_d.xml
 200                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-ready/s4u-async-ready_d.xml
 201                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waituntil/s4u-async-waituntil_d.xml
 202                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 203                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 204                                   ${CMAKE_CURRENT_SOURCE_DIR}/energy-boot/platform_boot.xml
 205                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 206                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-properties/s4u-platform-properties_d.xml
 207                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 208                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 209                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 210                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 211                   PARENT_SCOPE)
 212 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py                     PARENT_SCOPE)
 213 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 214                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 215                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 216                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)
 217