buildtools/Cmake/MakeJava.cmake

   1 cmake_minimum_required(VERSION 2.8.6)
   2
   3 include(UseJava)
   4
   5 # Rules to build libSG_java
   6 #
   7 add_library(SG_java SHARED ${JMSG_C_SRC})
   8 set_target_properties(SG_java PROPERTIES VERSION ${libSG_java_version})
   9 get_target_property(COMMON_INCLUDES SG_java INCLUDE_DIRECTORIES)
  10 set_target_properties(SG_java PROPERTIES
  11   INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  12 add_dependencies(SG_java simgrid)
  13
  14 if(WIN32)
  15   get_target_property(SIMGRID_LIB_NAME_NAME SG_java LIBRARY_OUTPUT_NAME)
  16   set_target_properties(SG_java PROPERTIES
  17     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at ${SIMGRID_LIB_NAME}"
  18     PREFIX "")
  19   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  20   message(STATUS "pexports: ${PEXPORTS_PATH}")
  21   if(PEXPORTS_PATH)
  22     add_custom_command(TARGET SG_java POST_BUILD
  23       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/SG_java.dll > ${CMAKE_BINARY_DIR}/SG_java.def)
  24   endif(PEXPORTS_PATH)
  25 else()
  26   target_link_libraries(SG_java simgrid)
  27 endif()
  28
  29 # Rules to build simgrid.jar
  30 #
  31
  32 ## Files to include in simgrid.jar
  33 ##
  34 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  35 set(MANIFEST_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF")
  36 set(LIBSIMGRID_SO
  37   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  38 set(LIBSG_JAVA_SO
  39   ${CMAKE_SHARED_LIBRARY_PREFIX}SG_java${CMAKE_SHARED_LIBRARY_SUFFIX})
  40
  41 ## Name of the "NATIVE" folder in simgrid.jar
  42 ##
  43 if(CMAKE_SYSTEM_PROCESSOR MATCHES ".86")
  44   if(${ARCH_32_BITS})
  45     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/i386/")
  46   else()
  47     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/amd64/")
  48   endif()
  49 else()
  50   message(WARNING "Unknown system type. Processor: ${CMAKE_SYSTEM_PROCESSOR}; System: ${CMAKE_SYSTEM_NAME}")
  51   set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR/")
  52 endif()
  53 message("Native libraries bundled into: ${JSG_BUNDLE}")
  54
  55 ## Don't strip libraries if not in release mode
  56 ##
  57 if(release)
  58   set(STRIP_COMMAND "${CMAKE_STRIP}")
  59 else()
  60   set(STRIP_COMMAND "true")
  61 endif()
  62
  63 ## Here is how to build simgrid.jar
  64 ##
  65 set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  66 add_jar(SG_java_pre_jar ${JMSG_JAVA_SRC})
  67
  68 add_custom_command(
  69   COMMENT "Finalize simgrid.jar..."
  70   OUTPUT ${SIMGRID_JAR}_finalized
  71   DEPENDS simgrid SG_java SG_java_pre_jar
  72           ${SIMGRID_JAR} ${MANIFEST_FILE}
  73           ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
  74           ${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}
  75           ${CMAKE_HOME_DIRECTORY}/COPYING
  76           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  77           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  78   COMMAND ${CMAKE_COMMAND} -E remove_directory "NATIVE"
  79   COMMAND ${CMAKE_COMMAND} -E make_directory "${JSG_BUNDLE}"
  80   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}" "${JSG_BUNDLE}"
  81   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSIMGRID_SO}"
  82   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}" "${JSG_BUNDLE}"
  83   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSG_JAVA_SO}"
  84   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/COPYING" "${JSG_BUNDLE}"
  85   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog" "${JSG_BUNDLE}"
  86   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java" "${JSG_BUNDLE}"
  87   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} "NATIVE"
  88   COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
  89   COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
  90   )
  91 add_custom_target(SG_java_jar ALL DEPENDS ${SIMGRID_JAR}_finalized)