Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
SMPI - fail when unimplemented MPI calls are used.
[simgrid.git] / FindSimGrid.cmake
1 # CMake find module to search for the SimGrid library. 
2
3 # Copyright (c) 2016-2018. The SimGrid Team.
4 #
5 # This file is free software; you can redistribute it and/or modify it
6 # under the terms of the license (GNU LGPL) which comes with this package.
7
8 #
9 # USERS OF PROGRAMS USING SIMGRID
10 # -------------------------------
11 #
12 # If cmake does not find this file, add its path to CMAKE_PREFIX_PATH:
13 #    CMAKE_PREFIX_PATH="/path/to/FindSimGrid.cmake:$CMAKE_PREFIX_PATH"  cmake .
14 #
15 # If this file does not find SimGrid, define SimGrid_PATH:
16 #    SimGrid_PATH=/path/to/simgrid  cmake .
17
18 #
19 # DEVELOPERS OF PROGRAMS USING SIMGRID
20 # ------------------------------------
21 #
22 #  1. Include this file in your own CMakeLists.txt
23 #     Either by copying it in your tree, or (recommended) by using the
24 #     version automatically installed by SimGrid.
25 #    
26 #  2. Afterward, if you have CMake >= 2.8.12, this will define a
27 #     target called 'SimGrid::Simgrid'. Use it as:
28 #       target_link_libraries(your-simulator SimGrid::SimGrid)
29 #
30 #    With older CMake (< 2.8.12), it simply defines several variables:
31 #       SimGrid_INCLUDE_DIR - the SimGrid include directories
32 #       SimGrid_LIBRARY - link your simulator against it to use SimGrid
33 #    Use as:
34 #      include_directories("${SimGrid_INCLUDE_DIR}" SYSTEM)
35 #      target_link_libraries(your-simulator ${SimGrid_LIBRARY})
36 #
37 #  In both cases, it also define a SimGrid_VERSION macro, that you
38 #    can use to deal with API evolutions as follows:
39 #
40 #    #if SimGrid_VERSION < 31800
41 #      (code to use if the installed version is lower than v3.18)
42 #    #elif SimGrid_VERSION < 31900
43 #      (code to use if we are using SimGrid v3.18.x)
44 #    #else
45 #      (code to use with SimGrid v3.19+)
46 #    #endif
47
48
49 # IMPROVING THIS FILE
50 # -------------------
51 #  - Use automatic SimGridConfig.cmake creation via export/install(EXPORT in main CMakeLists.txt:
52 #    https://cliutils.gitlab.io/modern-cmake/chapters/exporting.html
53 #    https://cmake.org/Wiki/CMake/Tutorials/How_to_create_a_ProjectConfig.cmake_file
54 #    https://github.com/boostcon/cppnow_presentations_2017/blob/master/05-19-2017_friday/effective_cmake__daniel_pfeifer__cppnow_05-19-2017.pdf
55
56 cmake_minimum_required(VERSION 2.8)
57
58 find_path(SimGrid_INCLUDE_DIR
59   NAMES simgrid_config.h
60   PATHS ${SimGrid_PATH}/include /opt/simgrid/include
61 )
62 find_library(SimGrid_LIBRARY
63   NAMES simgrid
64   PATHS ${SimGrid_PATH}/lib /opt/simgrid/lib
65 )
66 mark_as_advanced(SimGrid_INCLUDE_DIR)
67 mark_as_advanced(SimGrid_LIBRARY)
68
69 if (SimGrid_INCLUDE_DIR)
70   set(SimGrid_VERSION_REGEX "^#define SIMGRID_VERSION_(MAJOR|MINOR|PATCH) ([0-9]+)$")
71   file(STRINGS "${SimGrid_INCLUDE_DIR}/simgrid_config.h" SimGrid_VERSION_STRING REGEX ${SimGrid_VERSION_REGEX})
72   set(SimGrid_VERSION "")
73
74   # Concat the matches to MAJOR.MINOR.PATCH assuming they appear in this order
75   foreach(match ${SimGrid_VERSION_STRING})
76     if(SimGrid_VERSION)
77       set(SimGrid_VERSION "${SimGrid_VERSION}.")
78     endif()
79     string(REGEX REPLACE ${SimGrid_VERSION_REGEX} "${SimGrid_VERSION}\\2" SimGrid_VERSION ${match})
80     set(SimGrid_VERSION_${CMAKE_MATCH_1} ${CMAKE_MATCH_2})
81   endforeach()
82   unset(SimGrid_VERSION_STRING)
83   unset(SimGrid_VERSION_REGEX)  
84 endif ()
85
86 include(FindPackageHandleStandardArgs)
87 find_package_handle_standard_args(SimGrid
88   FOUND_VAR SimGrid_FOUND
89   REQUIRED_VARS SimGrid_INCLUDE_DIR SimGrid_LIBRARY
90   VERSION_VAR SimGrid_VERSION
91 )
92
93 if (SimGrid_FOUND AND NOT CMAKE_VERSION VERSION_LESS 2.8.12)
94   add_library(SimGrid::SimGrid SHARED IMPORTED)
95   set_target_properties(SimGrid::SimGrid PROPERTIES
96     INTERFACE_SYSTEM_INCLUDE_DIRECTORIES ${SimGrid_INCLUDE_DIR}
97     INTERFACE_COMPILE_FEATURES cxx_alias_templates
98     IMPORTED_LOCATION ${SimGrid_LIBRARY}
99   )
100   # We need C++11, so check for it just in case the user removed it since compiling SimGrid
101   if (NOT CMAKE_VERSION VERSION_LESS 3.8)
102     # 3.8+ allows us to simply require C++11 (or higher)
103     set_property(TARGET SimGrid::SimGrid PROPERTY INTERFACE_COMPILE_FEATURES cxx_std_11)
104   elseif (NOT CMAKE_VERSION VERSION_LESS 3.1)
105     # 3.1+ is similar but for certain features. We pick just one
106     set_property(TARGET SimGrid::SimGrid PROPERTY INTERFACE_COMPILE_FEATURES cxx_alias_templates)
107   else ()
108     # Old CMake can't do much. Just check the CXX_FLAGS and inform the user when a C++11 feature does not work
109     include(CheckCXXSourceCompiles)
110     set(CMAKE_REQUIRED_FLAGS "${CMAKE_CXX_FLAGS}")
111     check_cxx_source_compiles("using Foo = int; int main(){}" _SIMGRID_CXX11_ENABLED)
112     if (NOT _SIMGRID_CXX11_ENABLED)
113         message(WARNING "C++11 is required to use SimGrid. Enable it with e.g. -std=c++11")
114     endif ()
115     unset(_SIMGRID_CXX11_ENABLED CACHE)
116   endif ()
117 endif ()
118