CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.8)
   2 message(STATUS "Cmake version ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
   3 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_HOME_DIRECTORY}/tools/cmake/Modules)
   4
   5 project(SimGrid C CXX)
   6
   7 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
   8 #     Check for the compiler        #
   9 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  10
  11 ### Need to set rc ccompiler before enable language
  12 if(WIN32)
  13   SET(CMAKE_RC_COMPILER "windres")
  14 endif()
  15
  16 ##
  17 ## Check the C/C++ standard that we need
  18 ##   See also tools/cmake/GCCFlags.cmake that sets our paranoid warning flags
  19 if (MSVC)
  20   message("-- You are compiling SimGrid with MicroSoft Visual C. Good luck.")
  21
  22   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  23   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  24 else() # gcc or clang
  25   INCLUDE(CheckCCompilerFlag)
  26   CHECK_C_COMPILER_FLAG(-fstack-cleaner HAVE_C_STACK_CLEANER)
  27
  28   ## Request full debugging flags
  29   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
  30   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
  31   set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -g")
  32
  33   if (CMAKE_COMPILER_IS_GNUCC)
  34     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.7")
  35       message(FATAL_ERROR
  36               "SimGrid needs at least g++ version 4.7 to compile but you have ${CMAKE_CXX_COMPILER_VERSION}."
  37               "You need a sufficient support of c++11 to compile SimGrid.")
  38     endif()
  39   endif()
  40
  41   ## We need a decent support of the c++11 standard
  42   include(CheckCXXCompilerFlag)
  43   CHECK_CXX_COMPILER_FLAG("-std=gnu++11" COMPILER_SUPPORTS_CXX11)
  44   if(COMPILER_SUPPORTS_CXX11)
  45     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
  46   else()
  47     message(FATAL_ERROR
  48             "The compiler ${CMAKE_CXX_COMPILER} (v${CMAKE_CXX_COMPILER_VERSION}) has no C++11 support. "
  49             "Please use a decent C++ compiler.")
  50   endif()
  51
  52   ### And we need C11 standard, too
  53   include(CheckCCompilerFlag)
  54   CHECK_C_COMPILER_FLAG("-std=gnu11" COMPILER_SUPPORTS_C11)
  55   if(COMPILER_SUPPORTS_C11)
  56     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu11")
  57   else()
  58     message(FATAL_ERROR
  59             "The compiler ${CMAKE_C_COMPILER} (v${CMAKE_C_COMPILER_VERSION}) has no C11 support. "
  60             "Please use a decent C compiler "
  61             "(note that c++11 support of ${CMAKE_CXX_COMPILER} seems ok).")
  62   endif()
  63   if(APPLE AND (CMAKE_C_COMPILER_VERSION VERSION_LESS "4.6"))
  64       ### gcc 4.[1-5] cannot compile ucontext on OSX
  65       message(STATUS "Ucontext can't be used with this version of gcc (must be greater than 4.5)")
  66       set(HAVE_UCONTEXT_H 0)
  67   endif()
  68 endif() # NOT MSVC
  69
  70 ### SMPI vs. Fortran
  71 if ((NOT DEFINED enable_smpi OR enable_smpi) AND NOT APPLE) # smpi is enabled by default
  72   # Call enable_language(Fortran) in order to load the build rules for
  73   # this language, needed by teshsuite/smpi/mpich-test/.  Use
  74   # CMAKE_FORCE_Fortran_COMPILER to bypass checks for a working
  75   # compiler (smpiff don't exist at configure time).
  76   include(CMakeForceCompiler)
  77   if(NOT COMMAND CMAKE_FORCE_Fortran_COMPILER)
  78     MACRO(CMAKE_FORCE_Fortran_COMPILER compiler id)
  79       SET(CMAKE_Fortran_COMPILER "${compiler}")
  80       SET(CMAKE_Fortran_COMPILER_ID_RUN TRUE)
  81       SET(CMAKE_Fortran_COMPILER_ID ${id})
  82       SET(CMAKE_Fortran_COMPILER_WORKS TRUE)
  83       SET(CMAKE_Fortran_COMPILER_FORCED TRUE)
  84
  85       # Set old compiler id variables.
  86       IF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  87         SET(CMAKE_COMPILER_IS_GNUG77 1)
  88       ENDIF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  89     ENDMACRO(CMAKE_FORCE_Fortran_COMPILER)
  90   endif()
  91   CMAKE_FORCE_Fortran_COMPILER(smpiff smpiff)
  92   enable_language(Fortran OPTIONAL)
  93 endif()
  94
  95 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  96 #     Build the version number      #
  97 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  98
  99 set(SIMGRID_VERSION_MAJOR "3")
 100 set(SIMGRID_VERSION_MINOR "13")
 101 set(SIMGRID_VERSION_PATCH "0")
 102 set(SIMGRID_VERSION_EXTRA "-devel") # Extra words to add to version string (e.g. -rc1)
 103
 104 set(SIMGRID_VERSION_DATE  "2016") # Year for copyright information
 105
 106 if(${SIMGRID_VERSION_PATCH} EQUAL "0")
 107   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}")
 108 else()
 109   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}")
 110 endif()
 111
 112 set(SIMGRID_VERSION_STRING "SimGrid version ${release_version}${SIMGRID_VERSION_EXTRA}")
 113 set(SIMGRID_VERSION_BANNER "SIMGRID_VERSION_STRING\\nCopyright (c) 2004-${SIMGRID_VERSION_DATE}. The Simgrid Team.")
 114 if(release)
 115   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nRelease build")
 116 else()
 117   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nDevelopment build")
 118 endif()
 119
 120 set(libsimgrid_version "${release_version}")
 121 set(libsimgrid-java_version "${release_version}")
 122
 123 ### SET THE LIBRARY EXTENSION
 124 if(APPLE) #MAC
 125   set(LIB_EXE "dylib")
 126 else()
 127   if(WIN32) #WINDOWS
 128     set(LIB_EXE "a")
 129     set(BIN_EXE ".exe")
 130   else() #UNIX
 131     set(LIB_EXE "so")
 132   endif()
 133 endif()
 134
 135 execute_process(COMMAND         ${CMAKE_LINKER} --version
 136                 OUTPUT_VARIABLE LINKER_VERSION)
 137 string(REGEX MATCH "[0-9].[0-9]*" LINKER_VERSION "${LINKER_VERSION}")
 138
 139 ### Find programs and paths
 140 FIND_PROGRAM(GCOV_PATH gcov)
 141 include(FindPerl)
 142 if(NOT PERL_FOUND)
 143   message(FATAL_ERROR "Please install Perl to compile SimGrid.")
 144 endif()
 145
 146 if (APPLE)
 147   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 148   set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 149 endif()
 150 SET(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib)
 151
 152 ### Compute the include paths
 153 set(INCLUDES
 154   ${CMAKE_HOME_DIRECTORY}
 155   ${CMAKE_HOME_DIRECTORY}/include
 156   ${CMAKE_HOME_DIRECTORY}/src/include
 157   ${CMAKE_BINARY_DIR}
 158   ${CMAKE_BINARY_DIR}/include
 159   )
 160
 161 if(NOT CMAKE_CROSSCOMPILING AND EXISTS /usr/include/)
 162   set(INCLUDES ${INCLUDES} /usr/include/)
 163 endif()
 164
 165 ### Check 32bits or 64bits
 166 IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
 167   SET(ARCH_32_BITS 1)
 168 ELSE()
 169   SET(ARCH_32_BITS 0)
 170 ENDIF()
 171
 172 if(WIN32)
 173
 174   set(CMAKE_INCLUDE_WIN "${CMAKE_C_COMPILER}")
 175   set(CMAKE_LIB_WIN "${CMAKE_C_COMPILER}")
 176   string(REGEX REPLACE "/bin/gcc.*" "/include"  CMAKE_INCLUDE_WIN "${CMAKE_INCLUDE_WIN}")
 177   string(REGEX REPLACE "/bin/gcc.*" "/lib"  CMAKE_LIB_WIN "${CMAKE_LIB_WIN}")
 178   set(INCLUDES ${INCLUDES} ${CMAKE_INCLUDE_WIN})
 179   unset(CMAKE_INCLUDE_WIN)
 180
 181 endif()
 182
 183 include_directories(${INCLUDES})
 184
 185 ### Setup Options
 186 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Option.cmake)
 187
 188 ### Determine the assembly flavor that we need today
 189 set(HAVE_RAW_CONTEXTS 0)
 190 include(CMakeDetermineSystem)
 191 IF(CMAKE_SYSTEM_PROCESSOR MATCHES ".86|AMD64|amd64")
 192   IF(${ARCH_32_BITS})
 193     message(STATUS "System processor: i686 (${CMAKE_SYSTEM_PROCESSOR}, 32 bits)")
 194     set(PROCESSOR_i686 1)
 195     set(PROCESSOR_x86_64 0)
 196   ELSE()
 197     message(STATUS "System processor: x86_64 (${CMAKE_SYSTEM_PROCESSOR}, 64 bits)")
 198     set(PROCESSOR_i686 0)
 199     set(PROCESSOR_x86_64 1)
 200   ENDIF()
 201   if (WIN32)
 202     message(STATUS "Disable fast raw contexts on Windows.")
 203   else()
 204     set(HAVE_RAW_CONTEXTS 1)
 205   endif()
 206 ELSE()
 207   set(PROCESSOR_i686 0)
 208   set(PROCESSOR_x86_64 0)
 209 ENDIF()
 210
 211 include(CheckFunctionExists)
 212 include(CheckTypeSize)
 213 include(CheckIncludeFile)
 214 include(CheckIncludeFiles)
 215 include(CheckLibraryExists)
 216 include(CheckSymbolExists)
 217
 218 set(HAVE_GRAPHVIZ 0)
 219 include(FindGraphviz)
 220 include(FindLibSigc++)
 221
 222 set(HAVE_LUA 0)
 223 if(enable_lua)
 224   include(FindLuaSimgrid)
 225 endif()
 226
 227 set(HAVE_NS3 0)
 228 if(enable_ns3)
 229   include(FindNS3)
 230   if (NOT HAVE_NS3)
 231     message(FATAL_ERROR "Cannot find NS3. Please install it (apt-get install ns3 libns3-dev) or disable that cmake option")
 232   endif()
 233 endif()
 234
 235 if(WIN32)
 236   set(Boost_USE_STATIC_LIBS 1)
 237 endif()
 238
 239 find_package(Boost 1.48)
 240 if(Boost_FOUND)
 241   include_directories(${Boost_INCLUDE_DIRS})
 242 else()
 243   if(APPLE)
 244     message(FATAL_ERROR "Failed to find Boost libraries (Try to install them with 'sudo fink install boost1.53.nopython')")
 245   else()
 246     message(FATAL_ERROR "Failed to find Boost libraries."
 247                         "Did you install libboost-dev and libboost-context-dev?"
 248                         "(libboost-context-dev is optional)")
 249   endif()
 250 endif()
 251
 252 # Try again to see if we have libboost-context
 253 find_package(Boost 1.42 COMPONENTS context)
 254 set(Boost_FOUND 1) # We don't care of whether this component is missing
 255
 256 if(Boost_FOUND AND Boost_CONTEXT_FOUND)
 257   # We should use feature detection for this instead:
 258   if (Boost_VERSION LESS 105600)
 259     message("Found Boost.Context API v1")
 260     set(HAVE_BOOST_CONTEXTS 1)
 261   else()
 262     message("Found Boost.Context API v2")
 263     set(HAVE_BOOST_CONTEXTS 2)
 264   endif()
 265 else()
 266   message ("   boost        : found.")
 267   message ("   boost-context: missing. Install libboost-context-dev for this optional feature.")
 268   set(HAVE_BOOST_CONTEXTS 0)
 269 endif()
 270
 271 # Checks for header libraries functions.
 272 CHECK_LIBRARY_EXISTS(execinfo backtrace              "" HAVE_BACKTRACE_IN_LIBEXECINFO)
 273 CHECK_LIBRARY_EXISTS(rt      clock_gettime           "" HAVE_POSIX_GETTIME)
 274
 275 CHECK_LIBRARY_EXISTS(pthread pthread_create          "" HAVE_PTHREAD)
 276 CHECK_LIBRARY_EXISTS(pthread sem_init                "" HAVE_SEM_INIT_LIB)
 277 CHECK_LIBRARY_EXISTS(pthread sem_open                "" HAVE_SEM_OPEN_LIB)
 278 set(HAVE_PTHREAD_SETAFFINITY 0)
 279 CHECK_LIBRARY_EXISTS(pthread pthread_setaffinity_np  "" HAVE_PTHREAD_SETAFFINITY)
 280
 281 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 282   set(CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 283 elseif(MINGW)
 284   # Use the GNU version of unusual modifiers like PRIx64
 285   add_definitions(-D__USE_MINGW_ANSI_STDIO=1)
 286   set(CMAKE_REQUIRED_DEFINITIONS "-D__USE_MINGW_ANSI_STDIO=1")
 287 else()
 288   set(CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 289 endif()
 290
 291 CHECK_INCLUDE_FILE("valgrind/valgrind.h" HAVE_VALGRIND_H)
 292 CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 293 CHECK_INCLUDE_FILE("execinfo.h" HAVE_EXECINFO_H)
 294 CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 295 CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 296 CHECK_INCLUDE_FILE("sys/sysctl.h" HAVE_SYS_SYSCTL_H)
 297 CHECK_INCLUDE_FILE("ucontext.h" HAVE_UCONTEXT_H)
 298 CHECK_INCLUDE_FILE("linux/futex.h" HAVE_FUTEX_H)
 299
 300 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 301 CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 302 CHECK_FUNCTION_EXISTS(getdtablesize HAVE_GETDTABLESIZE)
 303 CHECK_FUNCTION_EXISTS(sysconf HAVE_SYSCONF)
 304 CHECK_FUNCTION_EXISTS(popen HAVE_POPEN)
 305 CHECK_FUNCTION_EXISTS(process_vm_readv HAVE_PROCESS_VM_READV)
 306 CHECK_FUNCTION_EXISTS(mmap HAVE_MMAP)
 307
 308 CHECK_SYMBOL_EXISTS(vasprintf stdio.h HAVE_VASPRINTF)
 309 if(MINGW)
 310   # The detection of vasprintf fails on MinGW, assumingly because it's
 311   # defined as an inline function in stdio.h instead of a regular
 312   # function. So force the result to be 1 despite of the test.
 313   set(HAVE_VASPRINTF 1)
 314 endif()
 315
 316 foreach(var
 317   HAVE_VALGRIND_H
 318   HAVE_UNISTD_H
 319   HAVE_EXECINFO_H
 320   HAVE_SIGNAL_H
 321   HAVE_SYS_PARAM_H
 322   HAVE_SYS_SYSCTL_H
 323   HAVE_UCONTEXT_H
 324   HAVE_FUTEX_H
 325   HAVE_GETTIMEOFDAY
 326   HAVE_NANOSLEEP
 327   HAVE_GETDTABLESIZE
 328   HAVE_SYSCONF
 329   HAVE_POPEN
 330   HAVE_PROCESS_VM_READV
 331   HAVE_MMAP
 332   HAVE_VASPRINTF)
 333   if(${var})
 334     set(${var} 1)
 335   else()
 336     set(${var} 0)
 337   endif()
 338 endforeach()
 339
 340 #Check if __thread is defined
 341 execute_process(
 342   COMMAND "${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_thread_storage.c -o testprog"
 343   WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 344   RESULT_VARIABLE HAVE_thread_storage_run)
 345 file(REMOVE testprog)
 346 if(HAVE_thread_storage_run)
 347   set(HAVE_THREAD_LOCAL_STORAGE 1)
 348 else()
 349   set(HAVE_THREAD_LOCAL_STORAGE 0)
 350 endif()
 351
 352 # Our usage of mmap is Linux-specific (flag MAP_ANONYMOUS), but kFreeBSD uses a GNU libc
 353 IF(HAVE_MMAP AND
 354    NOT "${CMAKE_SYSTEM}" MATCHES "Linux" AND
 355    NOT "${CMAKE_SYSTEM}" MATCHES "kFreeBSD" AND
 356    NOT "${CMAKE_SYSTEM}" MATCHES "GNU" AND
 357    NOT  "${CMAKE_SYSTEM}" MATCHES "Darwin")
 358   SET(HAVE_MMAP 0)
 359   message(STATUS "Warning: MMAP is thought as non functional on this architecture (${CMAKE_SYSTEM})")
 360 ENDIF()
 361
 362 if(HAVE_MMAP AND HAVE_THREAD_LOCAL_STORAGE)
 363   SET(HAVE_MMALLOC 1)
 364 else()
 365   SET(HAVE_MMALLOC 0)
 366 endif()
 367
 368 if(enable_jedule)
 369   set(HAVE_JEDULE 1)
 370 else()
 371   set(HAVE_JEDULE 0)
 372 endif()
 373
 374 if(enable_mallocators)
 375   SET(HAVE_MALLOCATOR 1)
 376 else()
 377   SET(HAVE_MALLOCATOR 0)
 378 endif()
 379
 380 if(enable_model-checking AND HAVE_MMALLOC)
 381   SET(HAVE_MC 1)
 382   include(FindLibunwind)
 383   include(FindLibdw)
 384 else()
 385   if(enable_model-checking)
 386     message(STATUS "Warning: support for model-checking has been disabled because you are missing either mmap or __thread.")
 387   endif()
 388   SET(HAVE_MC 0)
 389   SET(HAVE_MMALLOC 0)
 390 endif()
 391
 392 if(enable_smpi)
 393   include(FindGFortran)
 394   SET(HAVE_SMPI 1)
 395   if("${CMAKE_SYSTEM}" MATCHES "Linux")
 396     SET(USE_LIBUTIL 0)
 397     SET(HAVE_PRIVATIZATION 1)
 398   elseif("${CMAKE_SYSTEM}" MATCHES "^FreeBSD")
 399     SET(USE_LIBUTIL 0)
 400     SET(HAVE_PRIVATIZATION 0)
 401   else()
 402     message (STATUS "Warning:  no support for SMPI automatic privatization on this platform")
 403     SET(HAVE_PRIVATIZATION 0)
 404   endif()
 405 else()
 406   SET(HAVE_SMPI 0)
 407 endif()
 408
 409 #--------------------------------------------------------------------------------------------------
 410 ### Check for GNU dynamic linker
 411 CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 412 if (HAVE_DLFCN_H)
 413     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_gnu_dynlinker.c -ldl -o test_gnu_ld
 414       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 415       OUTPUT_VARIABLE HAVE_GNU_LD_compil
 416     )
 417     if(HAVE_GNU_LD_compil)
 418       set(HAVE_GNU_LD 0)
 419       message(STATUS "Warning: test program toward GNU ld failed to compile:")
 420       message(STATUS "${HAVE_GNU_LD_comp_output}")
 421     else()
 422
 423       execute_process(COMMAND ./test_gnu_ld
 424           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 425           RESULT_VARIABLE HAVE_GNU_LD_run
 426           OUTPUT_VARIABLE var_exec
 427       )
 428
 429       if(NOT HAVE_GNU_LD_run)
 430         set(HAVE_GNU_LD 1)
 431         message(STATUS "We are using GNU dynamic linker")
 432       else()
 433         set(HAVE_GNU_LD 0)
 434         message(STATUS "Warning: error while checking for GNU ld:")
 435         message(STATUS "Test output: '${var_exec}'")
 436         message(STATUS "Exit status: ${HAVE_GNU_LD_run}")
 437       endif()
 438       file(REMOVE test_gnu_ld)
 439     endif()
 440 endif()
 441
 442
 443 #--------------------------------------------------------------------------------------------------
 444 ### Initialize of CONTEXT THREADS
 445
 446 set(HAVE_THREAD_CONTEXTS 0)
 447
 448 if(HAVE_PTHREAD)
 449   ### Test that we have a way to create semaphores
 450
 451   if(HAVE_SEM_OPEN_LIB)
 452     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_open.c -lpthread -o sem_open
 453       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 454       OUTPUT_VARIABLE HAVE_SEM_OPEN_compil
 455     )
 456
 457     # Test sem_open by compiling:
 458     if(HAVE_SEM_OPEN_compil)
 459       set(HAVE_SEM_OPEN 0)
 460       message(STATUS "Warning: sem_open not compilable")
 461       message(STATUS "HAVE_SEM_OPEN_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 462     else()
 463       set(HAVE_SEM_OPEN 1)
 464       message(STATUS "sem_open is compilable")
 465     endif()
 466
 467     # If we're not crosscompiling, we check by executing the program:
 468     if (HAVE_SEM_OPEN AND NOT CMAKE_CROSSCOMPILING)
 469       execute_process(COMMAND ./sem_open
 470         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 471         RESULT_VARIABLE HAVE_SEM_OPEN_run
 472         OUTPUT_VARIABLE var_compil
 473       )
 474       if (NOT HAVE_SEM_OPEN_run)
 475         set(HAVE_SEM_OPEN 1)
 476         message(STATUS "sem_open is executable")
 477       else()
 478         set(HAVE_SEM_OPEN 0)
 479         if(EXISTS "${CMAKE_BINARY_DIR}/sem_open")
 480           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open exists!")
 481         else()
 482           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open not exists!")
 483         endif()
 484         message(STATUS "Warning: sem_open not executable")
 485         message(STATUS "Compilation output: '${var_compil}'")
 486         message(STATUS "Exit result of sem_open: ${HAVE_SEM_OPEN_run}")
 487       endif()
 488     endif()
 489     file(REMOVE sem_open)
 490
 491   else()
 492     set(HAVE_SEM_OPEN 0)
 493   endif()
 494
 495   if(HAVE_SEM_INIT_LIB)
 496     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_init.c -lpthread -o sem_init
 497       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 498       RESULT_VARIABLE HAVE_SEM_INIT_run
 499       OUTPUT_VARIABLE HAVE_SEM_INIT_compil)
 500
 501     # Test sem_init by compiling:
 502     if(HAVE_SEM_INIT_compil)
 503       set(HAVE_SEM_INIT 0)
 504       message(STATUS "Warning: sem_init not compilable")
 505       message(STATUS "HAVE_SEM_INIT_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 506     else()
 507       set(HAVE_SEM_INIT 1)
 508       message(STATUS "sem_init is compilable")
 509     endif()
 510
 511     # If we're not crosscompiling, we check by executing the program:
 512     if (HAVE_SEM_INIT AND NOT CMAKE_CROSSCOMPILING)
 513       execute_process(COMMAND ./sem_init
 514         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 515         RESULT_VARIABLE HAVE_SEM_INIT_run
 516         OUTPUT_VARIABLE var_compil
 517       )
 518       if (NOT HAVE_SEM_INIT_run)
 519         set(HAVE_SEM_INIT 1)
 520         message(STATUS "sem_init is executable")
 521       else()
 522         set(HAVE_SEM_INIT 0)
 523         if(EXISTS "${CMAKE_BINARY_DIR}/sem_init")
 524           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init exists!")
 525         else()
 526           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init not exists!")
 527         endif()
 528         message(STATUS "Warning: sem_init not executable")
 529         message(STATUS "Compilation output: '${var_compil}'")
 530         message(STATUS "Exit result of sem_init: ${HAVE_SEM_INIT_run}")
 531       endif()
 532     endif()
 533     file(REMOVE sem_init)
 534   endif()
 535
 536   if(NOT HAVE_SEM_OPEN AND NOT HAVE_SEM_INIT)
 537     message(FATAL_ERROR "Semaphores are not usable (neither sem_open nor sem_init is both compilable and executable), but they are mandatory to threads (you may need to mount /dev).")
 538   endif()
 539
 540   set(HAVE_THREAD_CONTEXTS 1)
 541   message("-- Support for thread context factory ok.")
 542 endif()
 543
 544
 545 set(HAVE_UCONTEXT_CONTEXTS 0)
 546 if(NOT HAVE_UCONTEXT_H)
 547   message("-- No ucontext factory: <ucontext.h> not found.")
 548 elseif(APPLE)
 549   message("-- No ucontext factory: Apple don't want us to use them.")
 550   set(HAVE_UCONTEXT_H 0)
 551 else()
 552   try_compile(compile_makecontext ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_makecontext.c
 553     OUTPUT_VARIABLE compile_makecontext_output)
 554
 555   #If can have both context
 556   if(compile_makecontext)
 557     set(HAVE_UCONTEXT_CONTEXTS 1)
 558     message("-- Support for ucontext factory ok.")
 559   else()
 560     message("-- Error: <ucontext.h> exists, but makecontext is not compilable. Compilation output:\n ${compile_makecontext_output}")
 561     message("-- No ucontext factory: makecontext() is not compilable.")
 562   endif()
 563
 564   # Stack setup (size and address)
 565   try_run(RUN_makecontext_VAR COMPILE_makecontext_VAR
 566     ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stacksetup.c
 567     RUN_OUTPUT_VARIABLE stack_setup)
 568
 569   LIST(LENGTH stack_setup stack_setup_len)
 570   if("${stack_setup_len}" STREQUAL "2")
 571     LIST(GET stack_setup 0 makecontext_addr)
 572     LIST(GET stack_setup 1 makecontext_size)
 573     set(sg_makecontext_stack_addr "#define sg_makecontext_stack_addr(skaddr) (${makecontext_addr})")
 574     set(sg_makecontext_stack_size "#define sg_makecontext_stack_size(sksize) (${makecontext_size})")
 575   else()
 576     message(FATAL_ERROR "Could not figure out the stack setup. Compil: ${RUN_makecontext_VAR}. Exec: ${COMPILE_makecontext_VAR}. Output: ${stack_setup}")
 577   endif()
 578 endif()
 579
 580 # Stack growth direction (upward or downward). Used for the following contexts: SysV, raw, Boost
 581 try_run(RUN_stackgrowth_VAR COMPILE_stackgrowth_VAR
 582   ${CMAKE_BINARY_DIR}
 583   ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stackgrowth.c
 584   RUN_OUTPUT_VARIABLE stack
 585   COPY_FILE test_stackgrowth)
 586
 587 if("${stack}" STREQUAL "down")
 588   set(PTH_STACKGROWTH "-1")
 589 elseif("${stack}" STREQUAL "up")
 590   set(PTH_STACKGROWTH "1")
 591 else()
 592   if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
 593     set(PTH_STACKGROWTH "-1")
 594   elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "i686")
 595     set(PTH_STACKGROWTH "-1")
 596   else()
 597     message(FATAL_ERROR "Could not figure out the stack direction. Test prog returned: ${stack}; CMAKE_SYSTEM_PROCESSOR: ${CMAKE_SYSTEM_PROCESSOR}.")
 598   endif()
 599 endif()
 600 # If the test ran well, remove the test binary
 601 file(REMOVE test_stackgrowth)
 602 #--------------------------------------------------------------------------------------------------
 603
 604 ### check for addr2line
 605 find_path(ADDR2LINE NAMES addr2line     PATHS NO_DEFAULT_PATHS)
 606 if(ADDR2LINE)
 607   set(ADDR2LINE "${ADDR2LINE}/addr2line")
 608 endif()
 609
 610 ###############
 611 ## GIT version check
 612 ##
 613 if(EXISTS ${CMAKE_HOME_DIRECTORY}/.git/)
 614   execute_process(
 615      COMMAND git remote
 616      COMMAND head -n 1
 617      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 618      OUTPUT_VARIABLE remote
 619      OUTPUT_STRIP_TRAILING_WHITESPACE)
 620   #message(STATUS "Git remote: ${remote}")
 621   execute_process(COMMAND git config --get remote.${remote}.url
 622      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 623      OUTPUT_VARIABLE url
 624      OUTPUT_STRIP_TRAILING_WHITESPACE)
 625   #message(STATUS "Git url: ${url}")
 626   if(url)
 627     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=oneline --abbrev-commit -1
 628        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 629        OUTPUT_VARIABLE GIT_VERSION
 630        OUTPUT_STRIP_TRAILING_WHITESPACE)
 631     message(STATUS "Git version: ${GIT_VERSION}")
 632
 633     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log -n 1 --pretty=format:%ai .
 634        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 635        OUTPUT_VARIABLE GIT_DATE
 636        OUTPUT_STRIP_TRAILING_WHITESPACE)
 637     message(STATUS "Git date: ${GIT_DATE}")
 638     string(REGEX REPLACE " .*" "" GIT_VERSION "${GIT_VERSION}")
 639
 640     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=format:%H -1
 641        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 642        OUTPUT_VARIABLE SIMGRID_GITHASH
 643        OUTPUT_STRIP_TRAILING_WHITESPACE)
 644   endif()
 645 elseif(EXISTS ${CMAKE_HOME_DIRECTORY}/.gitversion)
 646   FILE(STRINGS ${CMAKE_HOME_DIRECTORY}/.gitversion GIT_VERSION)
 647 endif()
 648
 649 if(GIT_VERSION)
 650   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} at commit ${GIT_VERSION}")
 651 endif()
 652 if(GIT_DATE)
 653   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} (${GIT_DATE})")
 654 endif()
 655
 656 ### Generate the required headers and scripts
 657 #############################################
 658 # Avoid triggering a (full) rebuild by touching the files if they did not really change
 659 configure_file("${CMAKE_HOME_DIRECTORY}/tools/cmake/src/internal_config.h.in" "${CMAKE_BINARY_DIR}/src/internal_config.h.generated"    @ONLY IMMEDIATE)
 660 configure_file("${CMAKE_HOME_DIRECTORY}/include/simgrid_config.h.in"          "${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated" @ONLY IMMEDIATE)
 661 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/src/internal_config.h.generated ${CMAKE_BINARY_DIR}/src/internal_config.h)
 662 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated ${CMAKE_BINARY_DIR}/include/simgrid_config.h)
 663 file(REMOVE ${CMAKE_BINARY_DIR}/src/internal_config.h.generated)
 664 file(REMOVE ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated)
 665
 666 # We need two versions of the SMPI scripts because they contain the path to the library
 667 # so, it depends of whether SimGrid is installed, or run from the sources (during the build)
 668
 669 file(READ ${CMAKE_HOME_DIRECTORY}/src/smpi/smpitools.sh SMPITOOLS_SH) # Definitions shared amongst all SMPI scripts, inlined in each of them
 670
 671 ### SMPI script used when simgrid is installed
 672 set(exec_prefix ${CMAKE_INSTALL_PREFIX})
 673 set(includeflag "-I${CMAKE_INSTALL_PREFIX}/include -I${CMAKE_INSTALL_PREFIX}/include/smpi")
 674 set(includedir "${CMAKE_INSTALL_PREFIX}/include")
 675 set(libdir ${exec_prefix}/lib)
 676 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_INSTALL_PREFIX}/lib")
 677 if(NS3_LIBRARY_PATH)
 678   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 679 endif()
 680 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 681
 682 configure_file(${CMAKE_HOME_DIRECTORY}/include/smpi/mpif.h.in ${CMAKE_BINARY_DIR}/include/smpi/mpif.h @ONLY)
 683 foreach(script cc cxx ff f90 run)
 684   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/bin/smpi${script} @ONLY)
 685 endforeach()
 686
 687 ### SMPI scripts used when compiling simgrid
 688 set(exec_prefix "${CMAKE_BINARY_DIR}/smpi_script/")
 689 set(includeflag "-I${CMAKE_HOME_DIRECTORY}/include -I${CMAKE_HOME_DIRECTORY}/include/smpi")
 690 set(includeflag "${includeflag} -I${CMAKE_BINARY_DIR}/include -I${CMAKE_BINARY_DIR}/include/smpi")
 691 set(includedir "${CMAKE_HOME_DIRECTORY}/include")
 692 set(libdir "${CMAKE_BINARY_DIR}/lib")
 693 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_BINARY_DIR}/lib")
 694 if(NS3_LIBRARY_PATH)
 695   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 696 endif()
 697 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 698
 699 foreach(script cc cxx ff f90 run)
 700   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script} @ONLY)
 701 endforeach()
 702
 703 if(NOT WIN32)
 704   foreach(script cc cxx ff f90 run)
 705     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpi${script})
 706     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script})
 707   endforeach()
 708 endif()
 709
 710 set(generated_headers_to_install
 711   ${CMAKE_CURRENT_BINARY_DIR}/include/smpi/mpif.h
 712   ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h
 713   )
 714
 715 set(generated_headers
 716   ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h
 717   )
 718
 719 set(generated_files_to_clean
 720   ${generated_headers}
 721   ${generated_headers_to_install}
 722   ${CMAKE_BINARY_DIR}/bin/smpicc
 723   ${CMAKE_BINARY_DIR}/bin/smpicxx
 724   ${CMAKE_BINARY_DIR}/bin/smpiff
 725   ${CMAKE_BINARY_DIR}/bin/smpif90
 726   ${CMAKE_BINARY_DIR}/bin/smpirun
 727   ${CMAKE_BINARY_DIR}/bin/colorize
 728   ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
 729   ${CMAKE_BINARY_DIR}/examples/smpi/tracing/smpi_traced.trace
 730   )
 731
 732 if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_HOME_DIRECTORY}")
 733   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt COPYONLY)
 734   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt COPYONLY)
 735   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allReduce.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt COPYONLY)
 736   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_barrier.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt COPYONLY)
 737   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_bcast.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt COPYONLY)
 738   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_with_isend.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt COPYONLY)
 739   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt COPYONLY)
 740   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoallv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt COPYONLY)
 741   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_waitall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt COPYONLY)
 742   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_reducescatter.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt COPYONLY)
 743   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_gather.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt COPYONLY)
 744   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allgatherv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt COPYONLY)
 745   configure_file(${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/hostfile ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile COPYONLY)
 746
 747   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/description_file ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file COPYONLY)
 748   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/README ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README COPYONLY)
 749   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/smpi_replay.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt COPYONLY)
 750   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt COPYONLY)
 751   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt COPYONLY)
 752   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt COPYONLY)
 753   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt COPYONLY)
 754   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt COPYONLY)
 755   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt COPYONLY)
 756   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt COPYONLY)
 757   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt COPYONLY)
 758   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt COPYONLY)
 759   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt COPYONLY)
 760   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt COPYONLY)
 761   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt COPYONLY)
 762   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt COPYONLY)
 763   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt COPYONLY)
 764   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt COPYONLY)
 765   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt COPYONLY)
 766   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt COPYONLY)
 767   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt COPYONLY)
 768   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt COPYONLY)
 769   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt COPYONLY)
 770   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt COPYONLY)
 771   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt COPYONLY)
 772   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt COPYONLY)
 773   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt COPYONLY)
 774   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt COPYONLY)
 775   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt COPYONLY)
 776   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt COPYONLY)
 777   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt COPYONLY)
 778   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt COPYONLY)
 779   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt COPYONLY)
 780   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt COPYONLY)
 781   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt COPYONLY)
 782
 783   set(generated_files_to_clean
 784     ${generated_files_to_clean}
 785     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt
 786     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt
 787     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt
 788     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt
 789     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt
 790     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt
 791     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt
 792     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt
 793     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt
 794     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt
 795     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt
 796     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt
 797     ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile
 798     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file
 799     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README
 800     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt
 801     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt
 802     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt
 803     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt
 804     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt
 805     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt
 806     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt
 807     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt
 808     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt
 809     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt
 810     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt
 811     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt
 812     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt
 813     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt
 814     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt
 815     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt
 816     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt
 817     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt
 818     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt
 819     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt
 820     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt
 821     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt
 822     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt
 823     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt
 824     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt
 825     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt
 826     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt
 827     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt
 828     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt
 829     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt
 830     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt
 831     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt
 832     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt
 833     )
 834 endif()
 835
 836 SET_DIRECTORY_PROPERTIES(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES
 837   "${generated_files_to_clean}")
 838
 839 ### Define source packages for Libs
 840 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/DefinePackages.cmake)
 841
 842 ### Build some Maintainer files
 843 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MaintainerMode.cmake)
 844 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/UnitTesting.cmake)
 845
 846 ### Setup gcc & clang flags
 847 if (NOT MSVC)
 848   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/GCCFlags.cmake)
 849 endif()
 850
 851 ### Make Libs
 852 if(NOT WIN32)
 853   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLib.cmake)
 854 else()
 855   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLibWin.cmake)
 856 endif()
 857
 858 if(enable_java)
 859   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Java.cmake)
 860 endif()
 861
 862 ### Make tests
 863 if(enable_memcheck_xml)
 864   set(enable_memcheck true)
 865 endif()
 866
 867 INCLUDE(CTest)
 868 ENABLE_TESTING()
 869 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Tests.cmake)
 870 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/CTestConfig.cmake)
 871
 872 ### Define subdirectories
 873 foreach(cmakefile ${CMAKEFILES_TXT})
 874   string(REPLACE "/CMakeLists.txt" "" repository ${cmakefile})
 875   add_subdirectory("${CMAKE_HOME_DIRECTORY}/${repository}")
 876 endforeach()
 877
 878 ### Setup the distrib
 879 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Distrib.cmake)
 880
 881 ### Build the doc (Windows downloads the doc instead of regenerating)
 882 #
 883 if(NOT WIN32)
 884   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Documentation.cmake)
 885 else()
 886   find_program(WGET_PROGRAM  NAMES wget)
 887   message(STATUS "wget: ${WGET_PROGRAM}")
 888   if(WGET_PROGRAM)
 889     ADD_CUSTOM_TARGET(documentation
 890       COMMENT "Downloading the SimGrid documentation..."
 891       COMMAND ${WGET_PROGRAM} -r -np -nH -nd http://simgrid.gforge.inria.fr/simgrid/${release_version}/doc/
 892       WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html
 893     )
 894   endif()
 895 endif()
 896
 897 ### Print the result of configuration
 898 message("")
 899 message("##########################################")
 900 message("#### Content of src/internal_config.h ####")
 901 message("##########################################")
 902 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h config_output)
 903 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8) # Pass the file header
 904 foreach(line ${config_output})
 905   message("   ${line}")
 906 endforeach()
 907 message("##########################################")
 908 message("####   Content of simgrid_config.h    ####")
 909 message("##########################################")
 910 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h config_output)
 911 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8 9 -1) # Pass the file header
 912 foreach(line ${config_output})
 913   message("   ${line}")
 914 endforeach()
 915 message("##########################################")
 916 message("####   End of configuration headers   ####")
 917 message("##########################################")
 918
 919 message("\nConfiguration of package `simgrid':")
 920 message("        Home directory ..............: ${CMAKE_HOME_DIRECTORY}")
 921 message("        Build Name ..................: ${BUILDNAME}")
 922 message("        Cmake Generator .............: ${CMAKE_GENERATOR}")
 923 message("        Site ........................: ${SITE}")
 924 message("        Install prefix ..............: ${CMAKE_INSTALL_PREFIX}")
 925 if(release)
 926   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (release build)")
 927 else()
 928   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (development build)")
 929 endif()
 930 message("")
 931 message("        Compiler: C .................: ${CMAKE_C_COMPILER} (id: ${CMAKE_C_COMPILER_ID})")
 932 message("                version .............: ${CMAKE_C_COMPILER_VERSION}")
 933 message("                is gnu ..............: ${CMAKE_COMPILER_IS_GNUCC}")
 934 message("        Compiler: C++ ...............: ${CMAKE_CXX_COMPILER} (id: ${CMAKE_CXX_COMPILER_ID})")
 935 message("                version .............: ${CMAKE_CXX_COMPILER_VERSION}")
 936 if(${Java_FOUND})
 937   message("        Compiler: Javac .............: ${Java_JAVAC_EXECUTABLE}")
 938   message("                version .............: ${Java_VERSION_STRING}")
 939 if(${SWIG_FOUND})
 940   message("                SWIG ................: Version ${SWIG_VERSION} found.")
 941 else()
 942   message("                SWIG ................: Missing.")
 943 endif()
 944 endif()
 945 if(CMAKE_Fortran_COMPILER)
 946   message("        Compiler: Fortran ...........: ${CMAKE_Fortran_COMPILER} (id: ${CMAKE_Fortran_COMPILER_ID})")
 947   message("                version .............: ${CMAKE_Fortran_COMPILER_VERSION}")
 948 endif()
 949 message("        Linker: .....................: ${CMAKE_LINKER}")
 950 message("                version .............: ${LINKER_VERSION}")
 951 message("        Make program: ...............: ${CMAKE_MAKE_PROGRAM}")
 952 message("")
 953 message("        CFlags ......................: ${CMAKE_C_FLAGS}")
 954 message("        CXXFlags ....................: ${CMAKE_CXX_FLAGS}")
 955 message("        LDFlags .....................: ${CMAKE_C_LINK_FLAGS}")
 956 message("        with LTO ....................: ${enable_lto}")
 957 message("")
 958
 959 if (HAVE_NS3)
 960   message("        Compile NS-3 ................: yes (path: ${NS3_PATH})")
 961 else()
 962   message("        Compile NS-3 ................: NO  (hint: ${NS3_HINT})")
 963 endif()
 964
 965 if (${Java_FOUND})
 966   message("        Compile Java ................: yes")
 967   message("          Native lib in jar .........: ${enable_lib_in_jar}")
 968 else()
 969   message("        Compile Java ................: NO")
 970 endif()
 971 message("        Compile Lua .................: ${HAVE_LUA}")
 972 message("        Compile Smpi ................: ${HAVE_SMPI}")
 973 message("          Smpi fortran ..............: ${SMPI_FORTRAN}")
 974 message("          MPICH3 testsuite ..........: ${enable_smpi_MPICH3_testsuite}")
 975 message("          Privatization .............: ${HAVE_PRIVATIZATION}")
 976 message("        Compile Boost.Context support: ${HAVE_BOOST_CONTEXTS}")
 977 message("")
 978 message("        Maintainer mode .............: ${enable_maintainer_mode}")
 979 message("        Documentation................: ${enable_documentation}")
 980 message("        Model checking ..............: ${HAVE_MC}")
 981 message("        Jedule  mode ................: ${HAVE_JEDULE}")
 982 message("        Graphviz mode ...............: ${HAVE_GRAPHVIZ}")
 983 message("        Sigc++ mode .................: ${SIMGRID_HAVE_LIBSIG}")
 984 message("        Mallocators .................: ${enable_mallocators}")
 985 message("")
 986 message("        Simgrid dependencies ........: ${SIMGRID_DEP}")
 987 message("")
 988
 989 execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_BINARY_DIR}/Testing/Notes/)
 990 file(WRITE ${PROJECT_BINARY_DIR}/Testing/Notes/Build  "GIT version : ${GIT_VERSION}\n")
 991 file(APPEND ${PROJECT_BINARY_DIR}/Testing/Notes/Build "Release     : simgrid-${release_version}\n")
 992
 993 INCLUDE(Dart)