buildtools/Cmake/MakeJava.cmake

   1 cmake_minimum_required(VERSION 2.8.6)
   2
   3 include(UseJava)
   4
   5 # Rules to build libsimgrid-java
   6 #
   7 add_library(simgrid-java SHARED ${JMSG_C_SRC})
   8 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
   9 if (CMAKE_VERSION VERSION_LESS "2.8.8")
  10   include_directories(${JNI_INCLUDE_DIRS})
  11
  12   message(WARNING "[Java] Try to workaround missing feature in older CMake.  You should better update CMake to version 2.8.8 or above.")
  13   get_directory_property(CHECK_INCLUDES INCLUDE_DIRECTORIES)
  14 else()
  15   get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  16   if (COMMON_INCLUDES)
  17     set_target_properties(simgrid-java PROPERTIES
  18       INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  19   else()
  20     set_target_properties(simgrid-java PROPERTIES
  21       INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  22   endif()
  23   add_dependencies(simgrid-java simgrid)
  24
  25   get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  26 endif()
  27 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  28
  29 target_link_libraries(simgrid-java simgrid)
  30
  31
  32
  33
  34 if(WIN32)
  35   exec_program("java -d32 -version"
  36                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  37   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  38   if(${POSITION} GREATER -1)
  39     message(FATAL_ERROR "Java JVM needs to be 32 bits to be able to run with Simgrid on Windows for now")
  40   endif()
  41
  42   set_target_properties(simgrid-java PROPERTIES
  43     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at"
  44     PREFIX "")
  45   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  46   message(STATUS "pexports: ${PEXPORTS_PATH}")
  47   if(PEXPORTS_PATH)
  48     add_custom_command(TARGET simgrid-java POST_BUILD
  49       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/simgrid-java.dll > ${CMAKE_BINARY_DIR}/lib/simgrid-java.def)
  50   endif(PEXPORTS_PATH)
  51 endif()
  52
  53 # Rules to build simgrid.jar
  54 #
  55
  56 ## Files to include in simgrid.jar
  57 ##
  58 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  59 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  60 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  61
  62
  63 set(LIBSIMGRID_SO
  64   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  65 set(LIBSIMGRID_JAVA_SO
  66   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  67
  68 ## Name of the "NATIVE" folder in simgrid.jar
  69 ##
  70 if(CMAKE_SYSTEM_PROCESSOR MATCHES ".86")
  71   if(${ARCH_32_BITS})
  72     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/i386/")
  73   else()
  74     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/amd64/")
  75   endif()
  76 else()
  77   message(WARNING "Unknown system type. Processor: ${CMAKE_SYSTEM_PROCESSOR}; System: ${CMAKE_SYSTEM_NAME}")
  78   set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR}/")
  79 endif()
  80 message("-- [Java] Native libraries bundled into: ${JSG_BUNDLE}")
  81
  82 ## Don't strip libraries if not in release mode
  83 ##
  84 if(release)
  85   set(STRIP_COMMAND "${CMAKE_STRIP}")
  86 else()
  87   set(STRIP_COMMAND "true")
  88 endif()
  89
  90 ## Here is how to build simgrid.jar
  91 ##
  92 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  93   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  94   add_jar(simgrid-java_pre_jar ${JMSG_JAVA_SRC})
  95 else()
  96   add_jar(simgrid-java_pre_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  97 endif()
  98
  99 add_custom_command(
 100   COMMENT "Finalize simgrid.jar..."
 101   OUTPUT ${SIMGRID_JAR}_finalized
 102   DEPENDS simgrid simgrid-java simgrid-java_pre_jar
 103           ${SIMGRID_JAR} ${MANIFEST_IN_FILE}
 104           ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 105           ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 106           ${CMAKE_HOME_DIRECTORY}/COPYING
 107           ${CMAKE_HOME_DIRECTORY}/ChangeLog
 108           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
 109           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
 110   COMMAND ${CMAKE_COMMAND} -E remove_directory "NATIVE"
 111   COMMAND ${CMAKE_COMMAND} -E make_directory "${JSG_BUNDLE}"
 112   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}" "${JSG_BUNDLE}"
 113   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSIMGRID_SO}"
 114   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}" "${JSG_BUNDLE}"
 115   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSIMGRID_JAVA_SO}"
 116   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/COPYING" "${JSG_BUNDLE}"
 117   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog" "${JSG_BUNDLE}"
 118   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java" "${JSG_BUNDLE}"
 119   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1" "${JSG_BUNDLE}"
 120   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
 121   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
 122   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
 123   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} "NATIVE"
 124   COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
 125   COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
 126   )
 127 add_custom_target(simgrid-java_jar ALL DEPENDS ${SIMGRID_JAR}_finalized)