configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22
  23 AC_SUBST(ac_configure_args)
  24 ###############
  25 ## System checks
  26 ##
  27 SG_CONFIGURE_PART(System checks...)
  28 AC_PROG_CC(xlC gcc cc)
  29 AM_SANITY_CHECK
  30 AC_PROG_MAKE_SET
  31 AC_CHECK_PRINTF_NULL
  32 AC_CHECK_VA_COPY
  33
  34 # Checks for header files.
  35 AC_HEADER_STDC
  36 AC_HEADER_TIME
  37 AC_CHECK_HEADERS([sys/socket.h \
  38                   sys/stat.h \
  39                   windows.h winsock.h winsock2.h \
  40                   sys/time.h \
  41                   errno.h unistd.h \
  42                   execinfo.h\
  43                   signal.h ])
  44 AC_CHECK_FUNCS([gettimeofday usleep \
  45                 getdtablesize \
  46                 sysconf\
  47                 readv\
  48                 popen\
  49                 signal])
  50
  51 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  52 AC_FUNC_SNPRINTF
  53 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  54 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  55 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  56 # we don't use those:
  57 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
  58 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
  59
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_C_INLINE
  64 AC_TYPE_SIZE_T
  65
  66 ###################################
  67 ## SimGrid and GRAS specific checks
  68 ##
  69
  70 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  71 # Check architecture signature begin
  72 GRAS_ARCH
  73 # Check architecture signature end
  74 GRAS_CHECK_STRUCT_COMPACTION
  75
  76
  77 dnl ##
  78 dnl ##  CONTEXT IMPLEMENTATION
  79 dnl ##
  80
  81 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  82
  83 dnl #
  84 dnl #  1. determine possibilities
  85 dnl #
  86
  87 dnl #  check for MCSC method
  88 AC_MSG_CHECKING(on top of what can we build the contexts)
  89 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
  90 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
  91 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  92
  93 dnl #  check for pthread method
  94 AC_CHECK_HEADERS([pthread.h])
  95 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  96
  97 dnl #
  98 dnl #  2. make a general decision
  99 dnl #
 100
 101 if test ".$mcsc" = .yes; then
 102    mcsc=yes
 103 elif test ".$pthread" = .yes; then
 104    pthread=yes
 105 else
 106     ac_header=windows.h
 107     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 108     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 109       windows_context=yes
 110     else
 111       AC_ERROR([no appropriate backend found])
 112     fi
 113 fi
 114
 115 dnl #
 116 dnl #  3. allow decision to be overridden by user
 117 dnl #
 118
 119 AC_MSG_CHECKING(what kind of backend should we use)
 120
 121 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126 case $with_context in
 127  ucontext) ;;
 128  pthread) ;;
 129  windows) ;;
 130  auto) with_context=ucontext;;
 131  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
 132 esac
 133
 134 if test "x$with_context" = "xucontext" ; then
 135   if test ".$mcsc" = .yes; then
 136     AC_MSG_RESULT(found working ucontext. Great!)
 137     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 138   else
 139     if test ".$windows_context" = .yes ; then
 140       AC_MSG_RESULT(use windows context portability layer.)
 141       with_context=windows
 142     else
 143       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 144       with_context=pthread
 145     fi
 146   fi
 147 fi
 148
 149 if test "x$with_context" = "xpthread"; then
 150   AC_CHECK_HEADERS([pthread.h])
 151   AC_CHECK_LIB(pthread,pthread_create,,
 152     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
 153   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 154   AC_MSG_RESULT(You have pthreads. Let's use them.)
 155 fi
 156
 157 dnl #
 158 dnl #  4. determine a few additional details
 159 dnl #
 160
 161 if test "x$with_context" = "xucontext" ; then
 162 dnl #  direction of stack grow
 163   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 164   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 165       PTH_STACK_GROWTH="down"
 166   else
 167       PTH_STACK_GROWTH="up"
 168   fi
 169   AC_SUBST(PTH_STACK_GROWTH)
 170
 171   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 172 fi
 173
 174 #########################################
 175 ## Check for libraries extra-dependencies
 176 ##
 177
 178 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 179 SIMGRID_DEP=""
 180 AC_SUBST([SIMGRID_DEP])
 181
 182 GRAS_DEP=""
 183 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 184 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 185
 186 AC_MSG_CHECKING(for extra dependencies of libgras)
 187 case $host_os in
 188   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
 189 esac
 190
 191 if test "x$GRAS_DEP" = x; then
 192    AC_MSG_RESULT(none)
 193 else
 194    AC_MSG_RESULT($GRAS_DEP)
 195 fi
 196 AC_SUBST([GRAS_DEP])
 197
 198 ##############################################
 199 ## Enhance maintainer mode and SUBST variables
 200 ## (must be placed after any compilation tests since our overprotective flags
 201 ##  let some tests fail)
 202
 203 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 204 # Next line is modified by sed when building gramine source tree
 205 gramine_mode=no
 206 if test x$gramine_mode = xyes
 207 then
 208   USE_MAINTAINER_MODE=no
 209 fi
 210 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 211
 212
 213 AM_MAINTAINER_MODE
 214 if test x$USE_MAINTAINER_MODE = xyes
 215 then
 216    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 217    enable_compile_warnings=yes
 218 fi
 219 SG_COMPILE_FLAGS
 220
 221 AC_SUBST(CFLAGS)
 222 AC_SUBST(CPPFLAGS)
 223 AC_SUBST(LDFLAGS)
 224 AC_SUBST([abs_builddir])
 225 AC_SUBST([abs_srcdir])
 226 AC_SUBST([abs_top_builddir])
 227 AC_SUBST([abs_top_srcdir])
 228
 229 #####################
 230 ## Check for programs
 231 ##
 232
 233 SG_CONFIGURE_PART(Check for programs...)
 234 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 235 WARNING="This file is generated, do not edit"
 236 AC_SUBST(WARNING)
 237
 238
 239 # Can we rebuild the parsers?
 240 # We really want flex and refuse other lex. So, the parser is portable and
 241 # does not induce extra lib dependency
 242 AC_PROG_FLEX(2.5.30)
 243
 244 # Can we rebuild the xml-lexers from the XML specification?
 245 # if not, simply touch the flex source files (which are distributed in
 246 #  tarballs even if generated by flexml) and hope for the best.
 247 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 248 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 249
 250 if test x$USE_MAINTAINER_MODE = xyes
 251 then
 252    # Check for doxygen when in maintainer mode since dist* targets fail
 253    # without it
 254    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 255    if test x$DOXYGEN = x ; then
 256      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 257    fi
 258 fi
 259
 260 # Can we extract really usable backtraces? (also need the popen function)
 261 AC_PATH_PROG(ADDR2LINE, addr2line)
 262 if test x$ADDR2LINE != x ; then
 263   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 264 fi
 265
 266 ###################
 267 ## Makes the output
 268 ##
 269
 270
 271 #
 272 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 273 #  src/amok/Makefile
 274
 275 SG_CONFIGURE_PART(Generating files...)
 276
 277 # Core of the libraries
 278
 279 AC_CONFIG_FILES([
 280   Makefile
 281   include/Makefile
 282   src/Makefile
 283   src/ucontext_stack.h
 284 ])
 285
 286 # GRAMINE_CUT_BEGIN
 287
 288 # Testsuite
 289
 290 AC_CONFIG_FILES([
 291   testsuite/Makefile
 292   testsuite/run_tests
 293   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 294 ],[
 295     for file in                                                 \
 296      testsuite/run_tests                                        \
 297      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 298     ; do                                                        \
 299       test -e $file && chmod +x $file;                          \
 300     done
 301 ])
 302
 303 # Examples, documentation and tools
 304
 305 AC_CONFIG_FILES([
 306   examples/Makefile
 307     examples/msg/Makefile           examples/msg/run_msg_test
 308     examples/simdag/Makefile        examples/simdag/test_simdag
 309     examples/gras/Makefile
 310       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 311       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 312       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 313       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 314       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 315       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 316       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 317       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 318
 319       examples/gras/p2p/Makefile
 320       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 321       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 322
 323     examples/amok/Makefile
 324       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 325       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 326   doc/Makefile
 327     doc/Doxyfile
 328   tools/graspe-slave            tools/Makefile
 329     tools/gras/Makefile
 330 ],[
 331     for file in                                                 \
 332      tools/graspe-slave           tools/graspe-master           \
 333      \
 334      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 335      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 336      \
 337      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 338      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 339      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 340      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 341      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 342      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 343      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 344      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 345      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 346      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 347      examples/msg/run_msg_test                                  \
 348      examples/simdag/test_simdag                                \
 349     ; do                                                        \
 350       test -e $file && chmod +x $file;                          \
 351     done
 352 ])
 353
 354
 355 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 356 #    examples/gras/pastry/test_sg
 357
 358
 359
 360 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 361 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 362
 363
 364 # GRAMINE_CUT_END
 365
 366 AC_OUTPUT
 367
 368 echo "
 369
 370 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 371
 372         Compiler:        ${CC} (version: ${GCC_VERSION})
 373
 374         CFlags:          ${CFLAGS}
 375         CPPFlags:        ${CPPFLAGS}
 376         LDFlags:         ${LDFLAGS}
 377
 378         Context backend: ${with_context}
 379 "
 380
 381 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 382   echo "WARNING:"
 383   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 384   echo "WARNING: This is not really supported, so you should configure SimGrid like:"
 385   echo "WARNING:"
 386   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 387   echo "WARNING:"
 388 fi
 389
 390 exit 0;