buildtools/Cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/shared/doxygen/)
   7 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/)
   8
   9 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/"
  10   DESTINATION "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/ref_guide/html/"
  11   PATTERN ".svn" EXCLUDE
  12   PATTERN ".git" EXCLUDE
  13   PATTERN "*.o" EXCLUDE
  14   PATTERN "*~" EXCLUDE
  15   )
  16
  17 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/user_guide/html/"
  18   DESTINATION "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/user_guide/html/"
  19   PATTERN ".svn" EXCLUDE
  20   PATTERN ".git" EXCLUDE
  21   PATTERN "*.o" EXCLUDE
  22   PATTERN "*~" EXCLUDE
  23   )
  24
  25 #### Generate the manpages
  26 if(NOT WIN32)
  27   if( NOT MANPAGE_DIR)
  28     set( MANPAGE_DIR ${CMAKE_BINARY_DIR}/manpages )
  29   endif()
  30
  31   add_custom_target(manpages ALL
  32     COMMAND ${CMAKE_COMMAND} -E make_directory ${MANPAGE_DIR}
  33     COMMAND pod2man ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl > ${MANPAGE_DIR}/simgrid_update_xml.1
  34     COMMENT "Generating manpages"
  35     )
  36   install(FILES ${MANPAGE_DIR}/simgrid_update_xml.1 ${CMAKE_HOME_DIRECTORY}/tools/tesh/tesh.1
  37     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/man/man1)
  38
  39 endif()
  40
  41 # binaries
  42 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/smpicc
  43   ${CMAKE_BINARY_DIR}/bin/smpif2c
  44   ${CMAKE_BINARY_DIR}/bin/smpiff
  45   ${CMAKE_BINARY_DIR}/bin/smpif90
  46   ${CMAKE_BINARY_DIR}/bin/smpirun
  47   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  48
  49 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  50   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  51
  52 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  53   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  54
  55 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  56   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  57   RENAME simgrid-colorizer)
  58
  59 add_custom_target(simgrid-colorizer ALL
  60   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  61   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  62   )
  63
  64 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  65   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  66   RENAME simgrid_update_xml)
  67
  68 add_custom_target(simgrid_update_xml ALL
  69   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  70   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  71   )
  72
  73 # libraries
  74 install(TARGETS simgrid
  75   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  76
  77 if(enable_smpi)
  78   install(TARGETS smpi
  79     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  80 endif()
  81
  82 if(enable_lib_static AND NOT WIN32)
  83   install(TARGETS simgrid_static
  84     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  85   if(enable_smpi)
  86     install(TARGETS smpi_static
  87       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  88   endif()
  89 endif()
  90
  91 # include files
  92 set(HEADERS
  93   ${headers_to_install}
  94   ${generated_headers_to_install}
  95   )
  96 foreach(file ${HEADERS})
  97   get_filename_component(location ${file} PATH)
  98   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  99   install(FILES ${file}
 100     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
 101 endforeach(file ${HEADERS})
 102
 103 # example files
 104 foreach(file ${examples_to_install})
 105   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
 106   get_filename_component(location ${file} PATH)
 107   install(FILES "examples/${file}"
 108     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
 109 endforeach(file ${examples_to_install})
 110
 111 # bindings cruft
 112
 113 if(HAVE_LUA)
 114   file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
 115   add_custom_target(simgrid_lua ALL
 116     DEPENDS simgrid
 117     ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 118     )
 119   add_custom_command(
 120     OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 121     COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 122     )
 123   install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 124     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 125     )
 126 endif()
 127
 128 ###########################################
 129 ### Fill in the "make uninstall" target ###
 130 ###########################################
 131
 132 add_custom_target(uninstall
 133   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 134   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
 135   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 136   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsmpi*
 137   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
 138   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
 139   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 140   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif2c
 141   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 142   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
 143   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 144   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 145   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 146   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 147   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 148   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 149   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 150   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 151   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 152   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 153   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 154   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 155   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 156   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 157   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 158   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 159   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 160   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 161   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 162     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 163   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 164   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 165   )
 166
 167 if(HAVE_LUA)
 168   add_custom_command(TARGET uninstall
 169     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 170     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 171     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 172     )
 173 endif()
 174
 175 ################################################################
 176 ## Build a sain "make dist" target to build a source package ###
 177 ##   containing only the files that I explicitely state      ###
 178 ##   (instead of any cruft laying on my disk as CPack does)  ###
 179 ################################################################
 180
 181 # This is the complete list of what will be added to the source archive
 182 set(source_to_pack
 183   ${headers_to_install}
 184   ${source_of_generated_headers}
 185   ${BINDINGS_SRC}
 186   ${GTNETS_SRC}
 187   ${JEDULE_SRC}
 188   ${LUA_SRC}
 189   ${MC_SRC}
 190   ${MSG_SRC}
 191   ${NS3_SRC}
 192   ${RNGSTREAM_SRC}
 193   ${SIMDAG_SRC}
 194   ${SIMIX_SRC}
 195   ${SMPI_SRC}
 196   ${SURF_SRC}
 197   ${TRACING_SRC}
 198   ${XBT_RL_SRC}
 199   ${XBT_SRC}
 200   ${EXTRA_DIST}
 201   ${CMAKE_SOURCE_FILES}
 202   ${EXAMPLES_CMAKEFILES_TXT}
 203   ${TESHSUITE_CMAKEFILES_TXT}
 204   ${TESTSUITE_CMAKEFILES_TXT}
 205   ${TOOLS_CMAKEFILES_TXT}
 206   ${DOC_FIGS}
 207   ${DOC_IMG}
 208   ${DOC_SOURCES}
 209   ${DOC_TOOLS}
 210   ${PLATFORMS_EXAMPLES}
 211   ${README_files}
 212   ${bin_files}
 213   ${examples_src}
 214   ${tesh_files}
 215   ${teshsuite_src}
 216   ${testsuite_src}
 217   ${tools_src}
 218   ${txt_files}
 219   ${xml_files}
 220   )
 221
 222 ##########################################
 223 ### Fill in the "make dist-dir" target ###
 224 ##########################################
 225
 226 add_custom_target(dist-dir
 227   COMMENT "Generating the distribution directory"
 228   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 229   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 230   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 231   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/user_guide/html/
 232   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/ref_guide/html/
 233   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/user_guide/html/ ${PROJECT_NAME}-${release_version}/doc/user_guide/html/
 234   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/ ${PROJECT_NAME}-${release_version}/doc/ref_guide/html/
 235   )
 236 add_dependencies(dist-dir simgrid_documentation)
 237 add_dependencies(dist-dir maintainer_files)
 238
 239 set(dirs_in_tarball "")
 240 foreach(file ${source_to_pack})
 241   #message(${file})
 242   # This damn prefix is still set somewhere (seems to be in subdirs)
 243   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 244
 245   # Create the directory on need
 246   get_filename_component(file_location ${file} PATH)
 247   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 248   if(NOT OPERATION)
 249     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 250     add_custom_command(
 251       TARGET dist-dir
 252       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 253       )
 254   endif()
 255
 256   # Actually copy the file
 257   add_custom_command(
 258     TARGET dist-dir
 259     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}/
 260     )
 261 endforeach(file ${source_to_pack})
 262
 263 add_custom_command(
 264   TARGET dist-dir
 265   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 266   )
 267
 268 ######################################
 269 ### Fill in the "make dist" target ###
 270 ######################################
 271
 272 add_custom_target(dist
 273   COMMENT "Removing the distribution directory"
 274   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 275   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 276   )
 277
 278 add_custom_command(
 279   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 280   COMMENT "Compressing the archive from the distribution directory"
 281   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 282   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 283   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 284   )
 285 add_dependencies(dist dist-dir)
 286
 287 if(NOT enable_maintainer_mode)
 288   add_custom_target(echo-dist
 289     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 290     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 291     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 292     )
 293   add_dependencies(dist echo-dist)
 294 endif()
 295
 296 ###########################################
 297 ### Fill in the "make distcheck" target ###
 298 ###########################################
 299
 300 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 301
 302 # Allow to test the "make dist"
 303 add_custom_target(distcheck
 304   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 305   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 306
 307   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 308   COMMAND ${CMAKE_COMMAND} -E tar  xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 309
 310   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 311   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 312   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 313
 314   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 315   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 316   ${CMAKE_COMMAND}
 317   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 318   -Denable_lua=ON
 319   -Denable_model-checking=ON
 320   ..
 321   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 322   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 323
 324   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 325   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest || true
 326
 327   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 328   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 329   COMMAND ${CMAKE_COMMAND} -E create_symlink
 330   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 331   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 332
 333   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 334   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 335   )
 336 #add_dependencies(distcheck dist)
 337
 338 #######################################
 339 ### Fill in the "make check" target ###
 340 #######################################
 341
 342 if(enable_memcheck)
 343   add_custom_target(check
 344     COMMAND ctest -D ExperimentalMemCheck
 345     )
 346 else()
 347   add_custom_target(check
 348     COMMAND make test
 349     )
 350 endif()
 351
 352 #######################################
 353 ### Fill in the "make xxx-clean" target ###
 354 #######################################
 355
 356 add_custom_target(maintainer-clean
 357   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 358   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 359   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 360   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 361   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 362   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 363   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 364   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 365   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 366   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 367   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 368   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 369   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 370   )
 371
 372 add_custom_target(supernovae-clean
 373   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_sg.c
 374   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_smpi.c
 375   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 376   )
 377
 378
 379 include(CPack)