Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
A few more tiers file and a convenient perl script for the alnem project. I
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.0.2-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15
16 AM_INIT_AUTOMAKE(gnu)
17 AC_CONFIG_MACRO_DIR(acmacro) 
18 ACLOCAL="$ACLOCAL -I acmacro"
19 AC_PROG_LIBTOOL
20
21 ###############
22 ## System checks
23 ##
24 SG_CONFIGURE_PART(System checks...)
25 AC_PROG_CC(xlC gcc cc)
26 AM_SANITY_CHECK
27 AC_PROG_MAKE_SET
28 AC_CHECK_PRINTF_NULL
29 AC_CHECK_VA_COPY
30
31 # Checks for header files.
32 AC_HEADER_STDC
33 AC_HEADER_TIME
34 AC_CHECK_HEADERS([sys/socket.h \
35                   sys/stat.h \
36                   windows.h winsock.h winsock2.h \
37                   sys/time.h \
38                   errno.h unistd.h \
39                   execinfo.h])
40 AC_CHECK_FUNCS([gettimeofday usleep \
41                 getdtablesize \
42                 sysconf\
43                 readv\
44                 popen])
45                 
46 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
47 AC_FUNC_SNPRINTF
48 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
49 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
50 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
51 # we don't use those:
52 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
53 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
54
55
56 # Checks for typedefs, structures, and compiler characteristics.
57 AC_C_CONST
58 AC_C_INLINE
59 AC_TYPE_SIZE_T
60
61 ###################################
62 ## SimGrid and GRAS specific checks
63 ##
64
65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
66 # Check architecture signature begin
67 GRAS_ARCH
68 # Check architecture signature end
69 GRAS_CHECK_STRUCT_COMPACTION
70
71
72 dnl ##
73 dnl ##  CONTEXT IMPLEMENTATION
74 dnl ##
75
76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
77
78 dnl #
79 dnl #  1. determine possibilities
80 dnl #
81
82 dnl #  check for MCSC method
83 AC_MSG_CHECKING(on top of what can we build the contexts)
84 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
85 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
86 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
87
88 dnl #  check for pthread method
89 AC_CHECK_HEADERS([pthread.h])
90 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
91
92 dnl #
93 dnl #  2. make a general decision
94 dnl #
95
96 if test ".$mcsc" = .yes; then
97    mcsc=yes
98 elif test ".$pthread" = .yes; then
99    pthread=yes
100 else
101     ac_header=windows.h
102     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
103     if test `eval echo '${'$as_ac_Header'}'` = yes; then
104       windows_context=yes
105     else
106       AC_ERROR([no appropriate backend found])
107     fi
108 fi
109
110 dnl #
111 dnl #  3. allow decision to be overridden by user
112 dnl #
113
114 AC_MSG_CHECKING(what kind of backend should we use)
115 AC_ARG_WITH(context,
116   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
117   with_context=auto)
118 case $with_context in
119  ucontext) ;;
120  pthread) ;;
121  windows) ;;
122  auto) with_context=ucontext;;
123  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
124 esac
125
126 if test "x$with_context" = "xucontext" ; then
127   if test ".$mcsc" = .yes; then
128     AC_MSG_RESULT(found working ucontext. Great!)
129     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
130   else
131     if test ".$windows_context" = .yes ; then
132       AC_MSG_RESULT(use windows context portability layer.)
133       with_context=windows
134     else
135       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
136       with_context=pthread
137     fi
138   fi
139 fi
140
141 if test "x$with_context" = "xpthread"; then
142   AC_CHECK_HEADERS([pthread.h])
143   AC_CHECK_LIB(pthread,pthread_create,,
144     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
145   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
146   AC_MSG_RESULT(You have pthreads. Let's use them.)
147 fi
148
149 dnl #
150 dnl #  4. determine a few additional details
151 dnl #
152
153 if test "x$with_context" = "xucontext" ; then
154 dnl #  direction of stack grow
155   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
156   if test ".$ac_cv_check_stackgrowth" = ".down"; then
157       PTH_STACK_GROWTH="down"
158   else
159       PTH_STACK_GROWTH="up"
160   fi
161   AC_SUBST(PTH_STACK_GROWTH)
162   
163   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
164 fi
165
166 #########################################
167 ## Check for libraries extra-dependencies
168 ##
169
170 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
171 SIMGRID_DEP=""
172 AC_SUBST([SIMGRID_DEP])
173
174 GRAS_DEP=""
175 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
176 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
177
178 AC_MSG_CHECKING(for extra dependencies of libgras)
179 case $host_os in
180   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
181 esac
182            
183 if test "x$GRAS_DEP" = x; then 
184    AC_MSG_RESULT(none)
185 else
186    AC_MSG_RESULT($GRAS_DEP)
187 fi
188 AC_SUBST([GRAS_DEP])
189
190 ##############################################
191 ## Enhance maintainer mode and SUBST variables
192 ## (must be placed after any compilation tests since our overprotective flags
193 ##  let some tests fail)
194
195 AM_MAINTAINER_MODE
196 if test x$USE_MAINTAINER_MODE = xyes 
197 then
198    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
199    enable_compile_warnings=yes   
200 fi
201 SG_COMPILE_FLAGS
202
203 AC_SUBST(CFLAGS)
204 AC_SUBST(CPPFLAGS)
205 AC_SUBST(LDFLAGS)
206 AC_SUBST([abs_builddir])
207 AC_SUBST([abs_srcdir])
208 AC_SUBST([abs_top_builddir])
209 AC_SUBST([abs_top_srcdir])
210
211 #####################
212 ## Check for programs
213 ##
214
215 SG_CONFIGURE_PART(Check for programs...)
216 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
217 WARNING="This file is generated, do not edit"
218 AC_SUBST(WARNING)
219
220 # Can we rebuild the parsers?
221 # We really want flex and refuse other lex. So, the parser is portable and
222 # does not induce extra lib dependency
223 AC_PROG_FLEX(2.5.30)
224                 
225 # Can we rebuild the xml-lexers from the XML specification?
226 # if not, simply touch the flex source files (which are distributed in
227 #  tarballs even if generated by flexml) and hope for the best.
228 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
229 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
230
231 if test x$USE_MAINTAINER_MODE = xyes 
232 then
233    # Check for doxygen when in maintainer mode since dist* targets fail
234    # without it
235    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
236    if test x$DOXYGEN = x ; then 
237      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
238    fi
239 fi
240
241 # Can we extract really usable backtraces? (also need the popen function)
242 AC_PATH_PROG(ADDR2LINE, addr2line)
243 if test x$ADDR2LINE != x ; then
244   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
245 fi
246
247 ###################
248 ## Makes the output
249 ##
250
251
252 #
253 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
254 #  src/amok/Makefile
255
256 SG_CONFIGURE_PART(Generating files...)
257 AC_CONFIG_FILES([
258   Makefile
259   include/Makefile
260   src/Makefile
261   src/ucontext_stack.h
262   examples/Makefile 
263     examples/msg/Makefile           examples/msg/run_msg_test
264     examples/gras/Makefile 
265       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
266       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
267       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
268       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
269       examples/gras/tokenS/Makefile examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl
270       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
271       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
272       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
273
274       examples/gras/p2p/Makefile
275       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
276       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
277       
278     examples/amok/Makefile       
279       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
280       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
281   doc/Makefile
282     doc/Doxyfile
283   tools/graspe-slave            tools/Makefile
284     tools/gras/Makefile
285   testsuite/Makefile
286   testsuite/run_tests    
287   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
288 ],[
289     for file in                                                 \
290      testsuite/run_tests                                        \
291      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
292      tools/graspe-slave           tools/graspe-master           \
293      \
294      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
295      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
296      \
297      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
298      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
299      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
300      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
301      examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl  \
302      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
303      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
304      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
305      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
306      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
307      examples/msg/run_msg_test                                  \
308     ; do                                                        \
309       test -e $file && chmod +x $file;                          \
310     done
311 ])
312
313
314 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
315 #    examples/gras/pastry/test_sg   
316
317
318
319 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
320 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
321
322
323
324 AC_OUTPUT
325
326 echo "
327
328 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
329
330         Compiler:        ${CC} (version: ${GCC_VERSION})
331         
332         CFlags:          ${CFLAGS}
333         LDFlags:         ${LDFLAGS}
334
335         Context backend: ${with_context}
336 "
337
338 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
339   echo "WARNING:"
340   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
341   echo "WARNING: This is not really supported, so you should configure SimGrid like:"
342   echo "WARNING:"
343   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
344   echo "WARNING:"
345 fi
346
347 exit 0;