configure.ac

   1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
   2
   3 dnl This file is part of the SimGrid project. This is free software:
   4 dnl You can redistribute and/or modify it under the terms of the
   5 dnl GNU LGPL (v2.1) licence.
   6
   7 ######################
   8 ## Setup the autotools
   9 ##
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
  13 AC_CONFIG_SRCDIR([include/gras.h])
  14 AC_CONFIG_HEADERS([src/gras_config.h])
  15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  16
  17 AC_REVISION($Revision$)
  18 AC_CANONICAL_TARGET
  19 AC_LANG([C])
  20 AM_PROG_GCJ
  21
  22 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  23 AC_CONFIG_MACRO_DIR(acmacro)
  24 ACLOCAL="$ACLOCAL -I acmacro"
  25
  26 dnl Next few lines is a hack to prevent libtool checking for F77
  27 m4_undefine([AC_PROG_F77])
  28 m4_defun([AC_PROG_F77],[])
  29
  30 dnl We do build a proper DLL when using win32
  31 AC_LIBTOOL_WIN32_DLL
  32 AC_PROG_LIBTOOL
  33
  34 ###############
  35 ## System checks
  36 ##
  37 SG_CONFIGURE_PART([System checks...])
  38 AC_PROG_CC(xlC gcc cc)
  39 AM_SANITY_CHECK
  40 AC_PROG_MAKE_SET
  41 AC_CHECK_PRINTF_NULL
  42 AC_CHECK_VA_COPY
  43
  44 # Checks for header files.
  45 AC_HEADER_STDC
  46 AC_HEADER_TIME
  47 AC_CHECK_HEADERS([sys/socket.h \
  48                   sys/stat.h \
  49                   windows.h winsock.h winsock2.h \
  50                   sys/time.h \
  51                   errno.h unistd.h \
  52                   execinfo.h\
  53                   signal.h ])
  54 AC_CHECK_FUNCS([gettimeofday usleep \
  55                 getdtablesize \
  56                 sysconf\
  57                 readv\
  58                 popen\
  59                 signal\
  60                 getline])
  61
  62 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  63 AC_FUNC_SNPRINTF
  64 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  65 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  66 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  67
  68 # Checks for typedefs, structures, and compiler characteristics.
  69 AC_C_CONST
  70 AC_C_INLINE
  71 AC_TYPE_SIZE_T
  72
  73 ###################################
  74 ## SimGrid and GRAS specific checks
  75 ##
  76
  77 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  78 # Check architecture signature begin
  79 GRAS_ARCH
  80 # Check architecture signature end
  81 GRAS_CHECK_STRUCT_COMPACTION
  82
  83
  84 dnl ##
  85 dnl ##  CONTEXT IMPLEMENTATION
  86 dnl ##
  87
  88 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  89
  90 dnl #
  91 dnl #  1. determine possibilities
  92 dnl #
  93
  94 dnl #  check for MCSC method
  95 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  96
  97 dnl #  check for pthread method
  98 AC_CHECK_HEADERS([pthread.h])
  99 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
 100
 101 dnl #
 102 dnl #  2. make a general decision
 103 dnl #
 104
 105 if test ".$mcsc" = .yes; then
 106    mcsc=yes
 107 elif test ".$pthread" = .yes; then
 108    pthread=yes
 109 else
 110     ac_header=windows.h
 111     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 112     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 113       windows_context=yes
 114     else
 115       AC_ERROR([no appropriate backend found])
 116     fi
 117 fi
 118 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
 119
 120
 121 dnl #
 122 dnl #  3. allow decision to be overridden by user
 123 dnl #
 124
 125 AC_MSG_CHECKING(what kind of backend should we use)
 126
 127 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 128 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 129
 130 AC_ARG_WITH(context,
 131   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 132   with_context=auto)
 133
 134 if test "x$with_context$mcsc" = "xucontextno" ; then
 135   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 136 fi
 137
 138 case $with_context in
 139  ucontext) ;;
 140  pthread) ;;
 141  pthreads) ;;
 142  windows) ;;
 143  auto) with_context=ucontext;;
 144  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 145 esac
 146
 147 if test "x$with_context" = "xucontext" ; then
 148   if test ".$mcsc" = .yes; then
 149     AC_MSG_RESULT(found working ucontext. Great!)
 150     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 151   else
 152     if test ".$windows_context" = .yes ; then
 153       AC_MSG_RESULT(use windows context portability layer.)
 154       with_context=windows
 155     else
 156       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 157       with_context=pthread
 158     fi
 159   fi
 160 fi
 161
 162 if test "x$with_context" = "xpthreads"; then
 163   with_context=pthread
 164 fi
 165 if test "x$with_context" = "xpthread"; then
 166   AC_CHECK_HEADERS([pthread.h])
 167   AC_CHECK_LIB(pthread,pthread_create,,
 168     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 169   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 170   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
 171 fi
 172 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
 173
 174 dnl #
 175 dnl #  4. determine a few additional details
 176 dnl #
 177
 178 if test "x$with_context" = "xucontext" ; then
 179 dnl #  direction of stack grow
 180   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 181   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 182       PTH_STACK_GROWTH="down"
 183   else
 184       PTH_STACK_GROWTH="up"
 185   fi
 186   AC_SUBST(PTH_STACK_GROWTH)
 187
 188   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 189 fi
 190
 191 #########################################
 192 ## Check for libraries extra-dependencies
 193 ##
 194
 195 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 196
 197 SIMGRID_DEP=""
 198 SMPI_DEP=""
 199 GRAS_DEP=""
 200
 201 if test xpthread=xyes ; then
 202   # if the pthreads are usable
 203   if test "x$with_context" = "xpthread" ; then
 204     # if we use them to implement the xbt_context
 205     SIMGRID_DEP="-lpthread"
 206   fi
 207   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 208   if test "x$with_context" != "xwindows" ; then
 209     GRAS_DEP="-lpthread"
 210   fi
 211 fi
 212
 213 #########################################
 214 ## Build optional modules (gtnets)
 215 ##
 216 gtnets=no
 217 AC_ARG_WITH(gtnets,
 218   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 219   gtnets_path="$withval",gtnets_path="no")
 220 if test "x$gtnets_path" = "xno" ; then
 221   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 222 else
 223   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
 224   AC_MSG_CHECKING(for gtnets)
 225   AC_LANG_PUSH([C++])
 226   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
 227   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
 228   LDFLAGS_SAV=$LDFLAGS
 229   CPPFLAGS_SAV=$CPPFLAGS
 230   CPPFLAGS+=$GTNETS_CPPFLAGS
 231   LDFLAGS+=$GTNETS_LDFLAGS
 232   AC_TRY_LINK([ #include <simulator.h>
 233               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
 234   CPPFLAGS=$CPPFLAGS_SAV
 235   LDFLAGS=$LDFLAGS_SAV
 236   AC_LANG_POP([C++])
 237
 238   if test "x$gtnets" = xyes ; then
 239     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
 240     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
 241     AC_MSG_RESULT(Found working gtnets library.)
 242     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
 243   else
 244     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
 245   fi
 246 fi
 247 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
 248
 249 #########################################
 250 ## Build optional modules (csdp)
 251 ##
 252 csdp=no
 253 AC_ARG_WITH(csdp,
 254   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
 255   csdp_path="$withval",csdp_path="no")
 256 if test "x$csdp_path" = "xno" ; then
 257   AC_MSG_RESULT(Eventually you will come to csdp.)
 258 else
 259   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
 260   AC_MSG_CHECKING(for csdp)
 261   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
 262   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
 263
 264   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
 265
 266   CPPFLAGS_SAV=$CPPFLAGS
 267   CPPFLAGS+=$CSDP_CPPFLAGS
 268   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
 269   CPPFLAGS=$CPPFLAGS_SAV
 270
 271
 272
 273   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
 274      csdp=yes;
 275   else
 276      csdp=no;
 277   fi
 278   if test "x$csdp" = xyes; then
 279     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
 280     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
 281     AC_MSG_RESULT(Found working sdp library.)
 282     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 283   else
 284     AC_MSG_RESULT(Could not find any working sdp library.)
 285   fi;
 286 fi
 287 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 288
 289 AC_SUBST([SIMGRID_DEP])
 290 AC_SUBST([SMPI_DEP])
 291
 292 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 293 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 294
 295 AC_MSG_CHECKING(for extra dependencies of libgras)
 296 case $host_os in
 297   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 298             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
 299             AC_DEFINE(CONTEXT_THREADS,1);;
 300 esac
 301
 302
 303
 304 if test "x$GRAS_DEP" = x; then
 305    AC_MSG_RESULT(none)
 306 else
 307    AC_MSG_RESULT($GRAS_DEP)
 308 fi
 309 AC_SUBST([GRAS_DEP])
 310
 311 ##############################################
 312 ## Enhance maintainer mode and SUBST variables
 313 ## (must be placed after any compilation tests since our overprotective flags
 314 ##  let some tests fail)
 315
 316 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 317 # Next line is modified by sed when building gramine source tree
 318 gramine_mode=no
 319 if test x$gramine_mode = xyes
 320 then
 321   USE_MAINTAINER_MODE=no
 322 fi
 323 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 324
 325
 326 AM_MAINTAINER_MODE
 327 if test x$USE_MAINTAINER_MODE = xyes
 328 then
 329    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 330    enable_compile_warnings=yes
 331 fi
 332 SG_COMPILE_FLAGS
 333
 334 AC_SUBST([CFLAGS])
 335 AC_SUBST([CPPFLAGS])
 336 AC_SUBST([LDFLAGS])
 337 AC_SUBST([AM_CPPFLAGS])
 338 AC_SUBST([abs_builddir])
 339 AC_SUBST([abs_srcdir])
 340 AC_SUBST([abs_top_builddir])
 341 AC_SUBST([abs_top_srcdir])
 342
 343 ##############################################
 344 ## Specific mode for build daemons.
 345 ## (they compile the SVN without having the autotools installed)
 346 AC_ARG_ENABLE(botbuild,
 347               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
 348               botbuild=$enableval,botbuild=no)
 349 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
 350
 351 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
 352   echo "ERROR: "
 353   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
 354   echo "ERROR: For this, just call configure this way:"
 355   echo "ERROR:"
 356   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
 357   echo "ERROR:"
 358   exit 1
 359 fi
 360
 361
 362 SG_CONFIGURE_PART(Check for Java bindings...)
 363 # Java cruft
 364 AC_ARG_ENABLE(java,
 365               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 366               disable_java=$enableval,disable_java=yes)
 367 AC_MSG_CHECKING(whether to compile java bindings)
 368 if test "x$disable_java" != "xyes" ; then
 369    use_java="disabled by user"
 370 else
 371   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 372   AC_PATH_PROG([JAVA],  [java] , `which java`)
 373   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 374   AC_CHECK_HEADERS(jni.h)
 375   if test -n "$JAVAC"   \
 376      && test -n "$JAVA" \
 377      && test -n "$JAR"  \
 378      && test "x$ac_cv_header_jni_h" = "xyes" ; then
 379
 380      use_java="yes"
 381   else
 382      use_java="no"
 383   fi
 384 fi
 385 AC_MSG_RESULT($use_java)
 386 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 387
 388 #####################
 389 ## Check for programs
 390 ##
 391
 392 SG_CONFIGURE_PART(Check for programs...)
 393 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 394 WARNING="This file is generated, do not edit"
 395 AC_SUBST(WARNING)
 396
 397
 398 # Can we rebuild the parsers?
 399 # We really want flex and refuse other lex. So, the parser is portable and
 400 # does not induce extra lib dependency
 401 AC_PROG_FLEX(2.5.30)
 402
 403 # Can we rebuild the xml-lexers from the XML specification?
 404 # if not, simply touch the flex source files (which are distributed in
 405 #  tarballs even if generated by flexml) and hope for the best.
 406 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 407 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 408
 409 if test x$USE_MAINTAINER_MODE = xyes
 410 then
 411    # Check for doxygen when in maintainer mode since dist* targets fail
 412    # without it
 413    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 414    if test x$DOXYGEN = x ; then
 415      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 416    fi
 417 fi
 418
 419 # Can we extract really usable backtraces? (also need the popen function)
 420 AC_PATH_PROG(ADDR2LINE, addr2line)
 421 if test x$ADDR2LINE != x ; then
 422   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 423 fi
 424
 425 AC_SUBST(ac_configure_args)
 426 # Can we make status line about the compilation result?
 427 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 428 if test x$MD5SUM != xno ; then
 429   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 430                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 431 else
 432   build_version="no_md5sum_binary"
 433 fi
 434 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 435 AC_SUBST(build_id)
 436
 437 ###################
 438 ## Makes the output
 439 ##
 440
 441
 442 #
 443 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 444 #  src/amok/Makefile
 445
 446 SG_CONFIGURE_PART(Generating files...)
 447
 448 # Core of the libraries
 449
 450 AC_CONFIG_FILES([
 451   Makefile
 452   include/Makefile
 453   src/Makefile
 454   src/ucontext_stack.h
 455 ])
 456
 457 # Tools being embeeded in gramine (stub generator)
 458 AC_CONFIG_FILES([
 459   tools/Makefile
 460     tools/gras/Makefile
 461     tools/tesh/Makefile
 462 ])
 463
 464
 465 # GRAMINE_CUT_BEGIN
 466
 467 # Tools NOT being embeeded in gramine
 468 AC_CONFIG_FILES([
 469   tools/graspe-slave
 470 ],[
 471     for file in                                                 \
 472      tools/graspe-slave           tools/graspe-master           \
 473     ; do                                                        \
 474       test -e $file && chmod +x $file;                          \
 475     done
 476 ])
 477
 478 # Testsuite
 479
 480 AC_CONFIG_FILES([
 481   testsuite/Makefile
 482   testsuite/run_tests
 483 ],[
 484     for file in                                                 \
 485      testsuite/run_tests                                        \
 486     ; do                                                        \
 487       test -e $file && chmod +x $file;                          \
 488     done
 489 ])
 490
 491 # Teshsuite (testsuite using tesh)
 492 AC_CONFIG_FILES([
 493   teshsuite/Makefile
 494 ])
 495
 496 # Documentation
 497 AC_CONFIG_FILES([
 498   doc/Makefile
 499   doc/Doxyfile
 500 ])
 501
 502 # Examples
 503
 504 #      examples/gras/p2p/Makefile
 505 #      examples/gras/p2p/chord/Makefile
 506 #      examples/gras/p2p/can/Makefile
 507
 508 AC_CONFIG_FILES([
 509     examples/java/Makefile
 510       examples/java/basic/Makefile
 511       examples/java/comm_time/Makefile
 512       examples/java/suspend/Makefile
 513       examples/java/ping_pong/Makefile
 514 ])
 515
 516 AC_CONFIG_FILES([
 517   examples/Makefile
 518     examples/msg/Makefile
 519     examples/simdag/Makefile
 520     examples/gras/Makefile
 521       examples/gras/ping/Makefile
 522       examples/gras/rpc/Makefile
 523       examples/gras/spawn/Makefile
 524       examples/gras/synchro/Makefile
 525       examples/gras/timer/Makefile
 526       examples/gras/chrono/Makefile
 527       examples/gras/mutual_exclusion/simple_token/Makefile
 528       examples/gras/mmrpc/Makefile
 529       examples/gras/pmm/Makefile
 530       examples/gras/all2all/Makefile
 531     examples/amok/Makefile
 532 ])
 533
 534 AC_CONFIG_FILES([
 535   src/smpi/smpicc
 536   src/smpi/smpirun
 537 ])
 538
 539 # GRAMINE_CUT_END
 540
 541 AC_OUTPUT
 542
 543 echo "
 544
 545 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 546
 547         Compiler:        ${CC} (version: ${GCC_VERSION})
 548
 549         CFlags:          ${CFLAGS}
 550         CPPFlags:        ${CPPFLAGS}
 551         LDFlags:         ${LDFLAGS}
 552
 553         Context backend: ${with_context}
 554         Compile Java:    ${use_java}
 555
 556         Maintainer mode: ${USE_MAINTAINER_MODE}
 557
 558 "
 559 if test x$botbuild = xyes ; then
 560   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
 561   echo
 562 fi
 563
 564 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
 565   echo "WARNING: "
 566   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
 567   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
 568   echo "WARNING:"
 569   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
 570   echo "WARNING:"
 571 fi
 572
 573 echo $build_id > stamp.configure
 574
 575 exit 0;