buildtools/Cmake/MakeJava.cmake

   1 cmake_minimum_required(VERSION 2.8.6)
   2
   3 include(UseJava)
   4
   5 # Rules to build libsimgrid-java
   6 #
   7 add_library(simgrid-java SHARED ${JMSG_C_SRC})
   8 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
   9 if (CMAKE_VERSION VERSION_LESS "2.8.8")
  10   include_directories(${JNI_INCLUDE_DIRS})
  11
  12   message("[Java] Try to workaround missing feature in older CMake. You should better update CMake to version 2.8.8 or above.")
  13   get_directory_property(CHECK_INCLUDES INCLUDE_DIRECTORIES)
  14 else()
  15   get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  16   if (COMMON_INCLUDES)
  17     set_target_properties(simgrid-java PROPERTIES
  18       INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  19   else()
  20     set_target_properties(simgrid-java PROPERTIES
  21       INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  22   endif()
  23
  24   get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  25 endif()
  26 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  27
  28 target_link_libraries(simgrid-java simgrid)
  29
  30
  31 if(WIN32)
  32   exec_program("java -d32 -version"
  33                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  34   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  35   if(${POSITION} GREATER -1)
  36     message("POTENTIAL ERROR: Java JVM needs to be 32 bits to be able to run with Simgrid on Windows for now")
  37   endif()
  38
  39   set_target_properties(simgrid-java PROPERTIES
  40     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at"
  41     PREFIX "")
  42   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  43   message(STATUS "pexports: ${PEXPORTS_PATH}")
  44   if(PEXPORTS_PATH)
  45     add_custom_command(TARGET simgrid-java POST_BUILD
  46       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/simgrid-java.dll > ${CMAKE_BINARY_DIR}/lib/simgrid-java.def)
  47   endif(PEXPORTS_PATH)
  48 endif()
  49
  50 # Rules to build simgrid.jar
  51 #
  52
  53 ## Files to include in simgrid.jar
  54 ##
  55 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  56 set(SIMGRID_FULL_JAR "${CMAKE_BINARY_DIR}/simgrid_full.jar")
  57 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  58 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  59
  60
  61 set(LIBSIMGRID_SO
  62   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  63 set(LIBSIMGRID_JAVA_SO
  64   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  65 set(LIBSURF_JAVA_SO
  66   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  67
  68 ## Don't strip libraries if not in release mode
  69 ##
  70 if(release)
  71   set(STRIP_COMMAND "${CMAKE_STRIP}")
  72 else()
  73   set(STRIP_COMMAND "true")
  74 endif()
  75
  76 ## Here is how to build simgrid.jar
  77 ##
  78 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  79   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  80   add_jar(simgrid-java_pre_jar ${JMSG_JAVA_SRC})
  81 else()
  82   add_jar(simgrid-java_pre_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  83 endif()
  84
  85 set(JAVA_BUNDLE "${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/java_bundle.sh")
  86 set(JAVA_BUNDLE_SO_FILES
  87   ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
  88   ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
  89   ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
  90   )
  91 set(JAVA_BUNDLE_TXT_FILES
  92   ${CMAKE_HOME_DIRECTORY}/COPYING
  93   ${CMAKE_HOME_DIRECTORY}/ChangeLog
  94   ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  95   ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  96   )
  97 add_custom_command(
  98   COMMENT "Finalize simgrid.jar..."
  99   OUTPUT ${SIMGRID_JAR}_finalized
 100   DEPENDS simgrid simgrid-java simgrid-java_pre_jar
 101           ${SIMGRID_JAR} ${MANIFEST_IN_FILE}
 102           ${JAVA_BUNDLE_SO_FILES} ${JAVA_BUNDLE_TXT_FILES}
 103   COMMAND ${JAVA_BUNDLE} "${SIMGRID_JAR}" "${Java_JAVA_EXECUTABLE}" "${STRIP_COMMAND}" -so ${JAVA_BUNDLE_SO_FILES} -txt ${JAVA_BUNDLE_TXT_FILES}
 104   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
 105   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
 106   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
 107   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR}
 108   COMMAND ${CMAKE_COMMAND} -E copy ${SIMGRID_JAR} ${SIMGRID_FULL_JAR}
 109   COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_FULL_JAR} "NATIVE"
 110   COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
 111   COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
 112   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc ${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/*.java ${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/*/*.java
 113   COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_FULL_JAR} doc/javadoc
 114   )
 115 add_custom_target(simgrid-java_jar ALL DEPENDS ${SIMGRID_JAR}_finalized)
 116
 117 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 118
 119 if(enable_maintainer_mode)
 120   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 121   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 122
 123   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 124
 125   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 126
 127   if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_BINARY_DIR}")
 128     add_custom_command(TARGET surf-java POST_BUILD
 129       COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.cxx" "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.cxx"
 130       COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.h" "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.h"
 131     )
 132   endif()
 133
 134   swig_link_libraries(surf-java simgrid)
 135 else()
 136   add_library(surf-java SHARED ${JSURF_C_SRC})
 137   target_link_libraries(surf-java simgrid)
 138 endif()
 139
 140 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 141 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 142
 143 add_dependencies(simgrid-java surf-java)
 144 add_dependencies(simgrid-java_pre_jar surf-java)
 145
 146 if(WIN32)
 147   set_target_properties(surf-java PROPERTIES
 148     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at"
 149     PREFIX "")
 150   if(PEXPORTS_PATH)
 151     add_custom_command(TARGET surf-java POST_BUILD
 152       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/surf-java.dll > ${CMAKE_BINARY_DIR}/lib/surf-java.def)
 153   endif(PEXPORTS_PATH)
 154 endif()