configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal])
  48
  49 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  50 AC_FUNC_SNPRINTF
  51 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  52 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  53 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  54 # we don't use those:
  55 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
  56 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
  57
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_CONST
  61 AC_C_INLINE
  62 AC_TYPE_SIZE_T
  63
  64 ###################################
  65 ## SimGrid and GRAS specific checks
  66 ##
  67
  68 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  69 # Check architecture signature begin
  70 GRAS_ARCH
  71 # Check architecture signature end
  72 GRAS_CHECK_STRUCT_COMPACTION
  73
  74
  75 dnl ##
  76 dnl ##  CONTEXT IMPLEMENTATION
  77 dnl ##
  78
  79 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  80
  81 dnl #
  82 dnl #  1. determine possibilities
  83 dnl #
  84
  85 dnl #  check for MCSC method
  86 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  87
  88 dnl #  check for pthread method
  89 AC_CHECK_HEADERS([pthread.h])
  90 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  91
  92 dnl #
  93 dnl #  2. make a general decision
  94 dnl #
  95
  96 if test ".$mcsc" = .yes; then
  97    mcsc=yes
  98 elif test ".$pthread" = .yes; then
  99    pthread=yes
 100 else
 101     ac_header=windows.h
 102     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 103     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 104       windows_context=yes
 105     else
 106       AC_ERROR([no appropriate backend found])
 107     fi
 108 fi
 109
 110 dnl #
 111 dnl #  3. allow decision to be overridden by user
 112 dnl #
 113
 114 AC_MSG_CHECKING(what kind of backend should we use)
 115
 116 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 117
 118 AC_ARG_WITH(context,
 119   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 120   with_context=auto)
 121
 122 if test "x$with_context$mcsc" = "xucontextno" ; then
 123   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 124 fi
 125
 126 case $with_context in
 127  ucontext) ;;
 128  pthread) ;;
 129  windows) ;;
 130  auto) with_context=ucontext;;
 131  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 132 esac
 133
 134 if test "x$with_context" = "xucontext" ; then
 135   if test ".$mcsc" = .yes; then
 136     AC_MSG_RESULT(found working ucontext. Great!)
 137     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 138   else
 139     if test ".$windows_context" = .yes ; then
 140       AC_MSG_RESULT(use windows context portability layer.)
 141       with_context=windows
 142     else
 143       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 144       with_context=pthread
 145     fi
 146   fi
 147 fi
 148
 149 if test "x$with_context" = "xpthread"; then
 150   AC_CHECK_HEADERS([pthread.h])
 151   AC_CHECK_LIB(pthread,pthread_create,,
 152     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
 153   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 154   AC_MSG_RESULT(You have pthreads. Let's use them.)
 155 fi
 156
 157 dnl #
 158 dnl #  4. determine a few additional details
 159 dnl #
 160
 161 if test "x$with_context" = "xucontext" ; then
 162 dnl #  direction of stack grow
 163   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 164   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 165       PTH_STACK_GROWTH="down"
 166   else
 167       PTH_STACK_GROWTH="up"
 168   fi
 169   AC_SUBST(PTH_STACK_GROWTH)
 170
 171   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 172 fi
 173
 174 #########################################
 175 ## Check for libraries extra-dependencies
 176 ##
 177
 178 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 179
 180 AC_MSG_CHECKING(for csdp)
 181 SIMGRID_DEP=""
 182 sdp=no
 183 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 184 if test "x$csdp" = xyes; then
 185   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 186   AC_MSG_RESULT(Found working sdp library.)
 187 else
 188   AC_MSG_RESULT(Could not find any working sdp library.)
 189 fi;
 190 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 191
 192 AC_SUBST([SIMGRID_DEP])
 193
 194 GRAS_DEP=""
 195 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 196 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 197
 198 AC_MSG_CHECKING(for extra dependencies of libgras)
 199 case $host_os in
 200   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
 201 esac
 202
 203 if test "x$GRAS_DEP" = x; then
 204    AC_MSG_RESULT(none)
 205 else
 206    AC_MSG_RESULT($GRAS_DEP)
 207 fi
 208 AC_SUBST([GRAS_DEP])
 209
 210 ##############################################
 211 ## Enhance maintainer mode and SUBST variables
 212 ## (must be placed after any compilation tests since our overprotective flags
 213 ##  let some tests fail)
 214
 215 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 216 # Next line is modified by sed when building gramine source tree
 217 gramine_mode=no
 218 if test x$gramine_mode = xyes
 219 then
 220   USE_MAINTAINER_MODE=no
 221 fi
 222 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 223
 224
 225 AM_MAINTAINER_MODE
 226 if test x$USE_MAINTAINER_MODE = xyes
 227 then
 228    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 229    enable_compile_warnings=yes
 230 fi
 231 SG_COMPILE_FLAGS
 232
 233 AC_SUBST(CFLAGS)
 234 AC_SUBST(CPPFLAGS)
 235 AC_SUBST(LDFLAGS)
 236 AC_SUBST([abs_builddir])
 237 AC_SUBST([abs_srcdir])
 238 AC_SUBST([abs_top_builddir])
 239 AC_SUBST([abs_top_srcdir])
 240
 241 #####################
 242 ## Check for programs
 243 ##
 244
 245 SG_CONFIGURE_PART(Check for programs...)
 246 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 247 WARNING="This file is generated, do not edit"
 248 AC_SUBST(WARNING)
 249
 250
 251 # Can we rebuild the parsers?
 252 # We really want flex and refuse other lex. So, the parser is portable and
 253 # does not induce extra lib dependency
 254 AC_PROG_FLEX(2.5.30)
 255
 256 # Can we rebuild the xml-lexers from the XML specification?
 257 # if not, simply touch the flex source files (which are distributed in
 258 #  tarballs even if generated by flexml) and hope for the best.
 259 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 260 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 261
 262 if test x$USE_MAINTAINER_MODE = xyes
 263 then
 264    # Check for doxygen when in maintainer mode since dist* targets fail
 265    # without it
 266    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 267    if test x$DOXYGEN = x ; then
 268      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 269    fi
 270 fi
 271
 272 # Can we extract really usable backtraces? (also need the popen function)
 273 AC_PATH_PROG(ADDR2LINE, addr2line)
 274 if test x$ADDR2LINE != x ; then
 275   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 276 fi
 277
 278 AC_SUBST(ac_configure_args)
 279 # Can we make status line about the compilation result?
 280 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 281 if test x$MD5SUM != xno ; then
 282   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 283                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 284 else
 285   build_version="no_md5sum_binary"
 286 fi
 287 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 288 AC_SUBST(build_id)
 289
 290 ###################
 291 ## Makes the output
 292 ##
 293
 294
 295 #
 296 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 297 #  src/amok/Makefile
 298
 299 SG_CONFIGURE_PART(Generating files...)
 300
 301 # Core of the libraries
 302
 303 AC_CONFIG_FILES([
 304   Makefile
 305   include/Makefile
 306   src/Makefile
 307   src/ucontext_stack.h
 308 ])
 309
 310 # Tools being embeeded in gramine (stub generator)
 311 AC_CONFIG_FILES([
 312   tools/Makefile
 313     tools/gras/Makefile
 314 ])
 315
 316 # GRAMINE_CUT_BEGIN
 317
 318 # Tools NOT being embeeded in gramine
 319 AC_CONFIG_FILES([
 320   tools/graspe-slave
 321 ],[
 322     for file in                                                 \
 323      tools/graspe-slave           tools/graspe-master           \
 324     ; do                                                        \
 325       test -e $file && chmod +x $file;                          \
 326     done
 327 ])
 328
 329 # Testsuite
 330
 331 AC_CONFIG_FILES([
 332   testsuite/Makefile
 333   testsuite/run_tests
 334   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 335 ],[
 336     for file in                                                 \
 337      testsuite/run_tests                                        \
 338      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 339     ; do                                                        \
 340       test -e $file && chmod +x $file;                          \
 341     done
 342 ])
 343
 344 # Documentation
 345 AC_CONFIG_FILES([
 346   doc/Makefile
 347   doc/Doxyfile
 348 ])
 349
 350 # Examples
 351
 352 AC_CONFIG_FILES([
 353   examples/Makefile
 354     examples/msg/Makefile           examples/msg/run_msg_test
 355     examples/simdag/Makefile        examples/simdag/test_simdag
 356     examples/gras/Makefile
 357       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 358       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 359       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 360       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 361       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 362       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 363       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 364       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 365
 366       examples/gras/p2p/Makefile
 367       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 368       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 369
 370     examples/amok/Makefile
 371       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 372       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 373 ],[
 374     for file in                                                 \
 375      \
 376      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 377      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 378      \
 379      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 380      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 381      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 382      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 383      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 384      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 385      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 386      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 387      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 388      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 389      examples/msg/run_msg_test                                  \
 390      examples/simdag/test_simdag                                \
 391     ; do                                                        \
 392       test -e $file && chmod +x $file;                          \
 393     done
 394 ])
 395
 396 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 397 #    examples/gras/pastry/test_sg
 398
 399
 400
 401 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 402 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 403
 404
 405 # GRAMINE_CUT_END
 406
 407 AC_OUTPUT
 408
 409 echo "
 410
 411 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 412
 413         Compiler:        ${CC} (version: ${GCC_VERSION})
 414
 415         CFlags:          ${CFLAGS}
 416         CPPFlags:        ${CPPFLAGS}
 417         LDFlags:         ${LDFLAGS}
 418
 419         Context backend: ${with_context}
 420 "
 421
 422 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 423   echo "WARNING:"
 424   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 425   echo "WARNING: You may want to enable this by specifying:"
 426   echo "WARNING:"
 427   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 428   echo "WARNING:"
 429 fi
 430 echo $build_id > stamp.configure
 431
 432 exit 0;