Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
5b57c285a0efad5bbfca94a93011a68936a0568d
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15 AM_PROG_GCJ
16
17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
18 AC_CONFIG_MACRO_DIR(acmacro) 
19 ACLOCAL="$ACLOCAL -I acmacro"
20
21 dnl Next few lines is a hack to prevent libtool checking for F77
22 m4_undefine([AC_PROG_F77])
23 m4_defun([AC_PROG_F77],[])
24
25 dnl We do build a proper DLL when using win32
26 AC_LIBTOOL_WIN32_DLL
27 AC_PROG_LIBTOOL
28
29 ###############
30 ## System checks
31 ##
32 SG_CONFIGURE_PART([System checks...])
33 AC_PROG_CC(xlC gcc cc)
34 AM_SANITY_CHECK
35 AC_PROG_MAKE_SET
36 AC_CHECK_PRINTF_NULL
37 AC_CHECK_VA_COPY
38
39 # Checks for header files.
40 AC_HEADER_STDC
41 AC_HEADER_TIME
42 AC_CHECK_HEADERS([sys/socket.h \
43                   sys/stat.h \
44                   windows.h winsock.h winsock2.h \
45                   sys/time.h \
46                   errno.h unistd.h \
47                   execinfo.h\
48                   signal.h ])
49 AC_CHECK_FUNCS([gettimeofday usleep \
50                 getdtablesize \
51                 sysconf\
52                 readv\
53                 popen\
54                 signal\
55                 getline])
56                 
57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
58 AC_FUNC_SNPRINTF
59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
62
63 # Checks for typedefs, structures, and compiler characteristics.
64 AC_C_CONST
65 AC_C_INLINE
66 AC_TYPE_SIZE_T
67
68 ###################################
69 ## SimGrid and GRAS specific checks
70 ##
71
72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
73 # Check architecture signature begin
74 GRAS_ARCH
75 # Check architecture signature end
76 GRAS_CHECK_STRUCT_COMPACTION
77
78
79 dnl ##
80 dnl ##  CONTEXT IMPLEMENTATION
81 dnl ##
82
83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
84
85 dnl #
86 dnl #  1. determine possibilities
87 dnl #
88
89 dnl #  check for MCSC method
90 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
91
92 dnl #  check for pthread method
93 AC_CHECK_HEADERS([pthread.h])
94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
95
96 dnl #
97 dnl #  2. make a general decision
98 dnl #
99
100 if test ".$mcsc" = .yes; then
101    mcsc=yes
102 elif test ".$pthread" = .yes; then
103    pthread=yes
104 else
105     ac_header=windows.h
106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
108       windows_context=yes
109     else
110       AC_ERROR([no appropriate backend found])
111     fi
112 fi
113
114 dnl #
115 dnl #  3. allow decision to be overridden by user
116 dnl #
117
118 AC_MSG_CHECKING(what kind of backend should we use)
119
120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
122
123 AC_ARG_WITH(context,
124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
125   with_context=auto)
126
127 if test "x$with_context$mcsc" = "xucontextno" ; then 
128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
129 fi
130
131 case $with_context in
132  ucontext) ;;
133  pthread) ;;
134  pthreads) ;;
135  windows) ;;
136  auto) with_context=ucontext;;
137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
138 esac
139
140 if test "x$with_context" = "xucontext" ; then
141   if test ".$mcsc" = .yes; then
142     AC_MSG_RESULT(found working ucontext. Great!)
143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
144   else
145     if test ".$windows_context" = .yes ; then
146       AC_MSG_RESULT(use windows context portability layer.)
147       with_context=windows
148     else
149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
150       with_context=pthread
151     fi
152   fi
153 fi
154
155 if test "x$with_context" = "xpthreads"; then
156   with_context=pthread
157 fi
158 if test "x$with_context" = "xpthread"; then
159   AC_CHECK_HEADERS([pthread.h])
160   AC_CHECK_LIB(pthread,pthread_create,,
161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
163   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
164 fi
165 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
166
167 dnl #
168 dnl #  4. determine a few additional details
169 dnl #
170
171 if test "x$with_context" = "xucontext" ; then
172 dnl #  direction of stack grow
173   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
174   if test ".$ac_cv_check_stackgrowth" = ".down"; then
175       PTH_STACK_GROWTH="down"
176   else
177       PTH_STACK_GROWTH="up"
178   fi
179   AC_SUBST(PTH_STACK_GROWTH)
180   
181   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
182 fi
183
184 #########################################
185 ## Check for libraries extra-dependencies
186 ##
187
188 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
189
190 SIMGRID_DEP=""
191 GRAS_DEP=""
192
193 if test xpthread=xyes ; then 
194   # if the pthreads are usable
195   if test "x$with_context" = "xpthread" ; then
196     # if we use them to implement the xbt_context
197     SIMGRID_DEP="-lpthread"
198   fi
199   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
200   if test "x$with_context" != "xwindows" ; then
201     GRAS_DEP="-lpthread"
202   fi
203 fi
204
205 #########################################
206 ## Build optional modules (gtnets)
207 ##
208 gtnets=no
209 AC_ARG_WITH(gtnets,
210   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
211   gtnets_path="$withval",gtnets_path="no")
212 if test "x$gtnets_path" = "xno" ; then
213   AC_MSG_RESULT(Eventually you will come to GTNetS.)
214 else  
215   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
216   AC_MSG_CHECKING(for gtnets)
217   AC_LANG_PUSH([C++])  
218   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
219   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
220   LDFLAGS_SAV=$LDFLAGS  
221   CPPFLAGS_SAV=$CPPFLAGS
222   CPPFLAGS+=$GTNETS_CPPFLAGS
223   LDFLAGS+=$GTNETS_LDFLAGS
224   AC_TRY_LINK([ #include <simulator.h>
225               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
226   CPPFLAGS=$CPPFLAGS_SAV
227   LDFLAGS=$LDFLAGS_SAV
228   AC_LANG_POP([C++])  
229
230   if test "x$gtnets" = xyes ; then 
231     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
232     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
233     AC_MSG_RESULT(Found working gtnets library.)
234     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
235   else
236     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
237   fi
238 fi
239 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
240
241 #########################################
242 ## Build optional modules (csdp)
243 ##
244 csdp=no
245 AC_ARG_WITH(csdp,
246   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
247   csdp_path="$withval",csdp_path="no")
248 if test "x$csdp_path" = "xno" ; then
249   AC_MSG_RESULT(Eventually you will come to csdp.)
250 else  
251   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
252   AC_MSG_CHECKING(for csdp)
253   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
254   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
255
256   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
257   
258   CPPFLAGS_SAV=$CPPFLAGS
259   CPPFLAGS+=$CSDP_CPPFLAGS
260   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
261   CPPFLAGS=$CPPFLAGS_SAV
262
263   
264
265   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
266      csdp=yes;
267   else 
268      csdp=no;
269   fi
270   if test "x$csdp" = xyes; then 
271     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
272     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
273     AC_MSG_RESULT(Found working sdp library.)
274     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
275   else
276     AC_MSG_RESULT(Could not find any working sdp library.)
277   fi;
278 fi
279 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
280
281 AC_SUBST([SIMGRID_DEP])
282
283 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
284 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
285
286 AC_MSG_CHECKING(for extra dependencies of libgras)
287 case $host_os in
288   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
289             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
290             AC_DEFINE(CONTEXT_THREADS,1);;
291 esac
292            
293 if test "x$GRAS_DEP" = x; then 
294    AC_MSG_RESULT(none)
295 else
296    AC_MSG_RESULT($GRAS_DEP)
297 fi
298 AC_SUBST([GRAS_DEP])
299
300 ##############################################
301 ## Enhance maintainer mode and SUBST variables
302 ## (must be placed after any compilation tests since our overprotective flags
303 ##  let some tests fail)
304
305 # Check whether we are doing a regular build or a GRAMINE (minimal) one
306 # Next line is modified by sed when building gramine source tree
307 gramine_mode=no
308 if test x$gramine_mode = xyes
309 then
310   USE_MAINTAINER_MODE=no
311 fi
312 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
313
314
315 AM_MAINTAINER_MODE
316 if test x$USE_MAINTAINER_MODE = xyes 
317 then
318    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
319    enable_compile_warnings=yes   
320 fi
321 SG_COMPILE_FLAGS
322
323 AC_SUBST([CFLAGS])
324 AC_SUBST([CPPFLAGS])
325 AC_SUBST([LDFLAGS])
326 AC_SUBST([AM_CPPFLAGS])
327 AC_SUBST([abs_builddir])
328 AC_SUBST([abs_srcdir])
329 AC_SUBST([abs_top_builddir])
330 AC_SUBST([abs_top_srcdir])
331
332
333
334 SG_CONFIGURE_PART(Check for Java bindings...)
335 # Java cruft
336 AC_ARG_ENABLE(java,
337               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
338               want_java=$enableval,want_java=yes)
339 if test "x$want_java" != "xyes" ; then
340    AC_MSG_CHECKING(whether to compile java bindings)
341    AC_MSG_RESULT(disabled by user)
342    use_java="disabled by user"
343 else
344   AC_PATH_PROG([JAVAC], [javac], `which javac`)
345   AC_PATH_PROG([JAVA],  [java] , `which java`)
346   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
347   AC_CHECK_HEADERS(jni.h)
348   AC_MSG_CHECKING(whether to compile java bindings)
349   if test -n "$JAVAC"   \
350      && test -n "$JAVA" \
351      && test -n "$JAR"  \
352      && test "x$ac_cv_header_jni_h" = "xyes" ; then
353    
354      use_java="yes"
355   else   
356      use_java="no"
357   fi
358   AC_MSG_RESULT($use_java)
359 fi
360 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
361
362 #####################
363 ## Check for programs
364 ##
365
366 SG_CONFIGURE_PART(Check for programs...)
367 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
368 WARNING="This file is generated, do not edit"
369 AC_SUBST(WARNING)
370
371
372 # Can we rebuild the parsers?
373 # We really want flex and refuse other lex. So, the parser is portable and
374 # does not induce extra lib dependency
375 AC_PROG_FLEX(2.5.30)
376                 
377 # Can we rebuild the xml-lexers from the XML specification?
378 # if not, simply touch the flex source files (which are distributed in
379 #  tarballs even if generated by flexml) and hope for the best.
380 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
381 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
382
383 if test x$USE_MAINTAINER_MODE = xyes 
384 then
385    # Check for doxygen when in maintainer mode since dist* targets fail
386    # without it
387    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
388    if test x$DOXYGEN = x ; then 
389      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
390    fi
391 fi
392
393 # Can we extract really usable backtraces? (also need the popen function)
394 AC_PATH_PROG(ADDR2LINE, addr2line)
395 if test x$ADDR2LINE != x ; then
396   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
397 fi
398
399 AC_SUBST(ac_configure_args)
400 # Can we make status line about the compilation result?
401 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
402 if test x$MD5SUM != xno ; then
403   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
404                  xargs cat| $MD5SUM | sed 's/ .*$//'`
405 else 
406   build_version="no_md5sum_binary"
407 fi
408 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
409 AC_SUBST(build_id)
410
411 ###################
412 ## Makes the output
413 ##
414
415
416 #
417 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
418 #  src/amok/Makefile
419
420 SG_CONFIGURE_PART(Generating files...)
421
422 # Core of the libraries
423
424 AC_CONFIG_FILES([
425   Makefile
426   include/Makefile
427   src/Makefile
428   src/ucontext_stack.h
429 ])
430
431 # Tools being embeeded in gramine (stub generator)
432 AC_CONFIG_FILES([
433   tools/Makefile
434     tools/gras/Makefile
435     tools/tesh/Makefile
436 ])
437
438
439 # GRAMINE_CUT_BEGIN
440
441 # Tools NOT being embeeded in gramine
442 AC_CONFIG_FILES([
443   tools/graspe-slave
444 ],[
445     for file in                                                 \
446      tools/graspe-slave           tools/graspe-master           \
447     ; do                                                        \
448       test -e $file && chmod +x $file;                          \
449     done
450 ])
451
452 # Testsuite
453
454 AC_CONFIG_FILES([  
455   testsuite/Makefile
456   testsuite/run_tests    
457   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
458 ],[
459     for file in                                                 \
460      testsuite/run_tests                                        \
461      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
462     ; do                                                        \
463       test -e $file && chmod +x $file;                          \
464     done
465 ])
466
467 # Documentation
468 AC_CONFIG_FILES([
469   doc/Makefile
470   doc/Doxyfile
471 ])
472
473 # Examples
474
475 #      examples/gras/p2p/Makefile
476 #      examples/gras/p2p/chord/Makefile
477 #      examples/gras/p2p/can/Makefile
478
479 if test "x$use_java" = "xyes" ; then
480 AC_CONFIG_FILES([
481     examples/java/Makefile
482       examples/java/basic/Makefile
483       examples/java/comm_time/Makefile
484       examples/java/suspend/Makefile
485       examples/java/ping_pong/Makefile
486 ])
487 fi
488
489 AC_CONFIG_FILES([
490   examples/Makefile 
491     examples/msg/Makefile
492     examples/simdag/Makefile        examples/simdag/test_simdag
493     examples/gras/Makefile
494       examples/gras/ping/Makefile   
495       examples/gras/rpc/Makefile
496       examples/gras/spawn/Makefile
497       examples/gras/synchro/Makefile
498       examples/gras/timer/Makefile
499       examples/gras/chrono/Makefile
500       examples/gras/mutual_exclusion/simple_token/Makefile
501       examples/gras/mmrpc/Makefile
502       examples/gras/pmm/Makefile
503       examples/gras/all2all/Makefile
504     examples/amok/Makefile       
505       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
506       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
507 ],[
508     for file in                                                 \
509      \
510      examples/simdag/test_simdag                                \
511      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
512      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
513     ; do                                                        \
514       test -e $file && chmod +x $file;                          \
515     done
516 ])
517
518
519 # GRAMINE_CUT_END
520
521 AC_OUTPUT
522
523 echo "
524
525 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
526
527         Compiler:        ${CC} (version: ${GCC_VERSION})
528         
529         CFlags:          ${CFLAGS}
530         CPPFlags:        ${CPPFLAGS}
531         LDFlags:         ${LDFLAGS}
532
533         Context backend: ${with_context}
534 "
535
536 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
537   echo "WARNING:"
538   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
539   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
540   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
541   echo "WARNING:"
542   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
543   echo "WARNING:"
544 fi
545 echo $build_id > stamp.configure
546
547 exit 0;