Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
add a newline at the end of the file to make gcc happy
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15
16 AM_INIT_AUTOMAKE(gnu)
17 AC_CONFIG_MACRO_DIR(acmacro) 
18 ACLOCAL="$ACLOCAL -I acmacro"
19 AC_LIBTOOL_WIN32_DLL
20 AC_PROG_LIBTOOL
21
22 ###############
23 ## System checks
24 ##
25 SG_CONFIGURE_PART(System checks...)
26 AC_PROG_CC(xlC gcc cc)
27 AM_SANITY_CHECK
28 AC_PROG_MAKE_SET
29 AC_CHECK_PRINTF_NULL
30 AC_CHECK_VA_COPY
31
32 # Checks for header files.
33 AC_HEADER_STDC
34 AC_HEADER_TIME
35 AC_CHECK_HEADERS([sys/socket.h \
36                   sys/stat.h \
37                   windows.h winsock.h winsock2.h \
38                   sys/time.h \
39                   errno.h unistd.h \
40                   execinfo.h\
41                   signal.h ])
42 AC_CHECK_FUNCS([gettimeofday usleep \
43                 getdtablesize \
44                 sysconf\
45                 readv\
46                 popen\
47                 signal])
48                 
49 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
50 AC_FUNC_SNPRINTF
51 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
52 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
53 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
54 # we don't use those:
55 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
56 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
57
58
59 # Checks for typedefs, structures, and compiler characteristics.
60 AC_C_CONST
61 AC_C_INLINE
62 AC_TYPE_SIZE_T
63
64 ###################################
65 ## SimGrid and GRAS specific checks
66 ##
67
68 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
69 # Check architecture signature begin
70 GRAS_ARCH
71 # Check architecture signature end
72 GRAS_CHECK_STRUCT_COMPACTION
73
74
75 dnl ##
76 dnl ##  CONTEXT IMPLEMENTATION
77 dnl ##
78
79 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
80
81 dnl #
82 dnl #  1. determine possibilities
83 dnl #
84
85 dnl #  check for MCSC method
86 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
87
88 dnl #  check for pthread method
89 AC_CHECK_HEADERS([pthread.h])
90 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
91
92 dnl #
93 dnl #  2. make a general decision
94 dnl #
95
96 if test ".$mcsc" = .yes; then
97    mcsc=yes
98 elif test ".$pthread" = .yes; then
99    pthread=yes
100 else
101     ac_header=windows.h
102     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
103     if test `eval echo '${'$as_ac_Header'}'` = yes; then
104       windows_context=yes
105     else
106       AC_ERROR([no appropriate backend found])
107     fi
108 fi
109
110 dnl #
111 dnl #  3. allow decision to be overridden by user
112 dnl #
113
114 AC_MSG_CHECKING(what kind of backend should we use)
115
116 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
117
118 AC_ARG_WITH(context,
119   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
120   with_context=auto)
121
122 if test "x$with_context$mcsc" = "xucontextno" ; then 
123   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
124 fi
125
126 case $with_context in
127  ucontext) ;;
128  pthread) ;;
129  windows) ;;
130  auto) with_context=ucontext;;
131  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
132 esac
133
134 if test "x$with_context" = "xucontext" ; then
135   if test ".$mcsc" = .yes; then
136     AC_MSG_RESULT(found working ucontext. Great!)
137     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
138   else
139     if test ".$windows_context" = .yes ; then
140       AC_MSG_RESULT(use windows context portability layer.)
141       with_context=windows
142     else
143       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
144       with_context=pthread
145     fi
146   fi
147 fi
148
149 if test "x$with_context" = "xpthread"; then
150   AC_CHECK_HEADERS([pthread.h])
151   AC_CHECK_LIB(pthread,pthread_create,,
152     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
153   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
154   AC_MSG_RESULT(You have pthreads. Let's use them.)
155 fi
156
157 dnl #
158 dnl #  4. determine a few additional details
159 dnl #
160
161 if test "x$with_context" = "xucontext" ; then
162 dnl #  direction of stack grow
163   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
164   if test ".$ac_cv_check_stackgrowth" = ".down"; then
165       PTH_STACK_GROWTH="down"
166   else
167       PTH_STACK_GROWTH="up"
168   fi
169   AC_SUBST(PTH_STACK_GROWTH)
170   
171   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
172 fi
173
174
175 #########################################
176 ## Build optional modules (simix)
177 ##
178 SG_CONFIGURE_PART(Optional modules)
179 AC_ARG_ENABLE(simix,
180   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
181   enable_simix=$enableval,enable_simix=no)
182 if test "x$enable_simix" = "xyes" ; then
183   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
184   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
185 else 
186   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
187 fi
188 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
189
190 #########################################
191 ## Check for libraries extra-dependencies
192 ##
193
194 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
195
196 AC_MSG_CHECKING(for csdp)
197 SIMGRID_DEP=""
198 sdp=no
199 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
200 if test "x$csdp" = xyes; then 
201   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
202   AC_MSG_RESULT(Found working sdp library.)
203   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
204 else
205   AC_MSG_RESULT(Could not find any working sdp library.)
206 fi;
207 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
208
209 AC_SUBST([SIMGRID_DEP])
210
211 GRAS_DEP=""
212 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
213 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
214
215 AC_MSG_CHECKING(for extra dependencies of libgras)
216 case $host_os in
217   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
218 esac
219            
220 if test "x$GRAS_DEP" = x; then 
221    AC_MSG_RESULT(none)
222 else
223    AC_MSG_RESULT($GRAS_DEP)
224 fi
225 AC_SUBST([GRAS_DEP])
226
227
228 ##############################################
229 ## Enhance maintainer mode and SUBST variables
230 ## (must be placed after any compilation tests since our overprotective flags
231 ##  let some tests fail)
232
233 # Check whether we are doing a regular build or a GRAMINE (minimal) one
234 # Next line is modified by sed when building gramine source tree
235 gramine_mode=no
236 if test x$gramine_mode = xyes
237 then
238   USE_MAINTAINER_MODE=no
239 fi
240 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
241
242
243 AM_MAINTAINER_MODE
244 if test x$USE_MAINTAINER_MODE = xyes 
245 then
246    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
247    enable_compile_warnings=yes   
248 fi
249 SG_COMPILE_FLAGS
250
251 AC_SUBST(CFLAGS)
252 AC_SUBST(CPPFLAGS)
253 AC_SUBST(LDFLAGS)
254 AC_SUBST([abs_builddir])
255 AC_SUBST([abs_srcdir])
256 AC_SUBST([abs_top_builddir])
257 AC_SUBST([abs_top_srcdir])
258
259 #####################
260 ## Check for programs
261 ##
262
263 SG_CONFIGURE_PART(Check for programs...)
264 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
265 WARNING="This file is generated, do not edit"
266 AC_SUBST(WARNING)
267
268
269 # Can we rebuild the parsers?
270 # We really want flex and refuse other lex. So, the parser is portable and
271 # does not induce extra lib dependency
272 AC_PROG_FLEX(2.5.30)
273                 
274 # Can we rebuild the xml-lexers from the XML specification?
275 # if not, simply touch the flex source files (which are distributed in
276 #  tarballs even if generated by flexml) and hope for the best.
277 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
278 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
279
280 if test x$USE_MAINTAINER_MODE = xyes 
281 then
282    # Check for doxygen when in maintainer mode since dist* targets fail
283    # without it
284    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
285    if test x$DOXYGEN = x ; then 
286      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
287    fi
288 fi
289
290 # Can we extract really usable backtraces? (also need the popen function)
291 AC_PATH_PROG(ADDR2LINE, addr2line)
292 if test x$ADDR2LINE != x ; then
293   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
294 fi
295
296 AC_SUBST(ac_configure_args)
297 # Can we make status line about the compilation result?
298 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
299 if test x$MD5SUM != xno ; then
300   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
301                  xargs cat| $MD5SUM | sed 's/ .*$//'`
302 else 
303   build_version="no_md5sum_binary"
304 fi
305 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
306 AC_SUBST(build_id)
307
308 ###################
309 ## Makes the output
310 ##
311
312
313 #
314 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
315 #  src/amok/Makefile
316
317 SG_CONFIGURE_PART(Generating files...)
318
319 # Core of the libraries
320
321 AC_CONFIG_FILES([
322   Makefile
323   include/Makefile
324   src/Makefile
325   src/ucontext_stack.h
326 ])
327
328 # Tools being embeeded in gramine (stub generator)
329 AC_CONFIG_FILES([
330   tools/Makefile
331     tools/gras/Makefile
332 ])
333
334 # GRAMINE_CUT_BEGIN
335
336 # Tools NOT being embeeded in gramine
337 AC_CONFIG_FILES([
338   tools/graspe-slave
339 ],[
340     for file in                                                 \
341      tools/graspe-slave           tools/graspe-master           \
342     ; do                                                        \
343       test -e $file && chmod +x $file;                          \
344     done
345 ])
346
347 # Testsuite
348
349 AC_CONFIG_FILES([  
350   testsuite/Makefile
351   testsuite/run_tests    
352   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
353 ],[
354     for file in                                                 \
355      testsuite/run_tests                                        \
356      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
357     ; do                                                        \
358       test -e $file && chmod +x $file;                          \
359     done
360 ])
361
362 # Documentation
363 AC_CONFIG_FILES([
364   doc/Makefile
365   doc/Doxyfile
366 ])
367
368 # Examples
369
370 AC_CONFIG_FILES([
371   examples/Makefile 
372     examples/msg/Makefile           examples/msg/run_msg_test
373     examples/simdag/Makefile        examples/simdag/test_simdag
374     examples/gras/Makefile 
375       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
376       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
377       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
378       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
379       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
380       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
381       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
382       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
383
384       examples/gras/p2p/Makefile
385       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
386       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
387       
388     examples/amok/Makefile       
389       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
390       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
391 ],[
392     for file in                                                 \
393      \
394      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
395      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
396      \
397      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
398      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
399      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
400      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
401      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
402      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
403      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
404      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
405      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
406      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
407      examples/msg/run_msg_test                                  \
408      examples/simdag/test_simdag                                \
409     ; do                                                        \
410       test -e $file && chmod +x $file;                          \
411     done
412 ])
413
414 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
415 #    examples/gras/pastry/test_sg   
416
417
418
419 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
420 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
421
422
423 # GRAMINE_CUT_END
424
425 AC_OUTPUT
426
427 echo "
428
429 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
430
431         Compiler:        ${CC} (version: ${GCC_VERSION})
432         
433         CFlags:          ${CFLAGS}
434         CPPFlags:        ${CPPFLAGS}
435         LDFlags:         ${LDFLAGS}
436
437         Context backend: ${with_context}
438 "
439
440 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
441   echo "WARNING:"
442   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
443   echo "WARNING: You may want to enable this by specifying:"
444   echo "WARNING:"
445   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
446   echo "WARNING:"
447 fi
448 echo $build_id > stamp.configure
449
450 exit 0;