configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_PROG_LIBTOOL
  20
  21 ###############
  22 ## System checks
  23 ##
  24 SG_CONFIGURE_PART(System checks...)
  25 AC_PROG_CC(xlC gcc cc)
  26 AM_SANITY_CHECK
  27 AC_PROG_MAKE_SET
  28 AC_CHECK_PRINTF_NULL
  29 AC_CHECK_VA_COPY
  30
  31 # Checks for header files.
  32 AC_HEADER_STDC
  33 AC_HEADER_TIME
  34 AC_CHECK_HEADERS([sys/socket.h \
  35                   sys/stat.h \
  36                   windows.h winsock.h winsock2.h \
  37                   sys/time.h \
  38                   errno.h unistd.h \
  39                   execinfo.h])
  40 AC_CHECK_FUNCS([gettimeofday usleep \
  41                 getdtablesize \
  42                 sysconf\
  43                 readv\
  44                 popen])
  45
  46 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  47 AC_FUNC_SNPRINTF
  48 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  49 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  50 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  51 # we don't use those:
  52 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
  53 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
  54
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_TYPE_SIZE_T
  60
  61 ###################################
  62 ## SimGrid and GRAS specific checks
  63 ##
  64
  65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  66 # Check architecture signature begin
  67 GRAS_ARCH
  68 # Check architecture signature end
  69 GRAS_CHECK_STRUCT_COMPACTION
  70
  71
  72 dnl ##
  73 dnl ##  CONTEXT IMPLEMENTATION
  74 dnl ##
  75
  76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  77
  78 dnl #
  79 dnl #  1. determine possibilities
  80 dnl #
  81
  82 dnl #  check for MCSC method
  83 AC_MSG_CHECKING(on top of what can we build the contexts)
  84 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
  85 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
  86 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  87
  88 dnl #  check for pthread method
  89 AC_CHECK_HEADERS([pthread.h])
  90 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  91
  92 dnl #
  93 dnl #  2. make a general decision
  94 dnl #
  95
  96 if test ".$mcsc" = .yes; then
  97    mcsc=yes
  98 elif test ".$pthread" = .yes; then
  99    pthread=yes
 100 else
 101     ac_header=windows.h
 102     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 103     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 104       windows_context=yes
 105     else
 106       AC_ERROR([no appropriate backend found])
 107     fi
 108 fi
 109
 110 dnl #
 111 dnl #  3. allow decision to be overridden by user
 112 dnl #
 113
 114 AC_MSG_CHECKING(what kind of backend should we use)
 115
 116 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 117
 118 AC_ARG_WITH(context,
 119   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 120   with_context=auto)
 121 case $with_context in
 122  ucontext) ;;
 123  pthread) ;;
 124  windows) ;;
 125  auto) with_context=ucontext;;
 126  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
 127 esac
 128
 129 if test "x$with_context" = "xucontext" ; then
 130   if test ".$mcsc" = .yes; then
 131     AC_MSG_RESULT(found working ucontext. Great!)
 132     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 133   else
 134     if test ".$windows_context" = .yes ; then
 135       AC_MSG_RESULT(use windows context portability layer.)
 136       with_context=windows
 137     else
 138       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 139       with_context=pthread
 140     fi
 141   fi
 142 fi
 143
 144 if test "x$with_context" = "xpthread"; then
 145   AC_CHECK_HEADERS([pthread.h])
 146   AC_CHECK_LIB(pthread,pthread_create,,
 147     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
 148   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 149   AC_MSG_RESULT(You have pthreads. Let's use them.)
 150 fi
 151
 152 dnl #
 153 dnl #  4. determine a few additional details
 154 dnl #
 155
 156 if test "x$with_context" = "xucontext" ; then
 157 dnl #  direction of stack grow
 158   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 159   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 160       PTH_STACK_GROWTH="down"
 161   else
 162       PTH_STACK_GROWTH="up"
 163   fi
 164   AC_SUBST(PTH_STACK_GROWTH)
 165
 166   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 167 fi
 168
 169 #########################################
 170 ## Check for libraries extra-dependencies
 171 ##
 172
 173 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 174 SIMGRID_DEP=""
 175 AC_SUBST([SIMGRID_DEP])
 176
 177 GRAS_DEP=""
 178 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 179 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 180
 181 AC_MSG_CHECKING(for extra dependencies of libgras)
 182 case $host_os in
 183   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
 184 esac
 185
 186 if test "x$GRAS_DEP" = x; then
 187    AC_MSG_RESULT(none)
 188 else
 189    AC_MSG_RESULT($GRAS_DEP)
 190 fi
 191 AC_SUBST([GRAS_DEP])
 192
 193 ##############################################
 194 ## Enhance maintainer mode and SUBST variables
 195 ## (must be placed after any compilation tests since our overprotective flags
 196 ##  let some tests fail)
 197
 198 AM_MAINTAINER_MODE
 199 if test x$USE_MAINTAINER_MODE = xyes
 200 then
 201    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 202    enable_compile_warnings=yes
 203 fi
 204 SG_COMPILE_FLAGS
 205
 206 AC_SUBST(CFLAGS)
 207 AC_SUBST(CPPFLAGS)
 208 AC_SUBST(LDFLAGS)
 209 AC_SUBST([abs_builddir])
 210 AC_SUBST([abs_srcdir])
 211 AC_SUBST([abs_top_builddir])
 212 AC_SUBST([abs_top_srcdir])
 213
 214 #####################
 215 ## Check for programs
 216 ##
 217
 218 SG_CONFIGURE_PART(Check for programs...)
 219 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 220 WARNING="This file is generated, do not edit"
 221 AC_SUBST(WARNING)
 222
 223 # Can we rebuild the parsers?
 224 # We really want flex and refuse other lex. So, the parser is portable and
 225 # does not induce extra lib dependency
 226 AC_PROG_FLEX(2.5.30)
 227
 228 # Can we rebuild the xml-lexers from the XML specification?
 229 # if not, simply touch the flex source files (which are distributed in
 230 #  tarballs even if generated by flexml) and hope for the best.
 231 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 232 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 233
 234 if test x$USE_MAINTAINER_MODE = xyes
 235 then
 236    # Check for doxygen when in maintainer mode since dist* targets fail
 237    # without it
 238    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 239    if test x$DOXYGEN = x ; then
 240      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 241    fi
 242 fi
 243
 244 # Can we extract really usable backtraces? (also need the popen function)
 245 AC_PATH_PROG(ADDR2LINE, addr2line)
 246 if test x$ADDR2LINE != x ; then
 247   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 248 fi
 249
 250 ###################
 251 ## Makes the output
 252 ##
 253
 254
 255 #
 256 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 257 #  src/amok/Makefile
 258
 259 SG_CONFIGURE_PART(Generating files...)
 260 AC_CONFIG_FILES([
 261   Makefile
 262   include/Makefile
 263   src/Makefile
 264   src/ucontext_stack.h
 265   examples/Makefile
 266     examples/msg/Makefile           examples/msg/run_msg_test
 267     examples/gras/Makefile
 268       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 269       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 270       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 271       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 272       examples/gras/tokenS/Makefile examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl
 273       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 274       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 275       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 276
 277       examples/gras/p2p/Makefile
 278       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 279       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 280
 281     examples/amok/Makefile
 282       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 283       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 284   doc/Makefile
 285     doc/Doxyfile
 286   tools/graspe-slave            tools/Makefile
 287     tools/gras/Makefile
 288   testsuite/Makefile
 289   testsuite/run_tests
 290   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 291 ],[
 292     for file in                                                 \
 293      testsuite/run_tests                                        \
 294      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 295      tools/graspe-slave           tools/graspe-master           \
 296      \
 297      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 298      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 299      \
 300      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 301      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 302      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 303      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 304      examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl  \
 305      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 306      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 307      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 308      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 309      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 310      examples/msg/run_msg_test                                  \
 311     ; do                                                        \
 312       test -e $file && chmod +x $file;                          \
 313     done
 314 ])
 315
 316
 317 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 318 #    examples/gras/pastry/test_sg
 319
 320
 321
 322 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 323 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 324
 325
 326
 327 AC_OUTPUT
 328
 329 echo "
 330
 331 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 332
 333         Compiler:        ${CC} (version: ${GCC_VERSION})
 334
 335         CFlags:          ${CFLAGS}
 336         LDFlags:         ${LDFLAGS}
 337
 338         Context backend: ${with_context}
 339 "
 340
 341 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 342   echo "WARNING:"
 343   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 344   echo "WARNING: This is not really supported, so you should configure SimGrid like:"
 345   echo "WARNING:"
 346   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 347   echo "WARNING:"
 348 fi
 349
 350 exit 0;