tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 find_package(Java 1.7 COMPONENTS Runtime Development)
   7 if (NOT ${Java_FOUND})
   8   message(FATAL_ERROR "Java not found (need at least Java7). Please install the JDK or disable that option")
   9 endif()
  10 set(Java_FOUND 1)
  11 include(UseJava)
  12
  13 find_package(JNI REQUIRED)
  14 message("-- [Java] JNI found: ${JNI_FOUND}")
  15 message("-- [Java] JNI include dirs: ${JNI_INCLUDE_DIRS}")
  16
  17 find_package(SWIG)
  18 if(${SWIG_FOUND})
  19   include(UseSWIG)
  20   message("-- [Java] Swig found: version ${SWIG_VERSION}")
  21 else()
  22   message("-- [Java] Swig NOT FOUND. Surf java bindings won't get refreshed. That's fine unless you work on this part yourself.")
  23 endif()
  24 mark_as_advanced(SWIG_EXECUTABLE)
  25
  26
  27 # Rules to build libsimgrid-java
  28 #
  29 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  30 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
  31
  32 get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  33 if (COMMON_INCLUDES)
  34   set_target_properties(simgrid-java PROPERTIES
  35     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  36 else()
  37   set_target_properties(simgrid-java PROPERTIES
  38     INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  39 endif()
  40
  41 get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  42 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  43
  44 target_link_libraries(simgrid-java simgrid)
  45
  46
  47 if(WIN32)
  48   exec_program("java -d32 -version" OUTPUT_VARIABLE IS_32_BITS_JVM)
  49   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  50   if(NOT ${POSITION} GREATER -1)
  51     message(fatal_error "SimGrid can only use Java 64 bits")
  52   endif()
  53 endif()
  54
  55 # Rules to build simgrid.jar
  56 #
  57
  58 ## Files to include in simgrid.jar
  59 ##
  60 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  61 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  62 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  63
  64 set(LIBSIMGRID_SO
  65   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  66 set(LIBSIMGRID_JAVA_SO
  67   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  68 set(LIBSURF_JAVA_SO
  69   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  70
  71 ## Here is how to build simgrid.jar
  72 ##
  73 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  74   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  75   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  76 else()
  77   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  78 endif()
  79
  80 add_custom_command(
  81   TARGET simgrid-java_jar POST_BUILD
  82   COMMENT "Add the documentation into simgrid.jar..."
  83   DEPENDS ${MANIFEST_IN_FILE}
  84           ${CMAKE_HOME_DIRECTORY}/COPYING
  85           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  86           ${CMAKE_HOME_DIRECTORY}/NEWS
  87           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  88           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  89
  90   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  91   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  92   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  93
  94   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.surf org.simgrid.trace
  95
  96   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc -C ${CMAKE_HOME_DIRECTORY} COPYING ChangeLog ChangeLog.SimGrid-java LICENSE-LGPL-2.1 NEWS
  97   )
  98
  99 ###
 100 ### Pack the java libraries into the jarfile if asked to do so
 101 ###
 102
 103 if(enable_lib_in_jar)
 104
 105   # Stripping disabled for the time being to make Java debuggable. We should introduce a proper option for that.
 106   #find_program(STRIP_COMMAND strip)
 107   #mark_as_advanced(STRIP_COMMAND)
 108   #if(NOT STRIP_COMMAND)
 109   #  set(STRIP_COMMAND "cmake -E echo (strip not found)")
 110   #endif()
 111
 112   set(SG_SYSTEM_NAME ${CMAKE_SYSTEM_NAME})
 113
 114   if(${SG_SYSTEM_NAME} MATCHES "kFreeBSD")
 115     set(SG_SYSTEM_NAME GNU/kFreeBSD)
 116   endif()
 117
 118   set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
 119   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
 120     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/x86)
 121   endif()
 122   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 123        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 124     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/amd64)
 125   endif()
 126   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "armv7l")
 127     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/arm) # Default arm (soft-float ABI)
 128   endif()
 129
 130   add_custom_command(
 131     TARGET simgrid-java_jar POST_BUILD
 132     COMMENT "Add the native libs into simgrid.jar..."
 133     DEPENDS simgrid-java
 134             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 135             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 136             ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
 137
 138     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 139     COMMAND ${CMAKE_COMMAND} -E make_directory                                     ${JAVA_NATIVE_PATH}
 140     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}
 141     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}
 142     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}    ${JAVA_NATIVE_PATH}
 143
 144     ## strip seems to fail on Mac on binaries that are already stripped.
 145     ## It then spits: "symbols referenced by indirect symbol table entries that can't be stripped"
 146     #COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}      || true
 147     #COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO} || true
 148     #COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSURF_JAVA_SO}    || true
 149
 150     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 151
 152     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 153     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 154     )
 155
 156   if (HAVE_BOOST_CONTEXT)
 157     add_custom_command(
 158       TARGET simgrid-java_jar POST_BUILD
 159       COMMENT "Add the boost_context lib into simgrid.jar..."
 160       COMMAND ${CMAKE_COMMAND} -E copy ${Boost_CONTEXT_LIBRARY_RELEASE}  ${JAVA_NATIVE_PATH}
 161       COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 162     )
 163   endif()
 164
 165   if(MINGW)
 166     find_library(WINPTHREAD_DLL
 167       NAME winpthread winpthread-1
 168       PATHS C:\\MinGW C:\\MinGW64 C:\\MinGW\\bin C:\\MinGW64\\bin
 169     )
 170     add_custom_command(
 171       TARGET simgrid-java_jar POST_BUILD
 172       COMMENT "Add the MinGW libs into simgrid.jar..."
 173       DEPENDS ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 174
 175       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 176       COMMAND ${CMAKE_COMMAND} -E make_directory          ${JAVA_NATIVE_PATH}
 177       COMMAND ${CMAKE_COMMAND} -E copy ${WINPTHREAD_DLL}  ${JAVA_NATIVE_PATH}
 178
 179       COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 180       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 181     )
 182   endif(MINGW)
 183 endif(enable_lib_in_jar)
 184
 185 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 186
 187 if(${SWIG_FOUND})
 188   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 189   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 190
 191   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 192
 193   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 194   swig_link_libraries(surf-java simgrid)
 195 else()
 196   add_library(surf-java SHARED ${JSURF_C_SRC})
 197   target_link_libraries(surf-java simgrid)
 198 endif()
 199
 200 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 201 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 202
 203 add_dependencies(simgrid-java surf-java)
 204 add_dependencies(simgrid-java_jar surf-java)
 205