configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.2-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal\
  48                 getline])
  49
  50 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  51 AC_FUNC_SNPRINTF
  52 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  53 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  54 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_TYPE_SIZE_T
  60
  61 ###################################
  62 ## SimGrid and GRAS specific checks
  63 ##
  64
  65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  66 # Check architecture signature begin
  67 GRAS_ARCH
  68 # Check architecture signature end
  69 GRAS_CHECK_STRUCT_COMPACTION
  70
  71
  72 dnl ##
  73 dnl ##  CONTEXT IMPLEMENTATION
  74 dnl ##
  75
  76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  77
  78 dnl #
  79 dnl #  1. determine possibilities
  80 dnl #
  81
  82 dnl #  check for MCSC method
  83 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  84
  85 dnl #  check for pthread method
  86 AC_CHECK_HEADERS([pthread.h])
  87 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  88
  89 dnl #
  90 dnl #  2. make a general decision
  91 dnl #
  92
  93 if test ".$mcsc" = .yes; then
  94    mcsc=yes
  95 elif test ".$pthread" = .yes; then
  96    pthread=yes
  97 else
  98     ac_header=windows.h
  99     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 100     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 101       windows_context=yes
 102     else
 103       AC_ERROR([no appropriate backend found])
 104     fi
 105 fi
 106
 107 dnl #
 108 dnl #  3. allow decision to be overridden by user
 109 dnl #
 110
 111 AC_MSG_CHECKING(what kind of backend should we use)
 112
 113 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 114 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 115
 116 AC_ARG_WITH(context,
 117   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 118   with_context=auto)
 119
 120 if test "x$with_context$mcsc" = "xucontextno" ; then
 121   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 122 fi
 123
 124 case $with_context in
 125  ucontext) ;;
 126  pthread) ;;
 127  windows) ;;
 128  auto) with_context=ucontext;;
 129  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 130 esac
 131
 132 if test "x$with_context" = "xucontext" ; then
 133   if test ".$mcsc" = .yes; then
 134     AC_MSG_RESULT(found working ucontext. Great!)
 135     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 136   else
 137     if test ".$windows_context" = .yes ; then
 138       AC_MSG_RESULT(use windows context portability layer.)
 139       with_context=windows
 140     else
 141       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 142       with_context=pthread
 143     fi
 144   fi
 145 fi
 146
 147 if test "x$with_context" = "xpthread"; then
 148   AC_CHECK_HEADERS([pthread.h])
 149   AC_CHECK_LIB(pthread,pthread_create,,
 150     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 151   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 152   AC_MSG_RESULT(You have pthreads. Let's use them.)
 153 fi
 154
 155 dnl #
 156 dnl #  4. determine a few additional details
 157 dnl #
 158
 159 if test "x$with_context" = "xucontext" ; then
 160 dnl #  direction of stack grow
 161   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 162   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 163       PTH_STACK_GROWTH="down"
 164   else
 165       PTH_STACK_GROWTH="up"
 166   fi
 167   AC_SUBST(PTH_STACK_GROWTH)
 168
 169   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 170 fi
 171
 172
 173 #########################################
 174 ## Build optional modules (simix)
 175 ##
 176 SG_CONFIGURE_PART(Optional modules)
 177 AC_ARG_ENABLE(simix,
 178   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
 179   enable_simix=$enableval,enable_simix=no)
 180 if test "x$enable_simix" = "xyes" ; then
 181   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
 182   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
 183 else
 184   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
 185 fi
 186 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
 187
 188 #########################################
 189 ## Check for libraries extra-dependencies
 190 ##
 191
 192 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 193
 194 SIMGRID_DEP=""
 195 GRAS_DEP=""
 196 AC_CHECK_LIB(pthread,pthread_create,SIMGRID_DEP="-lpthread"; GRAS_DEP="-lpthread")
 197
 198 AC_MSG_CHECKING(for csdp)
 199 sdp=no
 200 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 201 if test "x$csdp" = xyes; then
 202   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 203   AC_MSG_RESULT(Found working sdp library.)
 204   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 205 else
 206   AC_MSG_RESULT(Could not find any working sdp library.)
 207 fi;
 208 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 209
 210 AC_SUBST([SIMGRID_DEP])
 211
 212 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 213 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 214
 215 AC_MSG_CHECKING(for extra dependencies of libgras)
 216 case $host_os in
 217   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 218             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 219             AC_DEFINE(CONTEXT_THREADS,1);;
 220 esac
 221
 222 if test "x$GRAS_DEP" = x; then
 223    AC_MSG_RESULT(none)
 224 else
 225    AC_MSG_RESULT($GRAS_DEP)
 226 fi
 227 AC_SUBST([GRAS_DEP])
 228
 229
 230 ##############################################
 231 ## Enhance maintainer mode and SUBST variables
 232 ## (must be placed after any compilation tests since our overprotective flags
 233 ##  let some tests fail)
 234
 235 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 236 # Next line is modified by sed when building gramine source tree
 237 gramine_mode=no
 238 if test x$gramine_mode = xyes
 239 then
 240   USE_MAINTAINER_MODE=no
 241 fi
 242 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 243
 244
 245 AM_MAINTAINER_MODE
 246 if test x$USE_MAINTAINER_MODE = xyes
 247 then
 248    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 249    enable_compile_warnings=yes
 250 fi
 251 SG_COMPILE_FLAGS
 252
 253 AC_SUBST(CFLAGS)
 254 AC_SUBST(CPPFLAGS)
 255 AC_SUBST(LDFLAGS)
 256 AC_SUBST([abs_builddir])
 257 AC_SUBST([abs_srcdir])
 258 AC_SUBST([abs_top_builddir])
 259 AC_SUBST([abs_top_srcdir])
 260
 261 #####################
 262 ## Check for programs
 263 ##
 264
 265 SG_CONFIGURE_PART(Check for programs...)
 266 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 267 WARNING="This file is generated, do not edit"
 268 AC_SUBST(WARNING)
 269
 270
 271 # Can we rebuild the parsers?
 272 # We really want flex and refuse other lex. So, the parser is portable and
 273 # does not induce extra lib dependency
 274 AC_PROG_FLEX(2.5.30)
 275
 276 # Can we rebuild the xml-lexers from the XML specification?
 277 # if not, simply touch the flex source files (which are distributed in
 278 #  tarballs even if generated by flexml) and hope for the best.
 279 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 280 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 281
 282 if test x$USE_MAINTAINER_MODE = xyes
 283 then
 284    # Check for doxygen when in maintainer mode since dist* targets fail
 285    # without it
 286    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 287    if test x$DOXYGEN = x ; then
 288      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 289    fi
 290 fi
 291
 292 # Can we extract really usable backtraces? (also need the popen function)
 293 AC_PATH_PROG(ADDR2LINE, addr2line)
 294 if test x$ADDR2LINE != x ; then
 295   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 296 fi
 297
 298 AC_SUBST(ac_configure_args)
 299 # Can we make status line about the compilation result?
 300 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 301 if test x$MD5SUM != xno ; then
 302   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 303                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 304 else
 305   build_version="no_md5sum_binary"
 306 fi
 307 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 308 AC_SUBST(build_id)
 309
 310 ###################
 311 ## Makes the output
 312 ##
 313
 314
 315 #
 316 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 317 #  src/amok/Makefile
 318
 319 SG_CONFIGURE_PART(Generating files...)
 320
 321 # Core of the libraries
 322
 323 AC_CONFIG_FILES([
 324   Makefile
 325   include/Makefile
 326   src/Makefile
 327   src/ucontext_stack.h
 328 ])
 329
 330 # Tools being embeeded in gramine (stub generator)
 331 AC_CONFIG_FILES([
 332   tools/Makefile
 333     tools/gras/Makefile
 334 ])
 335 dnl tools/tesh/Makefile
 336
 337
 338 # GRAMINE_CUT_BEGIN
 339
 340 # Tools NOT being embeeded in gramine
 341 AC_CONFIG_FILES([
 342   tools/graspe-slave
 343 ],[
 344     for file in                                                 \
 345      tools/graspe-slave           tools/graspe-master           \
 346     ; do                                                        \
 347       test -e $file && chmod +x $file;                          \
 348     done
 349 ])
 350
 351 # Testsuite
 352
 353 AC_CONFIG_FILES([
 354   testsuite/Makefile
 355   testsuite/run_tests
 356   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 357 ],[
 358     for file in                                                 \
 359      testsuite/run_tests                                        \
 360      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 361     ; do                                                        \
 362       test -e $file && chmod +x $file;                          \
 363     done
 364 ])
 365
 366 # Documentation
 367 AC_CONFIG_FILES([
 368   doc/Makefile
 369   doc/Doxyfile
 370 ])
 371
 372 # Examples
 373
 374 AC_CONFIG_FILES([
 375   examples/Makefile
 376     examples/msg/Makefile           examples/msg/run_msg_test
 377     examples/simdag/Makefile        examples/simdag/test_simdag
 378     examples/gras/Makefile
 379       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 380       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 381       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 382       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 383       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 384       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 385       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 386       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 387
 388       examples/gras/p2p/Makefile
 389       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 390       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 391
 392     examples/amok/Makefile
 393       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 394       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 395 ],[
 396     for file in                                                 \
 397      \
 398      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 399      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 400      \
 401      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 402      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 403      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 404      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 405      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 406      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 407      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 408      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 409      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 410      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 411      examples/msg/run_msg_test                                  \
 412      examples/simdag/test_simdag                                \
 413     ; do                                                        \
 414       test -e $file && chmod +x $file;                          \
 415     done
 416 ])
 417
 418 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 419 #    examples/gras/pastry/test_sg
 420
 421
 422
 423 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 424 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 425
 426
 427 # GRAMINE_CUT_END
 428
 429 AC_OUTPUT
 430
 431 echo "
 432
 433 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 434
 435         Compiler:        ${CC} (version: ${GCC_VERSION})
 436
 437         CFlags:          ${CFLAGS}
 438         CPPFlags:        ${CPPFLAGS}
 439         LDFlags:         ${LDFLAGS}
 440
 441         Context backend: ${with_context}
 442 "
 443
 444 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 445   echo "WARNING:"
 446   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 447   echo "WARNING: You may want to enable this by specifying:"
 448   echo "WARNING:"
 449   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 450   echo "WARNING:"
 451 fi
 452 echo $build_id > stamp.configure
 453
 454 exit 0;