tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/doc/html/)
   7 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/"
   8   DESTINATION doc/simgrid/html/)
   9
  10 # binaries
  11 if(enable_smpi)
  12   install(PROGRAMS
  13     ${CMAKE_BINARY_DIR}/bin/smpicc
  14     ${CMAKE_BINARY_DIR}/bin/smpicxx
  15     ${CMAKE_BINARY_DIR}/bin/smpirun
  16     DESTINATION bin/)
  17   if(SMPI_FORTRAN)
  18     install(PROGRAMS
  19       ${CMAKE_BINARY_DIR}/bin/smpif90
  20       ${CMAKE_BINARY_DIR}/bin/smpiff
  21       DESTINATION bin/)
  22     install(PROGRAMS
  23       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  24       DESTINATION include/smpi/)
  25   endif()
  26 endif()
  27
  28 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh  DESTINATION bin/)
  29
  30 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator  DESTINATION bin/)
  31
  32 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  33   DESTINATION bin/
  34   RENAME simgrid-colorizer)
  35
  36 add_custom_target(simgrid-colorizer ALL
  37   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  38   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize)
  39
  40 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  41   DESTINATION bin/
  42   RENAME simgrid_update_xml)
  43
  44 add_custom_target(simgrid_update_xml ALL
  45   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  46   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  47
  48 # libraries
  49 install(TARGETS simgrid DESTINATION lib/)
  50
  51 if(enable_java)
  52   set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  53   install(TARGETS simgrid-java   DESTINATION lib/)
  54   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  55       DESTINATION java/
  56       RENAME simgrid.jar)
  57 endif()
  58
  59 # include files
  60 foreach(file ${headers_to_install}  ${generated_headers_to_install})
  61   get_filename_component(location ${file} PATH)
  62   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  63   install(FILES ${file} DESTINATION ${location})
  64 endforeach()
  65
  66 # example files
  67 foreach(file ${examples_to_install})
  68   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  69   get_filename_component(location ${file} PATH)
  70   install(FILES "examples/${file}"
  71     DESTINATION doc/simgrid/examples/${location})
  72 endforeach(file ${examples_to_install})
  73
  74 ###########################################
  75 ### Fill in the "make uninstall" target ###
  76 ###########################################
  77
  78 add_custom_target(uninstall
  79   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
  80   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
  81   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
  82   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
  83   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
  84   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
  85   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicxx
  86   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
  87   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
  88   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
  89   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
  90   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
  91   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
  92   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
  93   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
  94   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
  95   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
  96   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
  97   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
  98   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
  99   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 100   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 101   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 102   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 103   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid.h
 104   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 105   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 106   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 107   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 108   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 109   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicc.1
 110   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicxx.1
 111   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpirun.1
 112   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpiff.1
 113   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpif90.1
 114
 115
 116   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 117   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}")
 118
 119 if(SIMGRID_HAVE_LUA)
 120   add_custom_command(TARGET uninstall
 121     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 122     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 123     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/")
 124 endif()
 125
 126 ################################################################
 127 ## Build a sain "make dist" target to build a source package ###
 128 ##   containing only the files that I explicitely state      ###
 129 ##   (instead of any cruft laying on my disk as CPack does)  ###
 130 ################################################################
 131
 132 # This is the complete list of what will be added to the source archive
 133 set(source_to_pack
 134   ${headers_to_install}
 135   ${source_of_generated_headers}
 136   ${BINDINGS_SRC}
 137   ${JEDULE_SRC}
 138   ${JMSG_C_SRC}
 139   ${JMSG_JAVA_SRC}
 140   ${LUA_SRC}
 141   ${MC_SRC_BASE}
 142   ${MC_SRC}
 143   ${MC_SIMGRID_MC_SRC}
 144   ${MSG_SRC}
 145   ${S4U_SRC}
 146   ${NS3_SRC}
 147   ${PLUGINS_SRC}
 148   ${RNGSTREAM_SRC}
 149   ${SIMDAG_SRC}
 150   ${SIMGRID_SRC}
 151   ${SIMIX_SRC}
 152   ${SMPI_SRC}
 153   ${SURF_SRC}
 154   ${TRACING_SRC}
 155   ${XBT_RL_SRC}
 156   ${XBT_SRC}
 157   ${EXTRA_DIST}
 158   ${CMAKE_SOURCE_FILES}
 159   ${CMAKEFILES_TXT}
 160   ${DOC_FIGS}
 161   ${DOC_IMG}
 162   ${DOC_SOURCES}
 163   ${DOC_TOOLS}
 164   ${PLATFORMS_EXAMPLES}
 165   ${README_files}
 166   ${bin_files}
 167   ${examples_src}
 168   ${tesh_files}
 169   ${teshsuite_src}
 170   ${testsuite_src}
 171   ${tools_src}
 172   ${txt_files}
 173   ${xml_files}
 174   )
 175
 176 ##########################################
 177 ### Fill in the "make dist-dir" target ###
 178 ##########################################
 179
 180 add_custom_target(dist-dir
 181   COMMENT "Generating the distribution directory"
 182   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 183   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 184   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 185   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 186   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_BINARY_DIR}/doc/html/ ${PROJECT_NAME}-${release_version}/doc/html/
 187   COMMAND rm -f `grep -rl " Reference" ${PROJECT_NAME}-${release_version}/doc/html/` # Doxygen, go away
 188   COMMAND rm -f `grep -rl "Member List" ${PROJECT_NAME}-${release_version}/doc/html/` # Doxygen, you're getting annoying
 189   )
 190 add_dependencies(dist-dir maintainer_files)
 191
 192 set(dirs_in_tarball "")
 193 foreach(file ${source_to_pack})
 194   #message(${file})
 195   # This damn prefix is still set somewhere (seems to be in subdirs)
 196   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 197
 198   # Create the directory on need
 199   get_filename_component(file_location ${file} PATH)
 200   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 201   if(NOT OPERATION)
 202     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 203     add_custom_command(
 204       TARGET dist-dir
 205       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 206   endif()
 207
 208   # Actually copy the file
 209   add_custom_command(
 210     TARGET dist-dir
 211     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 212 endforeach(file ${source_to_pack})
 213
 214 add_custom_command(
 215   TARGET dist-dir
 216   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 217
 218 ##########################################################
 219 ### Link all sources to the bindir if srcdir != bindir ###
 220 ##########################################################
 221 add_custom_target(hardlinks
 222    COMMENT "Making the source files available from the bindir"
 223 )
 224 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 225   foreach(file ${source_to_pack})
 226     #message(${file})
 227     # This damn prefix is still set somewhere (seems to be in subdirs)
 228     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 229
 230     # Create the directory on need
 231     get_filename_component(file_location ${file} PATH)
 232     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 233     if(NOT OPERATION)
 234       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 235       add_custom_command(
 236         TARGET hardlinks
 237         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 238     endif()
 239
 240     # Actually copy the file
 241     add_custom_command(
 242       TARGET hardlinks
 243       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 244     )
 245   endforeach(file ${source_to_pack})
 246 endif()
 247
 248
 249 ######################################
 250 ### Fill in the "make dist" target ###
 251 ######################################
 252
 253 add_custom_target(dist
 254   COMMENT "Removing the distribution directory"
 255   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 256   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 257   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 258
 259 add_custom_command(
 260   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 261   COMMENT "Compressing the archive from the distribution directory"
 262   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 263   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 264   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 265 add_dependencies(dist dist-dir)
 266
 267 if(NOT enable_maintainer_mode)
 268   add_custom_target(echo-dist
 269     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 270     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 271     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------")
 272   add_dependencies(dist echo-dist)
 273 endif()
 274
 275 ###########################################
 276 ### Fill in the "make distcheck" target ###
 277 ###########################################
 278
 279 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 280
 281 # Allow to test the "make dist"
 282 add_custom_target(distcheck
 283   COMMAND ${CMAKE_COMMAND} -E echo "XXX compare archive with git repository"
 284   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 285
 286   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 287   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 288
 289   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 290   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 291
 292   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 293   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 294   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 295
 296   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 297   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 298           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 299
 300   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 301   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 302
 303   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 304   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 305
 306   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 307   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 308   COMMAND ${CMAKE_COMMAND} -E create_symlink
 309   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 310   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 311
 312   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install with documentation"
 313   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 314
 315   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 316   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 317   )
 318 add_dependencies(distcheck dist)
 319
 320 #######################################
 321 ### Fill in the "make check" target ###
 322 #######################################
 323
 324 if(enable_memcheck)
 325   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 326 else()
 327   add_custom_target(check COMMAND make test)
 328 endif()
 329
 330 #######################################
 331 ### Fill in the "make xxx-clean" target ###
 332 #######################################
 333
 334 add_custom_target(maintainer-clean
 335   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 336   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 337   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 338   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 339   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 340   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 341   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 342   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 343   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 344   COMMAND ${CMAKE_COMMAND} -E remove -f src/mpif.f90
 345   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}")
 346
 347 include(CPack)