buildtools/Cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3 ###############################
   4 # Declare the library content #
   5 ###############################
   6 # If we want supernovae, rewrite the libs' content to use it
   7 include(${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Supernovae.cmake)
   8
   9 # Actually declare our libraries
  10
  11 add_library(simgrid SHARED ${simgrid_sources})
  12 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  13
  14 if(enable_lib_static)
  15   add_library(simgrid_static STATIC ${simgrid_sources})
  16 endif()
  17
  18 if(enable_smpi)
  19   add_library(smpi SHARED ${SMPI_SRC})
  20   set_target_properties(smpi PROPERTIES VERSION ${libsmpi_version})
  21   if(enable_lib_static)
  22     add_library(smpi_static STATIC ${SMPI_SRC})
  23   endif()
  24 endif()
  25
  26 if(enable_java)
  27   add_library(SG_java SHARED ${JMSG_C_SRC})
  28   set_target_properties(SG_java PROPERTIES VERSION ${libSG_java_version})
  29   get_target_property(COMMON_INCLUDES SG_java INCLUDE_DIRECTORIES)
  30   set_target_properties(SG_java PROPERTIES
  31     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  32   add_dependencies(SG_java simgrid)
  33
  34   if(WIN32)
  35     get_target_property(SIMGRID_LIB_NAME_NAME SG_java LIBRARY_OUTPUT_NAME)
  36     set_target_properties(SG_java PROPERTIES
  37       LINK_FLAGS "-Wl,--subsystem,windows,--kill-at ${SIMGRID_LIB_NAME}"
  38       PREFIX "")
  39     find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  40     message(STATUS "pexports: ${PEXPORTS_PATH}")
  41     if(PEXPORTS_PATH)
  42       add_custom_command(TARGET SG_java POST_BUILD
  43         COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/SG_java.dll > ${CMAKE_BINARY_DIR}/SG_java.def)
  44     endif(PEXPORTS_PATH)
  45   else()
  46     target_link_libraries(SG_java simgrid)
  47   endif()
  48
  49   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  50   add_jar(SG_java_jar ${JMSG_JAVA_SRC})
  51
  52   set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  53   set(MANIFEST_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF")
  54
  55   if(CMAKE_SYSTEM_PROCESSOR MATCHES ".86")
  56     if(${ARCH_32_BITS})
  57       set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/x86/")
  58     else()
  59       set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/amd64/")
  60     endif()
  61   else()
  62     message(WARNING "Unknown system type. Processor: ${CMAKE_SYSTEM_PROCESSOR}; System: ${CMAKE_SYSTEM_NAME}")
  63     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR/")
  64   endif()
  65   message("Native libraries bundled into: ${JSG_BUNDLE}")
  66
  67   set(LIBSIMGRID_SO
  68     ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  69   set(LIBSG_JAVA_SO
  70     ${CMAKE_SHARED_LIBRARY_PREFIX}SG_java${CMAKE_SHARED_LIBRARY_SUFFIX})
  71
  72   add_custom_command(
  73     COMMENT "Finalize simgrid.jar..."
  74     OUTPUT ${SIMGRID_JAR}_finalized
  75     DEPENDS ${SIMGRID_JAR} ${MANIFEST_FILE}
  76             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
  77             ${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}
  78             ${CMAKE_HOME_DIRECTORY}/COPYING
  79             ${CMAKE_HOME_DIRECTORY}/ChangeLog
  80             ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  81     COMMAND ${CMAKE_COMMAND} -E remove_directory "NATIVE"
  82     COMMAND ${CMAKE_COMMAND} -E make_directory "${JSG_BUNDLE}"
  83     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}" "${JSG_BUNDLE}"
  84     COMMAND ${CMAKE_STRIP} -S "${JSG_BUNDLE}/${LIBSIMGRID_SO}"
  85     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}" "${JSG_BUNDLE}"
  86     COMMAND ${CMAKE_STRIP} -S "${JSG_BUNDLE}/${LIBSG_JAVA_SO}"
  87     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/COPYING" "${JSG_BUNDLE}"
  88     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog" "${JSG_BUNDLE}"
  89     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java" "${JSG_BUNDLE}"
  90     COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} "NATIVE"
  91     COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
  92     COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
  93     )
  94   add_custom_target(SG_java_jar_finalize DEPENDS ${SIMGRID_JAR}_finalized)
  95   add_dependencies(SG_java_jar SG_java_jar_finalize)
  96 endif()
  97
  98 add_dependencies(simgrid maintainer_files)
  99
 100 # if supernovaeing, we need some depends to make sure that the source gets generated
 101 if (enable_supernovae)
 102   add_dependencies(simgrid ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
 103   if(enable_lib_static)
 104     add_dependencies(simgrid_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
 105   endif()
 106
 107   if(enable_smpi)
 108     add_dependencies(smpi ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
 109     if(enable_lib_static)
 110       add_dependencies(smpi_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
 111     endif()
 112   endif()
 113 endif()
 114
 115 # Compute the dependencies of SimGrid
 116 #####################################
 117 set(SIMGRID_DEP "-lm -lpcre")
 118
 119 if(pthread)
 120   if(${CONTEXT_THREADS})
 121     SET(SIMGRID_DEP "${SIMGRID_DEP} -pthread")
 122   endif()
 123 endif()
 124
 125 if(HAVE_LUA)
 126   ADD_CUSTOM_TARGET(link_simgrid_lua ALL
 127     DEPENDS     simgrid
 128     ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
 129     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
 130     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
 131     )
 132   add_custom_command(
 133     OUTPUT      ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
 134     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
 135     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
 136     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 137     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/lua/
 138     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} #for test
 139
 140     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 141     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/msg/masterslave/
 142     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} #for test
 143
 144     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 145     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/simdag/
 146     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} #for test
 147     )
 148   SET(SIMGRID_DEP "${SIMGRID_DEP} -l${LIB_LUA_NAME}")
 149 endif()
 150
 151 if(HAVE_GRAPHVIZ)
 152   if(HAVE_CGRAPH_LIB)
 153     SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
 154   else()
 155     if(HAVE_AGRAPH_LIB)
 156       SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
 157     endif()
 158   endif()
 159 endif()
 160
 161 if(HAVE_GTNETS)
 162   SET(SIMGRID_DEP "${SIMGRID_DEP} -lgtnets")
 163 endif()
 164
 165 if(HAVE_MC)
 166   # The availability of libunwind was checked in CompleteInFiles.cmake
 167   #   (that includes FindLibunwind.cmake), so simply load it now.
 168
 169   # This supposes that the host machine is either an AMD or a X86.
 170   # This is deeply wrong, and should be fixed by manually loading -lunwind-PLAT (FIXME)
 171   if(PROCESSOR_x86_64)
 172     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86_64")
 173   else()
 174     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86")
 175   endif()
 176 endif()
 177
 178 if(MMALLOC_WANT_OVERRIDE_LEGACY AND HAVE_GNU_LD)
 179   SET(SIMGRID_DEP "${SIMGRID_DEP} -ldl")
 180 endif()
 181
 182 if(HAVE_NS3)
 183   if(${NS3_VERSION} EQUAL 310)
 184     SET(SIMGRID_DEP "${SIMGRID_DEP} -lns3")
 185     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_NS3_3_10")
 186     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_NS3_3_10")
 187   else()
 188     SET(SIMGRID_DEP "${SIMGRID_DEP} -lns3-core -lns3-csma -lns3-point-to-point -lns3-internet -lns3-applications")
 189   endif()
 190 endif()
 191
 192 if(HAVE_POSIX_GETTIME)
 193   SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
 194 endif()
 195
 196 target_link_libraries(simgrid   ${SIMGRID_DEP})
 197
 198 # Compute the dependencies of SMPI
 199 ##################################
 200 set(SMPI_DEP "")
 201 if(APPLE)
 202   set(SMPI_DEP "-Wl,-U -Wl,_smpi_simulated_main")
 203 endif()
 204 if(enable_smpi)
 205   target_link_libraries(smpi    simgrid ${SMPI_DEP})
 206 endif()
 207
 208 # Pass dependencies to static libs
 209 ##################################
 210 if(enable_lib_static)
 211   target_link_libraries(simgrid_static  ${SIMGRID_DEP})
 212   add_dependencies(simgrid_static maintainer_files)
 213   set_target_properties(simgrid_static PROPERTIES OUTPUT_NAME simgrid)
 214   if(enable_smpi)
 215     target_link_libraries(smpi_static   simgrid ${SMPI_DEP})
 216     set_target_properties(smpi_static PROPERTIES OUTPUT_NAME smpi)
 217   endif()
 218 endif()
 219
 220 # Dependencies from maintainer mode
 221 ###################################
 222 if(enable_maintainer_mode AND BISON_EXE AND LEX_EXE)
 223   add_dependencies(simgrid automaton_generated_src)
 224 endif()