Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Specific Makefile.am for buildtools. Allows for a clean target in there
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.3.4-svn],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision: 6267 $)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AC_PROG_CXX
21 AM_PROG_GCJ
22
23 AM_INIT_AUTOMAKE([gnu -Wno-portability])
24 AC_CONFIG_MACRO_DIR(acmacro) 
25 ACLOCAL="$ACLOCAL -I acmacro"
26
27 dnl Next few lines is a hack to prevent libtool checking for F77
28 m4_undefine([AC_PROG_F77])
29 m4_defun([AC_PROG_F77],[])
30
31 dnl We do build a proper DLL when using win32
32 AC_LIBTOOL_WIN32_DLL
33 AC_PROG_LIBTOOL
34
35 ###############
36 ## SVN version check
37 ##
38 if test -e .svn && echo $VERSION | grep -q svn; then
39   VERSION="$VERSION-r`svnversion`"
40   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
41   PACKAGE_STRING="$PACKAGE_STRING r`svnversion`"
42 else if test -e .git && echo $VERSION | grep -q svn; then
43   ver=`git log --oneline -1 | sed 's| .*||'`
44   VERSION=`echo "$VERSION-r$ver" | sed 's/svn/git/'`
45   PACKAGE_VERSION=`echo "$PACKAGE_VERSION-r$ver" | sed 's/svn/git/'`
46   PACKAGE_STRING=`echo "$PACKAGE_STRING r$ver" | sed 's/svn/git/'`
47 fi fi
48
49 ###############
50 ## System checks
51 ##
52 SG_CONFIGURE_PART([System checks...])
53 AC_PROG_CC(xlC gcc cc)
54 AM_SANITY_CHECK
55 AC_PROG_MAKE_SET
56 AC_CHECK_PRINTF_NULL
57 AC_CHECK_VA_COPY
58
59 # Checks for header files.
60 AC_HEADER_STDC
61 AC_HEADER_TIME
62 AC_CHECK_HEADERS([sys/socket.h \
63                   sys/stat.h \
64                   windows.h winsock.h winsock2.h \
65                   sys/time.h \
66                   errno.h unistd.h \
67                   execinfo.h\
68                   signal.h ])
69 AC_CHECK_FUNCS([gettimeofday usleep \
70                 getdtablesize \
71                 sysconf\
72                 readv\
73                 popen\
74                 signal])
75   
76 dnl GNU systems before POSIX2008 need the _GNU_SOURCE definition to find getline (and simgrid does pass this)             
77 AC_MSG_CHECKING(a usable getline)
78 AC_LINK_IFELSE([
79     #define _GNU_SOURCE
80     #include <stdio.h>
81     int main(void){
82       FILE * fp;
83       char * line = NULL;
84       size_t len = 0;
85       getline(&line, &len, fp);
86     }
87   ],[
88     AC_MSG_RESULT(found)
89   ],[
90     AC_SUBST(need_getline, ["#define SIMGRID_NEED_GETLINE 1 /* enable the getline replacement*/"])
91     AC_DEFINE(SIMGRID_NEED_GETLINE, 1, enable the getline replacement)
92     AC_MSG_RESULT(not found (activating internal implementation))
93   ])
94               
95 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
96 AC_FUNC_SNPRINTF
97 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
98 AC_CHECK_FUNC(  asprintf, :,[
99     AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf replacement)
100     AC_SUBST(need_asprintf, ["#define SIMGRID_NEED_ASPRINTF 1 /* enable the asprintf replacement */"]) 
101    ])
102 AC_CHECK_FUNC( vasprintf, :,[
103     AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf replacement)
104     AC_SUBST(need_vasprintf, ["#define SIMGRID_NEED_VASPRINTF 1 /*enable the vasprintf replacement */"]) 
105    ])
106
107 # Checks for typedefs, structures, and compiler characteristics.
108 AC_C_CONST
109 AC_C_INLINE
110 AC_TYPE_SIZE_T
111
112 ###################################
113 ## SimGrid and GRAS specific checks
114 ##
115
116 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
117 # Check architecture signature begin
118 GRAS_ARCH
119 # Check architecture signature end
120 GRAS_CHECK_STRUCT_COMPACTION
121
122
123 dnl ##
124 dnl ##  CONTEXT IMPLEMENTATION
125 dnl ##
126
127 SG_CONFIGURE_PART([Checking threads, contexts or assimilated...])
128
129 dnl #
130 dnl #  1. determine possibilities
131 dnl #
132
133 dnl #  check for MCSC method (ucontexts)
134 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
135
136 dnl #  check for pthread method
137 AC_CHECK_HEADERS([pthread.h])
138 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
139
140 if test x$pthread = xyes ; then
141   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
142   if test ${HAVE_SEM_INIT} = yes ; then
143      AC_MSG_CHECKING(if sem_init is compilable)
144      AC_TRY_COMPILE([#include <semaphore.h>],
145                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
146      if test ${HAVE_SEM_INIT} = yes ; then
147         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
148         AC_MSG_RESULT(yes)
149      else
150         AC_MSG_RESULT(no)
151      fi
152   fi
153   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
154   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
155      AC_MSG_CHECKING(if sem_timedwait is compilable)
156      AC_TRY_COMPILE([#include <semaphore.h>],
157                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
158      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
159         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
160         AC_MSG_RESULT(yes)
161      else
162         AC_MSG_RESULT(no)
163      fi
164   fi
165
166   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
167   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
168      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
169      AC_TRY_COMPILE([#include <pthread.h>],
170                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
171      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
172         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
173         AC_MSG_RESULT(yes)
174      else
175         AC_MSG_RESULT(no)
176      fi
177   fi
178 fi
179
180 dnl #
181 dnl #  2. make a general decision
182 dnl #
183
184 if test ".$mcsc" = .yes; then
185    # ucontext found
186    mcsc=yes
187 elif test ".$pthread" = .yes; then
188    # ucontext not found, but pthread found
189    pthread=yes
190 else
191     ac_header=windows.h
192     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
193     if test `eval echo '${'$as_ac_Header'}'` = yes; then
194       windows_context=yes
195     else
196       AC_ERROR([no appropriate backend found])
197     fi
198 fi
199 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
200
201
202 dnl #
203 dnl #  3. allow decision to be overridden by user
204 dnl #
205
206 AC_MSG_CHECKING(what kind of backend should we use)
207
208 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
209 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
210
211 AC_ARG_WITH(context,
212   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
213   with_context=auto)
214
215 if test "x$with_context$mcsc" = "xucontextno" ; then 
216   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
217 fi
218
219 case $with_context in
220  ucontext) ;;
221  pthread) ;;
222  pthreads) ;;
223  windows) ;;
224  auto) with_context=ucontext;;
225  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
226 esac
227
228 if test "x$with_context" = "xucontext" ; then
229   if test ".$mcsc" = .yes; then
230     AC_MSG_RESULT(found working ucontext. Great!)
231     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
232     AC_CHECK_HEADERS([valgrind/valgrind.h])
233   else
234     if test ".$windows_context" = .yes ; then
235       AC_MSG_RESULT(use windows context portability layer.)
236       with_context=windows
237     else
238       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
239       with_context=pthread
240     fi
241   fi
242 fi
243
244 if test "x$with_context" = "xpthread"; then
245   if test x$pthread != xyes ; then # reuse previous checks
246     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
247   fi
248   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
249   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
250 fi
251 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
252
253 dnl #
254 dnl #  4. determine a few additional details
255 dnl #
256
257 if test "x$with_context" = "xucontext" ; then
258 dnl #  direction of stack grow
259   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
260   if test ".$ac_cv_check_stackgrowth" = ".down"; then
261       PTH_STACK_GROWTH="down"
262   else
263       PTH_STACK_GROWTH="up"
264   fi
265   AC_SUBST(PTH_STACK_GROWTH)
266   
267   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
268 fi
269
270 #########################################
271 ## Check for libraries extra-dependencies
272 ##
273
274 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
275
276 SIMGRID_DEP=""
277 SMPI_DEP=""
278 GRAS_DEP=""
279
280 if test xpthread=xyes ; then 
281   # if the pthreads are usable
282   if test "x$with_context" = "xpthread" ; then
283     # if we use them to implement the xbt_context
284     SIMGRID_DEP="-lpthread"
285   fi
286   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
287   if test "x$with_context" != "xwindows" ; then
288     GRAS_DEP="-lpthread"
289   fi
290 fi
291 AC_SEARCH_LIBS([connect],[socket],[],[],[]) # need -lsocket on solaris
292
293 #########################################
294 ## Build optional modules (gtnets)
295 ##
296 gtnets=no
297 AC_ARG_WITH(gtnets,
298   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
299   gtnets_path="$withval",gtnets_path="no")
300 if test "x$gtnets_path" = "xno" ; then
301   AC_MSG_RESULT(Eventually you will come to GTNetS.)
302 else  
303   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
304   AC_MSG_CHECKING(for gtnets)
305   AC_LANG_PUSH([C++])  
306   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
307   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
308   LDFLAGS_SAV=$LDFLAGS  
309   CPPFLAGS_SAV=$CPPFLAGS
310   CPPFLAGS+=$GTNETS_CPPFLAGS
311   LDFLAGS+=$GTNETS_LDFLAGS
312   AC_TRY_LINK([ #include <simulator.h>
313               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
314   CPPFLAGS=$CPPFLAGS_SAV
315   LDFLAGS=$LDFLAGS_SAV
316   AC_LANG_POP([C++])  
317 fi
318
319 if test "x$gtnets" = "xyes" ; then
320   AC_MSG_RESULT(Enabling GTNETS support.)
321   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
322   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
323   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
324 fi
325 AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
326
327
328
329 AC_SUBST([SIMGRID_DEP])
330 AC_SUBST([SMPI_DEP])
331
332 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
333 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
334
335 AC_MSG_CHECKING(for extra dependencies of libgras)
336 case $host_os in
337   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
338             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
339             AC_DEFINE(CONTEXT_THREADS,1);;
340 esac
341
342
343
344 if test "x$GRAS_DEP" = x; then 
345    AC_MSG_RESULT(none)
346 else
347    AC_MSG_RESULT($GRAS_DEP)
348 fi
349 AC_SUBST([GRAS_DEP])
350
351 ##############################################
352 ## Enhance maintainer mode and SUBST variables
353 ## (must be placed after any compilation tests since our overprotective flags
354 ##  let some tests fail)
355
356 # Check whether we are doing a regular build or a GRAMINE (minimal) one
357 # Next line is modified by sed when building gramine source tree
358 gramine_mode=no
359 if test x$gramine_mode = xyes
360 then
361   USE_MAINTAINER_MODE=no
362 fi
363 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
364
365 AM_MAINTAINER_MODE
366 if test x$USE_MAINTAINER_MODE = xyes 
367 then
368    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
369    force_compile_warnings=yes   
370 fi
371 SG_COMPILE_FLAGS
372
373 ##
374 ## Support for the supernovae compilation mode
375 ##
376 AC_ARG_ENABLE(supernovae,
377               AS_HELP_STRING([--enable-supernovae],[Put the whole library in one compilation unit only to help gcc optimizing the code]),
378               [supernovae=$enableval],
379               [supernovae=no])
380 AM_CONDITIONAL(SUPERNOVAE_MODE, test x$supernovae != xno)
381
382 AC_SUBST([CFLAGS])
383 AC_SUBST([CPPFLAGS])
384 AC_SUBST([LDFLAGS])
385 AC_SUBST([AM_CPPFLAGS])
386 AC_SUBST([abs_builddir])
387 AC_SUBST([abs_srcdir])
388 AC_SUBST([abs_top_builddir])
389 AC_SUBST([abs_top_srcdir])
390
391 ##############################################
392 ## Specific mode for build daemons.
393 ## (they compile the SVN without having the autotools installed)
394 AC_ARG_ENABLE(botbuild,
395               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
396               botbuild=$enableval,botbuild=no)
397 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
398
399 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
400   echo "ERROR: "
401   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
402   echo "ERROR: For this, just call configure this way:"
403   echo "ERROR:"
404   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
405   echo "ERROR:"
406   exit 1
407 fi
408
409
410 SG_CONFIGURE_PART(Checking Java bindings...)
411 # Java cruft
412 AC_ARG_ENABLE(java,
413               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
414               disable_java=$enableval,disable_java=yes)
415 if test "x$disable_java" != "xyes" ; then
416    use_java="disabled by user"
417 else
418   AC_PATH_PROG([JAVAC], [javac], `which javac`)
419   AC_PATH_PROG([JAVA],  [java] , `which java`)
420   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
421   AC_CHECK_HEADERS(jni.h)
422   if test -n "$JAVAC" && test -n "$JAVA" && test -n "$JAR" && test "x$ac_cv_header_jni_h" = "xyes" ; then
423      use_java="yes"
424      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
425   else   
426      use_java="no"
427   fi
428 fi
429 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
430 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
431
432
433 #####################
434 ## Check for programs
435 ##
436
437 SG_CONFIGURE_PART(Checking programs...)
438 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
439 WARNING="This file is generated, do not edit"
440 AC_SUBST(WARNING)
441
442
443 # Can we rebuild the parsers?
444 # We really want flex and refuse other lex. So, the parser is portable and
445 # does not induce extra lib dependency
446 AC_PROG_FLEX(2.5.30)
447                 
448 # Can we rebuild the xml-lexers from the XML specification?
449 # if not, simply touch the flex source files (which are distributed in
450 #  tarballs even if generated by flexml) and hope for the best.
451 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
452 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
453
454 # Check for doxygen when in maintainer mode which is helpful to build doc & dist
455 AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
456 AM_CONDITIONAL(HAVE_DOXYGEN,test x$DOXYGEN != x)
457
458 # Can we rebuild the publication list from the bib file?
459 AC_CHECK_PROG(BIBTEX,bibtex,`which flexml`,NOTFOUND)
460 AC_CHECK_PROG(BIBTOOL,bibtool,`which bibtool`,NOTFOUND)
461 AC_CHECK_PROG(ICONV,iconv,`which iconv`,NOTFOUND)
462 AC_CHECK_PROG(BIBTEX2HTML,bibtex2html,`which bibtex2html`,NOTFOUND)
463
464 BIBTEX2HTML_VER="date"
465 if test "x$BIBTEX2HTML" != "xNOTFOUND" ; then
466    BIBTEX2HTML_VER=`$BIBTEX2HTML --help 2>&1 | grep date`
467 fi;
468
469 AC_MSG_CHECKING(whether you have the right bibtex2html and will be able to build HTML files from the bibtex file)
470 AM_CONDITIONAL(HAVE_BIBTEX2HTML,test "x$BIBTEX2HTML_VER" == "x"     &&
471                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
472                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
473                                 test "x$ICONV" != "xNOTFOUND"         )
474
475 if test "x$BIBTEX2HTML_VER" == "x"     &&
476                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
477                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
478                                 test "x$ICONV" != "xNOTFOUND"; then
479    AC_MSG_RESULT(yes)
480 else
481    AC_MSG_RESULT(no)
482 fi
483
484 # Can we extract really usable backtraces? (also need the popen function)
485 AC_PATH_PROG(ADDR2LINE, addr2line)
486 if test x$ADDR2LINE != x ; then
487   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
488 fi
489
490 AC_SUBST(ac_configure_args)
491 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
492 # Can we make status line about the compilation result?
493 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
494 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
495 AC_SUBST(build_id)
496
497 ###################
498 ## Makes the output
499 ##
500
501
502 #
503 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
504 #  src/amok/Makefile
505
506 SG_CONFIGURE_PART(Generating files...)
507
508 # Core of the libraries
509
510 AC_CONFIG_FILES([
511   Makefile
512   include/Makefile
513   include/simgrid_config.h
514   src/Makefile
515   src/context_sysv_config.h
516 ])
517
518 # Tools being embeeded in gramine (stub generator)
519 AC_CONFIG_FILES([
520   tools/Makefile
521     tools/gras/Makefile
522     tools/tesh/Makefile
523 ])
524 #    tools/tesh2/Makefile
525
526
527 # GRAMINE_CUT_BEGIN
528
529 # Tools NOT being embeeded in gramine
530 AC_CONFIG_FILES([
531   tools/graspe-slave
532 ],[
533     for file in                                                 \
534      tools/graspe-slave           tools/graspe-master           \
535      checkall                     examples/java/runtest         \
536      src/mk_supernovae.sh                                       \
537     ; do                                                        \
538       test -e $file && chmod +x $file;                          \
539     done
540 ])
541
542 # build tools && Testsuite
543
544 AC_CONFIG_FILES([  
545   buildtools/Makefile
546   testsuite/Makefile
547   testsuite/run_tests    
548 ],[
549     for file in                                                 \
550      testsuite/run_tests                                        \
551     ; do                                                        \
552       test -e $file && chmod +x $file;                          \
553     done
554 ])
555
556 # Teshsuite (testsuite using tesh)
557 AC_CONFIG_FILES([  
558   teshsuite/Makefile
559 ])
560
561 # Documentation
562 AC_CONFIG_FILES([
563   doc/Makefile
564   doc/Doxyfile
565 ])
566
567 # Examples
568
569 #      examples/gras/p2p/Makefile
570 #      examples/gras/p2p/chord/Makefile
571 #      examples/gras/p2p/can/Makefile
572
573 AC_CONFIG_FILES([
574     examples/java/Makefile
575       examples/java/basic/Makefile
576       examples/java/comm_time/Makefile
577       examples/java/suspend/Makefile
578       examples/java/ping_pong/Makefile
579 ])
580
581 AC_CONFIG_FILES([
582   examples/Makefile 
583     examples/msg/Makefile
584     examples/simdag/Makefile
585     examples/gras/Makefile
586       examples/gras/ping/Makefile   
587       examples/gras/rpc/Makefile
588       examples/gras/spawn/Makefile
589       examples/gras/synchro/Makefile
590       examples/gras/timer/Makefile
591       examples/gras/properties/Makefile
592       examples/gras/chrono/Makefile
593       examples/gras/mutual_exclusion/simple_token/Makefile
594       examples/gras/mmrpc/Makefile
595       examples/gras/pmm/Makefile
596       examples/gras/all2all/Makefile
597     examples/amok/Makefile       
598     examples/smpi/Makefile       
599 ])
600 #      examples/gras/replay/Makefile
601
602 AC_CONFIG_FILES([
603   src/smpi/smpicc
604   src/smpi/smpirun
605 ],[
606     for file in                                                 \
607       src/smpi/smpicc                                           \
608       src/smpi/smpirun                                          \
609     ; do                                                        \
610       test -e $file && chmod +x $file;                          \
611     done
612 ])
613
614 # GRAMINE_CUT_END
615
616 AC_OUTPUT
617
618 echo "
619
620 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
621
622         Compiler:        ${CC} (version: ${GCC_VERSION})
623         
624         CFlags:          ${CFLAGS}
625         CPPFlags:        ${CPPFLAGS}
626         LDFlags:         ${LDFLAGS}
627
628         Context backend: ${with_context}
629         Compile Java:    ${use_java}
630         
631         Maintainer mode: ${USE_MAINTAINER_MODE}
632         Supernovae mode: ${supernovae}
633
634 "
635 if test x$botbuild = xyes ; then
636   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
637   echo
638 fi
639
640 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
641   echo "WARNING: "
642   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
643   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
644   echo "WARNING:"
645   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
646   echo "WARNING:"
647 fi
648
649 echo $build_id > stamp.configure
650
651 exit 0;