configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal\
  48                 getline])
  49
  50 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  51 AC_FUNC_SNPRINTF
  52 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  53 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  54 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_TYPE_SIZE_T
  60
  61 ###################################
  62 ## SimGrid and GRAS specific checks
  63 ##
  64
  65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  66 # Check architecture signature begin
  67 GRAS_ARCH
  68 # Check architecture signature end
  69 GRAS_CHECK_STRUCT_COMPACTION
  70
  71
  72 dnl ##
  73 dnl ##  CONTEXT IMPLEMENTATION
  74 dnl ##
  75
  76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  77
  78 dnl #
  79 dnl #  1. determine possibilities
  80 dnl #
  81
  82 dnl #  check for MCSC method
  83 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  84
  85 dnl #  check for pthread method
  86 AC_CHECK_HEADERS([pthread.h])
  87 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  88
  89 dnl #
  90 dnl #  2. make a general decision
  91 dnl #
  92
  93 if test ".$mcsc" = .yes; then
  94    mcsc=yes
  95 elif test ".$pthread" = .yes; then
  96    pthread=yes
  97 else
  98     ac_header=windows.h
  99     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 100     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 101       windows_context=yes
 102     else
 103       AC_ERROR([no appropriate backend found])
 104     fi
 105 fi
 106
 107 dnl #
 108 dnl #  3. allow decision to be overridden by user
 109 dnl #
 110
 111 AC_MSG_CHECKING(what kind of backend should we use)
 112
 113 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 114 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 115
 116 AC_ARG_WITH(context,
 117   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 118   with_context=auto)
 119
 120 if test "x$with_context$mcsc" = "xucontextno" ; then
 121   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 122 fi
 123
 124 case $with_context in
 125  ucontext) ;;
 126  pthread) ;;
 127  pthreads) ;;
 128  windows) ;;
 129  auto) with_context=ucontext;;
 130  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 131 esac
 132
 133 if test "x$with_context" = "xucontext" ; then
 134   if test ".$mcsc" = .yes; then
 135     AC_MSG_RESULT(found working ucontext. Great!)
 136     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 137   else
 138     if test ".$windows_context" = .yes ; then
 139       AC_MSG_RESULT(use windows context portability layer.)
 140       with_context=windows
 141     else
 142       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 143       with_context=pthread
 144     fi
 145   fi
 146 fi
 147
 148 if test "x$with_context" = "xpthreads"; then
 149   with_context=pthread
 150 fi
 151 if test "x$with_context" = "xpthread"; then
 152   AC_CHECK_HEADERS([pthread.h])
 153   AC_CHECK_LIB(pthread,pthread_create,,
 154     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 155   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 156   AC_MSG_RESULT(You have pthreads. Let's use them.)
 157 fi
 158
 159 dnl #
 160 dnl #  4. determine a few additional details
 161 dnl #
 162
 163 if test "x$with_context" = "xucontext" ; then
 164 dnl #  direction of stack grow
 165   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 166   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 167       PTH_STACK_GROWTH="down"
 168   else
 169       PTH_STACK_GROWTH="up"
 170   fi
 171   AC_SUBST(PTH_STACK_GROWTH)
 172
 173   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 174 fi
 175
 176
 177 #########################################
 178 ## Build optional modules (simix)
 179 ##
 180 SG_CONFIGURE_PART(Optional modules)
 181 AC_ARG_ENABLE(simix,
 182   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
 183   enable_simix=$enableval,enable_simix=no)
 184 if test "x$enable_simix" = "xyes" ; then
 185   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
 186   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
 187 else
 188   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
 189 fi
 190 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
 191
 192 #########################################
 193 ## Check for libraries extra-dependencies
 194 ##
 195
 196 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 197
 198 SIMGRID_DEP=""
 199 GRAS_DEP=""
 200 if test xpthread=xyes ; then
 201   # if the pthreads are usable
 202   if test "x$with_context" = "xpthread" ; then
 203     # if we use them to implement the xbt_context
 204     SIMGRID_DEP="-lpthread"
 205   fi
 206   # we need them in any case for the gras lib (which is multithreaded)
 207   GRAS_DEP="-lpthread"
 208 fi
 209
 210 AC_MSG_CHECKING(for csdp)
 211 sdp=no
 212 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 213 if test "x$csdp" = xyes; then
 214   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 215   AC_MSG_RESULT(Found working sdp library.)
 216   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 217 else
 218   AC_MSG_RESULT(Could not find any working sdp library.)
 219 fi;
 220 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 221
 222 AC_SUBST([SIMGRID_DEP])
 223
 224 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 225 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 226
 227 AC_MSG_CHECKING(for extra dependencies of libgras)
 228 case $host_os in
 229   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 230             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 231             AC_DEFINE(CONTEXT_THREADS,1);;
 232 esac
 233
 234 if test "x$GRAS_DEP" = x; then
 235    AC_MSG_RESULT(none)
 236 else
 237    AC_MSG_RESULT($GRAS_DEP)
 238 fi
 239 AC_SUBST([GRAS_DEP])
 240
 241
 242 ##############################################
 243 ## Enhance maintainer mode and SUBST variables
 244 ## (must be placed after any compilation tests since our overprotective flags
 245 ##  let some tests fail)
 246
 247 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 248 # Next line is modified by sed when building gramine source tree
 249 gramine_mode=no
 250 if test x$gramine_mode = xyes
 251 then
 252   USE_MAINTAINER_MODE=no
 253 fi
 254 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 255
 256
 257 AM_MAINTAINER_MODE
 258 if test x$USE_MAINTAINER_MODE = xyes
 259 then
 260    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 261    enable_compile_warnings=yes
 262 fi
 263 SG_COMPILE_FLAGS
 264
 265 AC_SUBST(CFLAGS)
 266 AC_SUBST(CPPFLAGS)
 267 AC_SUBST(LDFLAGS)
 268 AC_SUBST([abs_builddir])
 269 AC_SUBST([abs_srcdir])
 270 AC_SUBST([abs_top_builddir])
 271 AC_SUBST([abs_top_srcdir])
 272
 273 #####################
 274 ## Check for programs
 275 ##
 276
 277 SG_CONFIGURE_PART(Check for programs...)
 278 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 279 WARNING="This file is generated, do not edit"
 280 AC_SUBST(WARNING)
 281
 282
 283 # Can we rebuild the parsers?
 284 # We really want flex and refuse other lex. So, the parser is portable and
 285 # does not induce extra lib dependency
 286 AC_PROG_FLEX(2.5.30)
 287
 288 # Can we rebuild the xml-lexers from the XML specification?
 289 # if not, simply touch the flex source files (which are distributed in
 290 #  tarballs even if generated by flexml) and hope for the best.
 291 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 292 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 293
 294 if test x$USE_MAINTAINER_MODE = xyes
 295 then
 296    # Check for doxygen when in maintainer mode since dist* targets fail
 297    # without it
 298    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 299    if test x$DOXYGEN = x ; then
 300      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 301    fi
 302 fi
 303
 304 # Can we extract really usable backtraces? (also need the popen function)
 305 AC_PATH_PROG(ADDR2LINE, addr2line)
 306 if test x$ADDR2LINE != x ; then
 307   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 308 fi
 309
 310 AC_SUBST(ac_configure_args)
 311 # Can we make status line about the compilation result?
 312 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 313 if test x$MD5SUM != xno ; then
 314   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 315                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 316 else
 317   build_version="no_md5sum_binary"
 318 fi
 319 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 320 AC_SUBST(build_id)
 321
 322 ###################
 323 ## Makes the output
 324 ##
 325
 326
 327 #
 328 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 329 #  src/amok/Makefile
 330
 331 SG_CONFIGURE_PART(Generating files...)
 332
 333 # Core of the libraries
 334
 335 AC_CONFIG_FILES([
 336   Makefile
 337   include/Makefile
 338   src/Makefile
 339   src/ucontext_stack.h
 340 ])
 341
 342 # Tools being embeeded in gramine (stub generator)
 343 AC_CONFIG_FILES([
 344   tools/Makefile
 345     tools/gras/Makefile
 346     tools/tesh/Makefile
 347 ])
 348
 349
 350 # GRAMINE_CUT_BEGIN
 351
 352 # Tools NOT being embeeded in gramine
 353 AC_CONFIG_FILES([
 354   tools/graspe-slave
 355 ],[
 356     for file in                                                 \
 357      tools/graspe-slave           tools/graspe-master           \
 358     ; do                                                        \
 359       test -e $file && chmod +x $file;                          \
 360     done
 361 ])
 362
 363 # Testsuite
 364
 365 AC_CONFIG_FILES([
 366   testsuite/Makefile
 367   testsuite/run_tests
 368   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 369 ],[
 370     for file in                                                 \
 371      testsuite/run_tests                                        \
 372      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 373     ; do                                                        \
 374       test -e $file && chmod +x $file;                          \
 375     done
 376 ])
 377
 378 # Documentation
 379 AC_CONFIG_FILES([
 380   doc/Makefile
 381   doc/Doxyfile
 382 ])
 383
 384 # Examples
 385
 386 AC_CONFIG_FILES([
 387   examples/Makefile
 388     examples/msg/Makefile
 389     examples/simdag/Makefile        examples/simdag/test_simdag
 390     examples/gras/Makefile
 391       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 392       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 393       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 394       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 395       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 396       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 397       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 398       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 399
 400       examples/gras/p2p/Makefile
 401       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 402       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 403
 404     examples/amok/Makefile
 405       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 406       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 407 ],[
 408     for file in                                                 \
 409      \
 410      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 411      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 412      \
 413      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 414      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 415      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 416      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 417      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 418      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 419      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 420      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 421      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 422      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 423      examples/msg/run_msg_test                                  \
 424      examples/simdag/test_simdag                                \
 425     ; do                                                        \
 426       test -e $file && chmod +x $file;                          \
 427     done
 428 ])
 429
 430 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 431 #    examples/gras/pastry/test_sg
 432
 433
 434
 435 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 436 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 437
 438
 439 # GRAMINE_CUT_END
 440
 441 AC_OUTPUT
 442
 443 echo "
 444
 445 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 446
 447         Compiler:        ${CC} (version: ${GCC_VERSION})
 448
 449         CFlags:          ${CFLAGS}
 450         CPPFlags:        ${CPPFLAGS}
 451         LDFlags:         ${LDFLAGS}
 452
 453         Context backend: ${with_context}
 454 "
 455
 456 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 457   echo "WARNING:"
 458   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 459   echo "WARNING: You may want to enable this by specifying:"
 460   echo "WARNING:"
 461   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 462   echo "WARNING:"
 463 fi
 464 echo $build_id > stamp.configure
 465
 466 exit 0;