FindSimGrid.cmake

   1 # CMake find module to search for the SimGrid library.
   2
   3 # Copyright (c) 2016-2019. The SimGrid Team.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the license (GNU LGPL) which comes with this package.
   7
   8 #
   9 # USERS OF PROGRAMS USING SIMGRID
  10 # -------------------------------
  11 #
  12 # If cmake does not find this file, add its path to CMAKE_PREFIX_PATH:
  13 #    CMAKE_PREFIX_PATH="/path/to/FindSimGrid.cmake:$CMAKE_PREFIX_PATH"  cmake .
  14 #
  15 # If this file does not find SimGrid, define SimGrid_PATH:
  16 #    SimGrid_PATH=/path/to/simgrid  cmake .
  17
  18 #
  19 # DEVELOPERS OF PROGRAMS USING SIMGRID
  20 # ------------------------------------
  21 #
  22 #  1. Include this file in your own CMakeLists.txt (before defining any target)
  23 #     Either by copying it in your tree, or (recommended) by using the
  24 #     version automatically installed by SimGrid.
  25 #
  26 #  2. Afterward, if you have CMake >= 2.8.12, this will define a
  27 #     target called 'SimGrid::Simgrid'. Use it as:
  28 #       target_link_libraries(your-simulator SimGrid::SimGrid)
  29 #
  30 #    With older CMake (< 2.8.12), it simply defines several variables:
  31 #       SimGrid_INCLUDE_DIR - the SimGrid include directories
  32 #       SimGrid_LIBRARY - link your simulator against it to use SimGrid
  33 #    Use as:
  34 #      include_directories("${SimGrid_INCLUDE_DIR}" SYSTEM)
  35 #      target_link_libraries(your-simulator ${SimGrid_LIBRARY})
  36 #
  37 #  In both cases, it also define a SimGrid_VERSION macro, that you
  38 #    can use to deal with API evolutions as follows:
  39 #
  40 #    #if SimGrid_VERSION < 31800
  41 #      (code to use if the installed version is lower than v3.18)
  42 #    #elif SimGrid_VERSION < 31900
  43 #      (code to use if we are using SimGrid v3.18.x)
  44 #    #else
  45 #      (code to use with SimGrid v3.19+)
  46 #    #endif
  47 #
  48 #  Since SimGrid header files require C++11, so we set CMAKE_CXX_STANDARD to 11.
  49 #    Change this variable in your own file if you need a later standard.
  50
  51 #
  52 # IMPROVING THIS FILE
  53 # -------------------
  54 #  - Use automatic SimGridConfig.cmake creation via export/install(EXPORT in main CMakeLists.txt:
  55 #    https://cliutils.gitlab.io/modern-cmake/chapters/exporting.html
  56 #    https://cmake.org/Wiki/CMake/Tutorials/How_to_create_a_ProjectConfig.cmake_file
  57 #    https://github.com/boostcon/cppnow_presentations_2017/blob/master/05-19-2017_friday/effective_cmake__daniel_pfeifer__cppnow_05-19-2017.pdf
  58
  59 cmake_minimum_required(VERSION 2.8)
  60
  61 set(CMAKE_CXX_STANDARD 11)
  62 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  63
  64 find_path(SimGrid_INCLUDE_DIR
  65   NAMES simgrid/config.h
  66   NAMES simgrid/version.h
  67   PATHS ${SimGrid_PATH}/include /opt/simgrid/include
  68 )
  69 if (NOT SimGrid_INCLUDE_DIR)
  70   # search under the old name
  71   find_path(SimGrid_INCLUDE_DIR
  72     NAMES simgrid_config.h
  73     PATHS ${SimGrid_PATH}/include /opt/simgrid/include
  74   )
  75 endif()
  76 find_library(SimGrid_LIBRARY
  77   NAMES simgrid
  78   PATHS ${SimGrid_PATH}/lib /opt/simgrid/lib
  79 )
  80 mark_as_advanced(SimGrid_INCLUDE_DIR)
  81 mark_as_advanced(SimGrid_LIBRARY)
  82
  83 if (SimGrid_INCLUDE_DIR)
  84   set(SimGrid_VERSION_REGEX "^#define SIMGRID_VERSION_(MAJOR|MINOR|PATCH) ([0-9]+)$")
  85   if (EXISTS "${SimGrid_INCLUDE_DIR}/simgrid/version.h")
  86     file(STRINGS "${SimGrid_INCLUDE_DIR}/simgrid/version.h" SimGrid_VERSION_STRING REGEX ${SimGrid_VERSION_REGEX})
  87   else()
  88     file(STRINGS "${SimGrid_INCLUDE_DIR}/simgrid_config.h" SimGrid_VERSION_STRING REGEX ${SimGrid_VERSION_REGEX})
  89   endif()
  90   set(SimGrid_VERSION "")
  91
  92   # Concat the matches to MAJOR.MINOR.PATCH assuming they appear in this order
  93   foreach(match ${SimGrid_VERSION_STRING})
  94     if(SimGrid_VERSION)
  95       set(SimGrid_VERSION "${SimGrid_VERSION}.")
  96     endif()
  97     string(REGEX REPLACE ${SimGrid_VERSION_REGEX} "${SimGrid_VERSION}\\2" SimGrid_VERSION ${match})
  98     set(SimGrid_VERSION_${CMAKE_MATCH_1} ${CMAKE_MATCH_2})
  99   endforeach()
 100   unset(SimGrid_VERSION_STRING)
 101   unset(SimGrid_VERSION_REGEX)
 102 endif ()
 103
 104 include(FindPackageHandleStandardArgs)
 105 find_package_handle_standard_args(SimGrid
 106   FOUND_VAR SimGrid_FOUND
 107   REQUIRED_VARS SimGrid_INCLUDE_DIR SimGrid_LIBRARY
 108   VERSION_VAR SimGrid_VERSION
 109 )
 110
 111 if (SimGrid_FOUND AND NOT CMAKE_VERSION VERSION_LESS 2.8.12)
 112   add_library(SimGrid::SimGrid SHARED IMPORTED)
 113   set_target_properties(SimGrid::SimGrid PROPERTIES
 114     INTERFACE_SYSTEM_INCLUDE_DIRECTORIES ${SimGrid_INCLUDE_DIR}
 115     INTERFACE_COMPILE_FEATURES cxx_alias_templates
 116     IMPORTED_LOCATION ${SimGrid_LIBRARY}
 117   )
 118   # We need C++11, so check for it just in case the user removed it since compiling SimGrid
 119   if (NOT CMAKE_VERSION VERSION_LESS 3.8)
 120     # 3.8+ allows us to simply require C++11 (or higher)
 121     set_property(TARGET SimGrid::SimGrid PROPERTY INTERFACE_COMPILE_FEATURES cxx_std_11)
 122   elseif (NOT CMAKE_VERSION VERSION_LESS 3.1)
 123     # 3.1+ is similar but for certain features. We pick just one
 124     set_property(TARGET SimGrid::SimGrid PROPERTY INTERFACE_COMPILE_FEATURES cxx_alias_templates)
 125   else ()
 126     # Old CMake can't do much. Just check the CXX_FLAGS and inform the user when a C++11 feature does not work
 127     include(CheckCXXSourceCompiles)
 128     set(CMAKE_REQUIRED_FLAGS "${CMAKE_CXX_FLAGS}")
 129     check_cxx_source_compiles("using Foo = int; int main(){}" _SIMGRID_CXX11_ENABLED)
 130     if (NOT _SIMGRID_CXX11_ENABLED)
 131         message(WARNING "C++11 is required to use SimGrid. Enable it with e.g. -std=c++11")
 132     endif ()
 133     unset(_SIMGRID_CXX11_ENABLED CACHE)
 134   endif ()
 135 endif ()
 136