buildtools/Cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 if(NOT EXISTS ${CMAKE_HOME_DIRECTORY}/doc/html/)
   7         file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html/)
   8 endif(NOT EXISTS ${CMAKE_HOME_DIRECTORY}/doc/html/)
   9 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/html/"
  10   DESTINATION "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/html/"
  11   PATTERN ".svn" EXCLUDE
  12   PATTERN ".git" EXCLUDE
  13   PATTERN "*.o" EXCLUDE
  14   PATTERN "*~" EXCLUDE
  15 )
  16
  17 #### Generate the manpages
  18 if(NOT WIN32)
  19 if( NOT MANPAGE_DIR)
  20         set( MANPAGE_DIR ${CMAKE_BINARY_DIR}/manpages )
  21 endif( NOT MANPAGE_DIR)
  22
  23 add_custom_target(manpages ALL
  24         COMMAND ${CMAKE_COMMAND} -E make_directory ${MANPAGE_DIR}
  25         COMMAND pod2man ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl > ${MANPAGE_DIR}/simgrid_update_xml.1
  26         COMMENT "Generating manpages"
  27 )
  28 install(FILES ${MANPAGE_DIR}/simgrid_update_xml.1
  29         DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/man/man1)
  30
  31 endif(NOT WIN32)
  32
  33 # binaries
  34 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/smpicc
  35                  ${CMAKE_BINARY_DIR}/bin/smpif2c
  36                  ${CMAKE_BINARY_DIR}/bin/smpiff
  37                  ${CMAKE_BINARY_DIR}/bin/smpirun
  38                 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  39
  40 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  41 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  42
  43 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  44 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  45
  46 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  47         DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  48                 RENAME simgrid-colorizer)
  49
  50 add_custom_target(simgrid-colorizer ALL
  51 COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  52 COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  53 )
  54
  55 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  56                 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  57                 RENAME simgrid_update_xml)
  58
  59 add_custom_target(simgrid_update_xml ALL
  60 COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  61 COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  62 )
  63
  64 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/gras_stub_generator
  65                 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  66
  67 # libraries
  68 install(TARGETS simgrid gras
  69         DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  70
  71 if(enable_smpi)
  72   install(TARGETS smpi
  73           DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  74 endif(enable_smpi)
  75
  76 if(enable_lib_static AND NOT WIN32)
  77         install(TARGETS simgrid_static
  78                 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  79         if(enable_smpi)
  80                 install(TARGETS smpi_static
  81                         DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  82         endif(enable_smpi)
  83 endif(enable_lib_static AND NOT WIN32)
  84
  85 # include files
  86 set(HEADERS
  87     ${headers_to_install}
  88     ${generated_headers_to_install}
  89     )
  90 foreach(file ${HEADERS})
  91   get_filename_component(location ${file} PATH)
  92   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  93   install(FILES ${file}
  94           DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
  95 endforeach(file ${HEADERS})
  96
  97 # example files
  98 foreach(file ${examples_to_install})
  99   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
 100   get_filename_component(location ${file} PATH)
 101   install(FILES "examples/${file}"
 102           DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
 103 endforeach(file ${examples_to_install})
 104
 105 # bindings cruft
 106
 107 if(HAVE_LUA)
 108         file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
 109         add_custom_target(simgrid_lua ALL
 110                 DEPENDS simgrid
 111                                 ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 112                 )
 113         add_custom_command(
 114                 OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 115                 COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 116         )
 117         install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 118                 DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 119                 )
 120 endif(HAVE_LUA)
 121
 122 ###########################################
 123 ### Fill in the "make uninstall" target ###
 124 ###########################################
 125
 126 add_custom_target(uninstall
 127 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 128 COMMAND ${CMAKE_COMMAND} -E     echo "uninstall doc ok"
 129 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/lib/libgras*
 130 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 131 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsmpi*
 132 COMMAND ${CMAKE_COMMAND} -E     echo "uninstall lib ok"
 133 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 134 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif2c
 135 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 136 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 137 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 138 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 139 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 140 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/gras_stub_generator
 141 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 142 COMMAND ${CMAKE_COMMAND} -E     echo "uninstall bin ok"
 143 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/amok
 144 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/gras
 145 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 146 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 147 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 148 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 149 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 150 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 151 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 152 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 153 COMMAND ${CMAKE_COMMAND} -E     remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 154 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 155 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/include/gras.h
 156 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 157 COMMAND ${CMAKE_COMMAND} -E     echo "uninstall include ok"
 158 COMMAND ${CMAKE_COMMAND} -E     remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 159 COMMAND ${CMAKE_COMMAND} -E     echo "uninstall man ok"
 160 WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 161 )
 162
 163 if(HAVE_LUA)
 164         add_custom_command(TARGET uninstall
 165         COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 166         COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 167         WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 168         )
 169 endif(HAVE_LUA)
 170
 171 ################################################################
 172 ## Build a sain "make dist" target to build a source package ###
 173 ##   containing only the files that I explicitely state      ###
 174 ##   (instead of any cruft laying on my disk as CPack does)  ###
 175 ################################################################
 176
 177 # This is the complete list of what will be added to the source archive
 178 set(source_to_pack
 179   ${headers_to_install}
 180   ${source_of_generated_headers}
 181   ${XBT_RL_SRC}
 182   ${EXTRA_DIST}
 183   ${SMPI_SRC}
 184   ${GRAS_RL_SRC}
 185   ${XBT_SRC}
 186   ${GTNETS_SRC}
 187   ${NS3_SRC}
 188   ${SURF_SRC}
 189   ${SIMIX_SRC}
 190   ${TRACING_SRC}
 191   ${MSG_SRC}
 192   ${SIMDAG_SRC}
 193   ${GRAS_COMMON_SRC}
 194   ${GRAS_SG_SRC}
 195   ${AMOK_SRC}
 196   ${LUA_SRC}
 197   ${MC_SRC}
 198   ${JEDULE_SRC}
 199   ${RNGSTREAM_SRC}
 200   ${BINDINGS_FILES}
 201   ${CMAKE_SOURCE_FILES}
 202   ${EXAMPLES_CMAKEFILES_TXT}
 203   ${TESHSUITE_CMAKEFILES_TXT}
 204   ${TOOLS_CMAKEFILES_TXT}
 205   ${TESTSUITE_CMAKEFILES_TXT}
 206   ${DOC_SOURCES}
 207   ${DOC_FIGS}
 208   ${README_files}
 209   ${xml_files}
 210   ${tesh_files}
 211   ${txt_files}
 212   ${bin_files}
 213   ${examples_src}
 214   ${teshsuite_src}
 215   ${tools_src}
 216   ${testsuite_src}
 217   ${PLATFORMS_EXAMPLES}
 218 )
 219
 220 ##########################################
 221 ### Fill in the "make dist-dir" target ###
 222 ##########################################
 223
 224 add_custom_target(dist-dir
 225   COMMENT "Generating the distribution directory"
 226   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 227   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 228   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 229   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 230   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/html/ ${PROJECT_NAME}-${release_version}/doc/html/
 231 )
 232 add_dependencies(dist-dir simgrid_documentation)
 233 add_dependencies(dist-dir maintainer_files)
 234
 235 set(dirs_in_tarball "")
 236 foreach(file ${source_to_pack})
 237   #message(${file})
 238   # This damn prefix is still set somewhere (seems to be in subdirs)
 239   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 240
 241   # Create the directory on need
 242   get_filename_component(file_location ${file} PATH)
 243   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 244   if(NOT OPERATION)
 245     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 246     add_custom_command(
 247       TARGET dist-dir
 248       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 249     )
 250   endif(NOT OPERATION)
 251
 252   # Actually copy the file
 253   add_custom_command(
 254     TARGET dist-dir
 255     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}/
 256   )
 257
 258   add_custom_command(
 259     TARGET dist-dir
 260     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 261   )
 262 endforeach(file ${source_to_pack})
 263
 264 ######################################
 265 ### Fill in the "make dist" target ###
 266 ######################################
 267
 268 add_custom_target(dist
 269   COMMENT "Removing the distribution directory"
 270   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 271   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 272 )
 273
 274 add_custom_command(
 275         OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 276         COMMENT "Compressing the archive from the distribution directory"
 277         COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 278         COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 279         COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 280 )
 281 add_dependencies(dist dist-dir)
 282
 283 if(NOT enable_maintainer_mode)
 284   add_custom_target(echo-dist
 285     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 286     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 287     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 288   )
 289    add_dependencies(dist echo-dist)
 290 endif(NOT enable_maintainer_mode)
 291
 292 ###########################################
 293 ### Fill in the "make distcheck" target ###
 294 ###########################################
 295
 296 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 297
 298 # Allow to test the "make dist"
 299 add_custom_target(distcheck
 300   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 301   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 302
 303   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 304   COMMAND ${CMAKE_COMMAND} -E tar  xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 305
 306   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 307   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 308   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 309
 310   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 311   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 312           ${CMAKE_COMMAND}
 313           -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 314           -Denable_lua=ON
 315           -Denable_model-checking=ON
 316           ..
 317   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 318   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 319
 320   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 321   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest || true
 322
 323   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 324   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 325   COMMAND ${CMAKE_COMMAND} -E create_symlink
 326                             ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 327                             ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 328
 329   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 330   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 331 )
 332 #add_dependencies(distcheck dist)
 333
 334 #######################################
 335 ### Fill in the "make check" target ###
 336 #######################################
 337
 338 if(enable_memcheck)
 339         add_custom_target(check
 340         COMMAND ctest -D ExperimentalMemCheck
 341         )
 342 else(enable_memcheck)
 343         add_custom_target(check
 344         COMMAND make test
 345         )
 346 endif(enable_memcheck)
 347
 348 #######################################
 349 ### Fill in the "make xxx-clean" target ###
 350 #######################################
 351
 352 add_custom_target(maintainer-clean
 353 COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 354 COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 355 COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 356 COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 357 COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 358 COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 359 COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 360 COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 361 COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 362 COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 363 COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 364 COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 365 WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 366 )
 367
 368 add_custom_target(supernovae-clean
 369 COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_gras.c
 370 COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_sg.c
 371 COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_smpi.c
 372 WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 373 )
 374
 375 #############################################
 376 ### Fill in the "make sync-gforge" target ###
 377 #############################################
 378
 379 add_custom_target(sync-gforge-doc
 380 COMMAND chmod g+rw -R doc/
 381 COMMAND chmod a+rX -R doc/
 382 COMMAND ssh scm.gforge.inria.fr mkdir /home/groups/simgrid/htdocs/simgrid/${release_version}/ || true
 383 COMMAND rsync --verbose --cvs-exclude --compress --delete --delete-excluded --rsh=ssh --ignore-times --recursive --links --perms --times --omit-dir-times
 384 doc/html/ scm.gforge.inria.fr:/home/groups/simgrid/htdocs/simgrid/${release_version}/doc/ || true
 385 COMMAND scp doc/html/simgrid_modules2.png doc/html/simgrid_modules.png doc/webcruft/simgrid_logo_2011.png  doc/webcruft/simgrid_logo_small.png scm.gforge.inria.fr:/home/groups/simgrid/htdocs/simgrid/${release_version}/
 386 WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 387 )
 388 add_dependencies(sync-gforge-doc simgrid_documentation)
 389
 390 add_custom_target(sync-gforge-dtd
 391 COMMAND scp src/surf/simgrid.dtd scm.gforge.inria.fr:/home/groups/simgrid/htdocs/simgrid/${release_version}/simgrid.dtd
 392 COMMAND scp src/surf/simgrid.dtd scm.gforge.inria.fr:/home/groups/simgrid/htdocs/simgrid.dtd
 393 WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 394 )
 395
 396 #PIPOL
 397 add_custom_target(sync-pipol
 398 COMMAND scp -r Experimental_bindings.sh Experimental.sh  MemCheck.sh pre-simgrid.sh navarro@pipol.inria.fr:~/
 399 COMMAND scp -r rc.* navarro@pipol.inria.fr:~/.pipol/
 400 COMMAND scp -r Nightly* navarro@pipol.inria.fr:~/.pipol/nightly
 401 COMMAND ssh navarro@pipol.inria.fr "chmod a=rwx ~/* ~/.pipol/rc.* ~/.pipol/nightly/*"
 402 WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/buildtools/pipol/"
 403 )
 404
 405 include(CPack)