Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Add a compilation mode suited to build daemons. It's ways more permissive than regula...
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15 AM_PROG_GCJ
16
17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
18 AC_CONFIG_MACRO_DIR(acmacro) 
19 ACLOCAL="$ACLOCAL -I acmacro"
20
21 dnl Next few lines is a hack to prevent libtool checking for F77
22 m4_undefine([AC_PROG_F77])
23 m4_defun([AC_PROG_F77],[])
24
25 dnl We do build a proper DLL when using win32
26 AC_LIBTOOL_WIN32_DLL
27 AC_PROG_LIBTOOL
28
29 ###############
30 ## System checks
31 ##
32 SG_CONFIGURE_PART([System checks...])
33 AC_PROG_CC(xlC gcc cc)
34 AM_SANITY_CHECK
35 AC_PROG_MAKE_SET
36 AC_CHECK_PRINTF_NULL
37 AC_CHECK_VA_COPY
38
39 # Checks for header files.
40 AC_HEADER_STDC
41 AC_HEADER_TIME
42 AC_CHECK_HEADERS([sys/socket.h \
43                   sys/stat.h \
44                   windows.h winsock.h winsock2.h \
45                   sys/time.h \
46                   errno.h unistd.h \
47                   execinfo.h\
48                   signal.h ])
49 AC_CHECK_FUNCS([gettimeofday usleep \
50                 getdtablesize \
51                 sysconf\
52                 readv\
53                 popen\
54                 signal\
55                 getline])
56                 
57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
58 AC_FUNC_SNPRINTF
59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
62
63 # Checks for typedefs, structures, and compiler characteristics.
64 AC_C_CONST
65 AC_C_INLINE
66 AC_TYPE_SIZE_T
67
68 ###################################
69 ## SimGrid and GRAS specific checks
70 ##
71
72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
73 # Check architecture signature begin
74 GRAS_ARCH
75 # Check architecture signature end
76 GRAS_CHECK_STRUCT_COMPACTION
77
78
79 dnl ##
80 dnl ##  CONTEXT IMPLEMENTATION
81 dnl ##
82
83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
84
85 dnl #
86 dnl #  1. determine possibilities
87 dnl #
88
89 dnl #  check for MCSC method
90 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
91
92 dnl #  check for pthread method
93 AC_CHECK_HEADERS([pthread.h])
94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
95
96 dnl #
97 dnl #  2. make a general decision
98 dnl #
99
100 if test ".$mcsc" = .yes; then
101    mcsc=yes
102 elif test ".$pthread" = .yes; then
103    pthread=yes
104 else
105     ac_header=windows.h
106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
108       windows_context=yes
109     else
110       AC_ERROR([no appropriate backend found])
111     fi
112 fi
113 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
114
115
116 dnl #
117 dnl #  3. allow decision to be overridden by user
118 dnl #
119
120 AC_MSG_CHECKING(what kind of backend should we use)
121
122 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
123 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
124
125 AC_ARG_WITH(context,
126   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
127   with_context=auto)
128
129 if test "x$with_context$mcsc" = "xucontextno" ; then 
130   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
131 fi
132
133 case $with_context in
134  ucontext) ;;
135  pthread) ;;
136  pthreads) ;;
137  windows) ;;
138  auto) with_context=ucontext;;
139  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
140 esac
141
142 if test "x$with_context" = "xucontext" ; then
143   if test ".$mcsc" = .yes; then
144     AC_MSG_RESULT(found working ucontext. Great!)
145     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
146   else
147     if test ".$windows_context" = .yes ; then
148       AC_MSG_RESULT(use windows context portability layer.)
149       with_context=windows
150     else
151       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
152       with_context=pthread
153     fi
154   fi
155 fi
156
157 if test "x$with_context" = "xpthreads"; then
158   with_context=pthread
159 fi
160 if test "x$with_context" = "xpthread"; then
161   AC_CHECK_HEADERS([pthread.h])
162   AC_CHECK_LIB(pthread,pthread_create,,
163     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
164   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
165   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
166 fi
167 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
168
169 dnl #
170 dnl #  4. determine a few additional details
171 dnl #
172
173 if test "x$with_context" = "xucontext" ; then
174 dnl #  direction of stack grow
175   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
176   if test ".$ac_cv_check_stackgrowth" = ".down"; then
177       PTH_STACK_GROWTH="down"
178   else
179       PTH_STACK_GROWTH="up"
180   fi
181   AC_SUBST(PTH_STACK_GROWTH)
182   
183   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
184 fi
185
186 #########################################
187 ## Check for libraries extra-dependencies
188 ##
189
190 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
191
192 SIMGRID_DEP=""
193 SMPI_DEP=""
194 GRAS_DEP=""
195
196 if test xpthread=xyes ; then 
197   # if the pthreads are usable
198   if test "x$with_context" = "xpthread" ; then
199     # if we use them to implement the xbt_context
200     SIMGRID_DEP="-lpthread"
201   fi
202   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
203   if test "x$with_context" != "xwindows" ; then
204     GRAS_DEP="-lpthread"
205   fi
206 fi
207
208 #########################################
209 ## Build optional modules (gtnets)
210 ##
211 gtnets=no
212 AC_ARG_WITH(gtnets,
213   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
214   gtnets_path="$withval",gtnets_path="no")
215 if test "x$gtnets_path" = "xno" ; then
216   AC_MSG_RESULT(Eventually you will come to GTNetS.)
217 else  
218   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
219   AC_MSG_CHECKING(for gtnets)
220   AC_LANG_PUSH([C++])  
221   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
222   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
223   LDFLAGS_SAV=$LDFLAGS  
224   CPPFLAGS_SAV=$CPPFLAGS
225   CPPFLAGS+=$GTNETS_CPPFLAGS
226   LDFLAGS+=$GTNETS_LDFLAGS
227   AC_TRY_LINK([ #include <simulator.h>
228               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
229   CPPFLAGS=$CPPFLAGS_SAV
230   LDFLAGS=$LDFLAGS_SAV
231   AC_LANG_POP([C++])  
232
233   if test "x$gtnets" = xyes ; then 
234     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
235     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
236     AC_MSG_RESULT(Found working gtnets library.)
237     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
238   else
239     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
240   fi
241 fi
242 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
243
244 #########################################
245 ## Build optional modules (csdp)
246 ##
247 csdp=no
248 AC_ARG_WITH(csdp,
249   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
250   csdp_path="$withval",csdp_path="no")
251 if test "x$csdp_path" = "xno" ; then
252   AC_MSG_RESULT(Eventually you will come to csdp.)
253 else  
254   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
255   AC_MSG_CHECKING(for csdp)
256   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
257   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
258
259   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
260   
261   CPPFLAGS_SAV=$CPPFLAGS
262   CPPFLAGS+=$CSDP_CPPFLAGS
263   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
264   CPPFLAGS=$CPPFLAGS_SAV
265
266   
267
268   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
269      csdp=yes;
270   else 
271      csdp=no;
272   fi
273   if test "x$csdp" = xyes; then 
274     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
275     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
276     AC_MSG_RESULT(Found working sdp library.)
277     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
278   else
279     AC_MSG_RESULT(Could not find any working sdp library.)
280   fi;
281 fi
282 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
283
284 AC_SUBST([SIMGRID_DEP])
285 AC_SUBST([SMPI_DEP])
286
287 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
288 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
289
290 AC_MSG_CHECKING(for extra dependencies of libgras)
291 case $host_os in
292   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
293             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
294             AC_DEFINE(CONTEXT_THREADS,1);;
295 esac
296
297
298
299 if test "x$GRAS_DEP" = x; then 
300    AC_MSG_RESULT(none)
301 else
302    AC_MSG_RESULT($GRAS_DEP)
303 fi
304 AC_SUBST([GRAS_DEP])
305
306 ##############################################
307 ## Enhance maintainer mode and SUBST variables
308 ## (must be placed after any compilation tests since our overprotective flags
309 ##  let some tests fail)
310
311 # Check whether we are doing a regular build or a GRAMINE (minimal) one
312 # Next line is modified by sed when building gramine source tree
313 gramine_mode=no
314 if test x$gramine_mode = xyes
315 then
316   USE_MAINTAINER_MODE=no
317 fi
318 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
319
320
321 AM_MAINTAINER_MODE
322 if test x$USE_MAINTAINER_MODE = xyes 
323 then
324    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
325    enable_compile_warnings=yes   
326 fi
327 SG_COMPILE_FLAGS
328
329 AC_SUBST([CFLAGS])
330 AC_SUBST([CPPFLAGS])
331 AC_SUBST([LDFLAGS])
332 AC_SUBST([AM_CPPFLAGS])
333 AC_SUBST([abs_builddir])
334 AC_SUBST([abs_srcdir])
335 AC_SUBST([abs_top_builddir])
336 AC_SUBST([abs_top_srcdir])
337
338 ##############################################
339 ## Specific mode for build daemons.
340 ## (they compile the SVN without having the autotools installed)
341 AC_ARG_ENABLE(botbuild,
342               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
343               botbuild=$enableval,botbuild=no)
344 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
345
346 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != yes ; then
347   echo "ERROR:"
348   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
349   echo "ERROR: For this, just call configure this way:"
350   echo "ERROR:"
351   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
352   echo "ERROR:"
353   exit 1
354 fi
355
356
357 SG_CONFIGURE_PART(Check for Java bindings...)
358 # Java cruft
359 AC_ARG_ENABLE(java,
360               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
361               want_java=$enableval,want_java=yes)
362 if test "x$want_java" != "xyes" ; then
363    AC_MSG_CHECKING(whether to compile java bindings)
364    AC_MSG_RESULT(disabled by user)
365    use_java="disabled by user"
366 else
367   AC_PATH_PROG([JAVAC], [javac], `which javac`)
368   AC_PATH_PROG([JAVA],  [java] , `which java`)
369   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
370   AC_CHECK_HEADERS(jni.h)
371   AC_MSG_CHECKING(whether to compile java bindings)
372   if test -n "$JAVAC"   \
373      && test -n "$JAVA" \
374      && test -n "$JAR"  \
375      && test "x$ac_cv_header_jni_h" = "xyes" ; then
376    
377      use_java="yes"
378   else   
379      use_java="no"
380   fi
381   AC_MSG_RESULT($use_java)
382 fi
383 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
384
385 #####################
386 ## Check for programs
387 ##
388
389 SG_CONFIGURE_PART(Check for programs...)
390 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
391 WARNING="This file is generated, do not edit"
392 AC_SUBST(WARNING)
393
394
395 # Can we rebuild the parsers?
396 # We really want flex and refuse other lex. So, the parser is portable and
397 # does not induce extra lib dependency
398 AC_PROG_FLEX(2.5.30)
399                 
400 # Can we rebuild the xml-lexers from the XML specification?
401 # if not, simply touch the flex source files (which are distributed in
402 #  tarballs even if generated by flexml) and hope for the best.
403 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
404 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
405
406 if test x$USE_MAINTAINER_MODE = xyes 
407 then
408    # Check for doxygen when in maintainer mode since dist* targets fail
409    # without it
410    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
411    if test x$DOXYGEN = x ; then 
412      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
413    fi
414 fi
415
416 # Can we extract really usable backtraces? (also need the popen function)
417 AC_PATH_PROG(ADDR2LINE, addr2line)
418 if test x$ADDR2LINE != x ; then
419   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
420 fi
421
422 AC_SUBST(ac_configure_args)
423 # Can we make status line about the compilation result?
424 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
425 if test x$MD5SUM != xno ; then
426   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
427                  xargs cat| $MD5SUM | sed 's/ .*$//'`
428 else 
429   build_version="no_md5sum_binary"
430 fi
431 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
432 AC_SUBST(build_id)
433
434 ###################
435 ## Makes the output
436 ##
437
438
439 #
440 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
441 #  src/amok/Makefile
442
443 SG_CONFIGURE_PART(Generating files...)
444
445 # Core of the libraries
446
447 AC_CONFIG_FILES([
448   Makefile
449   include/Makefile
450   src/Makefile
451   src/ucontext_stack.h
452 ])
453
454 # Tools being embeeded in gramine (stub generator)
455 AC_CONFIG_FILES([
456   tools/Makefile
457     tools/gras/Makefile
458     tools/tesh/Makefile
459 ])
460
461
462 # GRAMINE_CUT_BEGIN
463
464 # Tools NOT being embeeded in gramine
465 AC_CONFIG_FILES([
466   tools/graspe-slave
467 ],[
468     for file in                                                 \
469      tools/graspe-slave           tools/graspe-master           \
470     ; do                                                        \
471       test -e $file && chmod +x $file;                          \
472     done
473 ])
474
475 # Testsuite
476
477 AC_CONFIG_FILES([  
478   testsuite/Makefile
479   testsuite/run_tests    
480 ],[
481     for file in                                                 \
482      testsuite/run_tests                                        \
483     ; do                                                        \
484       test -e $file && chmod +x $file;                          \
485     done
486 ])
487
488 # Teshsuite (testsuite using tesh)
489 AC_CONFIG_FILES([  
490   teshsuite/Makefile
491 ])
492
493 # Documentation
494 AC_CONFIG_FILES([
495   doc/Makefile
496   doc/Doxyfile
497 ])
498
499 # Examples
500
501 #      examples/gras/p2p/Makefile
502 #      examples/gras/p2p/chord/Makefile
503 #      examples/gras/p2p/can/Makefile
504
505 if test "x$use_java" = "xyes" ; then
506 AC_CONFIG_FILES([
507     examples/java/Makefile
508       examples/java/basic/Makefile
509       examples/java/comm_time/Makefile
510       examples/java/suspend/Makefile
511       examples/java/ping_pong/Makefile
512 ])
513 fi
514
515 AC_CONFIG_FILES([
516   examples/Makefile 
517     examples/msg/Makefile
518     examples/simdag/Makefile
519     examples/gras/Makefile
520       examples/gras/ping/Makefile   
521       examples/gras/rpc/Makefile
522       examples/gras/spawn/Makefile
523       examples/gras/synchro/Makefile
524       examples/gras/timer/Makefile
525       examples/gras/chrono/Makefile
526       examples/gras/mutual_exclusion/simple_token/Makefile
527       examples/gras/mmrpc/Makefile
528       examples/gras/pmm/Makefile
529       examples/gras/all2all/Makefile
530     examples/amok/Makefile       
531       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
532       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
533 ],[
534     for file in                                                 \
535      \
536      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
537      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
538     ; do                                                        \
539       test -e $file && chmod +x $file;                          \
540     done
541 ])
542
543 AC_CONFIG_FILES([
544   src/smpi/smpicc
545   src/smpi/smpirun
546 ])
547
548 # GRAMINE_CUT_END
549
550 AC_OUTPUT
551
552 echo "
553
554 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
555
556         Compiler:        ${CC} (version: ${GCC_VERSION})
557         
558         CFlags:          ${CFLAGS}
559         CPPFlags:        ${CPPFLAGS}
560         LDFlags:         ${LDFLAGS}
561
562         Context backend: ${with_context}
563 "
564 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = yes ; then
565   echo "WARNING:"
566   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
567   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
568   echo "WARNING:"
569   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
570   echo "WARNING:"
571 fi
572
573 echo $build_id > stamp.configure
574
575 exit 0;