Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
2acc34ce7bff3ef4638e2dca9bf6d736e91af8e7
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15
16 AM_INIT_AUTOMAKE(gnu)
17 AC_CONFIG_MACRO_DIR(acmacro) 
18 ACLOCAL="$ACLOCAL -I acmacro"
19 AC_LIBTOOL_WIN32_DLL
20 AC_PROG_LIBTOOL
21
22 ###############
23 ## System checks
24 ##
25 SG_CONFIGURE_PART(System checks...)
26 AC_PROG_CC(xlC gcc cc)
27 AM_SANITY_CHECK
28 AC_PROG_MAKE_SET
29 AC_CHECK_PRINTF_NULL
30 AC_CHECK_VA_COPY
31
32 # Checks for header files.
33 AC_HEADER_STDC
34 AC_HEADER_TIME
35 AC_CHECK_HEADERS([sys/socket.h \
36                   sys/stat.h \
37                   windows.h winsock.h winsock2.h \
38                   sys/time.h \
39                   errno.h unistd.h \
40                   execinfo.h\
41                   signal.h ])
42 AC_CHECK_FUNCS([gettimeofday usleep \
43                 getdtablesize \
44                 sysconf\
45                 readv\
46                 popen\
47                 signal\
48                 getline])
49                 
50 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
51 AC_FUNC_SNPRINTF
52 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
53 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
54 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
55
56 # Checks for typedefs, structures, and compiler characteristics.
57 AC_C_CONST
58 AC_C_INLINE
59 AC_TYPE_SIZE_T
60
61 ###################################
62 ## SimGrid and GRAS specific checks
63 ##
64
65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
66 # Check architecture signature begin
67 GRAS_ARCH
68 # Check architecture signature end
69 GRAS_CHECK_STRUCT_COMPACTION
70
71
72 dnl ##
73 dnl ##  CONTEXT IMPLEMENTATION
74 dnl ##
75
76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
77
78 dnl #
79 dnl #  1. determine possibilities
80 dnl #
81
82 dnl #  check for MCSC method
83 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
84
85 dnl #  check for pthread method
86 AC_CHECK_HEADERS([pthread.h])
87 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
88
89 dnl #
90 dnl #  2. make a general decision
91 dnl #
92
93 if test ".$mcsc" = .yes; then
94    mcsc=yes
95 elif test ".$pthread" = .yes; then
96    pthread=yes
97 else
98     ac_header=windows.h
99     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
100     if test `eval echo '${'$as_ac_Header'}'` = yes; then
101       windows_context=yes
102     else
103       AC_ERROR([no appropriate backend found])
104     fi
105 fi
106
107 dnl #
108 dnl #  3. allow decision to be overridden by user
109 dnl #
110
111 AC_MSG_CHECKING(what kind of backend should we use)
112
113 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
114 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
115
116 AC_ARG_WITH(context,
117   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
118   with_context=auto)
119
120 if test "x$with_context$mcsc" = "xucontextno" ; then 
121   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
122 fi
123
124 case $with_context in
125  ucontext) ;;
126  pthread) ;;
127  pthreads) ;;
128  windows) ;;
129  auto) with_context=ucontext;;
130  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
131 esac
132
133 if test "x$with_context" = "xucontext" ; then
134   if test ".$mcsc" = .yes; then
135     AC_MSG_RESULT(found working ucontext. Great!)
136     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
137   else
138     if test ".$windows_context" = .yes ; then
139       AC_MSG_RESULT(use windows context portability layer.)
140       with_context=windows
141     else
142       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
143       with_context=pthread
144     fi
145   fi
146 fi
147
148 if test "x$with_context" = "xpthreads"; then
149   with_context=pthread
150 fi
151 if test "x$with_context" = "xpthread"; then
152   AC_CHECK_HEADERS([pthread.h])
153   AC_CHECK_LIB(pthread,pthread_create,,
154     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
155   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
156   AC_MSG_RESULT(You have pthreads. Let's use them.)
157 fi
158
159 dnl #
160 dnl #  4. determine a few additional details
161 dnl #
162
163 if test "x$with_context" = "xucontext" ; then
164 dnl #  direction of stack grow
165   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
166   if test ".$ac_cv_check_stackgrowth" = ".down"; then
167       PTH_STACK_GROWTH="down"
168   else
169       PTH_STACK_GROWTH="up"
170   fi
171   AC_SUBST(PTH_STACK_GROWTH)
172   
173   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
174 fi
175
176
177 #########################################
178 ## Build optional modules (simix)
179 ##
180 SG_CONFIGURE_PART(Optional modules)
181 AC_ARG_ENABLE(simix,
182   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
183   enable_simix=$enableval,enable_simix=no)
184 if test "x$enable_simix" = "xyes" ; then
185   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
186   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
187 else 
188   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
189 fi
190 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
191
192 #########################################
193 ## Build optional modules (gtnets)
194 ##
195 SG_CONFIGURE_PART(Optional modules)
196 AC_ARG_ENABLE(gtnets,
197   AS_HELP_STRING([--enable-gtnets], [Use the new GTNetS module (default=no)]),
198   enable_gtnets=$enableval,enable_gtnets=no)
199 if test "x$enable_gtnets" = "xyes" ; then
200   AC_MSG_RESULT("***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****")
201   AC_DEFINE(USE_GTNETS, 1, [Indicates whether we should use GTNetS or not])
202 else 
203   AC_MSG_RESULT(Eventually you will come to GTNetS: x$enable_gtnets)
204 fi
205 AM_CONDITIONAL(USE_GTNETS,test x$enable_gtnets != xno)
206
207 #########################################
208 ## Check for libraries extra-dependencies
209 ##
210
211 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
212
213 SIMGRID_DEP=""
214 GRAS_DEP=""
215 if test xpthread=xyes ; then 
216   # if the pthreads are usable
217   if test "x$with_context" = "xpthread" ; then
218     # if we use them to implement the xbt_context
219     SIMGRID_DEP="-lpthread"
220   fi
221   # we need them in any case for the gras lib (which is multithreaded)
222   GRAS_DEP="-lpthread"
223 fi
224
225 AC_MSG_CHECKING(for csdp)
226 sdp=no
227 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
228 if test "x$csdp" = xyes; then 
229   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
230   AC_MSG_RESULT(Found working sdp library.)
231   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
232 else
233   AC_MSG_RESULT(Could not find any working sdp library.)
234 fi;
235 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
236
237 AC_SUBST([SIMGRID_DEP])
238
239 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
240 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
241
242 AC_MSG_CHECKING(for extra dependencies of libgras)
243 case $host_os in
244   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
245             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
246             AC_DEFINE(CONTEXT_THREADS,1);;
247 esac
248            
249 if test "x$GRAS_DEP" = x; then 
250    AC_MSG_RESULT(none)
251 else
252    AC_MSG_RESULT($GRAS_DEP)
253 fi
254 AC_SUBST([GRAS_DEP])
255
256
257 ##############################################
258 ## Enhance maintainer mode and SUBST variables
259 ## (must be placed after any compilation tests since our overprotective flags
260 ##  let some tests fail)
261
262 # Check whether we are doing a regular build or a GRAMINE (minimal) one
263 # Next line is modified by sed when building gramine source tree
264 gramine_mode=no
265 if test x$gramine_mode = xyes
266 then
267   USE_MAINTAINER_MODE=no
268 fi
269 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
270
271
272 AM_MAINTAINER_MODE
273 if test x$USE_MAINTAINER_MODE = xyes 
274 then
275    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
276    enable_compile_warnings=yes   
277 fi
278 SG_COMPILE_FLAGS
279
280 AC_SUBST(CFLAGS)
281 AC_SUBST(CPPFLAGS)
282 AC_SUBST(LDFLAGS)
283 AC_SUBST([abs_builddir])
284 AC_SUBST([abs_srcdir])
285 AC_SUBST([abs_top_builddir])
286 AC_SUBST([abs_top_srcdir])
287
288 #####################
289 ## Check for programs
290 ##
291
292 SG_CONFIGURE_PART(Check for programs...)
293 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
294 WARNING="This file is generated, do not edit"
295 AC_SUBST(WARNING)
296
297
298 # Can we rebuild the parsers?
299 # We really want flex and refuse other lex. So, the parser is portable and
300 # does not induce extra lib dependency
301 AC_PROG_FLEX(2.5.30)
302                 
303 # Can we rebuild the xml-lexers from the XML specification?
304 # if not, simply touch the flex source files (which are distributed in
305 #  tarballs even if generated by flexml) and hope for the best.
306 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
307 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
308
309 if test x$USE_MAINTAINER_MODE = xyes 
310 then
311    # Check for doxygen when in maintainer mode since dist* targets fail
312    # without it
313    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
314    if test x$DOXYGEN = x ; then 
315      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
316    fi
317 fi
318
319 # Can we extract really usable backtraces? (also need the popen function)
320 AC_PATH_PROG(ADDR2LINE, addr2line)
321 if test x$ADDR2LINE != x ; then
322   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
323 fi
324
325 AC_SUBST(ac_configure_args)
326 # Can we make status line about the compilation result?
327 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
328 if test x$MD5SUM != xno ; then
329   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
330                  xargs cat| $MD5SUM | sed 's/ .*$//'`
331 else 
332   build_version="no_md5sum_binary"
333 fi
334 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
335 AC_SUBST(build_id)
336
337 ###################
338 ## Makes the output
339 ##
340
341
342 #
343 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
344 #  src/amok/Makefile
345
346 SG_CONFIGURE_PART(Generating files...)
347
348 # Core of the libraries
349
350 AC_CONFIG_FILES([
351   Makefile
352   include/Makefile
353   src/Makefile
354   src/ucontext_stack.h
355 ])
356
357 # Tools being embeeded in gramine (stub generator)
358 AC_CONFIG_FILES([
359   tools/Makefile
360     tools/gras/Makefile
361     tools/tesh/Makefile
362 ])
363
364
365 # GRAMINE_CUT_BEGIN
366
367 # Tools NOT being embeeded in gramine
368 AC_CONFIG_FILES([
369   tools/graspe-slave
370 ],[
371     for file in                                                 \
372      tools/graspe-slave           tools/graspe-master           \
373     ; do                                                        \
374       test -e $file && chmod +x $file;                          \
375     done
376 ])
377
378 # Testsuite
379
380 AC_CONFIG_FILES([  
381   testsuite/Makefile
382   testsuite/run_tests    
383   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
384 ],[
385     for file in                                                 \
386      testsuite/run_tests                                        \
387      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
388     ; do                                                        \
389       test -e $file && chmod +x $file;                          \
390     done
391 ])
392
393 # Documentation
394 AC_CONFIG_FILES([
395   doc/Makefile
396   doc/Doxyfile
397 ])
398
399 # Examples
400
401 AC_CONFIG_FILES([
402   examples/Makefile 
403     examples/msg/Makefile
404     examples/simdag/Makefile        examples/simdag/test_simdag
405     examples/gras/Makefile 
406       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
407       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
408       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
409       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
410       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
411       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
412       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
413       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
414
415       examples/gras/p2p/Makefile
416       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
417       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
418       
419     examples/amok/Makefile       
420       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
421       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
422 ],[
423     for file in                                                 \
424      \
425      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
426      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
427      \
428      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
429      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
430      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
431      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
432      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
433      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
434      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
435      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
436      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
437      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
438      examples/msg/run_msg_test                                  \
439      examples/simdag/test_simdag                                \
440     ; do                                                        \
441       test -e $file && chmod +x $file;                          \
442     done
443 ])
444
445 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
446 #    examples/gras/pastry/test_sg   
447
448
449
450 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
451 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
452
453
454 # GRAMINE_CUT_END
455
456 AC_OUTPUT
457
458 echo "
459
460 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
461
462         Compiler:        ${CC} (version: ${GCC_VERSION})
463         
464         CFlags:          ${CFLAGS}
465         CPPFlags:        ${CPPFLAGS}
466         LDFlags:         ${LDFLAGS}
467
468         Context backend: ${with_context}
469 "
470
471 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
472   echo "WARNING:"
473   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
474   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
475   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
476   echo "WARNING:"
477   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
478   echo "WARNING:"
479 fi
480 echo $build_id > stamp.configure
481
482 exit 0;