configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal])
  48
  49 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  50 AC_FUNC_SNPRINTF
  51 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  52 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  53 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  54 # we don't use those:
  55 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
  56 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
  57
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_CONST
  61 AC_C_INLINE
  62 AC_TYPE_SIZE_T
  63
  64 ###################################
  65 ## SimGrid and GRAS specific checks
  66 ##
  67
  68 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  69 # Check architecture signature begin
  70 GRAS_ARCH
  71 # Check architecture signature end
  72 GRAS_CHECK_STRUCT_COMPACTION
  73
  74
  75 dnl ##
  76 dnl ##  CONTEXT IMPLEMENTATION
  77 dnl ##
  78
  79 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  80
  81 dnl #
  82 dnl #  1. determine possibilities
  83 dnl #
  84
  85 dnl #  check for MCSC method
  86 AC_MSG_CHECKING(on top of what can we build the contexts)
  87 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
  88 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
  89 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  90
  91 dnl #  check for pthread method
  92 AC_CHECK_HEADERS([pthread.h])
  93 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  94
  95 dnl #
  96 dnl #  2. make a general decision
  97 dnl #
  98
  99 if test ".$mcsc" = .yes; then
 100    mcsc=yes
 101 elif test ".$pthread" = .yes; then
 102    pthread=yes
 103 else
 104     ac_header=windows.h
 105     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 106     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 107       windows_context=yes
 108     else
 109       AC_ERROR([no appropriate backend found])
 110     fi
 111 fi
 112
 113 dnl #
 114 dnl #  3. allow decision to be overridden by user
 115 dnl #
 116
 117 AC_MSG_CHECKING(what kind of backend should we use)
 118
 119 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 120
 121 AC_ARG_WITH(context,
 122   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 123   with_context=auto)
 124 case $with_context in
 125  ucontext) ;;
 126  pthread) ;;
 127  windows) ;;
 128  auto) with_context=ucontext;;
 129  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
 130 esac
 131
 132 if test "x$with_context" = "xucontext" ; then
 133   if test ".$mcsc" = .yes; then
 134     AC_MSG_RESULT(found working ucontext. Great!)
 135     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 136   else
 137     if test ".$windows_context" = .yes ; then
 138       AC_MSG_RESULT(use windows context portability layer.)
 139       with_context=windows
 140     else
 141       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 142       with_context=pthread
 143     fi
 144   fi
 145 fi
 146
 147 if test "x$with_context" = "xpthread"; then
 148   AC_CHECK_HEADERS([pthread.h])
 149   AC_CHECK_LIB(pthread,pthread_create,,
 150     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
 151   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 152   AC_MSG_RESULT(You have pthreads. Let's use them.)
 153 fi
 154
 155 dnl #
 156 dnl #  4. determine a few additional details
 157 dnl #
 158
 159 if test "x$with_context" = "xucontext" ; then
 160 dnl #  direction of stack grow
 161   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 162   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 163       PTH_STACK_GROWTH="down"
 164   else
 165       PTH_STACK_GROWTH="up"
 166   fi
 167   AC_SUBST(PTH_STACK_GROWTH)
 168
 169   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 170 fi
 171
 172 #########################################
 173 ## Check for libraries extra-dependencies
 174 ##
 175
 176 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 177 SIMGRID_DEP=""
 178 AC_SUBST([SIMGRID_DEP])
 179
 180 GRAS_DEP=""
 181 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 182 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 183
 184 AC_MSG_CHECKING(for extra dependencies of libgras)
 185 case $host_os in
 186   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
 187 esac
 188
 189 if test "x$GRAS_DEP" = x; then
 190    AC_MSG_RESULT(none)
 191 else
 192    AC_MSG_RESULT($GRAS_DEP)
 193 fi
 194 AC_SUBST([GRAS_DEP])
 195
 196 ##############################################
 197 ## Enhance maintainer mode and SUBST variables
 198 ## (must be placed after any compilation tests since our overprotective flags
 199 ##  let some tests fail)
 200
 201 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 202 # Next line is modified by sed when building gramine source tree
 203 gramine_mode=no
 204 if test x$gramine_mode = xyes
 205 then
 206   USE_MAINTAINER_MODE=no
 207 fi
 208 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 209
 210
 211 AM_MAINTAINER_MODE
 212 if test x$USE_MAINTAINER_MODE = xyes
 213 then
 214    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 215    enable_compile_warnings=yes
 216 fi
 217 SG_COMPILE_FLAGS
 218
 219 AC_SUBST(CFLAGS)
 220 AC_SUBST(CPPFLAGS)
 221 AC_SUBST(LDFLAGS)
 222 AC_SUBST([abs_builddir])
 223 AC_SUBST([abs_srcdir])
 224 AC_SUBST([abs_top_builddir])
 225 AC_SUBST([abs_top_srcdir])
 226
 227 #####################
 228 ## Check for programs
 229 ##
 230
 231 SG_CONFIGURE_PART(Check for programs...)
 232 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 233 WARNING="This file is generated, do not edit"
 234 AC_SUBST(WARNING)
 235
 236
 237 # Can we rebuild the parsers?
 238 # We really want flex and refuse other lex. So, the parser is portable and
 239 # does not induce extra lib dependency
 240 AC_PROG_FLEX(2.5.30)
 241
 242 # Can we rebuild the xml-lexers from the XML specification?
 243 # if not, simply touch the flex source files (which are distributed in
 244 #  tarballs even if generated by flexml) and hope for the best.
 245 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 246 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 247
 248 if test x$USE_MAINTAINER_MODE = xyes
 249 then
 250    # Check for doxygen when in maintainer mode since dist* targets fail
 251    # without it
 252    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 253    if test x$DOXYGEN = x ; then
 254      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 255    fi
 256 fi
 257
 258 # Can we extract really usable backtraces? (also need the popen function)
 259 AC_PATH_PROG(ADDR2LINE, addr2line)
 260 if test x$ADDR2LINE != x ; then
 261   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 262 fi
 263
 264 AC_SUBST(ac_configure_args)
 265 # Can we make status line about the compilation result?
 266 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 267 if test x$MD5SUM != xno ; then
 268   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 269                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 270 else
 271   build_version="no_md5sum_binary"
 272 fi
 273 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 274 AC_SUBST(build_id)
 275
 276 ###################
 277 ## Makes the output
 278 ##
 279
 280
 281 #
 282 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 283 #  src/amok/Makefile
 284
 285 SG_CONFIGURE_PART(Generating files...)
 286
 287 # Core of the libraries
 288
 289 AC_CONFIG_FILES([
 290   Makefile
 291   include/Makefile
 292   src/Makefile
 293   src/ucontext_stack.h
 294 ])
 295
 296 # Tools being embeeded in gramine (stub generator)
 297 AC_CONFIG_FILES([
 298   tools/Makefile
 299     tools/gras/Makefile
 300 ])
 301
 302 # GRAMINE_CUT_BEGIN
 303
 304 # Tools NOT being embeeded in gramine
 305 AC_CONFIG_FILES([
 306   tools/graspe-slave
 307 ],[
 308     for file in                                                 \
 309      tools/graspe-slave           tools/graspe-master           \
 310     ; do                                                        \
 311       test -e $file && chmod +x $file;                          \
 312     done
 313 ])
 314
 315 # Testsuite
 316
 317 AC_CONFIG_FILES([
 318   testsuite/Makefile
 319   testsuite/run_tests
 320   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 321 ],[
 322     for file in                                                 \
 323      testsuite/run_tests                                        \
 324      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 325     ; do                                                        \
 326       test -e $file && chmod +x $file;                          \
 327     done
 328 ])
 329
 330 # Documentation
 331 AC_CONFIG_FILES([
 332   doc/Makefile
 333   doc/Doxyfile
 334 ])
 335
 336 # Examples
 337
 338 AC_CONFIG_FILES([
 339   examples/Makefile
 340     examples/msg/Makefile           examples/msg/run_msg_test
 341     examples/simdag/Makefile        examples/simdag/test_simdag
 342     examples/gras/Makefile
 343       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 344       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 345       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 346       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 347       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 348       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 349       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 350       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 351
 352       examples/gras/p2p/Makefile
 353       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 354       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 355
 356     examples/amok/Makefile
 357       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 358       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 359 ],[
 360     for file in                                                 \
 361      \
 362      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 363      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 364      \
 365      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 366      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 367      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 368      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 369      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 370      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 371      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 372      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 373      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 374      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 375      examples/msg/run_msg_test                                  \
 376      examples/simdag/test_simdag                                \
 377     ; do                                                        \
 378       test -e $file && chmod +x $file;                          \
 379     done
 380 ])
 381
 382 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 383 #    examples/gras/pastry/test_sg
 384
 385
 386
 387 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 388 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 389
 390
 391 # GRAMINE_CUT_END
 392
 393 AC_OUTPUT
 394
 395 echo "
 396
 397 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 398
 399         Compiler:        ${CC} (version: ${GCC_VERSION})
 400
 401         CFlags:          ${CFLAGS}
 402         CPPFlags:        ${CPPFLAGS}
 403         LDFlags:         ${LDFLAGS}
 404
 405         Context backend: ${with_context}
 406 "
 407
 408 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 409   echo "WARNING:"
 410   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 411   echo "WARNING: This is not really supported, so you should configure SimGrid like:"
 412   echo "WARNING:"
 413   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 414   echo "WARNING:"
 415 fi
 416 echo $build_id > stamp.configure
 417
 418 exit 0;