tools/cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3 # On Mac OSX, specify that rpath is useful to look for the dependencies
   4 # See https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling and Java.cmake
   5 set(CMAKE_MACOSX_RPATH TRUE)
   6 if(APPLE)
   7   SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE) # When installed, use system path
   8   set(CMAKE_SKIP_BUILD_RPATH FALSE)         # When executing from build tree, take the lib from the build path if exists
   9   set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE) # When executing from build tree, take the lib from the system path if exists
  10
  11   # add the current location of libsimgrid-java.dynlib as a location for libsimgrid.dynlib
  12   # (useful when unpacking the native libraries from the jarfile)
  13   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  14 endif()
  15
  16 ###############################
  17 # Declare the library content #
  18 ###############################
  19
  20 # Actually declare our libraries
  21 add_library(simgrid SHARED ${simgrid_sources})
  22 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  23 # The library can obviously use the internal headers
  24 set_property(TARGET simgrid
  25              APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
  26
  27 add_dependencies(simgrid maintainer_files)
  28
  29 if(enable_model-checking)
  30   add_executable(simgrid-mc ${MC_SIMGRID_MC_SRC})
  31   target_link_libraries(simgrid-mc simgrid)
  32   set_target_properties(simgrid-mc
  33                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
  34   set_property(TARGET simgrid-mc
  35                APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
  36   install(TARGETS simgrid-mc # install that binary without breaking the rpath on Mac
  37     RUNTIME DESTINATION bin/)
  38 endif()
  39
  40
  41 # Compute the dependencies of SimGrid
  42 #####################################
  43 if (HAVE_BOOST_CONTEXTS)
  44   set(SIMGRID_DEP "${SIMGRID_DEP} ${Boost_CONTEXT_LIBRARY}")
  45 endif()
  46
  47 if(CMAKE_USE_PTHREADS_INIT AND ${HAVE_THREAD_CONTEXTS})
  48   set(SIMGRID_DEP "${SIMGRID_DEP} ${CMAKE_THREAD_LIBS_INIT}")
  49 endif()
  50
  51 if(SIMGRID_HAVE_LUA)
  52   ADD_CUSTOM_TARGET(link_simgrid_lua ALL
  53     DEPENDS     simgrid
  54     )
  55   SET(SIMGRID_DEP "${SIMGRID_DEP} ${LUA_LIBRARY} ${DL_LIBRARY}")
  56 endif()
  57
  58 if(HAVE_PAPI)
  59   SET(SIMGRID_DEP "${SIMGRID_DEP} -lpapi")
  60 endif()
  61
  62 if(HAVE_GRAPHVIZ)
  63   if(HAVE_CGRAPH_LIB)
  64     SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
  65   else()
  66     if(HAVE_AGRAPH_LIB)
  67       SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
  68     endif()
  69   endif()
  70 endif()
  71
  72 if(SIMGRID_HAVE_MC AND NOT ${DL_LIBRARY} STREQUAL "")
  73   SET(SIMGRID_DEP "${SIMGRID_DEP} ${DL_LIBRARY}")
  74 endif()
  75
  76 if(HAVE_POSIX_GETTIME)
  77   SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
  78 endif()
  79
  80 if("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
  81   set(SIMGRID_DEP "${SIMGRID_DEP} -lprocstat")
  82 endif()
  83
  84 # Compute the dependencies of SMPI
  85 ##################################
  86
  87 if(enable_smpi)
  88   if(NOT ${DL_LIBRARY} STREQUAL "")
  89     set(SIMGRID_DEP "${SIMGRID_DEP} ${DL_LIBRARY}") # for privatization
  90   endif()
  91   add_executable(smpimain src/smpi/smpi_main.c)
  92   target_link_libraries(smpimain simgrid)
  93   set_target_properties(smpimain
  94     PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib/simgrid)
  95   install(TARGETS smpimain # install that binary without breaking the rpath on Mac
  96     RUNTIME DESTINATION lib/simgrid)
  97
  98   if(SMPI_FORTRAN)
  99     if(CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 100       SET(SIMGRID_DEP "${SIMGRID_DEP} -lgfortran")
 101     elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
 102       SET(SIMGRID_DEP "${SIMGRID_DEP} -lifcore")
 103     elseif(CMAKE_Fortran_COMPILER_ID MATCHES "PGI|Flang")
 104       SET(SIMGRID_DEP "${SIMGRID_DEP} -lflang")
 105       if("${CMAKE_SYSTEM}" MATCHES "FreeBSD")
 106         set(SIMGRID_DEP "${SIMGRID_DEP} -lexecinfo")
 107         if ("${CMAKE_SYSTEM_VERSION}" MATCHES "12")
 108             set(SIMGRID_DEP "${SIMGRID_DEP} -lpgmath")
 109         endif()
 110       endif()
 111     endif()
 112   endif()
 113
 114 endif()
 115
 116 if(enable_smpi AND APPLE)
 117   set(SIMGRID_DEP "${SIMGRID_DEP} -Wl,-U -Wl,_smpi_simulated_main")
 118 endif()
 119
 120 # See https://github.com/HewlettPackard/foedus_code/blob/master/foedus-core/cmake/FindGccAtomic.cmake
 121 FIND_LIBRARY(GCCLIBATOMIC_LIBRARY NAMES atomic atomic.so.1 libatomic.so.1
 122   HINTS
 123     $ENV{HOME}/local/lib64
 124     $ENV{HOME}/local/lib
 125     /usr/local/lib64
 126     /usr/local/lib
 127     /opt/local/lib64
 128     /opt/local/lib
 129     /usr/lib64
 130     /usr/lib
 131     /lib64
 132     /lib
 133 )
 134
 135 # Fix a FTBFS on armel, mips, mipsel and friends (Debian's #872881)
 136 if(CMAKE_COMPILER_IS_GNUCC AND GCCLIBATOMIC_LIBRARY)
 137     set(SIMGRID_DEP   "${SIMGRID_DEP}   -Wl,--as-needed -latomic -Wl,--no-as-needed")
 138 endif()
 139
 140 if(enable_model-checking AND (NOT LINKER_VERSION VERSION_LESS "2.30"))
 141     set(SIMGRID_DEP   "${SIMGRID_DEP}   -Wl,-znoseparate-code")
 142 endif()
 143
 144 target_link_libraries(simgrid   ${SIMGRID_DEP})
 145
 146 # Dependencies from maintainer mode
 147 ###################################
 148 if(enable_maintainer_mode)
 149   add_dependencies(simgrid smpi_generated_headers_call_location_tracing)
 150 endif()
 151 if(enable_maintainer_mode AND PYTHON_EXE)
 152   add_dependencies(simgrid simcalls_generated_src)
 153 endif()
 154 if(enable_maintainer_mode AND BISON_EXE AND LEX_EXE)
 155   add_dependencies(simgrid automaton_generated_src)
 156 endif()