CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.8)
   2 message(STATUS "Cmake version ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
   3 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_HOME_DIRECTORY}/tools/cmake/Modules)
   4
   5 project(SimGrid C CXX)
   6
   7 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
   8 #     Check for the compiler        #
   9 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  10
  11 ### Need to set rc ccompiler before enable language
  12 if(WIN32)
  13   SET(CMAKE_RC_COMPILER "windres")
  14 endif()
  15
  16 ##
  17 ## Check the C/C++ standard that we need
  18 ##   See also tools/cmake/GCCFlags.cmake that sets our paranoid warning flags
  19 if (MSVC)
  20   message("-- You are compiling SimGrid with MicroSoft Visual C. Good luck.")
  21
  22   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  23   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  24 else() # gcc or clang
  25   INCLUDE(CheckCCompilerFlag)
  26   CHECK_C_COMPILER_FLAG(-fstack-cleaner HAVE_C_STACK_CLEANER)
  27
  28   ## Request full debugging flags
  29   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
  30   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
  31   set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -g")
  32
  33   if (CMAKE_COMPILER_IS_GNUCC)
  34     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.7")
  35       message(FATAL_ERROR
  36               "SimGrid needs at least g++ version 4.7 to compile but you have ${CMAKE_CXX_COMPILER_VERSION}."
  37               "You need a sufficient support of c++11 to compile SimGrid.")
  38     endif()
  39   endif()
  40
  41   ## We need a decent support of the c++11 standard
  42   include(CheckCXXCompilerFlag)
  43   CHECK_CXX_COMPILER_FLAG("-std=gnu++11" COMPILER_SUPPORTS_CXX11)
  44   if(COMPILER_SUPPORTS_CXX11)
  45     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
  46   else()
  47     message(FATAL_ERROR
  48             "The compiler ${CMAKE_CXX_COMPILER} (v${CMAKE_CXX_COMPILER_VERSION}) has no C++11 support. "
  49             "Please use a decent C++ compiler.")
  50   endif()
  51
  52   ### And we need C11 standard, too
  53   include(CheckCCompilerFlag)
  54   CHECK_C_COMPILER_FLAG("-std=gnu11" COMPILER_SUPPORTS_C11)
  55   if(COMPILER_SUPPORTS_C11)
  56     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu11")
  57   else()
  58     message(FATAL_ERROR
  59             "The compiler ${CMAKE_C_COMPILER} (v${CMAKE_C_COMPILER_VERSION}) has no C11 support. "
  60             "Please use a decent C compiler "
  61             "(note that c++11 support of ${CMAKE_CXX_COMPILER} seems ok).")
  62   endif()
  63   if(APPLE AND (CMAKE_C_COMPILER_VERSION VERSION_LESS "4.6"))
  64       ### gcc 4.[1-5] cannot compile ucontext on OSX
  65       message(STATUS "Ucontext can't be used with this version of gcc (must be greater than 4.5)")
  66       set(HAVE_UCONTEXT_H 0)
  67   endif()
  68 endif() # NOT MSVC
  69
  70 ### SMPI vs. Fortran
  71 if ((NOT DEFINED enable_smpi OR enable_smpi) AND NOT APPLE) # smpi is enabled by default
  72   # Call enable_language(Fortran) in order to load the build rules for
  73   # this language, needed by teshsuite/smpi/mpich-test/.  Use
  74   # CMAKE_FORCE_Fortran_COMPILER to bypass checks for a working
  75   # compiler (smpiff don't exist at configure time).
  76   include(CMakeForceCompiler)
  77   if(NOT COMMAND CMAKE_FORCE_Fortran_COMPILER)
  78     MACRO(CMAKE_FORCE_Fortran_COMPILER compiler id)
  79       SET(CMAKE_Fortran_COMPILER "${compiler}")
  80       SET(CMAKE_Fortran_COMPILER_ID_RUN TRUE)
  81       SET(CMAKE_Fortran_COMPILER_ID ${id})
  82       SET(CMAKE_Fortran_COMPILER_WORKS TRUE)
  83       SET(CMAKE_Fortran_COMPILER_FORCED TRUE)
  84
  85       # Set old compiler id variables.
  86       IF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  87         SET(CMAKE_COMPILER_IS_GNUG77 1)
  88       ENDIF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  89     ENDMACRO(CMAKE_FORCE_Fortran_COMPILER)
  90   endif()
  91   CMAKE_FORCE_Fortran_COMPILER(smpiff smpiff)
  92   enable_language(Fortran OPTIONAL)
  93 endif()
  94
  95 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  96 #     Build the version number      #
  97 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  98
  99 set(SIMGRID_VERSION_MAJOR "3")
 100 set(SIMGRID_VERSION_MINOR "13")
 101 set(SIMGRID_VERSION_PATCH "0")
 102 set(SIMGRID_VERSION_EXTRA "-devel") # Extra words to add to version string (e.g. -rc1)
 103
 104 set(SIMGRID_VERSION_DATE  "2016") # Year for copyright information
 105
 106 if(${SIMGRID_VERSION_PATCH} EQUAL "0")
 107   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}")
 108 else()
 109   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}")
 110 endif()
 111
 112 set(SIMGRID_VERSION_STRING "SimGrid version ${release_version}${SIMGRID_VERSION_EXTRA}")
 113 set(SIMGRID_VERSION_BANNER "SIMGRID_VERSION_STRING\\nCopyright (c) 2004-${SIMGRID_VERSION_DATE}. The Simgrid Team.")
 114 if(release)
 115   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nRelease build")
 116 else()
 117   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nDevelopment build")
 118 endif()
 119
 120 set(libsimgrid_version "${release_version}")
 121 set(libsimgrid-java_version "${release_version}")
 122
 123 ### SET THE LIBRARY EXTENSION
 124 if(APPLE) #MAC
 125   set(LIB_EXE "dylib")
 126 else()
 127   if(WIN32) #WINDOWS
 128     set(LIB_EXE "a")
 129     set(BIN_EXE ".exe")
 130   else() #UNIX
 131     set(LIB_EXE "so")
 132   endif()
 133 endif()
 134
 135 execute_process(COMMAND         ${CMAKE_LINKER} --version
 136                 OUTPUT_VARIABLE LINKER_VERSION)
 137 string(REGEX MATCH "[0-9].[0-9]*" LINKER_VERSION "${LINKER_VERSION}")
 138
 139 ### Find programs and paths
 140 FIND_PROGRAM(GCOV_PATH gcov)
 141 include(FindPerl)
 142 if(NOT PERL_FOUND)
 143   message(FATAL_ERROR "Please install Perl to compile SimGrid.")
 144 endif()
 145
 146 if (APPLE)
 147   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 148   set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 149 endif()
 150 SET(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib)
 151
 152 ### Compute the include paths
 153 set(INCLUDES
 154   ${CMAKE_HOME_DIRECTORY}
 155   ${CMAKE_HOME_DIRECTORY}/include
 156   ${CMAKE_HOME_DIRECTORY}/src/include
 157   ${CMAKE_BINARY_DIR}
 158   ${CMAKE_BINARY_DIR}/include
 159   )
 160
 161 if(NOT CMAKE_CROSSCOMPILING AND EXISTS /usr/include/)
 162   set(INCLUDES ${INCLUDES} /usr/include/)
 163 endif()
 164
 165 ### Check 32bits or 64bits
 166 IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
 167   SET(ARCH_32_BITS 1)
 168 ELSE()
 169   SET(ARCH_32_BITS 0)
 170 ENDIF()
 171
 172 if(WIN32)
 173
 174   set(CMAKE_INCLUDE_WIN "${CMAKE_C_COMPILER}")
 175   set(CMAKE_LIB_WIN "${CMAKE_C_COMPILER}")
 176   string(REGEX REPLACE "/bin/gcc.*" "/include"  CMAKE_INCLUDE_WIN "${CMAKE_INCLUDE_WIN}")
 177   string(REGEX REPLACE "/bin/gcc.*" "/lib"  CMAKE_LIB_WIN "${CMAKE_LIB_WIN}")
 178   set(INCLUDES ${INCLUDES} ${CMAKE_INCLUDE_WIN})
 179   unset(CMAKE_INCLUDE_WIN)
 180
 181 endif()
 182
 183 include_directories(${INCLUDES})
 184
 185 ### Setup Options
 186 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Option.cmake)
 187
 188 ### Determine the assembly flavor that we need today
 189 include(CMakeDetermineSystem)
 190 IF(CMAKE_SYSTEM_PROCESSOR MATCHES ".86|AMD64|amd64")
 191   IF(${ARCH_32_BITS})
 192     message(STATUS "System processor: i686 (${CMAKE_SYSTEM_PROCESSOR}, 32 bits)")
 193     set(PROCESSOR_i686 1)
 194   ELSE()
 195     message(STATUS "System processor: x86_64 (${CMAKE_SYSTEM_PROCESSOR}, 64 bits)")
 196     set(PROCESSOR_x86_64 1)
 197   ENDIF()
 198   if (WIN32)
 199     message(STATUS "Disable fast raw contextes on Windows.")
 200   else()
 201     set(HAVE_RAW_CONTEXTS 1)
 202   endif()
 203
 204 ENDIF()
 205
 206 include(CheckFunctionExists)
 207 include(CheckTypeSize)
 208 include(CheckIncludeFile)
 209 include(CheckIncludeFiles)
 210 include(CheckLibraryExists)
 211 include(CheckSymbolExists)
 212
 213 set(HAVE_GRAPHVIZ 0)
 214 include(FindGraphviz)
 215 include(FindLibSigc++)
 216
 217 set(HAVE_LUA 0)
 218 if(enable_lua)
 219   include(FindLuaSimgrid)
 220 endif()
 221
 222 set(HAVE_NS3 0)
 223 if(enable_ns3)
 224   include(FindNS3)
 225   if (NOT HAVE_NS3)
 226     message(FATAL_ERROR "Cannot find NS3. Please install it (apt-get install ns3 libns3-dev) or disable that cmake option")
 227   endif()
 228 endif()
 229
 230 if(WIN32)
 231   set(Boost_USE_STATIC_LIBS 1)
 232 endif()
 233
 234 find_package(Boost 1.48)
 235 if(Boost_FOUND)
 236   include_directories(${Boost_INCLUDE_DIRS})
 237 else()
 238   if(APPLE)
 239     message(FATAL_ERROR "Failed to find Boost libraries (Try to install them with 'sudo fink install boost1.53.nopython')")
 240   else()
 241     message(FATAL_ERROR "Failed to find Boost libraries."
 242                         "Did you install libboost-dev and libboost-context-dev?"
 243                         "(libboost-context-dev is optional)")
 244   endif()
 245 endif()
 246
 247 # Try again to see if we have libboost-context
 248 find_package(Boost 1.42 COMPONENTS context)
 249 set(Boost_FOUND 1) # We don't care of whether this component is missing
 250
 251 if(Boost_FOUND AND Boost_CONTEXT_FOUND)
 252   # We should use feature detection for this instead:
 253   if (Boost_VERSION LESS 105600)
 254     message("Found Boost.Context API v1")
 255     set(HAVE_BOOST_CONTEXTS 1)
 256   else()
 257     message("Found Boost.Context API v2")
 258     set(HAVE_BOOST_CONTEXTS 2)
 259   endif()
 260 else()
 261   message ("   boost        : found.")
 262   message ("   boost-context: missing. Install libboost-context-dev for this optional feature.")
 263   set(HAVE_BOOST_CONTEXTS 0)
 264 endif()
 265
 266 # Checks for header libraries functions.
 267 CHECK_LIBRARY_EXISTS(execinfo backtrace              "" HAVE_BACKTRACE_IN_LIBEXECINFO)
 268 CHECK_LIBRARY_EXISTS(rt      clock_gettime           "" HAVE_POSIX_GETTIME)
 269
 270 CHECK_LIBRARY_EXISTS(pthread pthread_create          "" HAVE_PTHREAD)
 271 CHECK_LIBRARY_EXISTS(pthread sem_init                "" HAVE_SEM_INIT_LIB)
 272 CHECK_LIBRARY_EXISTS(pthread sem_open                "" HAVE_SEM_OPEN_LIB)
 273 CHECK_LIBRARY_EXISTS(pthread pthread_setaffinity_np  "" HAVE_PTHREAD_SETAFFINITY)
 274
 275 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 276   set(CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 277 elseif(MINGW)
 278   # Use the GNU version of unusual modifiers like PRIx64
 279   add_definitions(-D__USE_MINGW_ANSI_STDIO=1)
 280   set(CMAKE_REQUIRED_DEFINITIONS "-D__USE_MINGW_ANSI_STDIO=1")
 281 else()
 282   set(CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 283 endif()
 284
 285 CHECK_INCLUDE_FILE("valgrind/valgrind.h" HAVE_VALGRIND_H)
 286 CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 287 CHECK_INCLUDE_FILE("execinfo.h" HAVE_EXECINFO_H)
 288 CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 289 CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 290 CHECK_INCLUDE_FILE("sys/sysctl.h" HAVE_SYS_SYSCTL_H)
 291 CHECK_INCLUDE_FILE("ucontext.h" HAVE_UCONTEXT_H)
 292 CHECK_INCLUDE_FILE("linux/futex.h" HAVE_FUTEX_H)
 293
 294 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 295 CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 296 CHECK_FUNCTION_EXISTS(getdtablesize HAVE_GETDTABLESIZE)
 297 CHECK_FUNCTION_EXISTS(sysconf HAVE_SYSCONF)
 298 CHECK_FUNCTION_EXISTS(popen HAVE_POPEN)
 299 CHECK_FUNCTION_EXISTS(process_vm_readv HAVE_PROCESS_VM_READV)
 300 CHECK_FUNCTION_EXISTS(mmap HAVE_MMAP)
 301
 302 CHECK_SYMBOL_EXISTS(vasprintf stdio.h HAVE_VASPRINTF)
 303 if(MINGW)
 304   # The detection of vasprintf fails on MinGW, assumingly because it's
 305   # defined as an inline function in stdio.h instead of a regular
 306   # function. So force the result to be 1 despite of the test.
 307   set(HAVE_VASPRINTF 1)
 308 endif()
 309
 310
 311 #Check if __thread is defined
 312 execute_process(
 313   COMMAND "${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_thread_storage.c -o testprog"
 314   WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 315   RESULT_VARIABLE HAVE_thread_storage_run)
 316 file(REMOVE testprog)
 317 if(HAVE_thread_storage_run)
 318   set(HAVE_THREAD_LOCAL_STORAGE 1)
 319 else()
 320   set(HAVE_THREAD_LOCAL_STORAGE 0)
 321 endif()
 322
 323 # Our usage of mmap is Linux-specific (flag MAP_ANONYMOUS), but kFreeBSD uses a GNU libc
 324 IF(HAVE_MMAP AND
 325    NOT "${CMAKE_SYSTEM}" MATCHES "Linux" AND
 326    NOT "${CMAKE_SYSTEM}" MATCHES "kFreeBSD" AND
 327    NOT "${CMAKE_SYSTEM}" MATCHES "GNU" AND
 328    NOT  "${CMAKE_SYSTEM}" MATCHES "Darwin")
 329   SET(HAVE_MMAP 0)
 330   message(STATUS "Warning: MMAP is thought as non functional on this architecture (${CMAKE_SYSTEM})")
 331 ENDIF()
 332
 333 if(HAVE_MMAP AND HAVE_THREAD_LOCAL_STORAGE)
 334   SET(HAVE_MMALLOC 1)
 335 else()
 336   SET(HAVE_MMALLOC 0)
 337 endif()
 338
 339 if(enable_jedule)
 340   set(HAVE_JEDULE 1)
 341 endif()
 342
 343 if(enable_mallocators)
 344   SET(HAVE_MALLOCATOR 1)
 345 else()
 346   SET(HAVE_MALLOCATOR 0)
 347 endif()
 348
 349 if(enable_model-checking AND HAVE_MMALLOC)
 350   SET(HAVE_MC 1)
 351   include(FindLibunwind)
 352   include(FindLibdw)
 353 else()
 354   if(enable_model-checking)
 355     message(STATUS "Warning: support for model-checking has been disabled because you are missing either mmap or __thread.")
 356   endif()
 357   SET(HAVE_MC 0)
 358   SET(HAVE_MMALLOC 0)
 359 endif()
 360
 361 if(enable_smpi)
 362   include(FindGFortran)
 363   SET(HAVE_SMPI 1)
 364   if("${CMAKE_SYSTEM}" MATCHES "Linux")
 365     SET(USE_LIBUTIL 0)
 366     SET(HAVE_PRIVATIZATION 1)
 367   elseif("${CMAKE_SYSTEM}" MATCHES "^FreeBSD")
 368     SET(USE_LIBUTIL 0)
 369     SET(HAVE_PRIVATIZATION 0)
 370   else()
 371     message (STATUS "Warning:  no support for SMPI automatic privatization on this platform")
 372     SET(HAVE_PRIVATIZATION 0)
 373   endif()
 374 endif()
 375
 376 #--------------------------------------------------------------------------------------------------
 377 ### Check for GNU dynamic linker
 378 CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 379 if (HAVE_DLFCN_H)
 380     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_gnu_dynlinker.c -ldl -o test_gnu_ld
 381       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 382       OUTPUT_VARIABLE HAVE_GNU_LD_compil
 383     )
 384     if(HAVE_GNU_LD_compil)
 385       set(HAVE_GNU_LD 0)
 386       message(STATUS "Warning: test program toward GNU ld failed to compile:")
 387       message(STATUS "${HAVE_GNU_LD_comp_output}")
 388     else()
 389
 390       execute_process(COMMAND ./test_gnu_ld
 391           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 392           RESULT_VARIABLE HAVE_GNU_LD_run
 393           OUTPUT_VARIABLE var_exec
 394       )
 395
 396       if(NOT HAVE_GNU_LD_run)
 397         set(HAVE_GNU_LD 1)
 398         message(STATUS "We are using GNU dynamic linker")
 399       else()
 400         set(HAVE_GNU_LD 0)
 401         message(STATUS "Warning: error while checking for GNU ld:")
 402         message(STATUS "Test output: '${var_exec}'")
 403         message(STATUS "Exit status: ${HAVE_GNU_LD_run}")
 404       endif()
 405       file(REMOVE test_gnu_ld)
 406     endif()
 407 endif()
 408
 409
 410 #--------------------------------------------------------------------------------------------------
 411 ### Initialize of CONTEXT THREADS
 412
 413 set(HAVE_THREAD_CONTEXTS 0)
 414
 415 if(HAVE_PTHREAD)
 416   ### Test that we have a way to create semaphores
 417
 418   if(HAVE_SEM_OPEN_LIB)
 419     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_open.c -lpthread -o sem_open
 420       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 421       OUTPUT_VARIABLE HAVE_SEM_OPEN_compil
 422     )
 423
 424     # Test sem_open by compiling:
 425     if(HAVE_SEM_OPEN_compil)
 426       set(HAVE_SEM_OPEN 0)
 427       message(STATUS "Warning: sem_open not compilable")
 428       message(STATUS "HAVE_SEM_OPEN_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 429     else()
 430       set(HAVE_SEM_OPEN 1)
 431       message(STATUS "sem_open is compilable")
 432     endif()
 433
 434     # If we're not crosscompiling, we check by executing the program:
 435     if (HAVE_SEM_OPEN AND NOT CMAKE_CROSSCOMPILING)
 436       execute_process(COMMAND ./sem_open
 437         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 438         RESULT_VARIABLE HAVE_SEM_OPEN_run
 439         OUTPUT_VARIABLE var_compil
 440       )
 441       if (NOT HAVE_SEM_OPEN_run)
 442         set(HAVE_SEM_OPEN 1)
 443         message(STATUS "sem_open is executable")
 444       else()
 445         set(HAVE_SEM_OPEN 0)
 446         if(EXISTS "${CMAKE_BINARY_DIR}/sem_open")
 447           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open exists!")
 448         else()
 449           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open not exists!")
 450         endif()
 451         message(STATUS "Warning: sem_open not executable")
 452         message(STATUS "Compilation output: '${var_compil}'")
 453         message(STATUS "Exit result of sem_open: ${HAVE_SEM_OPEN_run}")
 454       endif()
 455     endif()
 456     file(REMOVE sem_open)
 457
 458   else()
 459     set(HAVE_SEM_OPEN 0)
 460   endif()
 461
 462   if(HAVE_SEM_INIT_LIB)
 463     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_init.c -lpthread -o sem_init
 464       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 465       RESULT_VARIABLE HAVE_SEM_INIT_run
 466       OUTPUT_VARIABLE HAVE_SEM_INIT_compil)
 467
 468     # Test sem_init by compiling:
 469     if(HAVE_SEM_INIT_compil)
 470       set(HAVE_SEM_INIT 0)
 471       message(STATUS "Warning: sem_init not compilable")
 472       message(STATUS "HAVE_SEM_INIT_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 473     else()
 474       set(HAVE_SEM_INIT 1)
 475       message(STATUS "sem_init is compilable")
 476     endif()
 477
 478     # If we're not crosscompiling, we check by executing the program:
 479     if (HAVE_SEM_INIT AND NOT CMAKE_CROSSCOMPILING)
 480       execute_process(COMMAND ./sem_init
 481         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 482         RESULT_VARIABLE HAVE_SEM_INIT_run
 483         OUTPUT_VARIABLE var_compil
 484       )
 485       if (NOT HAVE_SEM_INIT_run)
 486         set(HAVE_SEM_INIT 1)
 487         message(STATUS "sem_init is executable")
 488       else()
 489         set(HAVE_SEM_INIT 0)
 490         if(EXISTS "${CMAKE_BINARY_DIR}/sem_init")
 491           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init exists!")
 492         else()
 493           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init not exists!")
 494         endif()
 495         message(STATUS "Warning: sem_init not executable")
 496         message(STATUS "Compilation output: '${var_compil}'")
 497         message(STATUS "Exit result of sem_init: ${HAVE_SEM_INIT_run}")
 498       endif()
 499     endif()
 500     file(REMOVE sem_init)
 501   endif()
 502
 503   if(NOT HAVE_SEM_OPEN AND NOT HAVE_SEM_INIT)
 504     message(FATAL_ERROR "Semaphores are not usable (neither sem_open nor sem_init is both compilable and executable), but they are mandatory to threads (you may need to mount /dev).")
 505   endif()
 506
 507   set(HAVE_THREAD_CONTEXTS 1)
 508   message("-- Support for thread context factory ok.")
 509 endif()
 510
 511
 512 set(HAVE_UCONTEXT_CONTEXTS 0)
 513 if(NOT HAVE_UCONTEXT_H)
 514   message("-- No ucontext factory: <ucontext.h> not found.")
 515 elseif(APPLE)
 516   message("-- No ucontext factory: Apple don't want us to use them.")
 517   set(HAVE_UCONTEXT_H 0)
 518 else()
 519   try_compile(compile_makecontext ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_makecontext.c
 520     OUTPUT_VARIABLE compile_makecontext_output)
 521
 522   #If can have both context
 523   if(compile_makecontext)
 524     set(HAVE_UCONTEXT_CONTEXTS 1)
 525     message("-- Support for ucontext factory ok.")
 526   else()
 527     message("-- Error: <ucontext.h> exists, but makecontext is not compilable. Compilation output:\n ${compile_makecontext_output}")
 528     message("-- No ucontext factory: makecontext() is not compilable.")
 529   endif()
 530
 531   # Stack setup (size and address)
 532   try_run(RUN_makecontext_VAR COMPILE_makecontext_VAR
 533     ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stacksetup.c
 534     RUN_OUTPUT_VARIABLE stack_setup)
 535
 536   LIST(LENGTH stack_setup stack_setup_len)
 537   if("${stack_setup_len}" STREQUAL "2")
 538     LIST(GET stack_setup 0 makecontext_addr)
 539     LIST(GET stack_setup 1 makecontext_size)
 540     set(sg_makecontext_stack_addr "#define sg_makecontext_stack_addr(skaddr) (${makecontext_addr})")
 541     set(sg_makecontext_stack_size "#define sg_makecontext_stack_size(sksize) (${makecontext_size})")
 542   else()
 543     message(FATAL_ERROR "Could not figure out the stack setup. Compil: ${RUN_makecontext_VAR}. Exec: ${COMPILE_makecontext_VAR}. Output: ${stack_setup}")
 544   endif()
 545 endif()
 546
 547 # Stack growth direction (upward or downward). Used for the following contexts: SysV, raw, Boost
 548 try_run(RUN_stackgrowth_VAR COMPILE_stackgrowth_VAR
 549   ${CMAKE_BINARY_DIR}
 550   ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stackgrowth.c
 551   RUN_OUTPUT_VARIABLE stack
 552   COPY_FILE test_stackgrowth)
 553
 554 if("${stack}" STREQUAL "down")
 555   set(PTH_STACKGROWTH "-1")
 556 elseif("${stack}" STREQUAL "up")
 557   set(PTH_STACKGROWTH "1")
 558 else()
 559   if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
 560     set(PTH_STACKGROWTH "-1")
 561   elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "i686")
 562     set(PTH_STACKGROWTH "-1")
 563   else()
 564     message(FATAL_ERROR "Could not figure out the stack direction. Test prog returned: ${stack}; CMAKE_SYSTEM_PROCESSOR: ${CMAKE_SYSTEM_PROCESSOR}.")
 565   endif()
 566 endif()
 567 # If the test ran well, remove the test binary
 568 file(REMOVE test_stackgrowth)
 569 #--------------------------------------------------------------------------------------------------
 570
 571 ### check for addr2line
 572 find_path(ADDR2LINE NAMES addr2line     PATHS NO_DEFAULT_PATHS)
 573 if(ADDR2LINE)
 574   set(ADDR2LINE "${ADDR2LINE}/addr2line")
 575 endif()
 576
 577 ###############
 578 ## GIT version check
 579 ##
 580 if(EXISTS ${CMAKE_HOME_DIRECTORY}/.git/)
 581   execute_process(
 582      COMMAND git remote
 583      COMMAND head -n 1
 584      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 585      OUTPUT_VARIABLE remote
 586      OUTPUT_STRIP_TRAILING_WHITESPACE)
 587   #message(STATUS "Git remote: ${remote}")
 588   execute_process(COMMAND git config --get remote.${remote}.url
 589      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 590      OUTPUT_VARIABLE url
 591      OUTPUT_STRIP_TRAILING_WHITESPACE)
 592   #message(STATUS "Git url: ${url}")
 593   if(url)
 594     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=oneline --abbrev-commit -1
 595        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 596        OUTPUT_VARIABLE GIT_VERSION
 597        OUTPUT_STRIP_TRAILING_WHITESPACE)
 598     message(STATUS "Git version: ${GIT_VERSION}")
 599
 600     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log -n 1 --pretty=format:%ai .
 601        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 602        OUTPUT_VARIABLE GIT_DATE
 603        OUTPUT_STRIP_TRAILING_WHITESPACE)
 604     message(STATUS "Git date: ${GIT_DATE}")
 605     string(REGEX REPLACE " .*" "" GIT_VERSION "${GIT_VERSION}")
 606
 607     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=format:%H -1
 608        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 609        OUTPUT_VARIABLE SIMGRID_GITHASH
 610        OUTPUT_STRIP_TRAILING_WHITESPACE)
 611   endif()
 612 elseif(EXISTS ${CMAKE_HOME_DIRECTORY}/.gitversion)
 613   FILE(STRINGS ${CMAKE_HOME_DIRECTORY}/.gitversion GIT_VERSION)
 614 endif()
 615
 616 if(GIT_VERSION)
 617   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} at commit ${GIT_VERSION}")
 618 endif()
 619 if(GIT_DATE)
 620   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} (${GIT_DATE})")
 621 endif()
 622
 623 ### Generate the required headers and scripts
 624 #############################################
 625 # Avoid triggering a (full) rebuild by touching the files if they did not really change
 626 configure_file("${CMAKE_HOME_DIRECTORY}/tools/cmake/src/internal_config.h.in" "${CMAKE_BINARY_DIR}/src/internal_config.h.generated"    @ONLY IMMEDIATE)
 627 configure_file("${CMAKE_HOME_DIRECTORY}/include/simgrid_config.h.in"          "${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated" @ONLY IMMEDIATE)
 628 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/src/internal_config.h.generated ${CMAKE_BINARY_DIR}/src/internal_config.h)
 629 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated ${CMAKE_BINARY_DIR}/include/simgrid_config.h)
 630 file(REMOVE ${CMAKE_BINARY_DIR}/src/internal_config.h.generated)
 631 file(REMOVE ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated)
 632
 633 # We need two versions of the SMPI scripts because they contain the path to the library
 634 # so, it depends of whether SimGrid is installed, or run from the sources (during the build)
 635
 636 file(READ ${CMAKE_HOME_DIRECTORY}/src/smpi/smpitools.sh SMPITOOLS_SH) # Definitions shared amongst all SMPI scripts, inlined in each of them
 637
 638 ### SMPI script used when simgrid is installed
 639 set(exec_prefix ${CMAKE_INSTALL_PREFIX})
 640 set(includeflag "-I${CMAKE_INSTALL_PREFIX}/include -I${CMAKE_INSTALL_PREFIX}/include/smpi")
 641 set(includedir "${CMAKE_INSTALL_PREFIX}/include")
 642 set(libdir ${exec_prefix}/lib)
 643 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_INSTALL_PREFIX}/lib")
 644 if(NS3_LIBRARY_PATH)
 645   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 646 endif()
 647 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 648
 649 configure_file(${CMAKE_HOME_DIRECTORY}/include/smpi/mpif.h.in ${CMAKE_BINARY_DIR}/include/smpi/mpif.h @ONLY)
 650 foreach(script cc cxx ff f90 run)
 651   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/bin/smpi${script} @ONLY)
 652 endforeach()
 653
 654 ### SMPI scripts used when compiling simgrid
 655 set(exec_prefix "${CMAKE_BINARY_DIR}/smpi_script/")
 656 set(includeflag "-I${CMAKE_HOME_DIRECTORY}/include -I${CMAKE_HOME_DIRECTORY}/include/smpi")
 657 set(includeflag "${includeflag} -I${CMAKE_BINARY_DIR}/include -I${CMAKE_BINARY_DIR}/include/smpi")
 658 set(includedir "${CMAKE_HOME_DIRECTORY}/include")
 659 set(libdir "${CMAKE_BINARY_DIR}/lib")
 660 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_BINARY_DIR}/lib")
 661 if(NS3_LIBRARY_PATH)
 662   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 663 endif()
 664 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 665
 666 foreach(script cc cxx ff f90 run)
 667   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script} @ONLY)
 668 endforeach()
 669
 670 if(NOT WIN32)
 671   foreach(script cc cxx ff f90 run)
 672     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpi${script})
 673     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script})
 674   endforeach()
 675 endif()
 676
 677 set(generated_headers_to_install
 678   ${CMAKE_CURRENT_BINARY_DIR}/include/smpi/mpif.h
 679   ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h
 680   )
 681
 682 set(generated_headers
 683   ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h
 684   )
 685
 686 set(generated_files_to_clean
 687   ${generated_headers}
 688   ${generated_headers_to_install}
 689   ${CMAKE_BINARY_DIR}/bin/smpicc
 690   ${CMAKE_BINARY_DIR}/bin/smpicxx
 691   ${CMAKE_BINARY_DIR}/bin/smpiff
 692   ${CMAKE_BINARY_DIR}/bin/smpif90
 693   ${CMAKE_BINARY_DIR}/bin/smpirun
 694   ${CMAKE_BINARY_DIR}/bin/colorize
 695   ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
 696   ${CMAKE_BINARY_DIR}/examples/smpi/tracing/smpi_traced.trace
 697   )
 698
 699 if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_HOME_DIRECTORY}")
 700   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt COPYONLY)
 701   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt COPYONLY)
 702   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allReduce.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt COPYONLY)
 703   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_barrier.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt COPYONLY)
 704   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_bcast.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt COPYONLY)
 705   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_with_isend.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt COPYONLY)
 706   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt COPYONLY)
 707   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoallv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt COPYONLY)
 708   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_waitall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt COPYONLY)
 709   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_reducescatter.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt COPYONLY)
 710   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_gather.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt COPYONLY)
 711   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allgatherv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt COPYONLY)
 712   configure_file(${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/hostfile ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile COPYONLY)
 713
 714   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/description_file ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file COPYONLY)
 715   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/README ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README COPYONLY)
 716   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/smpi_replay.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt COPYONLY)
 717   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt COPYONLY)
 718   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt COPYONLY)
 719   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt COPYONLY)
 720   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt COPYONLY)
 721   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt COPYONLY)
 722   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt COPYONLY)
 723   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt COPYONLY)
 724   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt COPYONLY)
 725   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt COPYONLY)
 726   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt COPYONLY)
 727   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt COPYONLY)
 728   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt COPYONLY)
 729   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt COPYONLY)
 730   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt COPYONLY)
 731   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt COPYONLY)
 732   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt COPYONLY)
 733   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt COPYONLY)
 734   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt COPYONLY)
 735   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt COPYONLY)
 736   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt COPYONLY)
 737   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt COPYONLY)
 738   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt COPYONLY)
 739   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt COPYONLY)
 740   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt COPYONLY)
 741   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt COPYONLY)
 742   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt COPYONLY)
 743   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt COPYONLY)
 744   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt COPYONLY)
 745   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt COPYONLY)
 746   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt COPYONLY)
 747   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt COPYONLY)
 748   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt COPYONLY)
 749
 750   set(generated_files_to_clean
 751     ${generated_files_to_clean}
 752     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt
 753     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt
 754     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt
 755     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt
 756     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt
 757     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt
 758     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt
 759     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt
 760     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt
 761     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt
 762     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt
 763     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt
 764     ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile
 765     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file
 766     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README
 767     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt
 768     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt
 769     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt
 770     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt
 771     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt
 772     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt
 773     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt
 774     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt
 775     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt
 776     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt
 777     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt
 778     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt
 779     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt
 780     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt
 781     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt
 782     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt
 783     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt
 784     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt
 785     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt
 786     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt
 787     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt
 788     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt
 789     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt
 790     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt
 791     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt
 792     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt
 793     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt
 794     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt
 795     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt
 796     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt
 797     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt
 798     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt
 799     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt
 800     )
 801 endif()
 802
 803 SET_DIRECTORY_PROPERTIES(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES
 804   "${generated_files_to_clean}")
 805
 806 ### Define source packages for Libs
 807 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/DefinePackages.cmake)
 808
 809 ### Build some Maintainer files
 810 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MaintainerMode.cmake)
 811 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/UnitTesting.cmake)
 812
 813 ### Setup gcc & clang flags
 814 if (NOT MSVC)
 815   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/GCCFlags.cmake)
 816 endif()
 817
 818 ### Make Libs
 819 if(NOT WIN32)
 820   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLib.cmake)
 821 else()
 822   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLibWin.cmake)
 823 endif()
 824
 825 if(enable_java)
 826   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Java.cmake)
 827 endif()
 828
 829 ### Make tests
 830 if(enable_memcheck_xml)
 831   set(enable_memcheck true)
 832 endif()
 833
 834 INCLUDE(CTest)
 835 ENABLE_TESTING()
 836 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Tests.cmake)
 837 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/CTestConfig.cmake)
 838
 839 ### Define subdirectories
 840 foreach(cmakefile ${CMAKEFILES_TXT})
 841   string(REPLACE "/CMakeLists.txt" "" repository ${cmakefile})
 842   add_subdirectory("${CMAKE_HOME_DIRECTORY}/${repository}")
 843 endforeach()
 844
 845 ### Setup the distrib
 846 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Distrib.cmake)
 847
 848 ### Build the doc (Windows downloads the doc instead of regenerating)
 849 #
 850 if(NOT WIN32)
 851   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Documentation.cmake)
 852 else()
 853   find_program(WGET_PROGRAM  NAMES wget)
 854   message(STATUS "wget: ${WGET_PROGRAM}")
 855   if(WGET_PROGRAM)
 856     ADD_CUSTOM_TARGET(documentation
 857       COMMENT "Downloading the SimGrid documentation..."
 858       COMMAND ${WGET_PROGRAM} -r -np -nH -nd http://simgrid.gforge.inria.fr/simgrid/${release_version}/doc/
 859       WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html
 860     )
 861   endif()
 862 endif()
 863
 864 ### Print the result of configuration
 865 message("")
 866 message("##########################################")
 867 message("#### Content of src/internal_config.h ####")
 868 message("##########################################")
 869 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h config_output)
 870 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8) # Pass the file header
 871 foreach(line ${config_output})
 872   message("   ${line}")
 873 endforeach()
 874 message("##########################################")
 875 message("####   Content of simgrid_config.h    ####")
 876 message("##########################################")
 877 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h config_output)
 878 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8 9 -1) # Pass the file header
 879 foreach(line ${config_output})
 880   message("   ${line}")
 881 endforeach()
 882 message("##########################################")
 883 message("####   End of configuration headers   ####")
 884 message("##########################################")
 885
 886 message("\nConfiguration of package `simgrid':")
 887 message("        Home directory ..............: ${CMAKE_HOME_DIRECTORY}")
 888 message("        Build Name ..................: ${BUILDNAME}")
 889 message("        Cmake Generator .............: ${CMAKE_GENERATOR}")
 890 message("        Site ........................: ${SITE}")
 891 message("        Install prefix ..............: ${CMAKE_INSTALL_PREFIX}")
 892 if(release)
 893   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (release build)")
 894 else()
 895   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (development build)")
 896 endif()
 897 message("")
 898 message("        Compiler: C .................: ${CMAKE_C_COMPILER} (id: ${CMAKE_C_COMPILER_ID})")
 899 message("                version .............: ${CMAKE_C_COMPILER_VERSION}")
 900 message("                is gnu ..............: ${CMAKE_COMPILER_IS_GNUCC}")
 901 message("        Compiler: C++ ...............: ${CMAKE_CXX_COMPILER} (id: ${CMAKE_CXX_COMPILER_ID})")
 902 message("                version .............: ${CMAKE_CXX_COMPILER_VERSION}")
 903 if(${Java_FOUND})
 904   message("        Compiler: Javac .............: ${Java_JAVAC_EXECUTABLE}")
 905   message("                version .............: ${Java_VERSION_STRING}")
 906 if(${SWIG_FOUND})
 907   message("                SWIG ................: Version ${SWIG_VERSION} found.")
 908 else()
 909   message("                SWIG ................: Missing.")
 910 endif()
 911 endif()
 912 if(CMAKE_Fortran_COMPILER)
 913   message("        Compiler: Fortran ...........: ${CMAKE_Fortran_COMPILER} (id: ${CMAKE_Fortran_COMPILER_ID})")
 914   message("                version .............: ${CMAKE_Fortran_COMPILER_VERSION}")
 915 endif()
 916 message("        Linker: .....................: ${CMAKE_LINKER}")
 917 message("                version .............: ${LINKER_VERSION}")
 918 message("        Make program: ...............: ${CMAKE_MAKE_PROGRAM}")
 919 message("")
 920 message("        CFlags ......................: ${CMAKE_C_FLAGS}")
 921 message("        CXXFlags ....................: ${CMAKE_CXX_FLAGS}")
 922 message("        LDFlags .....................: ${CMAKE_C_LINK_FLAGS}")
 923 message("        with LTO ....................: ${enable_lto}")
 924 message("")
 925
 926 if (HAVE_NS3)
 927   message("        Compile NS-3 ................: yes (path: ${NS3_PATH})")
 928 else()
 929   message("        Compile NS-3 ................: NO  (hint: ${NS3_HINT})")
 930 endif()
 931
 932 if (${Java_FOUND})
 933   message("        Compile Java ................: yes")
 934   message("          Native lib in jar .........: ${enable_lib_in_jar}")
 935 else()
 936   message("        Compile Java ................: NO")
 937 endif()
 938 message("        Compile Lua .................: ${HAVE_LUA}")
 939 message("        Compile Smpi ................: ${HAVE_SMPI}")
 940 message("          Smpi fortran ..............: ${SMPI_FORTRAN}")
 941 message("          MPICH3 testsuite ..........: ${enable_smpi_MPICH3_testsuite}")
 942 message("          Privatization .............: ${HAVE_PRIVATIZATION}")
 943 message("        Compile Boost.Context support: ${HAVE_BOOST_CONTEXTS}")
 944 message("")
 945 message("        Maintainer mode .............: ${enable_maintainer_mode}")
 946 message("        Documentation................: ${enable_documentation}")
 947 message("        Model checking ..............: ${HAVE_MC}")
 948 message("        Jedule  mode ................: ${HAVE_JEDULE}")
 949 message("        Graphviz mode ...............: ${HAVE_GRAPHVIZ}")
 950 message("        Sigc++ mode .................: ${SIMGRID_HAVE_LIBSIG}")
 951 message("        Mallocators .................: ${enable_mallocators}")
 952 message("")
 953 message("        Simgrid dependencies ........: ${SIMGRID_DEP}")
 954 message("")
 955
 956 execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_BINARY_DIR}/Testing/Notes/)
 957 file(WRITE ${PROJECT_BINARY_DIR}/Testing/Notes/Build  "GIT version : ${GIT_VERSION}\n")
 958 file(APPEND ${PROJECT_BINARY_DIR}/Testing/Notes/Build "Release     : simgrid-${release_version}\n")
 959
 960 INCLUDE(Dart)