configure.ac

   1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
   2
   3 dnl This file is part of the SimGrid project. This is free software:
   4 dnl You can redistribute and/or modify it under the terms of the
   5 dnl GNU LGPL (v2.1) licence.
   6
   7 ######################
   8 ## Setup the autotools
   9 ##
  10
  11 AC_PREREQ(2.59)
  12 AC_INIT([simgrid],[3.3.5-svn],[simgrid-devel@lists.gforge.inria.fr])
  13 AC_CONFIG_SRCDIR([include/gras.h])
  14 AC_CONFIG_HEADERS([src/gras_config.h])
  15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  16
  17 AC_REVISION($Revision: 6998 $)
  18 AC_CANONICAL_TARGET
  19 AC_LANG([C])
  20 AC_PROG_CXX
  21 AM_PROG_GCJ
  22
  23 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  24 AC_CONFIG_MACRO_DIR(acmacro)
  25 ACLOCAL="$ACLOCAL -I acmacro"
  26
  27 dnl Next few lines is a hack to prevent libtool checking for F77
  28 m4_undefine([AC_PROG_F77])
  29 m4_defun([AC_PROG_F77],[])
  30
  31 dnl We do build a proper DLL when using win32
  32 AC_LIBTOOL_WIN32_DLL
  33 AC_PROG_LIBTOOL
  34
  35 SIMGRID_DEP=""
  36 SMPI_DEP=""
  37 GRAS_DEP=""
  38
  39
  40 ###############
  41 ## SVN version check
  42 ##
  43 if test -e .svn && echo $VERSION | grep -q svn; then
  44   VERSION="$VERSION-r`svnversion`"
  45   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
  46   PACKAGE_STRING="$PACKAGE_STRING r`svnversion`"
  47 else if test -e .git && echo $VERSION | grep -q svn; then
  48   ver=`git log --oneline -1 | sed 's| .*||'`
  49   VERSION=`echo "$VERSION-r$ver" | sed 's/svn/git/'`
  50   PACKAGE_VERSION=`echo "$PACKAGE_VERSION-r$ver" | sed 's/svn/git/'`
  51   PACKAGE_STRING=`echo "$PACKAGE_STRING r$ver" | sed 's/svn/git/'`
  52 fi fi
  53
  54 ###############
  55 ## System checks
  56 ##
  57 SG_CONFIGURE_PART([System checks...])
  58 AC_PROG_CC(xlC gcc cc)
  59 AM_SANITY_CHECK
  60 AC_PROG_MAKE_SET
  61 AC_CHECK_PRINTF_NULL
  62 AC_CHECK_VA_COPY
  63
  64 # Checks for header files.
  65 AC_HEADER_STDC
  66 AC_HEADER_TIME
  67 AC_CHECK_HEADERS([sys/socket.h \
  68                   sys/stat.h \
  69                   windows.h winsock.h winsock2.h \
  70                   sys/time.h \
  71                   errno.h unistd.h \
  72                   execinfo.h\
  73                   signal.h ])
  74 AC_CHECK_FUNCS([gettimeofday usleep \
  75                 getdtablesize \
  76                 sysconf\
  77                 readv\
  78                 popen\
  79                 signal])
  80
  81 dnl GNU systems before POSIX2008 need the _GNU_SOURCE definition to find getline (and simgrid does pass this)
  82 AC_MSG_CHECKING(a usable getline)
  83 AC_LINK_IFELSE([
  84     #define _GNU_SOURCE
  85     #include <stdio.h>
  86     int main(void){
  87       FILE * fp;
  88       char * line = NULL;
  89       size_t len = 0;
  90       getline(&line, &len, fp);
  91     }
  92   ],[
  93     AC_MSG_RESULT(found)
  94   ],[
  95     AC_SUBST(need_getline, ["#define SIMGRID_NEED_GETLINE 1 /* enable the getline replacement*/"])
  96     AC_DEFINE(SIMGRID_NEED_GETLINE, 1, enable the getline replacement)
  97     AC_MSG_RESULT(not found (activating internal implementation))
  98   ])
  99
 100 dnl AC_MSG_CHECKING(POSIX timer functions)
 101 AC_CHECK_LIB(rt, [clock_gettime], [
 102     AC_DEFINE(HAVE_POSIX_GETTIME, 1, POSIX timer functions were found)
 103     SIMGRID_DEP="$SIMGRID_DEP -lrt"
 104     GRAS_DEP="$GRAS_DEP -lrt"
 105   ])
 106
 107 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
 108 AC_FUNC_SNPRINTF
 109 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
 110 AC_CHECK_FUNC(  asprintf, :,[
 111     AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf replacement)
 112     AC_SUBST(need_asprintf, ["#define SIMGRID_NEED_ASPRINTF 1 /* enable the asprintf replacement */"])
 113    ])
 114 AC_CHECK_FUNC( vasprintf, :,[
 115     AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf replacement)
 116     AC_SUBST(need_vasprintf, ["#define SIMGRID_NEED_VASPRINTF 1 /*enable the vasprintf replacement */"])
 117    ])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_CONST
 121 AC_C_INLINE
 122 AC_TYPE_SIZE_T
 123
 124 ###################################
 125 ## SimGrid and GRAS specific checks
 126 ##
 127
 128 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
 129 # Check architecture signature begin
 130 GRAS_ARCH
 131 # Check architecture signature end
 132 GRAS_CHECK_STRUCT_COMPACTION
 133
 134
 135 dnl ##
 136 dnl ##  CONTEXT IMPLEMENTATION
 137 dnl ##
 138
 139 SG_CONFIGURE_PART([Checking threads, contexts or assimilated...])
 140
 141 dnl #
 142 dnl #  1. determine possibilities
 143 dnl #
 144
 145 dnl #  check for MCSC method (ucontexts)
 146 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
 147
 148 dnl #  check for pthread method
 149 AC_CHECK_HEADERS([pthread.h])
 150 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
 151
 152 if test x$pthread = xyes ; then
 153   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
 154   if test ${HAVE_SEM_INIT} = yes ; then
 155      AC_MSG_CHECKING(if sem_init is compilable)
 156      AC_TRY_COMPILE([#include <semaphore.h>],
 157                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
 158      if test ${HAVE_SEM_INIT} = yes ; then
 159         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
 160         AC_MSG_RESULT(yes)
 161      else
 162         AC_MSG_RESULT(no)
 163      fi
 164   fi
 165   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
 166   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
 167      AC_MSG_CHECKING(if sem_timedwait is compilable)
 168      AC_TRY_COMPILE([#include <semaphore.h>],
 169                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
 170      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
 171         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
 172         AC_MSG_RESULT(yes)
 173      else
 174         AC_MSG_RESULT(no)
 175      fi
 176   fi
 177
 178   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
 179   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
 180      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
 181      AC_TRY_COMPILE([#include <pthread.h>],
 182                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
 183      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
 184         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
 185         AC_MSG_RESULT(yes)
 186      else
 187         AC_MSG_RESULT(no)
 188      fi
 189   fi
 190 fi
 191
 192 dnl #
 193 dnl #  2. make a general decision
 194 dnl #
 195
 196 if test ".$mcsc" = .yes; then
 197    # ucontext found
 198    mcsc=yes
 199 elif test ".$pthread" = .yes; then
 200    # ucontext not found, but pthread found
 201    pthread=yes
 202 else
 203     ac_header=windows.h
 204     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 205     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 206       windows_context=yes
 207     else
 208       AC_ERROR([no appropriate backend found])
 209     fi
 210 fi
 211 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
 212
 213
 214 dnl #
 215 dnl #  3. allow decision to be overridden by user
 216 dnl #
 217
 218 AC_MSG_CHECKING(what kind of backend should we use)
 219
 220 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 221 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 222
 223 AC_ARG_WITH(context,
 224   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 225   with_context=auto)
 226
 227 if test "x$with_context$mcsc" = "xucontextno" ; then
 228   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 229 fi
 230
 231 case $with_context in
 232  ucontext) ;;
 233  pthread) ;;
 234  pthreads) ;;
 235  windows) ;;
 236  auto) with_context=ucontext;;
 237  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 238 esac
 239
 240 if test "x$with_context" = "xucontext" ; then
 241   if test ".$mcsc" = .yes; then
 242     AC_MSG_RESULT(found working ucontext. Great!)
 243     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 244     AC_CHECK_HEADERS([valgrind/valgrind.h])
 245   else
 246     if test ".$windows_context" = .yes ; then
 247       AC_MSG_RESULT(use windows context portability layer.)
 248       with_context=windows
 249     else
 250       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 251       with_context=pthread
 252     fi
 253   fi
 254 fi
 255
 256 if test "x$with_context" = "xpthread"; then
 257   if test x$pthread != xyes ; then # reuse previous checks
 258     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
 259   fi
 260   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 261   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
 262 fi
 263 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
 264
 265 dnl #
 266 dnl #  4. determine a few additional details
 267 dnl #
 268
 269 if test "x$with_context" = "xucontext" ; then
 270 dnl #  direction of stack grow
 271   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 272   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 273       PTH_STACK_GROWTH="down"
 274   else
 275       PTH_STACK_GROWTH="up"
 276   fi
 277   AC_SUBST(PTH_STACK_GROWTH)
 278
 279   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 280 fi
 281
 282 #########################################
 283 ## Check for libraries extra-dependencies
 284 ##
 285
 286 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 287
 288 if test xpthread=xyes ; then
 289   # if the pthreads are usable
 290   if test "x$with_context" = "xpthread" ; then
 291     # if we use them to implement the xbt_context
 292     SIMGRID_DEP="$SIMGRID_DEP -lpthread"
 293   fi
 294   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 295   if test "x$with_context" != "xwindows" ; then
 296     GRAS_DEP="$GRAS_DEP -lpthread"
 297   fi
 298 fi
 299 AC_SEARCH_LIBS([connect],[socket],[],[],[]) # need -lsocket on solaris
 300
 301 #########################################
 302 ## Build optional modules (gtnets)
 303 ##
 304 gtnets=no
 305 AC_ARG_WITH(gtnets,
 306   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 307   gtnets_path="$withval",gtnets_path="no")
 308 if test "x$gtnets_path" = "xno" ; then
 309   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 310 else
 311   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
 312   AC_MSG_CHECKING(for gtnets)
 313   AC_LANG_PUSH([C++])
 314   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
 315   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
 316   LDFLAGS_SAV=$LDFLAGS
 317   CPPFLAGS_SAV=$CPPFLAGS
 318   CPPFLAGS+=$GTNETS_CPPFLAGS
 319   LDFLAGS+=$GTNETS_LDFLAGS
 320   AC_TRY_LINK([ #include <simulator.h>
 321               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
 322   CPPFLAGS=$CPPFLAGS_SAV
 323   LDFLAGS=$LDFLAGS_SAV
 324   AC_LANG_POP([C++])
 325 fi
 326
 327 if test "x$gtnets" = "xyes" ; then
 328   AC_MSG_RESULT(Enabling GTNETS support.)
 329   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
 330   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
 331   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
 332 fi
 333 AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
 334
 335
 336
 337 AC_SUBST([SIMGRID_DEP])
 338 AC_SUBST([SMPI_DEP])
 339
 340 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 341 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 342
 343 AC_MSG_CHECKING(for extra dependencies of libgras)
 344 case $host_os in
 345   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 346             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
 347             AC_DEFINE(CONTEXT_THREADS,1);;
 348 esac
 349
 350
 351
 352 if test "x$GRAS_DEP" = x; then
 353    AC_MSG_RESULT(none)
 354 else
 355    AC_MSG_RESULT($GRAS_DEP)
 356 fi
 357 AC_SUBST([GRAS_DEP])
 358
 359 ##############################################
 360 ## Enhance maintainer mode and SUBST variables
 361 ## (must be placed after any compilation tests since our overprotective flags
 362 ##  let some tests fail)
 363
 364 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 365 # Next line is modified by sed when building gramine source tree
 366 gramine_mode=no
 367 if test x$gramine_mode = xyes
 368 then
 369   USE_MAINTAINER_MODE=no
 370 fi
 371 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 372
 373 AM_MAINTAINER_MODE
 374 if test x$USE_MAINTAINER_MODE = xyes
 375 then
 376    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 377    force_compile_warnings=yes
 378 fi
 379 SG_COMPILE_FLAGS
 380
 381 ##
 382 ## Support for the supernovae compilation mode
 383 ##
 384 AC_ARG_ENABLE(supernovae,
 385               AS_HELP_STRING([--enable-supernovae],[Put the whole library in one compilation unit only to help gcc optimizing the code]),
 386               [supernovae=$enableval],
 387               [supernovae=no])
 388 AM_CONDITIONAL(SUPERNOVAE_MODE, test x$supernovae != xno)
 389
 390 AC_SUBST([CFLAGS])
 391 AC_SUBST([CPPFLAGS])
 392 AC_SUBST([LDFLAGS])
 393 AC_SUBST([AM_CPPFLAGS])
 394 AC_SUBST([abs_builddir])
 395 AC_SUBST([abs_srcdir])
 396 AC_SUBST([abs_top_builddir])
 397 AC_SUBST([abs_top_srcdir])
 398
 399 ##############################################
 400 ## Specific mode for build daemons.
 401 ## (they compile the SVN without having the autotools installed)
 402 AC_ARG_ENABLE(botbuild,
 403               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
 404               botbuild=$enableval,botbuild=no)
 405 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
 406
 407 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
 408   echo "ERROR: "
 409   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
 410   echo "ERROR: For this, just call configure this way:"
 411   echo "ERROR:"
 412   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
 413   echo "ERROR:"
 414   exit 1
 415 fi
 416
 417
 418 SG_CONFIGURE_PART(Checking Java bindings...)
 419 # Java cruft
 420 AC_ARG_ENABLE(java,
 421               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 422               disable_java=$enableval,disable_java=yes)
 423 if test "x$disable_java" != "xyes" ; then
 424    use_java="disabled by user"
 425 else
 426   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 427   AC_PATH_PROG([JAVA],  [java] , `which java`)
 428   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 429   AC_CHECK_HEADERS(jni.h)
 430   if test -n "$JAVAC" && test -n "$JAVA" && test -n "$JAR" && test "x$ac_cv_header_jni_h" = "xyes" ; then
 431      use_java="yes"
 432      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
 433   else
 434      use_java="no (you may want to install the java-gcj-compat-dev package)"
 435   fi
 436 fi
 437 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
 438 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 439
 440
 441 SG_CONFIGURE_PART(Checking Lua bindings...)
 442 AC_ARG_ENABLE(lua,
 443               AS_HELP_STRING([--disable-lua], [To not compile the Lua bindings even if the tools are found]),
 444               disable_lua=$enableval,disable_lua=yes)
 445 if test "x$disable_lua" != "xyes" ; then
 446    use_lua="disabled by user"
 447 else
 448   AC_CHECK_HEADERS(lua5.1/lualib.h)
 449   if test "x$ac_cv_header_lua5_1_lualib_h" = "xyes" ; then
 450      use_lua="yes"
 451      AC_DEFINE(HAVE_LUA,1, [defines whether Lua bindings must be compiled or not])
 452      SIMGRID_DEP="${SIMGRID_DEP} -ldl -llua5.1"
 453   else
 454      use_lua="no (you may want to install the liblua5.1-0-dev package)"
 455   fi
 456 fi
 457 AC_MSG_RESULT(decide whether to compile lua bindings... $use_lua)
 458 AM_CONDITIONAL(HAVE_LUA,test "x$use_lua" = "xyes")
 459
 460 SG_CONFIGURE_PART(Checking Ruby bindings...)
 461 # Ruby cruft
 462 AC_ARG_ENABLE(ruby,
 463               AS_HELP_STRING([--disable-ruby], [To not compile the Ruby bindings even if the tools are found]),
 464               disable_ruby=$enableval,disable_ruby=yes)
 465 if test "x$disable_ruby" != "xyes" ; then
 466    use_ruby="disabled by user"
 467 else
 468   CPPFLAGS="-I/usr/lib/ruby/1.8/i486-linux/ $CPPFLAGS"
 469   AC_MSG_CHECKING(checking ruby.h usability and presence)
 470   AC_COMPILE_IFELSE([
 471     #undef PACKAGE_NAME
 472     #undef PACKAGE_TARNAME
 473     #undef PACKAGE_VERSION
 474     #undef PACKAGE_STRING
 475     #undef PACKAGE_BUGREPORT
 476     #include <ruby.h>
 477   ], use_ruby=yes,use_ruby="no (Package ruby1.8-dev missing)")
 478   AC_MSG_RESULT($use_ruby)
 479   if test "x$use_ruby" = "xyes" ; then
 480      AC_DEFINE(HAVE_RUBY,1, [defines whether Ruby bindings must be compiled or not])
 481      SIMGRID_DEP="${SIMGRID_DEP} -lruby1.8"
 482   else
 483      AC_MSG_RESULT(Please install the ruby1.8-dev package (on debian and similar) to get ruby bindings)
 484   fi
 485 fi
 486 AC_MSG_RESULT(decide whether to compile ruby bindings... $use_ruby)
 487 AM_CONDITIONAL(HAVE_RUBY,test "x$use_ruby" = "xyes")
 488
 489
 490 #####################
 491 ## Check for programs
 492 ##
 493
 494 SG_CONFIGURE_PART(Checking programs...)
 495 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 496 WARNING="This file is generated, do not edit"
 497 AC_SUBST(WARNING)
 498
 499
 500 # Can we rebuild the parsers?
 501 # We really want flex and refuse other lex. So, the parser is portable and
 502 # does not induce extra lib dependency
 503 AC_PROG_FLEX(2.5.30)
 504
 505 # Can we rebuild the xml-lexers from the XML specification?
 506 # if not, simply touch the flex source files (which are distributed in
 507 #  tarballs even if generated by flexml) and hope for the best.
 508 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 509 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 510
 511 # Check for doxygen when in maintainer mode which is helpful to build doc & dist
 512 AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 513 AC_PATH_PROG(FIG2DEV,fig2dev,`which fig2dev`)
 514 AM_CONDITIONAL(HAVE_DOXYGEN,test x$DOXYGEN != x &&
 515                             test x$FIG2DEV != x)
 516
 517 # Can we rebuild the publication list from the bib file?
 518 AC_CHECK_PROG(BIBTEX,bibtex,`which flexml`,NOTFOUND)
 519 AC_CHECK_PROG(BIBTOOL,bibtool,`which bibtool`,NOTFOUND)
 520 AC_CHECK_PROG(ICONV,iconv,`which iconv`,NOTFOUND)
 521 AC_CHECK_PROG(BIBTEX2HTML,bibtex2html,`which bibtex2html`,NOTFOUND)
 522
 523 BIBTEX2HTML_VER="date"
 524 if test "x$BIBTEX2HTML" != "xNOTFOUND" ; then
 525    BIBTEX2HTML_VER=`$BIBTEX2HTML --help 2>&1 | grep date`
 526 fi;
 527
 528 AC_MSG_CHECKING(whether you have the right bibtex2html and will be able to build HTML files from the bibtex file)
 529 AM_CONDITIONAL(HAVE_BIBTEX2HTML,test "x$BIBTEX2HTML_VER" == "x"     &&
 530                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
 531                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
 532                                 test "x$ICONV" != "xNOTFOUND"         )
 533
 534 if test "x$BIBTEX2HTML_VER" == "x"     &&
 535                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
 536                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
 537                                 test "x$ICONV" != "xNOTFOUND"; then
 538    AC_MSG_RESULT(yes)
 539 else
 540    AC_MSG_RESULT(no)
 541 fi
 542
 543 # Can we extract really usable backtraces? (also need the popen function)
 544 AC_PATH_PROG(ADDR2LINE, addr2line)
 545 if test x$ADDR2LINE != x ; then
 546   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 547 fi
 548
 549 AC_SUBST(ac_configure_args)
 550 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
 551 # Can we make status line about the compilation result?
 552 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 553 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
 554 AC_SUBST(build_id)
 555
 556 ###################
 557 ## Makes the output
 558 ##
 559
 560
 561 #
 562 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 563 #  src/amok/Makefile
 564
 565 SG_CONFIGURE_PART(Generating files...)
 566
 567 # Core of the libraries
 568
 569 AC_CONFIG_FILES([
 570   Makefile
 571   include/Makefile
 572   include/simgrid_config.h
 573   src/Makefile
 574   src/context_sysv_config.h
 575 ])
 576
 577 # Tools being embeeded in gramine (stub generator)
 578 AC_CONFIG_FILES([
 579   tools/Makefile
 580     tools/gras/Makefile
 581     tools/tesh/Makefile
 582 ])
 583 #    tools/tesh2/Makefile
 584
 585
 586 # GRAMINE_CUT_BEGIN
 587
 588 # Tools NOT being embeeded in gramine
 589 AC_CONFIG_FILES([
 590   tools/graspe-slave
 591 ],[
 592     for file in                                                 \
 593      tools/graspe-slave           tools/graspe-master           \
 594      checkall                     examples/java/runtest         \
 595      src/mk_supernovae.sh                                       \
 596     ; do                                                        \
 597       test -e $file && chmod +x $file;                          \
 598     done
 599 ])
 600
 601 # build tools && Testsuite
 602
 603 AC_CONFIG_FILES([
 604   buildtools/Makefile
 605   testsuite/Makefile
 606   testsuite/run_tests
 607 ],[
 608     for file in                                                 \
 609      testsuite/run_tests                                        \
 610     ; do                                                        \
 611       test -e $file && chmod +x $file;                          \
 612     done
 613 ])
 614
 615 # Teshsuite (testsuite using tesh)
 616 AC_CONFIG_FILES([
 617   teshsuite/Makefile
 618 ])
 619
 620 # Documentation
 621 AC_CONFIG_FILES([
 622   doc/Makefile
 623   doc/Doxyfile
 624 ])
 625
 626 # Examples
 627
 628 #      examples/gras/p2p/Makefile
 629 #      examples/gras/p2p/chord/Makefile
 630 #      examples/gras/p2p/can/Makefile
 631
 632 AC_CONFIG_FILES([
 633     examples/java/Makefile
 634       examples/java/basic/Makefile
 635       examples/java/comm_time/Makefile
 636       examples/java/suspend/Makefile
 637       examples/java/ping_pong/Makefile
 638 ])
 639
 640 AC_CONFIG_FILES([
 641   examples/Makefile
 642     examples/msg/Makefile
 643     examples/simdag/Makefile
 644     examples/gras/Makefile
 645       examples/gras/ping/Makefile
 646       examples/gras/rpc/Makefile
 647       examples/gras/spawn/Makefile
 648       examples/gras/synchro/Makefile
 649       examples/gras/timer/Makefile
 650       examples/gras/properties/Makefile
 651       examples/gras/chrono/Makefile
 652       examples/gras/mutual_exclusion/simple_token/Makefile
 653       examples/gras/mmrpc/Makefile
 654       examples/gras/pmm/Makefile
 655       examples/gras/all2all/Makefile
 656     examples/amok/Makefile
 657     examples/smpi/Makefile
 658 ])
 659 #      examples/gras/replay/Makefile
 660
 661 AC_CONFIG_FILES([
 662   src/smpi/smpicc
 663   src/smpi/smpirun
 664 ],[
 665     for file in                                                 \
 666       src/smpi/smpicc                                           \
 667       src/smpi/smpirun                                          \
 668     ; do                                                        \
 669       test -e $file && chmod +x $file;                          \
 670     done
 671 ])
 672
 673 # GRAMINE_CUT_END
 674
 675 AC_OUTPUT
 676
 677 echo "
 678
 679 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 680
 681         Compiler:        ${CC} (version: ${GCC_VERSION})
 682
 683         CFlags:          ${CFLAGS}
 684         CPPFlags:        ${CPPFLAGS}
 685         LDFlags:         ${LDFLAGS}
 686
 687         Context backend: ${with_context}
 688         Compile Java:    ${use_java}
 689         Compile Lua:     ${use_lua}
 690         Compile Ruby:    ${use_ruby}
 691
 692         Maintainer mode: ${USE_MAINTAINER_MODE}
 693         Supernovae mode: ${supernovae}
 694
 695 "
 696 if test x$botbuild = xyes ; then
 697   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
 698   echo
 699 fi
 700
 701 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
 702   echo "WARNING: "
 703   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
 704   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
 705   echo "WARNING:"
 706   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
 707   echo "WARNING:"
 708 fi
 709
 710 echo $build_id > stamp.configure
 711
 712 exit 0;