tools/cmake/GCCFlags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing -Wno-format-nonliteral -Werror")
  18   if(CMAKE_COMPILER_IS_GNUCC)
  19     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  20   endif()
  21
  22   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment  -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing -Wno-format-nonliteral -Werror")
  23   if(CMAKE_COMPILER_IS_GNUCXX)
  24     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  25   endif()
  26   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang") # don't care about class that become struct
  27     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags")
  28   endif()
  29
  30   # the one specific to C but refused by C++
  31   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  32
  33   set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  34   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  35 endif()
  36
  37 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  38 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  39 if(enable_maintainer_mode)
  40   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  41   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  42 endif()
  43
  44 # Se the optimisation flags
  45 # NOTE, we should CMAKE_BUILD_TYPE for this
  46 if(enable_compile_optimizations)
  47   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  48 else()
  49   set(optCFLAGS "-O0 ")
  50 endif()
  51 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
  52     AND (NOT enable_model-checking))
  53   # This is redundant (already in -03):
  54   set(optCFLAGS "${optCFLAGS} -finline-functions ")
  55 endif()
  56
  57 # Configure LTO
  58 # NOTE, cmake 3.0 has a INTERPROCEDURAL_OPTIMIZATION target
  59 #       property for this (http://www.cmake.org/cmake/help/v3.0/prop_tgt/INTERPROCEDURAL_OPTIMIZATION.html)
  60 if(enable_lto) # User wants LTO. Try if we can do that
  61   set(enable_lto OFF)
  62   if(enable_compile_optimizations
  63       AND CMAKE_COMPILER_IS_GNUCC
  64       AND (NOT enable_model-checking))
  65     # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
  66     #   We are experiencing assertion failures even with 4.8 on MinGW.
  67     #   Push the support forward: will see if 4.9 works when we test it.
  68     #
  69     # On Linux, we got the following with GCC 4.8.4 on Centos and Ubuntu
  70     #    lto1: internal compiler error: in output_die, at dwarf2out.c:8478
  71     #    Please submit a full bug report, with preprocessed source if appropriate.
  72     # So instead, we push the support forward
  73
  74     if ( (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
  75          AND (LINKER_VERSION VERSION_GREATER "2.22"))
  76       set(enable_lto ON)
  77     endif()
  78   endif()
  79   if(enable_lto)
  80     message("-- LTO seems usable.")
  81   else()
  82     if(NOT enable_compile_optimizations)
  83       message("-- LTO disabled: Compile-time optimizations turned off.")
  84     else()
  85       if(enable_model-checking)
  86         message("-- LTO disabled when compiling with model-checking.")
  87       else()
  88         message("-- LTO does not seem usable -- try updating your build chain.")
  89       endif()
  90     endif()
  91   endif()
  92 else()
  93   message("-- LTO disabled on the command line.")
  94 endif()
  95 if(enable_lto) # User wants LTO, and it seems usable. Go for it
  96   set(optCFLAGS "${optCFLAGS} -flto ")
  97   # See https://gcc.gnu.org/wiki/LinkTimeOptimizationFAQ#ar.2C_nm_and_ranlib:
  98   # "Since version 4.9 gcc produces slim object files that only contain
  99   # the intermediate representation. In order to handle archives of
 100   # these objects you have to use the gcc wrappers:
 101   # gcc-ar, gcc-nm and gcc-ranlib."
 102   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 103       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 104     set (CMAKE_AR gcc-ar)
 105     set (CMAKE_RANLIB gcc-ranlib)
 106   endif()
 107 endif()
 108
 109 if(enable_model-checking AND enable_compile_optimizations)
 110   # Forget it, do not optimize the code (because it confuses the MC):
 111   set(optCFLAGS "-O0 ")
 112   # But you can still optimize this:
 113   foreach(s
 114       src/xbt/mmalloc/mm.c
 115       src/xbt/log.c src/xbt/xbt_log_appender_file.c
 116       src/xbt/xbt_log_layout_format.c src/xbt/xbt_log_layout_simple.c
 117       src/xbt/dict.cpp src/xbt/dict_elm.c src/xbt/dict_cursor.c
 118       src/xbt/dynar.cpp src/xbt/fifo.c src/xbt/heap.c src/xbt/swag.c
 119       src/xbt/str.c src/xbt/strbuff.c src/xbt/snprintf.c
 120       src/xbt/queue.c
 121       src/xbt/xbt_os_time.c src/xbt/xbt_os_thread.c
 122       src/xbt/backtrace_linux.c
 123       ${MC_SRC_BASE} ${MC_SRC})
 124       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
 125        if(CMAKE_COMPILER_IS_GNUCC)
 126          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 127       endif()
 128       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 129   endforeach()
 130 endif()
 131
 132 if(NOT enable_debug)
 133   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 134   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 135 endif()
 136
 137 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 138 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 139
 140 # Try to make Mac a bit more complient to open source standards
 141 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 142   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 143 endif()
 144
 145 set(TESH_OPTION "")
 146 if(enable_coverage)
 147   find_program(GCOV_PATH gcov)
 148   if(GCOV_PATH)
 149     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
 150     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
 151     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 152     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
 153     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
 154     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
 155     set(TESH_OPTION --enable-coverage)
 156     add_definitions(-fprofile-arcs -ftest-coverage)
 157   endif()
 158 endif()
 159
 160 if(NOT $ENV{CFLAGS} STREQUAL "")
 161   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 162   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 163 endif()
 164
 165 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 166   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 167   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 168 endif()
 169
 170 if(NOT $ENV{LDFLAGS} STREQUAL "")
 171   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 172   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 173 endif()
 174
 175 if(MINGW)
 176   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 177   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 178   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 179   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 180   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 181   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 182
 183   # JNI searches for stdcalls
 184   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 185   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 186   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 187   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 188
 189   # Specify the data model that we are using (yeah it may help Java)
 190   if(ARCH_32_BITS)
 191     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 192     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 193   else()
 194     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 195     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 196   endif()
 197 endif()