acmacro/context.m4

   1 dnl AC_CHECK_UCONTEXT: Check whether ucontext are working
   2
   3 dnl Most of the code is stolen from the GNU pth autoconf macros by
   4 dnl Ralf S. Engelschall.
   5 dnl # ``"Reuse an expert's code" is the right
   6 dnl #   advice for most people. But it's a useless
   7 dnl #   advice for the experts writing the code
   8 dnl #   in the first place.'
   9 dnl #               -- Dan J. Bernstein
  10 dnl
  11 dnl OK, you're definitely the expert on this point... :)
  12
  13 dnl ##
  14 dnl ##  Display Configuration Headers
  15 dnl ##
  16 dnl ##  configure.ac:
  17 dnl ##    AC_MSG_PART(<text>)
  18 dnl ##
  19
  20 m4_define(AC_MSG_PART,[dnl
  21 if test ".$enable_subdir" != .yes; then
  22     AC_MSG_RESULT()
  23     AC_MSG_RESULT(${TB}$1:${TN})
  24 fi
  25 ])dnl
  26
  27 dnl ##
  28 dnl ##  Display a message under --verbose
  29 dnl ##
  30 dnl ##  configure.ac:
  31 dnl ##    AC_MSG_VERBOSE(<text>)
  32 dnl ##
  33
  34 m4_define(AC_MSG_VERBOSE,[dnl
  35 if test ".$verbose" = .yes; then
  36     AC_MSG_RESULT([  $1])
  37 fi
  38 ])
  39
  40 dnl ##
  41 dnl ##  Do not display message for a command
  42 dnl ##
  43 dnl ##  configure.ac:
  44 dnl ##    AC_MSG_SILENT(...)
  45 dnl ##
  46
  47 m4_define(AC_FD_TMP, 9)
  48 m4_define(AC_MSG_SILENT,[dnl
  49 exec AC_FD_TMP>&AC_FD_MSG AC_FD_MSG>/dev/null
  50 $1
  51 exec AC_FD_MSG>&AC_FD_TMP AC_FD_TMP>&-
  52 ])
  53
  54 dnl ##
  55 dnl ##  Check for direction of stack growth
  56 dnl ##
  57 dnl ##  configure.ac:
  58 dnl ##    AC_CHECK_STACKGROWTH(<define>)
  59 dnl ##  acconfig.h:
  60 dnl ##    #undef <define>
  61 dnl ##  source.c:
  62 dnl ##    #include "config.h"
  63 dnl ##    #if <define> < 0
  64 dnl ##        ...stack grow down...
  65 dnl ##    #else
  66 dnl ##        ...stack grow up...
  67 dnl ##    #endif
  68 dnl ##
  69
  70 AC_DEFUN([AC_CHECK_STACKGROWTH],[dnl
  71 AC_MSG_CHECKING(for direction of stack growth)
  72 AC_CACHE_VAL(ac_cv_check_stackgrowth, [
  73 cross_compiling=no
  74 AC_TRY_RUN(
  75 changequote(<<, >>)dnl
  76 <<
  77 #include <stdio.h>
  78 #include <stdlib.h>
  79 static int iterate = 10;
  80 static int growsdown(int *x)
  81 {
  82     auto int y;
  83     y = (x > &y);
  84     if (--iterate > 0)
  85         y = growsdown(&y);
  86     if (y != (x > &y))
  87         exit(1);
  88     return y;
  89 }
  90 int main(int argc, char *argv[])
  91 {
  92     FILE *f;
  93     auto int x;
  94     if ((f = fopen("conftestval", "w")) == NULL)
  95         exit(1);
  96     fprintf(f, "%s\n", growsdown(&x) ? "down" : "up");;
  97     fclose(f);
  98     exit(0);
  99 }
 100 >>
 101 changequote([, ])dnl
 102 ,
 103 ac_cv_check_stackgrowth=`cat conftestval`,
 104 ac_cv_check_stackgrowth=down,
 105 ac_cv_check_stackgrowth=down
 106 )dnl
 107 ])dnl
 108 AC_MSG_RESULT([$ac_cv_check_stackgrowth])
 109 if test ".$ac_cv_check_stackgrowth" = ".down"; then
 110     val="-1"
 111 else
 112     val="+1"
 113 fi
 114 AC_DEFINE_UNQUOTED($1, $val, [define for stack growth])
 115 ])
 116
 117 dnl ##
 118 dnl ##  Check whether SVR4/SUSv2 makecontext(2), swapcontext(2) and
 119 dnl ##  friends can be used for user-space context switching
 120 dnl ##
 121 dnl ##  configure.ac:
 122 dnl ##     AC_CHECK_MCSC(<success-action>, <failure-action>)
 123 dnl ##
 124
 125 AC_DEFUN([AC_CHECK_MCSC], [
 126 AC_MSG_CHECKING(for usable SVR4/SUSv2 makecontext(2)/swapcontext(2))
 127 AC_CACHE_VAL(ac_cv_check_mcsc, [
 128 AC_TRY_RUN([
 129
 130 #include <stdio.h>
 131 #include <stdlib.h>
 132 #include <ucontext.h>
 133
 134 ucontext_t uc_child;
 135 ucontext_t uc_main;
 136
 137 void child(void)
 138 {
 139     if (swapcontext(&uc_child, &uc_main) != 0)
 140         exit(2);
 141 }
 142
 143 int main(int argc, char *argv[])
 144 {
 145     FILE *fp;
 146     void *stack;
 147
 148     /* the default is that it fails */
 149     if ((fp = fopen("conftestval", "w")) == NULL)
 150         exit(3);
 151     fprintf(fp, "no\n");
 152     fclose(fp);
 153
 154     /* configure a child user-space context */
 155     if ((stack = malloc(64*1024)) == NULL)
 156         exit(4);
 157     if (getcontext(&uc_child) != 0)
 158         exit(5);
 159     uc_child.uc_link = NULL;
 160     uc_child.uc_stack.ss_sp = (char *)stack+(32*1024);
 161     uc_child.uc_stack.ss_size = 32*1024;
 162     uc_child.uc_stack.ss_flags = 0;
 163     makecontext(&uc_child, child, 0);
 164
 165     /* switch into the user context */
 166     if (swapcontext(&uc_main, &uc_child) != 0)
 167         exit(6);
 168
 169     /* Fine, child came home */
 170     if ((fp = fopen("conftestval", "w")) == NULL)
 171         exit(7);
 172     fprintf(fp, "yes\n");
 173     fclose(fp);
 174
 175     /* die successfully */
 176     exit(0);
 177 }
 178 ],
 179 ac_cv_check_mcsc=`cat conftestval`,
 180 ac_cv_check_mcsc=no,
 181 ac_cv_check_mcsc=no
 182 )dnl
 183 ])dnl
 184 AC_MSG_RESULT([$ac_cv_check_mcsc])
 185 if test ".$ac_cv_check_mcsc" = .yes; then
 186     ifelse([$1], , :, [$1])
 187 else
 188     ifelse([$2], , :, [$2])
 189 fi
 190 ])dnl
 191
 192 dnl ##
 193 dnl ##  Check how stacks have to be setup for the functions
 194 dnl ##  sigstack(2), sigaltstack(2) and makecontext(2).
 195 dnl ##
 196 dnl ##  configure.ac:
 197 dnl ##    AC_CHECK_STACKSETUP(sigstack|sigaltstack|makecontext, <macro-addr>, <macro-size>)
 198 dnl ##  acconfig.h:
 199 dnl ##    #undef HAVE_{SIGSTACK|SIGALTSTACK|MAKECONTEXT}
 200 dnl ##    #undef HAVE_STACK_T
 201 dnl ##  header.h.in:
 202 dnl ##    @<macro-addr>@
 203 dnl ##    @<macro-size>@
 204 dnl ##  source.c:
 205 dnl ##    #include "header.h"
 206 dnl ##    xxx.sp_ss   = <macro-addr>(skaddr, sksize);
 207 dnl ##    xxx.sp_size = <macro-size>(skaddr, sksize);
 208 dnl ##
 209
 210 AC_DEFUN([AC_CHECK_STACKSETUP],[dnl
 211 dnl #   check for consistent usage
 212 ifelse($1,[sigstack],,[
 213 ifelse($1,[sigaltstack],,[
 214 ifelse($1,[makecontext],,[
 215 errprint(__file__:__line__: [AC_CHECK_STACKSETUP: only sigstack, sigaltstack and makecontext supported
 216 ])])])])
 217 dnl #   we require the C compiler and the standard headers
 218 AC_REQUIRE([AC_HEADER_STDC])dnl
 219 dnl #   we at least require the function to check
 220 AC_CHECK_FUNCS($1)
 221 dnl #   sigaltstack on some platforms uses stack_t instead of struct sigaltstack
 222 ifelse($1, sigaltstack, [
 223     AC_ONCE(stacksetup_stack_t, [
 224         AC_CHECK_TYPEDEF(stack_t, signal.h)
 225     ])
 226 ])
 227 dnl #   display processing header
 228 AC_MSG_CHECKING(for stack setup via $1)
 229 dnl #   but cache the whole results
 230 AC_CACHE_VAL(ac_cv_stacksetup_$1,[
 231 if test ".$ac_cv_func_$1" = .no; then
 232     dnl #   no need to check anything when function is already missing
 233     ac_cv_stacksetup_$1="N.A.:/*N.A.*/,/*N.A.*/"
 234 else
 235     dnl #   setup compile environment
 236     OCFLAGS="$CFLAGS"
 237     CFLAGS="$CFLAGS -DTEST_$1"
 238     cross_compiling=no
 239     dnl #   compile and run the test program
 240     AC_TRY_RUN([
 241 #include <stdio.h>
 242 #include <stdlib.h>
 243 #include <string.h>
 244 #if defined(TEST_sigstack) || defined(TEST_sigaltstack)
 245 #include <sys/types.h>
 246 #include <signal.h>
 247 #include <unistd.h>
 248 #endif
 249 #if defined(TEST_makecontext)
 250 #include <ucontext.h>
 251 #endif
 252 union alltypes {
 253     long   l;
 254     double d;
 255     void  *vp;
 256     void (*fp)(void);
 257     char  *cp;
 258 };
 259 static volatile char *handler_addr = (char *)0xDEAD;
 260 #if defined(TEST_sigstack) || defined(TEST_sigaltstack)
 261 static volatile int handler_done = 0;
 262 void handler(int sig)
 263 {
 264     char garbage[1024];
 265     int i;
 266     auto int dummy;
 267     for (i = 0; i < 1024; i++)
 268         garbage[i] = 'X';
 269     handler_addr = (char *)&dummy;
 270     handler_done = 1;
 271     return;
 272 }
 273 #endif
 274 #if defined(TEST_makecontext)
 275 static ucontext_t uc_handler;
 276 static ucontext_t uc_main;
 277 void handler(void)
 278 {
 279     char garbage[1024];
 280     int i;
 281     auto int dummy;
 282     for (i = 0; i < 1024; i++)
 283         garbage[i] = 'X';
 284     handler_addr = (char *)&dummy;
 285     swapcontext(&uc_handler, &uc_main);
 286     return;
 287 }
 288 #endif
 289 int main(int argc, char *argv[])
 290 {
 291     FILE *f;
 292     char *skaddr;
 293     char *skbuf;
 294     int sksize;
 295     char result[1024];
 296     int i;
 297     sksize = 32768;
 298     skbuf = (char *)malloc(sksize*2+2*sizeof(union alltypes));
 299     if (skbuf == NULL)
 300         exit(1);
 301     for (i = 0; i < sksize*2+2*sizeof(union alltypes); i++)
 302         skbuf[i] = 'A';
 303     skaddr = skbuf+sizeof(union alltypes);
 304 #if defined(TEST_sigstack) || defined(TEST_sigaltstack)
 305     {
 306         struct sigaction sa;
 307 #if defined(TEST_sigstack)
 308         struct sigstack ss;
 309 #elif defined(TEST_sigaltstack) && defined(HAVE_STACK_T)
 310         stack_t ss;
 311 #else
 312         struct sigaltstack ss;
 313 #endif
 314 #if defined(TEST_sigstack)
 315         ss.ss_sp      = (void *)(skaddr + sksize);
 316         ss.ss_onstack = 0;
 317         if (sigstack(&ss, NULL) < 0)
 318             exit(1);
 319 #elif defined(TEST_sigaltstack)
 320         ss.ss_sp    = (void *)(skaddr + sksize);
 321         ss.ss_size  = sksize;
 322         ss.ss_flags = 0;
 323         if (sigaltstack(&ss, NULL) < 0)
 324             exit(1);
 325 #endif
 326         memset((void *)&sa, 0, sizeof(struct sigaction));
 327         sa.sa_handler = handler;
 328         sa.sa_flags = SA_ONSTACK;
 329         sigemptyset(&sa.sa_mask);
 330         sigaction(SIGUSR1, &sa, NULL);
 331         kill(getpid(), SIGUSR1);
 332         while (!handler_done)
 333             /*nop*/;
 334     }
 335 #endif
 336 #if defined(TEST_makecontext)
 337     {
 338         if (getcontext(&uc_handler) != 0)
 339             exit(1);
 340         uc_handler.uc_link = NULL;
 341         uc_handler.uc_stack.ss_sp    = (void *)(skaddr + sksize);
 342         uc_handler.uc_stack.ss_size  = sksize;
 343         uc_handler.uc_stack.ss_flags = 0;
 344         makecontext(&uc_handler, handler, 0);
 345         swapcontext(&uc_main, &uc_handler);
 346     }
 347 #endif
 348     if (handler_addr == (char *)0xDEAD)
 349         exit(1);
 350     if (handler_addr < skaddr+sksize) {
 351         /* stack was placed into lower area */
 352         if (*(skaddr+sksize) != 'A')
 353              sprintf(result, "(skaddr)+(sksize)-%d,(sksize)-%d",
 354                      sizeof(union alltypes), sizeof(union alltypes));
 355         else
 356              strcpy(result, "(skaddr)+(sksize),(sksize)");
 357     }
 358     else {
 359         /* stack was placed into higher area */
 360         if (*(skaddr+sksize*2) != 'A')
 361             sprintf(result, "(skaddr),(sksize)-%d", sizeof(union alltypes));
 362         else
 363             strcpy(result, "(skaddr),(sksize)");
 364     }
 365     if ((f = fopen("conftestval", "w")) == NULL)
 366         exit(1);
 367     fprintf(f, "%s\n", result);
 368     fclose(f);
 369     exit(0);
 370 }
 371 ],[
 372 dnl #   test successully passed
 373 ac_cv_stacksetup_$1=`cat conftestval`
 374 ac_cv_stacksetup_$1="ok:$ac_cv_stacksetup_$1"
 375 ],[
 376 dnl #   test failed
 377 ac_cv_stacksetup_$1='guessed:(skaddr),(sksize)'
 378 ],[
 379 dnl #   cross-platform => failed
 380 ac_cv_stacksetup_$1='guessed:(skaddr),(sksize)'
 381 ])
 382 dnl #   restore original compile environment
 383 CFLAGS="$OCFLAGS"
 384 ])dnl
 385 fi
 386 dnl #   extract result ingredients of single cached result value
 387 type=`echo $ac_cv_stacksetup_$1 | sed -e 's;:.*$;;'`
 388 addr=`echo $ac_cv_stacksetup_$1 | sed -e 's;^.*:;;' -e 's;,.*$;;'`
 389 size=`echo $ac_cv_stacksetup_$1 | sed -e 's;^.*:;;' -e 's;^.*,;;'`
 390 dnl #   export result ingredients
 391 $2="#define $2(skaddr,sksize) ($addr)"
 392 $3="#define $3(skaddr,sksize) ($size)"
 393 AC_SUBST($2)dnl
 394 AC_SUBST($3)dnl
 395 dnl #   display result indicator
 396 AC_MSG_RESULT([$type])
 397 dnl #   display results in detail
 398 AC_MSG_VERBOSE([$]$2)
 399 AC_MSG_VERBOSE([$]$3)
 400 ])