Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
SURF: Kill the SDP model
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.3.2-svn],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision: 6267 $)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AC_PROG_CXX
21 AM_PROG_GCJ
22
23 AM_INIT_AUTOMAKE([gnu -Wno-portability])
24 AC_CONFIG_MACRO_DIR(acmacro) 
25 ACLOCAL="$ACLOCAL -I acmacro"
26
27 dnl Next few lines is a hack to prevent libtool checking for F77
28 m4_undefine([AC_PROG_F77])
29 m4_defun([AC_PROG_F77],[])
30
31 dnl We do build a proper DLL when using win32
32 AC_LIBTOOL_WIN32_DLL
33 AC_PROG_LIBTOOL
34
35 ###############
36 ## SVN version check
37 ##
38 if test -e .svn && cat $VERSION | grep -q svn; then
39   VERSION="$VERSION-r`svnversion`"
40   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
41   PACKAGE_STRING="PACKAGE_STRING r`svnversion`"  
42 fi
43
44 ###############
45 ## System checks
46 ##
47 SG_CONFIGURE_PART([System checks...])
48 AC_PROG_CC(xlC gcc cc)
49 AM_SANITY_CHECK
50 AC_PROG_MAKE_SET
51 AC_CHECK_PRINTF_NULL
52 AC_CHECK_VA_COPY
53
54 # Checks for header files.
55 AC_HEADER_STDC
56 AC_HEADER_TIME
57 AC_CHECK_HEADERS([sys/socket.h \
58                   sys/stat.h \
59                   windows.h winsock.h winsock2.h \
60                   sys/time.h \
61                   errno.h unistd.h \
62                   execinfo.h\
63                   signal.h ])
64 AC_CHECK_FUNCS([gettimeofday usleep \
65                 getdtablesize \
66                 sysconf\
67                 readv\
68                 popen\
69                 signal\
70                 getline])
71                 
72 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
73 AC_FUNC_SNPRINTF
74 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
75 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
76 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
77
78 # Checks for typedefs, structures, and compiler characteristics.
79 AC_C_CONST
80 AC_C_INLINE
81 AC_TYPE_SIZE_T
82
83 ###################################
84 ## SimGrid and GRAS specific checks
85 ##
86
87 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
88 # Check architecture signature begin
89 GRAS_ARCH
90 # Check architecture signature end
91 GRAS_CHECK_STRUCT_COMPACTION
92
93
94 dnl ##
95 dnl ##  CONTEXT IMPLEMENTATION
96 dnl ##
97
98 SG_CONFIGURE_PART([Checking threads, contexts or assimilated...])
99
100 dnl #
101 dnl #  1. determine possibilities
102 dnl #
103
104 dnl #  check for MCSC method (ucontexts)
105 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
106
107 dnl #  check for pthread method
108 AC_CHECK_HEADERS([pthread.h])
109 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
110
111 if test x$pthread = xyes ; then
112   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
113   if test ${HAVE_SEM_INIT} = yes ; then
114      AC_MSG_CHECKING(if sem_init is compilable)
115      AC_TRY_COMPILE([#include <semaphore.h>],
116                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
117      if test ${HAVE_SEM_INIT} = yes ; then
118         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
119         AC_MSG_RESULT(yes)
120      else
121         AC_MSG_RESULT(no)
122      fi
123   fi
124   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
125   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
126      AC_MSG_CHECKING(if sem_timedwait is compilable)
127      AC_TRY_COMPILE([#include <semaphore.h>],
128                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
129      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
130         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
131         AC_MSG_RESULT(yes)
132      else
133         AC_MSG_RESULT(no)
134      fi
135   fi
136
137   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
138   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
139      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
140      AC_TRY_COMPILE([#include <pthread.h>],
141                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
142      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
143         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
144         AC_MSG_RESULT(yes)
145      else
146         AC_MSG_RESULT(no)
147      fi
148   fi
149 fi
150
151 dnl #
152 dnl #  2. make a general decision
153 dnl #
154
155 if test ".$mcsc" = .yes; then
156    # ucontext found
157    mcsc=yes
158 elif test ".$pthread" = .yes; then
159    # ucontext not found, but pthread found
160    pthread=yes
161 else
162     ac_header=windows.h
163     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
164     if test `eval echo '${'$as_ac_Header'}'` = yes; then
165       windows_context=yes
166     else
167       AC_ERROR([no appropriate backend found])
168     fi
169 fi
170 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
171
172
173 dnl #
174 dnl #  3. allow decision to be overridden by user
175 dnl #
176
177 AC_MSG_CHECKING(what kind of backend should we use)
178
179 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
180 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
181
182 AC_ARG_WITH(context,
183   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
184   with_context=auto)
185
186 if test "x$with_context$mcsc" = "xucontextno" ; then 
187   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
188 fi
189
190 case $with_context in
191  ucontext) ;;
192  pthread) ;;
193  pthreads) ;;
194  windows) ;;
195  auto) with_context=ucontext;;
196  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
197 esac
198
199 if test "x$with_context" = "xucontext" ; then
200   if test ".$mcsc" = .yes; then
201     AC_MSG_RESULT(found working ucontext. Great!)
202     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
203     AC_CHECK_HEADERS([valgrind/valgrind.h])
204   else
205     if test ".$windows_context" = .yes ; then
206       AC_MSG_RESULT(use windows context portability layer.)
207       with_context=windows
208     else
209       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
210       with_context=pthread
211     fi
212   fi
213 fi
214
215 if test "x$with_context" = "xpthread"; then
216   if test x$pthread != xyes ; then # reuse previous checks
217     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
218   fi
219   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
220   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
221 fi
222 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
223
224 dnl #
225 dnl #  4. determine a few additional details
226 dnl #
227
228 if test "x$with_context" = "xucontext" ; then
229 dnl #  direction of stack grow
230   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
231   if test ".$ac_cv_check_stackgrowth" = ".down"; then
232       PTH_STACK_GROWTH="down"
233   else
234       PTH_STACK_GROWTH="up"
235   fi
236   AC_SUBST(PTH_STACK_GROWTH)
237   
238   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
239 fi
240
241 #########################################
242 ## Check for libraries extra-dependencies
243 ##
244
245 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
246
247 SIMGRID_DEP=""
248 SMPI_DEP=""
249 GRAS_DEP=""
250
251 if test xpthread=xyes ; then 
252   # if the pthreads are usable
253   if test "x$with_context" = "xpthread" ; then
254     # if we use them to implement the xbt_context
255     SIMGRID_DEP="-lpthread"
256   fi
257   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
258   if test "x$with_context" != "xwindows" ; then
259     GRAS_DEP="-lpthread"
260   fi
261 fi
262 AC_SEARCH_LIBS([connect],[socket],[],[],[]) # need -lsocket on solaris
263
264 #########################################
265 ## Build optional modules (gtnets)
266 ##
267 gtnets=no
268 AC_ARG_WITH(gtnets,
269   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
270   gtnets_path="$withval",gtnets_path="no")
271 if test "x$gtnets_path" = "xno" ; then
272   AC_MSG_RESULT(Eventually you will come to GTNetS.)
273 else  
274   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
275   AC_MSG_CHECKING(for gtnets)
276   AC_LANG_PUSH([C++])  
277   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
278   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
279   LDFLAGS_SAV=$LDFLAGS  
280   CPPFLAGS_SAV=$CPPFLAGS
281   CPPFLAGS+=$GTNETS_CPPFLAGS
282   LDFLAGS+=$GTNETS_LDFLAGS
283   AC_TRY_LINK([ #include <simulator.h>
284               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
285   CPPFLAGS=$CPPFLAGS_SAV
286   LDFLAGS=$LDFLAGS_SAV
287   AC_LANG_POP([C++])  
288 fi
289
290 if test "x$gtnets" = "xyes" ; then
291   AC_MSG_RESULT(Enabling GTNETS support.)
292   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
293   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
294   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
295 fi
296 AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
297
298
299
300 AC_SUBST([SIMGRID_DEP])
301 AC_SUBST([SMPI_DEP])
302
303 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
304 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
305
306 AC_MSG_CHECKING(for extra dependencies of libgras)
307 case $host_os in
308   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
309             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
310             AC_DEFINE(CONTEXT_THREADS,1);;
311 esac
312
313
314
315 if test "x$GRAS_DEP" = x; then 
316    AC_MSG_RESULT(none)
317 else
318    AC_MSG_RESULT($GRAS_DEP)
319 fi
320 AC_SUBST([GRAS_DEP])
321
322 ##############################################
323 ## Enhance maintainer mode and SUBST variables
324 ## (must be placed after any compilation tests since our overprotective flags
325 ##  let some tests fail)
326
327 # Check whether we are doing a regular build or a GRAMINE (minimal) one
328 # Next line is modified by sed when building gramine source tree
329 gramine_mode=no
330 if test x$gramine_mode = xyes
331 then
332   USE_MAINTAINER_MODE=no
333 fi
334 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
335
336
337 AM_MAINTAINER_MODE
338 if test x$USE_MAINTAINER_MODE = xyes 
339 then
340    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
341    force_compile_warnings=yes   
342 fi
343 SG_COMPILE_FLAGS
344
345 AC_SUBST([CFLAGS])
346 AC_SUBST([CPPFLAGS])
347 AC_SUBST([LDFLAGS])
348 AC_SUBST([AM_CPPFLAGS])
349 AC_SUBST([abs_builddir])
350 AC_SUBST([abs_srcdir])
351 AC_SUBST([abs_top_builddir])
352 AC_SUBST([abs_top_srcdir])
353
354 ##############################################
355 ## Specific mode for build daemons.
356 ## (they compile the SVN without having the autotools installed)
357 AC_ARG_ENABLE(botbuild,
358               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
359               botbuild=$enableval,botbuild=no)
360 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
361
362 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
363   echo "ERROR: "
364   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
365   echo "ERROR: For this, just call configure this way:"
366   echo "ERROR:"
367   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
368   echo "ERROR:"
369   exit 1
370 fi
371
372
373 SG_CONFIGURE_PART(Checking Java bindings...)
374 # Java cruft
375 AC_ARG_ENABLE(java,
376               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
377               disable_java=$enableval,disable_java=yes)
378 if test "x$disable_java" != "xyes" ; then
379    use_java="disabled by user"
380 else
381   AC_PATH_PROG([JAVAC], [javac], `which javac`)
382   AC_PATH_PROG([JAVA],  [java] , `which java`)
383   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
384   AC_CHECK_HEADERS(jni.h)
385   if test -n "$JAVAC" && test -n "$JAVA" && test -n "$JAR" && test "x$ac_cv_header_jni_h" = "xyes" ; then
386      use_java="yes"
387      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
388   else   
389      use_java="no"
390   fi
391 fi
392 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
393 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
394
395
396 #####################
397 ## Check for programs
398 ##
399
400 SG_CONFIGURE_PART(Checking programs...)
401 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
402 WARNING="This file is generated, do not edit"
403 AC_SUBST(WARNING)
404
405
406 # Can we rebuild the parsers?
407 # We really want flex and refuse other lex. So, the parser is portable and
408 # does not induce extra lib dependency
409 AC_PROG_FLEX(2.5.30)
410                 
411 # Can we rebuild the xml-lexers from the XML specification?
412 # if not, simply touch the flex source files (which are distributed in
413 #  tarballs even if generated by flexml) and hope for the best.
414 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
415 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
416
417 # Check for doxygen when in maintainer mode which is helpful to build doc & dist
418 AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
419 AM_CONDITIONAL(HAVE_DOXYGEN,test x$DOXYGEN != x)
420
421 # Can we extract really usable backtraces? (also need the popen function)
422 AC_PATH_PROG(ADDR2LINE, addr2line)
423 if test x$ADDR2LINE != x ; then
424   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
425 fi
426
427 AC_SUBST(ac_configure_args)
428 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
429 # Can we make status line about the compilation result?
430 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
431 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
432 AC_SUBST(build_id)
433
434 ###################
435 ## Makes the output
436 ##
437
438
439 #
440 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
441 #  src/amok/Makefile
442
443 SG_CONFIGURE_PART(Generating files...)
444
445 # Core of the libraries
446
447 AC_CONFIG_FILES([
448   Makefile
449   include/Makefile
450   src/Makefile
451   src/context_sysv_config.h
452 ])
453
454 # Tools being embeeded in gramine (stub generator)
455 AC_CONFIG_FILES([
456   tools/Makefile
457     tools/gras/Makefile
458     tools/tesh/Makefile
459 ])
460 #    tools/tesh2/Makefile
461
462
463 # GRAMINE_CUT_BEGIN
464
465 # Tools NOT being embeeded in gramine
466 AC_CONFIG_FILES([
467   tools/graspe-slave
468 ],[
469     for file in                                                 \
470      tools/graspe-slave           tools/graspe-master           \
471      checkall                     examples/java/runtest         \
472     ; do                                                        \
473       test -e $file && chmod +x $file;                          \
474     done
475 ])
476
477 # Testsuite
478
479 AC_CONFIG_FILES([  
480   testsuite/Makefile
481   testsuite/run_tests    
482 ],[
483     for file in                                                 \
484      testsuite/run_tests                                        \
485     ; do                                                        \
486       test -e $file && chmod +x $file;                          \
487     done
488 ])
489
490 # Teshsuite (testsuite using tesh)
491 AC_CONFIG_FILES([  
492   teshsuite/Makefile
493 ])
494
495 # Documentation
496 AC_CONFIG_FILES([
497   doc/Makefile
498   doc/Doxyfile
499 ])
500
501 # Examples
502
503 #      examples/gras/p2p/Makefile
504 #      examples/gras/p2p/chord/Makefile
505 #      examples/gras/p2p/can/Makefile
506
507 AC_CONFIG_FILES([
508     examples/java/Makefile
509       examples/java/basic/Makefile
510       examples/java/comm_time/Makefile
511       examples/java/suspend/Makefile
512       examples/java/ping_pong/Makefile
513 ])
514
515 AC_CONFIG_FILES([
516   examples/Makefile 
517     examples/msg/Makefile
518     examples/simdag/Makefile
519     examples/gras/Makefile
520       examples/gras/ping/Makefile   
521       examples/gras/rpc/Makefile
522       examples/gras/spawn/Makefile
523       examples/gras/synchro/Makefile
524       examples/gras/timer/Makefile
525       examples/gras/properties/Makefile
526       examples/gras/chrono/Makefile
527       examples/gras/mutual_exclusion/simple_token/Makefile
528       examples/gras/mmrpc/Makefile
529       examples/gras/pmm/Makefile
530       examples/gras/all2all/Makefile
531     examples/amok/Makefile       
532     examples/smpi/Makefile       
533 ])
534
535 AC_CONFIG_FILES([
536   src/smpi/smpicc
537   src/smpi/smpirun
538 ],[
539     for file in                                                 \
540       src/smpi/smpicc                                           \
541       src/smpi/smpirun                                          \
542     ; do                                                        \
543       test -e $file && chmod +x $file;                          \
544     done
545 ])
546
547 # GRAMINE_CUT_END
548
549 AC_OUTPUT
550
551 echo "
552
553 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
554
555         Compiler:        ${CC} (version: ${GCC_VERSION})
556         
557         CFlags:          ${CFLAGS}
558         CPPFlags:        ${CPPFLAGS}
559         LDFlags:         ${LDFLAGS}
560
561         Context backend: ${with_context}
562         Compile Java:    ${use_java}
563         
564         Maintainer mode: ${USE_MAINTAINER_MODE}
565
566 "
567 if test x$botbuild = xyes ; then
568   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
569   echo
570 fi
571
572 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
573   echo "WARNING: "
574   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
575   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
576   echo "WARNING:"
577   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
578   echo "WARNING:"
579 fi
580
581 echo $build_id > stamp.configure
582
583 exit 0;