configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15 AM_PROG_GCJ
  16
  17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  18 AC_CONFIG_MACRO_DIR(acmacro)
  19 ACLOCAL="$ACLOCAL -I acmacro"
  20
  21 dnl Next few lines is a hack to prevent libtool checking for F77
  22 m4_undefine([AC_PROG_F77])
  23 m4_defun([AC_PROG_F77],[])
  24
  25 dnl We do build a proper DLL when using win32
  26 AC_LIBTOOL_WIN32_DLL
  27 AC_PROG_LIBTOOL
  28
  29 ###############
  30 ## System checks
  31 ##
  32 SG_CONFIGURE_PART([System checks...])
  33 AC_PROG_CC(xlC gcc cc)
  34 AM_SANITY_CHECK
  35 AC_PROG_MAKE_SET
  36 AC_CHECK_PRINTF_NULL
  37 AC_CHECK_VA_COPY
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_HEADER_TIME
  42 AC_CHECK_HEADERS([sys/socket.h \
  43                   sys/stat.h \
  44                   windows.h winsock.h winsock2.h \
  45                   sys/time.h \
  46                   errno.h unistd.h \
  47                   execinfo.h\
  48                   signal.h ])
  49 AC_CHECK_FUNCS([gettimeofday usleep \
  50                 getdtablesize \
  51                 sysconf\
  52                 readv\
  53                 popen\
  54                 signal\
  55                 getline])
  56
  57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  58 AC_FUNC_SNPRINTF
  59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_TYPE_SIZE_T
  67
  68 ###################################
  69 ## SimGrid and GRAS specific checks
  70 ##
  71
  72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  73 # Check architecture signature begin
  74 GRAS_ARCH
  75 # Check architecture signature end
  76 GRAS_CHECK_STRUCT_COMPACTION
  77
  78
  79 dnl ##
  80 dnl ##  CONTEXT IMPLEMENTATION
  81 dnl ##
  82
  83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  84
  85 dnl #
  86 dnl #  1. determine possibilities
  87 dnl #
  88
  89 dnl #  check for MCSC method
  90 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  91
  92 dnl #  check for pthread method
  93 AC_CHECK_HEADERS([pthread.h])
  94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  95
  96 dnl #
  97 dnl #  2. make a general decision
  98 dnl #
  99
 100 if test ".$mcsc" = .yes; then
 101    mcsc=yes
 102 elif test ".$pthread" = .yes; then
 103    pthread=yes
 104 else
 105     ac_header=windows.h
 106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 108       windows_context=yes
 109     else
 110       AC_ERROR([no appropriate backend found])
 111     fi
 112 fi
 113
 114 dnl #
 115 dnl #  3. allow decision to be overridden by user
 116 dnl #
 117
 118 AC_MSG_CHECKING(what kind of backend should we use)
 119
 120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126
 127 if test "x$with_context$mcsc" = "xucontextno" ; then
 128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 129 fi
 130
 131 case $with_context in
 132  ucontext) ;;
 133  pthread) ;;
 134  pthreads) ;;
 135  windows) ;;
 136  auto) with_context=ucontext;;
 137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 138 esac
 139
 140 if test "x$with_context" = "xucontext" ; then
 141   if test ".$mcsc" = .yes; then
 142     AC_MSG_RESULT(found working ucontext. Great!)
 143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 144   else
 145     if test ".$windows_context" = .yes ; then
 146       AC_MSG_RESULT(use windows context portability layer.)
 147       with_context=windows
 148     else
 149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 150       with_context=pthread
 151     fi
 152   fi
 153 fi
 154
 155 if test "x$with_context" = "xpthreads"; then
 156   with_context=pthread
 157 fi
 158 if test "x$with_context" = "xpthread"; then
 159   AC_CHECK_HEADERS([pthread.h])
 160   AC_CHECK_LIB(pthread,pthread_create,,
 161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 163   AC_MSG_RESULT(You have pthreads. Let's use them.)
 164 fi
 165
 166 dnl #
 167 dnl #  4. determine a few additional details
 168 dnl #
 169
 170 if test "x$with_context" = "xucontext" ; then
 171 dnl #  direction of stack grow
 172   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 173   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 174       PTH_STACK_GROWTH="down"
 175   else
 176       PTH_STACK_GROWTH="up"
 177   fi
 178   AC_SUBST(PTH_STACK_GROWTH)
 179
 180   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 181 fi
 182
 183 #########################################
 184 ## Check for libraries extra-dependencies
 185 ##
 186
 187 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 188
 189 SIMGRID_DEP=""
 190 GRAS_DEP=""
 191
 192 if test xpthread=xyes ; then
 193   # if the pthreads are usable
 194   if test "x$with_context" = "xpthread" ; then
 195     # if we use them to implement the xbt_context
 196     SIMGRID_DEP="-lpthread"
 197   fi
 198   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 199   if test "x$with_context" != "xwindows" ; then
 200     GRAS_DEP="-lpthread"
 201   fi
 202 fi
 203
 204
 205 #########################################
 206 ## Build optional modules (gtnets)
 207 ##
 208 gtnets=no
 209 AC_ARG_WITH(gtnets,
 210   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 211   gtnets_path="$withval",gtnets_path="no")
 212 if test "x$gtnets_path" = "xno" ; then
 213   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 214 else
 215   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****)
 216   AC_MSG_CHECKING(for gtnets)
 217 #  AC_CHECK_LIB(gtnets,Simulator.RunUntilNextCompletion,gtnets=yes, gtnets=no,-L$gtnets_path/lib)
 218   AX_CXX_CHECK_LIB(gtnets,[Simulator::RunUntilNextCompletion],gtnets=yes, gtnets=no,-L$gtnets_path/lib)
 219
 220   if test "x$gtnets" = xyes ; then
 221     GTNETS_CFLAGS=-I$gtnets_path/include
 222     AC_SUBST([GTNETS_CFLAGS])
 223     GTNETS_LDFLAGS=-L$gtnets_path/lib
 224     AC_SUBST([GTNETS_LDFLAGS])
 225     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
 226     AC_MSG_RESULT(Found working gtnets library.)
 227     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
 228   else
 229     AC_MSG_RESULT(Could not find any working gtnets library.)
 230   fi
 231 fi
 232 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
 233
 234 #########################################
 235 ## Build optional modules (csdp)
 236 ##
 237 csdp=no
 238 AC_ARG_WITH(csdp,
 239   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, ie not using csdp)]),
 240   csdp_path="$withval",csdp_path="no")
 241 if test "x$csdp_path" = "xno" ; then
 242   AC_MSG_RESULT(Eventually you will come to csdp.)
 243 else
 244   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not ****)
 245   AC_MSG_CHECKING(for csdp)
 246   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,-L$csdp_path/lib -llapack -lblas -lm)
 247   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no,-I$csdp_path/include -I$csdp_path/include/csdp)
 248
 249   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
 250      csdp=yes;
 251   else
 252      csdp=no;
 253   fi
 254   if test "x$csdp" = xyes; then
 255     CSDP_CFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
 256     AC_SUBST([CSDP_CFLAGS])
 257     CSDP_LDFLAGS="-L$csdp_path/lib"
 258     AC_SUBST([CSDP_LDFLAGS])
 259     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS -lsdp -llapack -lblas -lm"
 260     AC_MSG_RESULT(Found working sdp library.)
 261     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 262   else
 263     AC_MSG_RESULT(Could not find any working sdp library.)
 264   fi;
 265 fi
 266 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 267
 268 AC_SUBST([SIMGRID_DEP])
 269
 270 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 271 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 272
 273 AC_MSG_CHECKING(for extra dependencies of libgras)
 274 case $host_os in
 275   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 276             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 277             AC_DEFINE(CONTEXT_THREADS,1);;
 278 esac
 279
 280 if test "x$GRAS_DEP" = x; then
 281    AC_MSG_RESULT(none)
 282 else
 283    AC_MSG_RESULT($GRAS_DEP)
 284 fi
 285 AC_SUBST([GRAS_DEP])
 286
 287 ##############################################
 288 ## Enhance maintainer mode and SUBST variables
 289 ## (must be placed after any compilation tests since our overprotective flags
 290 ##  let some tests fail)
 291
 292 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 293 # Next line is modified by sed when building gramine source tree
 294 gramine_mode=no
 295 if test x$gramine_mode = xyes
 296 then
 297   USE_MAINTAINER_MODE=no
 298 fi
 299 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 300
 301
 302 AM_MAINTAINER_MODE
 303 if test x$USE_MAINTAINER_MODE = xyes
 304 then
 305    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 306    enable_compile_warnings=yes
 307 fi
 308 SG_COMPILE_FLAGS
 309
 310 AC_SUBST(CFLAGS)
 311 AC_SUBST(CPPFLAGS)
 312 AC_SUBST(LDFLAGS)
 313 AC_SUBST([abs_builddir])
 314 AC_SUBST([abs_srcdir])
 315 AC_SUBST([abs_top_builddir])
 316 AC_SUBST([abs_top_srcdir])
 317
 318
 319
 320 SG_CONFIGURE_PART(Check for Java bindings...)
 321 # Java cruft
 322 AC_ARG_ENABLE(java,
 323               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 324               want_java=$enableval,want_java=yes)
 325 if test "x$want_java" != "xyes" ; then
 326    AC_MSG_CHECKING(whether to compile java bindings)
 327    AC_MSG_RESULT(disabled by user)
 328    use_java="disabled by user"
 329 else
 330   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 331   AC_PATH_PROG([JAVA],  [java] , `which java`)
 332   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 333   AC_CHECK_HEADERS(jni.h)
 334   AC_MSG_CHECKING(whether to compile java bindings)
 335   if test -n "$JAVAC"   \
 336      && test -n "$JAVA" \
 337      && test -n "$JAR"  \
 338      && test "x$ac_cv_header_jni_h" = "xyes" ; then
 339
 340      use_java="yes"
 341   else
 342      use_java="no"
 343   fi
 344   AC_MSG_RESULT($use_java)
 345 fi
 346 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 347
 348 #####################
 349 ## Check for programs
 350 ##
 351
 352 SG_CONFIGURE_PART(Check for programs...)
 353 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 354 WARNING="This file is generated, do not edit"
 355 AC_SUBST(WARNING)
 356
 357
 358 # Can we rebuild the parsers?
 359 # We really want flex and refuse other lex. So, the parser is portable and
 360 # does not induce extra lib dependency
 361 AC_PROG_FLEX(2.5.30)
 362
 363 # Can we rebuild the xml-lexers from the XML specification?
 364 # if not, simply touch the flex source files (which are distributed in
 365 #  tarballs even if generated by flexml) and hope for the best.
 366 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 367 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 368
 369 if test x$USE_MAINTAINER_MODE = xyes
 370 then
 371    # Check for doxygen when in maintainer mode since dist* targets fail
 372    # without it
 373    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 374    if test x$DOXYGEN = x ; then
 375      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 376    fi
 377 fi
 378
 379 # Can we extract really usable backtraces? (also need the popen function)
 380 AC_PATH_PROG(ADDR2LINE, addr2line)
 381 if test x$ADDR2LINE != x ; then
 382   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 383 fi
 384
 385 AC_SUBST(ac_configure_args)
 386 # Can we make status line about the compilation result?
 387 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 388 if test x$MD5SUM != xno ; then
 389   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 390                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 391 else
 392   build_version="no_md5sum_binary"
 393 fi
 394 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 395 AC_SUBST(build_id)
 396
 397 ###################
 398 ## Makes the output
 399 ##
 400
 401
 402 #
 403 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 404 #  src/amok/Makefile
 405
 406 SG_CONFIGURE_PART(Generating files...)
 407
 408 # Core of the libraries
 409
 410 AC_CONFIG_FILES([
 411   Makefile
 412   include/Makefile
 413   src/Makefile
 414   src/ucontext_stack.h
 415 ])
 416
 417 # Tools being embeeded in gramine (stub generator)
 418 AC_CONFIG_FILES([
 419   tools/Makefile
 420     tools/gras/Makefile
 421     tools/tesh/Makefile
 422 ])
 423
 424
 425 # GRAMINE_CUT_BEGIN
 426
 427 # Tools NOT being embeeded in gramine
 428 AC_CONFIG_FILES([
 429   tools/graspe-slave
 430 ],[
 431     for file in                                                 \
 432      tools/graspe-slave           tools/graspe-master           \
 433     ; do                                                        \
 434       test -e $file && chmod +x $file;                          \
 435     done
 436 ])
 437
 438 # Testsuite
 439
 440 AC_CONFIG_FILES([
 441   testsuite/Makefile
 442   testsuite/run_tests
 443   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 444 ],[
 445     for file in                                                 \
 446      testsuite/run_tests                                        \
 447      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 448     ; do                                                        \
 449       test -e $file && chmod +x $file;                          \
 450     done
 451 ])
 452
 453 # Documentation
 454 AC_CONFIG_FILES([
 455   doc/Makefile
 456   doc/Doxyfile
 457 ])
 458
 459 # Examples
 460
 461 #      examples/gras/p2p/Makefile
 462 #      examples/gras/p2p/chord/Makefile
 463 #      examples/gras/p2p/can/Makefile
 464
 465 if test "x$use_java" = "xyes" ; then
 466 AC_CONFIG_FILES([
 467     examples/java/Makefile
 468       examples/java/basic/Makefile
 469       examples/java/comm_time/Makefile
 470       examples/java/suspend/Makefile
 471       examples/java/ping_pong/Makefile
 472 ])
 473 fi
 474
 475 AC_CONFIG_FILES([
 476   examples/Makefile
 477     examples/msg/Makefile
 478     examples/simdag/Makefile        examples/simdag/test_simdag
 479     examples/gras/Makefile
 480       examples/gras/ping/Makefile
 481       examples/gras/rpc/Makefile
 482       examples/gras/spawn/Makefile
 483       examples/gras/synchro/Makefile
 484       examples/gras/timer/Makefile
 485       examples/gras/chrono/Makefile
 486       examples/gras/mutual_exclusion/simple_token/Makefile
 487       examples/gras/mmrpc/Makefile
 488       examples/gras/pmm/Makefile
 489       examples/gras/all2all/Makefile
 490     examples/amok/Makefile
 491       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 492       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 493 ],[
 494     for file in                                                 \
 495      \
 496      examples/simdag/test_simdag                                \
 497      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 498      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 499     ; do                                                        \
 500       test -e $file && chmod +x $file;                          \
 501     done
 502 ])
 503
 504
 505 # GRAMINE_CUT_END
 506
 507 AC_OUTPUT
 508
 509 echo "
 510
 511 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 512
 513         Compiler:        ${CC} (version: ${GCC_VERSION})
 514
 515         CFlags:          ${CFLAGS}
 516         CPPFlags:        ${CPPFLAGS}
 517         LDFlags:         ${LDFLAGS}
 518
 519         Context backend: ${with_context}
 520 "
 521
 522 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 523   echo "WARNING:"
 524   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 525   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 526   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 527   echo "WARNING:"
 528   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 529   echo "WARNING:"
 530 fi
 531 echo $build_id > stamp.configure
 532
 533 exit 0;