configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15 AM_PROG_GCJ
  16
  17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  18 AC_CONFIG_MACRO_DIR(acmacro)
  19 ACLOCAL="$ACLOCAL -I acmacro"
  20
  21 dnl Next few lines is a hack to prevent libtool checking for F77
  22 m4_undefine([AC_PROG_F77])
  23 m4_defun([AC_PROG_F77],[])
  24
  25 dnl We do build a proper DLL when using win32
  26 AC_LIBTOOL_WIN32_DLL
  27 AC_PROG_LIBTOOL
  28
  29 ###############
  30 ## System checks
  31 ##
  32 SG_CONFIGURE_PART([System checks...])
  33 AC_PROG_CC(xlC gcc cc)
  34 AM_SANITY_CHECK
  35 AC_PROG_MAKE_SET
  36 AC_CHECK_PRINTF_NULL
  37 AC_CHECK_VA_COPY
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_HEADER_TIME
  42 AC_CHECK_HEADERS([sys/socket.h \
  43                   sys/stat.h \
  44                   windows.h winsock.h winsock2.h \
  45                   sys/time.h \
  46                   errno.h unistd.h \
  47                   execinfo.h\
  48                   signal.h ])
  49 AC_CHECK_FUNCS([gettimeofday usleep \
  50                 getdtablesize \
  51                 sysconf\
  52                 readv\
  53                 popen\
  54                 signal\
  55                 getline])
  56
  57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  58 AC_FUNC_SNPRINTF
  59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_TYPE_SIZE_T
  67
  68 ###################################
  69 ## SimGrid and GRAS specific checks
  70 ##
  71
  72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  73 # Check architecture signature begin
  74 GRAS_ARCH
  75 # Check architecture signature end
  76 GRAS_CHECK_STRUCT_COMPACTION
  77
  78
  79 dnl ##
  80 dnl ##  CONTEXT IMPLEMENTATION
  81 dnl ##
  82
  83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  84
  85 dnl #
  86 dnl #  1. determine possibilities
  87 dnl #
  88
  89 dnl #  check for MCSC method
  90 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  91
  92 dnl #  check for pthread method
  93 AC_CHECK_HEADERS([pthread.h])
  94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  95
  96 dnl #
  97 dnl #  2. make a general decision
  98 dnl #
  99
 100 if test ".$mcsc" = .yes; then
 101    mcsc=yes
 102 elif test ".$pthread" = .yes; then
 103    pthread=yes
 104 else
 105     ac_header=windows.h
 106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 108       windows_context=yes
 109     else
 110       AC_ERROR([no appropriate backend found])
 111     fi
 112 fi
 113
 114 dnl #
 115 dnl #  3. allow decision to be overridden by user
 116 dnl #
 117
 118 AC_MSG_CHECKING(what kind of backend should we use)
 119
 120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126
 127 if test "x$with_context$mcsc" = "xucontextno" ; then
 128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 129 fi
 130
 131 case $with_context in
 132  ucontext) ;;
 133  pthread) ;;
 134  pthreads) ;;
 135  windows) ;;
 136  auto) with_context=ucontext;;
 137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 138 esac
 139
 140 if test "x$with_context" = "xucontext" ; then
 141   if test ".$mcsc" = .yes; then
 142     AC_MSG_RESULT(found working ucontext. Great!)
 143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 144   else
 145     if test ".$windows_context" = .yes ; then
 146       AC_MSG_RESULT(use windows context portability layer.)
 147       with_context=windows
 148     else
 149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 150       with_context=pthread
 151     fi
 152   fi
 153 fi
 154
 155 if test "x$with_context" = "xpthreads"; then
 156   with_context=pthread
 157 fi
 158 if test "x$with_context" = "xpthread"; then
 159   AC_CHECK_HEADERS([pthread.h])
 160   AC_CHECK_LIB(pthread,pthread_create,,
 161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 163   AC_MSG_RESULT(You have pthreads. Let's use them.)
 164 fi
 165
 166 dnl #
 167 dnl #  4. determine a few additional details
 168 dnl #
 169
 170 if test "x$with_context" = "xucontext" ; then
 171 dnl #  direction of stack grow
 172   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 173   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 174       PTH_STACK_GROWTH="down"
 175   else
 176       PTH_STACK_GROWTH="up"
 177   fi
 178   AC_SUBST(PTH_STACK_GROWTH)
 179
 180   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 181 fi
 182
 183 #########################################
 184 ## Check for libraries extra-dependencies
 185 ##
 186
 187 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 188
 189 SIMGRID_DEP=""
 190 GRAS_DEP=""
 191
 192 if test xpthread=xyes ; then
 193   # if the pthreads are usable
 194   if test "x$with_context" = "xpthread" ; then
 195     # if we use them to implement the xbt_context
 196     SIMGRID_DEP="-lpthread"
 197   fi
 198   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 199   if test "x$with_context" != "xwindows" ; then
 200     GRAS_DEP="-lpthread"
 201   fi
 202 fi
 203
 204 #########################################
 205 ## Build optional modules (gtnets)
 206 ##
 207 gtnets=no
 208 AC_ARG_WITH(gtnets,
 209   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 210   gtnets_path="$withval",gtnets_path="no")
 211 if test "x$gtnets_path" = "xno" ; then
 212   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 213 else
 214   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
 215   AC_MSG_CHECKING(for gtnets)
 216   AC_LANG_PUSH([C++])
 217   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
 218   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
 219   LDFLAGS_SAV=$LDFLAGS
 220   CPPFLAGS_SAV=$CPPFLAGS
 221   CPPFLAGS+=$GTNETS_CPPFLAGS
 222   LDFLAGS+=$GTNETS_LDFLAGS
 223   AC_TRY_LINK([ #include <simulator.h>
 224               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
 225   CPPFLAGS=$CPPFLAGS_SAV
 226   LDFLAGS=$LDFLAGS_SAV
 227   AC_LANG_POP([C++])
 228
 229   if test "x$gtnets" = xyes ; then
 230     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
 231     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
 232     AC_MSG_RESULT(Found working gtnets library.)
 233     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
 234   else
 235     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
 236   fi
 237 fi
 238 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
 239
 240 #########################################
 241 ## Build optional modules (csdp)
 242 ##
 243 csdp=no
 244 AC_ARG_WITH(csdp,
 245   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
 246   csdp_path="$withval",csdp_path="no")
 247 if test "x$csdp_path" = "xno" ; then
 248   AC_MSG_RESULT(Eventually you will come to csdp.)
 249 else
 250   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
 251   AC_MSG_CHECKING(for csdp)
 252   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
 253   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
 254
 255   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
 256
 257   CPPFLAGS_SAV=$CPPFLAGS
 258   CPPFLAGS+=$CSDP_CPPFLAGS
 259   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
 260   CPPFLAGS=$CPPFLAGS_SAV
 261
 262
 263
 264   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
 265      csdp=yes;
 266   else
 267      csdp=no;
 268   fi
 269   if test "x$csdp" = xyes; then
 270     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
 271     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
 272     AC_MSG_RESULT(Found working sdp library.)
 273     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 274   else
 275     AC_MSG_RESULT(Could not find any working sdp library.)
 276   fi;
 277 fi
 278 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 279
 280 AC_SUBST([SIMGRID_DEP])
 281
 282 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 283 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 284
 285 AC_MSG_CHECKING(for extra dependencies of libgras)
 286 case $host_os in
 287   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 288             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
 289             AC_DEFINE(CONTEXT_THREADS,1);;
 290 esac
 291
 292 if test "x$GRAS_DEP" = x; then
 293    AC_MSG_RESULT(none)
 294 else
 295    AC_MSG_RESULT($GRAS_DEP)
 296 fi
 297 AC_SUBST([GRAS_DEP])
 298
 299 ##############################################
 300 ## Enhance maintainer mode and SUBST variables
 301 ## (must be placed after any compilation tests since our overprotective flags
 302 ##  let some tests fail)
 303
 304 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 305 # Next line is modified by sed when building gramine source tree
 306 gramine_mode=no
 307 if test x$gramine_mode = xyes
 308 then
 309   USE_MAINTAINER_MODE=no
 310 fi
 311 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 312
 313
 314 AM_MAINTAINER_MODE
 315 if test x$USE_MAINTAINER_MODE = xyes
 316 then
 317    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 318    enable_compile_warnings=yes
 319 fi
 320 SG_COMPILE_FLAGS
 321
 322 AC_SUBST([CFLAGS])
 323 AC_SUBST([CPPFLAGS])
 324 AC_SUBST([LDFLAGS])
 325 AC_SUBST([AM_CPPFLAGS])
 326 AC_SUBST([abs_builddir])
 327 AC_SUBST([abs_srcdir])
 328 AC_SUBST([abs_top_builddir])
 329 AC_SUBST([abs_top_srcdir])
 330
 331
 332
 333 SG_CONFIGURE_PART(Check for Java bindings...)
 334 # Java cruft
 335 AC_ARG_ENABLE(java,
 336               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 337               want_java=$enableval,want_java=yes)
 338 if test "x$want_java" != "xyes" ; then
 339    AC_MSG_CHECKING(whether to compile java bindings)
 340    AC_MSG_RESULT(disabled by user)
 341    use_java="disabled by user"
 342 else
 343   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 344   AC_PATH_PROG([JAVA],  [java] , `which java`)
 345   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 346   AC_CHECK_HEADERS(jni.h)
 347   AC_MSG_CHECKING(whether to compile java bindings)
 348   if test -n "$JAVAC"   \
 349      && test -n "$JAVA" \
 350      && test -n "$JAR"  \
 351      && test "x$ac_cv_header_jni_h" = "xyes" ; then
 352
 353      use_java="yes"
 354   else
 355      use_java="no"
 356   fi
 357   AC_MSG_RESULT($use_java)
 358 fi
 359 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 360
 361 #####################
 362 ## Check for programs
 363 ##
 364
 365 SG_CONFIGURE_PART(Check for programs...)
 366 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 367 WARNING="This file is generated, do not edit"
 368 AC_SUBST(WARNING)
 369
 370
 371 # Can we rebuild the parsers?
 372 # We really want flex and refuse other lex. So, the parser is portable and
 373 # does not induce extra lib dependency
 374 AC_PROG_FLEX(2.5.30)
 375
 376 # Can we rebuild the xml-lexers from the XML specification?
 377 # if not, simply touch the flex source files (which are distributed in
 378 #  tarballs even if generated by flexml) and hope for the best.
 379 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 380 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 381
 382 if test x$USE_MAINTAINER_MODE = xyes
 383 then
 384    # Check for doxygen when in maintainer mode since dist* targets fail
 385    # without it
 386    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 387    if test x$DOXYGEN = x ; then
 388      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 389    fi
 390 fi
 391
 392 # Can we extract really usable backtraces? (also need the popen function)
 393 AC_PATH_PROG(ADDR2LINE, addr2line)
 394 if test x$ADDR2LINE != x ; then
 395   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 396 fi
 397
 398 AC_SUBST(ac_configure_args)
 399 # Can we make status line about the compilation result?
 400 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 401 if test x$MD5SUM != xno ; then
 402   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 403                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 404 else
 405   build_version="no_md5sum_binary"
 406 fi
 407 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 408 AC_SUBST(build_id)
 409
 410 ###################
 411 ## Makes the output
 412 ##
 413
 414
 415 #
 416 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 417 #  src/amok/Makefile
 418
 419 SG_CONFIGURE_PART(Generating files...)
 420
 421 # Core of the libraries
 422
 423 AC_CONFIG_FILES([
 424   Makefile
 425   include/Makefile
 426   src/Makefile
 427   src/ucontext_stack.h
 428 ])
 429
 430 # Tools being embeeded in gramine (stub generator)
 431 AC_CONFIG_FILES([
 432   tools/Makefile
 433     tools/gras/Makefile
 434     tools/tesh/Makefile
 435 ])
 436
 437
 438 # GRAMINE_CUT_BEGIN
 439
 440 # Tools NOT being embeeded in gramine
 441 AC_CONFIG_FILES([
 442   tools/graspe-slave
 443 ],[
 444     for file in                                                 \
 445      tools/graspe-slave           tools/graspe-master           \
 446     ; do                                                        \
 447       test -e $file && chmod +x $file;                          \
 448     done
 449 ])
 450
 451 # Testsuite
 452
 453 AC_CONFIG_FILES([
 454   testsuite/Makefile
 455   testsuite/run_tests
 456   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 457 ],[
 458     for file in                                                 \
 459      testsuite/run_tests                                        \
 460      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 461     ; do                                                        \
 462       test -e $file && chmod +x $file;                          \
 463     done
 464 ])
 465
 466 # Documentation
 467 AC_CONFIG_FILES([
 468   doc/Makefile
 469   doc/Doxyfile
 470 ])
 471
 472 # Examples
 473
 474 #      examples/gras/p2p/Makefile
 475 #      examples/gras/p2p/chord/Makefile
 476 #      examples/gras/p2p/can/Makefile
 477
 478 if test "x$use_java" = "xyes" ; then
 479 AC_CONFIG_FILES([
 480     examples/java/Makefile
 481       examples/java/basic/Makefile
 482       examples/java/comm_time/Makefile
 483       examples/java/suspend/Makefile
 484       examples/java/ping_pong/Makefile
 485 ])
 486 fi
 487
 488 AC_CONFIG_FILES([
 489   examples/Makefile
 490     examples/msg/Makefile
 491     examples/simdag/Makefile        examples/simdag/test_simdag
 492     examples/gras/Makefile
 493       examples/gras/ping/Makefile
 494       examples/gras/rpc/Makefile
 495       examples/gras/spawn/Makefile
 496       examples/gras/synchro/Makefile
 497       examples/gras/timer/Makefile
 498       examples/gras/chrono/Makefile
 499       examples/gras/mutual_exclusion/simple_token/Makefile
 500       examples/gras/mmrpc/Makefile
 501       examples/gras/pmm/Makefile
 502       examples/gras/all2all/Makefile
 503     examples/amok/Makefile
 504       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 505       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 506 ],[
 507     for file in                                                 \
 508      \
 509      examples/simdag/test_simdag                                \
 510      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 511      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 512     ; do                                                        \
 513       test -e $file && chmod +x $file;                          \
 514     done
 515 ])
 516
 517
 518 # GRAMINE_CUT_END
 519
 520 AC_OUTPUT
 521
 522 echo "
 523
 524 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 525
 526         Compiler:        ${CC} (version: ${GCC_VERSION})
 527
 528         CFlags:          ${CFLAGS}
 529         CPPFlags:        ${CPPFLAGS}
 530         LDFlags:         ${LDFLAGS}
 531
 532         Context backend: ${with_context}
 533 "
 534
 535 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 536   echo "WARNING:"
 537   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 538   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 539   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 540   echo "WARNING:"
 541   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 542   echo "WARNING:"
 543 fi
 544 echo $build_id > stamp.configure
 545
 546 exit 0;