configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15 AM_PROG_GCJ
  16
  17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  18 AC_CONFIG_MACRO_DIR(acmacro)
  19 ACLOCAL="$ACLOCAL -I acmacro"
  20
  21 dnl Next few lines is a hack to prevent libtool checking for F77
  22 m4_undefine([AC_PROG_F77])
  23 m4_defun([AC_PROG_F77],[])
  24
  25 dnl We do build a proper DLL when using win32
  26 AC_LIBTOOL_WIN32_DLL
  27 AC_PROG_LIBTOOL
  28
  29 ###############
  30 ## System checks
  31 ##
  32 SG_CONFIGURE_PART([System checks...])
  33 AC_PROG_CC(xlC gcc cc)
  34 AM_SANITY_CHECK
  35 AC_PROG_MAKE_SET
  36 AC_CHECK_PRINTF_NULL
  37 AC_CHECK_VA_COPY
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_HEADER_TIME
  42 AC_CHECK_HEADERS([sys/socket.h \
  43                   sys/stat.h \
  44                   windows.h winsock.h winsock2.h \
  45                   sys/time.h \
  46                   errno.h unistd.h \
  47                   execinfo.h\
  48                   signal.h ])
  49 AC_CHECK_FUNCS([gettimeofday usleep \
  50                 getdtablesize \
  51                 sysconf\
  52                 readv\
  53                 popen\
  54                 signal\
  55                 getline])
  56
  57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  58 AC_FUNC_SNPRINTF
  59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_TYPE_SIZE_T
  67
  68 ###################################
  69 ## SimGrid and GRAS specific checks
  70 ##
  71
  72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  73 # Check architecture signature begin
  74 GRAS_ARCH
  75 # Check architecture signature end
  76 GRAS_CHECK_STRUCT_COMPACTION
  77
  78
  79 dnl ##
  80 dnl ##  CONTEXT IMPLEMENTATION
  81 dnl ##
  82
  83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  84
  85 dnl #
  86 dnl #  1. determine possibilities
  87 dnl #
  88
  89 dnl #  check for MCSC method
  90 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  91
  92 dnl #  check for pthread method
  93 AC_CHECK_HEADERS([pthread.h])
  94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  95
  96 dnl #
  97 dnl #  2. make a general decision
  98 dnl #
  99
 100 if test ".$mcsc" = .yes; then
 101    mcsc=yes
 102 elif test ".$pthread" = .yes; then
 103    pthread=yes
 104 else
 105     ac_header=windows.h
 106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 108       windows_context=yes
 109     else
 110       AC_ERROR([no appropriate backend found])
 111     fi
 112 fi
 113
 114 dnl #
 115 dnl #  3. allow decision to be overridden by user
 116 dnl #
 117
 118 AC_MSG_CHECKING(what kind of backend should we use)
 119
 120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126
 127 if test "x$with_context$mcsc" = "xucontextno" ; then
 128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 129 fi
 130
 131 case $with_context in
 132  ucontext) ;;
 133  pthread) ;;
 134  pthreads) ;;
 135  windows) ;;
 136  auto) with_context=ucontext;;
 137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 138 esac
 139
 140 if test "x$with_context" = "xucontext" ; then
 141   if test ".$mcsc" = .yes; then
 142     AC_MSG_RESULT(found working ucontext. Great!)
 143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 144   else
 145     if test ".$windows_context" = .yes ; then
 146       AC_MSG_RESULT(use windows context portability layer.)
 147       with_context=windows
 148     else
 149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 150       with_context=pthread
 151     fi
 152   fi
 153 fi
 154
 155 if test "x$with_context" = "xpthreads"; then
 156   with_context=pthread
 157 fi
 158 if test "x$with_context" = "xpthread"; then
 159   AC_CHECK_HEADERS([pthread.h])
 160   AC_CHECK_LIB(pthread,pthread_create,,
 161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 163   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
 164 fi
 165 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
 166
 167 dnl #
 168 dnl #  4. determine a few additional details
 169 dnl #
 170
 171 if test "x$with_context" = "xucontext" ; then
 172 dnl #  direction of stack grow
 173   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 174   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 175       PTH_STACK_GROWTH="down"
 176   else
 177       PTH_STACK_GROWTH="up"
 178   fi
 179   AC_SUBST(PTH_STACK_GROWTH)
 180
 181   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 182 fi
 183
 184 #########################################
 185 ## Check for libraries extra-dependencies
 186 ##
 187
 188 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 189
 190 SIMGRID_DEP=""
 191 SMPI_DEP=""
 192 GRAS_DEP=""
 193
 194 if test xpthread=xyes ; then
 195   # if the pthreads are usable
 196   if test "x$with_context" = "xpthread" ; then
 197     # if we use them to implement the xbt_context
 198     SIMGRID_DEP="-lpthread"
 199   fi
 200   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 201   if test "x$with_context" != "xwindows" ; then
 202     GRAS_DEP="-lpthread"
 203   fi
 204 fi
 205
 206 #########################################
 207 ## Build optional modules (gtnets)
 208 ##
 209 gtnets=no
 210 AC_ARG_WITH(gtnets,
 211   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 212   gtnets_path="$withval",gtnets_path="no")
 213 if test "x$gtnets_path" = "xno" ; then
 214   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 215 else
 216   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
 217   AC_MSG_CHECKING(for gtnets)
 218   AC_LANG_PUSH([C++])
 219   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
 220   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
 221   LDFLAGS_SAV=$LDFLAGS
 222   CPPFLAGS_SAV=$CPPFLAGS
 223   CPPFLAGS+=$GTNETS_CPPFLAGS
 224   LDFLAGS+=$GTNETS_LDFLAGS
 225   AC_TRY_LINK([ #include <simulator.h>
 226               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
 227   CPPFLAGS=$CPPFLAGS_SAV
 228   LDFLAGS=$LDFLAGS_SAV
 229   AC_LANG_POP([C++])
 230
 231   if test "x$gtnets" = xyes ; then
 232     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
 233     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
 234     AC_MSG_RESULT(Found working gtnets library.)
 235     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
 236   else
 237     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
 238   fi
 239 fi
 240 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
 241
 242 #########################################
 243 ## Build optional modules (csdp)
 244 ##
 245 csdp=no
 246 AC_ARG_WITH(csdp,
 247   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
 248   csdp_path="$withval",csdp_path="no")
 249 if test "x$csdp_path" = "xno" ; then
 250   AC_MSG_RESULT(Eventually you will come to csdp.)
 251 else
 252   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
 253   AC_MSG_CHECKING(for csdp)
 254   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
 255   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
 256
 257   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
 258
 259   CPPFLAGS_SAV=$CPPFLAGS
 260   CPPFLAGS+=$CSDP_CPPFLAGS
 261   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
 262   CPPFLAGS=$CPPFLAGS_SAV
 263
 264
 265
 266   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
 267      csdp=yes;
 268   else
 269      csdp=no;
 270   fi
 271   if test "x$csdp" = xyes; then
 272     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
 273     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
 274     AC_MSG_RESULT(Found working sdp library.)
 275     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 276   else
 277     AC_MSG_RESULT(Could not find any working sdp library.)
 278   fi;
 279 fi
 280 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 281
 282 AC_SUBST([SIMGRID_DEP])
 283 AC_SUBST([SMPI_DEP])
 284
 285 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 286 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 287
 288 AC_MSG_CHECKING(for extra dependencies of libgras)
 289 case $host_os in
 290   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 291             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
 292             AC_DEFINE(CONTEXT_THREADS,1);;
 293 esac
 294
 295 if test "x$GRAS_DEP" = x; then
 296    AC_MSG_RESULT(none)
 297 else
 298    AC_MSG_RESULT($GRAS_DEP)
 299 fi
 300 AC_SUBST([GRAS_DEP])
 301
 302 ##############################################
 303 ## Enhance maintainer mode and SUBST variables
 304 ## (must be placed after any compilation tests since our overprotective flags
 305 ##  let some tests fail)
 306
 307 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 308 # Next line is modified by sed when building gramine source tree
 309 gramine_mode=no
 310 if test x$gramine_mode = xyes
 311 then
 312   USE_MAINTAINER_MODE=no
 313 fi
 314 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 315
 316
 317 AM_MAINTAINER_MODE
 318 if test x$USE_MAINTAINER_MODE = xyes
 319 then
 320    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 321    enable_compile_warnings=yes
 322 fi
 323 SG_COMPILE_FLAGS
 324
 325 AC_SUBST([CFLAGS])
 326 AC_SUBST([CPPFLAGS])
 327 AC_SUBST([LDFLAGS])
 328 AC_SUBST([AM_CPPFLAGS])
 329 AC_SUBST([abs_builddir])
 330 AC_SUBST([abs_srcdir])
 331 AC_SUBST([abs_top_builddir])
 332 AC_SUBST([abs_top_srcdir])
 333
 334
 335
 336 SG_CONFIGURE_PART(Check for Java bindings...)
 337 # Java cruft
 338 AC_ARG_ENABLE(java,
 339               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 340               want_java=$enableval,want_java=yes)
 341 if test "x$want_java" != "xyes" ; then
 342    AC_MSG_CHECKING(whether to compile java bindings)
 343    AC_MSG_RESULT(disabled by user)
 344    use_java="disabled by user"
 345 else
 346   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 347   AC_PATH_PROG([JAVA],  [java] , `which java`)
 348   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 349   AC_CHECK_HEADERS(jni.h)
 350   AC_MSG_CHECKING(whether to compile java bindings)
 351   if test -n "$JAVAC"   \
 352      && test -n "$JAVA" \
 353      && test -n "$JAR"  \
 354      && test "x$ac_cv_header_jni_h" = "xyes" ; then
 355
 356      use_java="yes"
 357   else
 358      use_java="no"
 359   fi
 360   AC_MSG_RESULT($use_java)
 361 fi
 362 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 363
 364 #####################
 365 ## Check for programs
 366 ##
 367
 368 SG_CONFIGURE_PART(Check for programs...)
 369 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 370 WARNING="This file is generated, do not edit"
 371 AC_SUBST(WARNING)
 372
 373
 374 # Can we rebuild the parsers?
 375 # We really want flex and refuse other lex. So, the parser is portable and
 376 # does not induce extra lib dependency
 377 AC_PROG_FLEX(2.5.30)
 378
 379 # Can we rebuild the xml-lexers from the XML specification?
 380 # if not, simply touch the flex source files (which are distributed in
 381 #  tarballs even if generated by flexml) and hope for the best.
 382 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 383 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 384
 385 if test x$USE_MAINTAINER_MODE = xyes
 386 then
 387    # Check for doxygen when in maintainer mode since dist* targets fail
 388    # without it
 389    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 390    if test x$DOXYGEN = x ; then
 391      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 392    fi
 393 fi
 394
 395 # Can we extract really usable backtraces? (also need the popen function)
 396 AC_PATH_PROG(ADDR2LINE, addr2line)
 397 if test x$ADDR2LINE != x ; then
 398   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 399 fi
 400
 401 AC_SUBST(ac_configure_args)
 402 # Can we make status line about the compilation result?
 403 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 404 if test x$MD5SUM != xno ; then
 405   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 406                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 407 else
 408   build_version="no_md5sum_binary"
 409 fi
 410 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 411 AC_SUBST(build_id)
 412
 413 ###################
 414 ## Makes the output
 415 ##
 416
 417
 418 #
 419 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 420 #  src/amok/Makefile
 421
 422 SG_CONFIGURE_PART(Generating files...)
 423
 424 # Core of the libraries
 425
 426 AC_CONFIG_FILES([
 427   Makefile
 428   include/Makefile
 429   src/Makefile
 430   src/ucontext_stack.h
 431 ])
 432
 433 # Tools being embeeded in gramine (stub generator)
 434 AC_CONFIG_FILES([
 435   tools/Makefile
 436     tools/gras/Makefile
 437     tools/tesh/Makefile
 438 ])
 439
 440
 441 # GRAMINE_CUT_BEGIN
 442
 443 # Tools NOT being embeeded in gramine
 444 AC_CONFIG_FILES([
 445   tools/graspe-slave
 446 ],[
 447     for file in                                                 \
 448      tools/graspe-slave           tools/graspe-master           \
 449     ; do                                                        \
 450       test -e $file && chmod +x $file;                          \
 451     done
 452 ])
 453
 454 # Testsuite
 455
 456 AC_CONFIG_FILES([
 457   testsuite/Makefile
 458   testsuite/run_tests
 459   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 460 ],[
 461     for file in                                                 \
 462      testsuite/run_tests                                        \
 463      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 464     ; do                                                        \
 465       test -e $file && chmod +x $file;                          \
 466     done
 467 ])
 468
 469 # Documentation
 470 AC_CONFIG_FILES([
 471   doc/Makefile
 472   doc/Doxyfile
 473 ])
 474
 475 # Examples
 476
 477 #      examples/gras/p2p/Makefile
 478 #      examples/gras/p2p/chord/Makefile
 479 #      examples/gras/p2p/can/Makefile
 480
 481 if test "x$use_java" = "xyes" ; then
 482 AC_CONFIG_FILES([
 483     examples/java/Makefile
 484       examples/java/basic/Makefile
 485       examples/java/comm_time/Makefile
 486       examples/java/suspend/Makefile
 487       examples/java/ping_pong/Makefile
 488 ])
 489 fi
 490
 491 AC_CONFIG_FILES([
 492   examples/Makefile
 493     examples/msg/Makefile
 494     examples/simdag/Makefile        examples/simdag/test_simdag
 495     examples/gras/Makefile
 496       examples/gras/ping/Makefile
 497       examples/gras/rpc/Makefile
 498       examples/gras/spawn/Makefile
 499       examples/gras/synchro/Makefile
 500       examples/gras/timer/Makefile
 501       examples/gras/chrono/Makefile
 502       examples/gras/mutual_exclusion/simple_token/Makefile
 503       examples/gras/mmrpc/Makefile
 504       examples/gras/pmm/Makefile
 505       examples/gras/all2all/Makefile
 506     examples/amok/Makefile
 507       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 508       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 509 ],[
 510     for file in                                                 \
 511      \
 512      examples/simdag/test_simdag                                \
 513      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 514      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 515     ; do                                                        \
 516       test -e $file && chmod +x $file;                          \
 517     done
 518 ])
 519
 520
 521 # GRAMINE_CUT_END
 522
 523 AC_OUTPUT
 524
 525 echo "
 526
 527 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 528
 529         Compiler:        ${CC} (version: ${GCC_VERSION})
 530
 531         CFlags:          ${CFLAGS}
 532         CPPFlags:        ${CPPFLAGS}
 533         LDFlags:         ${LDFLAGS}
 534
 535         Context backend: ${with_context}
 536 "
 537
 538 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 539   echo "WARNING:"
 540   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 541   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 542   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 543   echo "WARNING:"
 544   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 545   echo "WARNING:"
 546 fi
 547 echo $build_id > stamp.configure
 548
 549 exit 0;