CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.8)
   2 message(STATUS "Cmake version ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
   3 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_HOME_DIRECTORY}/tools/cmake/Modules)
   4
   5 project(SimGrid C CXX)
   6
   7 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
   8 #     Check for the compiler        #
   9 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  10
  11 ### Need to set rc ccompiler before enable language
  12 if(WIN32)
  13   SET(CMAKE_RC_COMPILER "windres")
  14 endif()
  15
  16 ##
  17 ## Check the C/C++ standard that we need
  18 ##   See also tools/cmake/GCCFlags.cmake that sets our paranoid warning flags
  19 if (MSVC)
  20   message("-- You are compiling SimGrid with MicroSoft Visual C. Good luck.")
  21
  22   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  23   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
  24 else() # gcc or clang
  25   INCLUDE(CheckCCompilerFlag)
  26   CHECK_C_COMPILER_FLAG(-fstack-cleaner HAVE_C_STACK_CLEANER)
  27
  28   ## Request full debugging flags
  29   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
  30   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
  31   set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -g")
  32
  33   if (CMAKE_COMPILER_IS_GNUCC)
  34     if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.7")
  35       message(FATAL_ERROR
  36               "SimGrid needs at least g++ version 4.7 to compile but you have ${CMAKE_CXX_COMPILER_VERSION}."
  37               "You need a sufficient support of c++11 to compile SimGrid.")
  38     endif()
  39   endif()
  40
  41   ## We need a decent support of the c++11 standard
  42   include(CheckCXXCompilerFlag)
  43   CHECK_CXX_COMPILER_FLAG("-std=gnu++11" COMPILER_SUPPORTS_CXX11)
  44   if(COMPILER_SUPPORTS_CXX11)
  45     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
  46   else()
  47     message(FATAL_ERROR
  48             "The compiler ${CMAKE_CXX_COMPILER} (v${CMAKE_CXX_COMPILER_VERSION}) has no C++11 support. "
  49             "Please use a decent C++ compiler.")
  50   endif()
  51
  52   ### And we need C11 standard, too
  53   include(CheckCCompilerFlag)
  54   CHECK_C_COMPILER_FLAG("-std=gnu11" COMPILER_SUPPORTS_C11)
  55   if(COMPILER_SUPPORTS_C11)
  56     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu11")
  57   else()
  58     message(FATAL_ERROR
  59             "The compiler ${CMAKE_C_COMPILER} (v${CMAKE_C_COMPILER_VERSION}) has no C11 support. "
  60             "Please use a decent C compiler "
  61             "(note that c++11 support of ${CMAKE_CXX_COMPILER} seems ok).")
  62   endif()
  63   if(APPLE AND (CMAKE_C_COMPILER_VERSION VERSION_LESS "4.6"))
  64       ### gcc 4.[1-5] cannot compile ucontext on OSX
  65       message(STATUS "Ucontext can't be used with this version of gcc (must be greater than 4.5)")
  66       set(HAVE_UCONTEXT_H 0)
  67   endif()
  68 endif() # NOT MSVC
  69
  70 ### SMPI vs. Fortran
  71 if ((NOT DEFINED enable_smpi OR enable_smpi) AND NOT APPLE) # smpi is enabled by default
  72   # Call enable_language(Fortran) in order to load the build rules for
  73   # this language, needed by teshsuite/smpi/mpich-test/.  Use
  74   # CMAKE_FORCE_Fortran_COMPILER to bypass checks for a working
  75   # compiler (smpiff don't exist at configure time).
  76   include(CMakeForceCompiler)
  77   if(NOT COMMAND CMAKE_FORCE_Fortran_COMPILER)
  78     MACRO(CMAKE_FORCE_Fortran_COMPILER compiler id)
  79       SET(CMAKE_Fortran_COMPILER "${compiler}")
  80       SET(CMAKE_Fortran_COMPILER_ID_RUN TRUE)
  81       SET(CMAKE_Fortran_COMPILER_ID ${id})
  82       SET(CMAKE_Fortran_COMPILER_WORKS TRUE)
  83       SET(CMAKE_Fortran_COMPILER_FORCED TRUE)
  84
  85       # Set old compiler id variables.
  86       IF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  87         SET(CMAKE_COMPILER_IS_GNUG77 1)
  88       ENDIF("${CMAKE_Fortran_COMPILER_ID}" MATCHES "GNU")
  89     ENDMACRO(CMAKE_FORCE_Fortran_COMPILER)
  90   endif()
  91   CMAKE_FORCE_Fortran_COMPILER(smpiff smpiff)
  92   enable_language(Fortran OPTIONAL)
  93 endif()
  94
  95 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  96 #     Build the version number      #
  97 #-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#-#
  98
  99 set(SIMGRID_VERSION_MAJOR "3")
 100 set(SIMGRID_VERSION_MINOR "13")
 101 set(SIMGRID_VERSION_PATCH "0")
 102 set(SIMGRID_VERSION_EXTRA "-devel") # Extra words to add to version string (e.g. -rc1)
 103
 104 set(SIMGRID_VERSION_DATE  "2016") # Year for copyright information
 105
 106 if(${SIMGRID_VERSION_PATCH} EQUAL "0")
 107   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}")
 108 else()
 109   set(release_version "${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}")
 110 endif()
 111
 112 set(SIMGRID_VERSION_STRING "SimGrid version ${release_version}${SIMGRID_VERSION_EXTRA}")
 113 set(SIMGRID_VERSION_BANNER "SIMGRID_VERSION_STRING\\nCopyright (c) 2004-${SIMGRID_VERSION_DATE}. The Simgrid Team.")
 114 if(release)
 115   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nRelease build")
 116 else()
 117   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER}\\nDevelopment build")
 118 endif()
 119
 120 set(libsimgrid_version "${release_version}")
 121 set(libsimgrid-java_version "${release_version}")
 122
 123 ### SET THE LIBRARY EXTENSION
 124 if(APPLE) #MAC
 125   set(LIB_EXE "dylib")
 126 else()
 127   if(WIN32) #WINDOWS
 128     set(LIB_EXE "a")
 129     set(BIN_EXE ".exe")
 130   else() #UNIX
 131     set(LIB_EXE "so")
 132   endif()
 133 endif()
 134
 135 execute_process(COMMAND         ${CMAKE_LINKER} --version
 136                 OUTPUT_VARIABLE LINKER_VERSION)
 137 string(REGEX MATCH "[0-9].[0-9]*" LINKER_VERSION "${LINKER_VERSION}")
 138
 139 ### Find programs and paths
 140 FIND_PROGRAM(GCOV_PATH gcov)
 141 include(FindPerl)
 142 if(NOT PERL_FOUND)
 143   message(FATAL_ERROR "Please install Perl to compile SimGrid.")
 144 endif()
 145
 146 if (APPLE)
 147   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 148   set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 149 endif()
 150 SET(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib)
 151
 152 ### Compute the include paths
 153 set(INCLUDES
 154   ${CMAKE_HOME_DIRECTORY}
 155   ${CMAKE_HOME_DIRECTORY}/include
 156   ${CMAKE_HOME_DIRECTORY}/src/include
 157   ${CMAKE_BINARY_DIR}
 158   ${CMAKE_BINARY_DIR}/include
 159   )
 160
 161 if(NOT CMAKE_CROSSCOMPILING AND EXISTS /usr/include/)
 162   set(INCLUDES ${INCLUDES} /usr/include/)
 163 endif()
 164
 165 ### Check 32bits or 64bits
 166 IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
 167   SET(ARCH_32_BITS 1)
 168 ELSE()
 169   SET(ARCH_32_BITS 0)
 170 ENDIF()
 171
 172 if(WIN32)
 173
 174   set(CMAKE_INCLUDE_WIN "${CMAKE_C_COMPILER}")
 175   set(CMAKE_LIB_WIN "${CMAKE_C_COMPILER}")
 176   string(REGEX REPLACE "/bin/gcc.*" "/include"  CMAKE_INCLUDE_WIN "${CMAKE_INCLUDE_WIN}")
 177   string(REGEX REPLACE "/bin/gcc.*" "/lib"  CMAKE_LIB_WIN "${CMAKE_LIB_WIN}")
 178   set(INCLUDES ${INCLUDES} ${CMAKE_INCLUDE_WIN})
 179   unset(CMAKE_INCLUDE_WIN)
 180
 181 endif()
 182
 183 include_directories(${INCLUDES})
 184
 185 ### Setup Options
 186 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Option.cmake)
 187
 188 ### Determine the assembly flavor that we need today
 189 include(CMakeDetermineSystem)
 190 IF(CMAKE_SYSTEM_PROCESSOR MATCHES ".86|AMD64|amd64")
 191   IF(${ARCH_32_BITS})
 192     message(STATUS "System processor: i686 (${CMAKE_SYSTEM_PROCESSOR}, 32 bits)")
 193     set(PROCESSOR_i686 1)
 194     set(PROCESSOR_x86_64 0)
 195   ELSE()
 196     message(STATUS "System processor: x86_64 (${CMAKE_SYSTEM_PROCESSOR}, 64 bits)")
 197     set(PROCESSOR_i686 0)
 198     set(PROCESSOR_x86_64 1)
 199   ENDIF()
 200   if (WIN32)
 201     message(STATUS "Disable fast raw contextes on Windows.")
 202   else()
 203     set(HAVE_RAW_CONTEXTS 1)
 204   endif()
 205 ELSE()
 206   set(PROCESSOR_i686 0)
 207   set(PROCESSOR_x86_64 0)
 208 ENDIF()
 209
 210 include(CheckFunctionExists)
 211 include(CheckTypeSize)
 212 include(CheckIncludeFile)
 213 include(CheckIncludeFiles)
 214 include(CheckLibraryExists)
 215 include(CheckSymbolExists)
 216
 217 set(HAVE_GRAPHVIZ 0)
 218 include(FindGraphviz)
 219 include(FindLibSigc++)
 220
 221 set(HAVE_LUA 0)
 222 if(enable_lua)
 223   include(FindLuaSimgrid)
 224 endif()
 225
 226 set(HAVE_NS3 0)
 227 if(enable_ns3)
 228   include(FindNS3)
 229   if (NOT HAVE_NS3)
 230     message(FATAL_ERROR "Cannot find NS3. Please install it (apt-get install ns3 libns3-dev) or disable that cmake option")
 231   endif()
 232 endif()
 233
 234 if(WIN32)
 235   set(Boost_USE_STATIC_LIBS 1)
 236 endif()
 237
 238 find_package(Boost 1.48)
 239 if(Boost_FOUND)
 240   include_directories(${Boost_INCLUDE_DIRS})
 241 else()
 242   if(APPLE)
 243     message(FATAL_ERROR "Failed to find Boost libraries (Try to install them with 'sudo fink install boost1.53.nopython')")
 244   else()
 245     message(FATAL_ERROR "Failed to find Boost libraries."
 246                         "Did you install libboost-dev and libboost-context-dev?"
 247                         "(libboost-context-dev is optional)")
 248   endif()
 249 endif()
 250
 251 # Try again to see if we have libboost-context
 252 find_package(Boost 1.42 COMPONENTS context)
 253 set(Boost_FOUND 1) # We don't care of whether this component is missing
 254
 255 if(Boost_FOUND AND Boost_CONTEXT_FOUND)
 256   # We should use feature detection for this instead:
 257   if (Boost_VERSION LESS 105600)
 258     message("Found Boost.Context API v1")
 259     set(HAVE_BOOST_CONTEXTS 1)
 260   else()
 261     message("Found Boost.Context API v2")
 262     set(HAVE_BOOST_CONTEXTS 2)
 263   endif()
 264 else()
 265   message ("   boost        : found.")
 266   message ("   boost-context: missing. Install libboost-context-dev for this optional feature.")
 267   set(HAVE_BOOST_CONTEXTS 0)
 268 endif()
 269
 270 # Checks for header libraries functions.
 271 CHECK_LIBRARY_EXISTS(execinfo backtrace              "" HAVE_BACKTRACE_IN_LIBEXECINFO)
 272 CHECK_LIBRARY_EXISTS(rt      clock_gettime           "" HAVE_POSIX_GETTIME)
 273
 274 CHECK_LIBRARY_EXISTS(pthread pthread_create          "" HAVE_PTHREAD)
 275 CHECK_LIBRARY_EXISTS(pthread sem_init                "" HAVE_SEM_INIT_LIB)
 276 CHECK_LIBRARY_EXISTS(pthread sem_open                "" HAVE_SEM_OPEN_LIB)
 277 set(HAVE_PTHREAD_SETAFFINITY 0)
 278 CHECK_LIBRARY_EXISTS(pthread pthread_setaffinity_np  "" HAVE_PTHREAD_SETAFFINITY)
 279
 280 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 281   set(CMAKE_REQUIRED_DEFINITIONS "-D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 282 elseif(MINGW)
 283   # Use the GNU version of unusual modifiers like PRIx64
 284   add_definitions(-D__USE_MINGW_ANSI_STDIO=1)
 285   set(CMAKE_REQUIRED_DEFINITIONS "-D__USE_MINGW_ANSI_STDIO=1")
 286 else()
 287   set(CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
 288 endif()
 289
 290 SET(HAVE_VALGRIND_H 0)
 291 SET(HAVE_UNISTD_H 0)
 292 SET(HAVE_EXECINFO_H 0)
 293 SET(HAVE_SIGNAL_H 0)
 294 SET(HAVE_SYS_PARAM_H 0)
 295 SET(HAVE_SYS_SYSCTL_H 0)
 296 SET(HAVE_UCONTEXT_H 0)
 297 SET(HAVE_FUTEX_H 0)
 298
 299 CHECK_INCLUDE_FILE("valgrind/valgrind.h" HAVE_VALGRIND_H)
 300 CHECK_INCLUDE_FILE("unistd.h" HAVE_UNISTD_H)
 301 CHECK_INCLUDE_FILE("execinfo.h" HAVE_EXECINFO_H)
 302 CHECK_INCLUDE_FILE("signal.h" HAVE_SIGNAL_H)
 303 CHECK_INCLUDE_FILE("sys/param.h" HAVE_SYS_PARAM_H)
 304 CHECK_INCLUDE_FILE("sys/sysctl.h" HAVE_SYS_SYSCTL_H)
 305 CHECK_INCLUDE_FILE("ucontext.h" HAVE_UCONTEXT_H)
 306 CHECK_INCLUDE_FILE("linux/futex.h" HAVE_FUTEX_H)
 307
 308 SET(HAVE_GETTIMEOFDAY 0)
 309 SET(HAVE_NANOSLEEP 0)
 310 SET(HAVE_GETDTABLESIZE 0)
 311 SET(HAVE_SYSCONF 0)
 312 SET(HAVE_POPEN 0)
 313 SET(HAVE_PROCESS_VM_READV 0)
 314 SET(HAVE_MMAP 0)
 315
 316 CHECK_FUNCTION_EXISTS(gettimeofday HAVE_GETTIMEOFDAY)
 317 CHECK_FUNCTION_EXISTS(nanosleep HAVE_NANOSLEEP)
 318 CHECK_FUNCTION_EXISTS(getdtablesize HAVE_GETDTABLESIZE)
 319 CHECK_FUNCTION_EXISTS(sysconf HAVE_SYSCONF)
 320 CHECK_FUNCTION_EXISTS(popen HAVE_POPEN)
 321 CHECK_FUNCTION_EXISTS(process_vm_readv HAVE_PROCESS_VM_READV)
 322 CHECK_FUNCTION_EXISTS(mmap HAVE_MMAP)
 323
 324 SET(HAVE_VASPRINTF 0)
 325 CHECK_SYMBOL_EXISTS(vasprintf stdio.h HAVE_VASPRINTF)
 326 if(MINGW)
 327   # The detection of vasprintf fails on MinGW, assumingly because it's
 328   # defined as an inline function in stdio.h instead of a regular
 329   # function. So force the result to be 1 despite of the test.
 330   set(HAVE_VASPRINTF 1)
 331 endif()
 332
 333
 334 #Check if __thread is defined
 335 execute_process(
 336   COMMAND "${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_thread_storage.c -o testprog"
 337   WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 338   RESULT_VARIABLE HAVE_thread_storage_run)
 339 file(REMOVE testprog)
 340 if(HAVE_thread_storage_run)
 341   set(HAVE_THREAD_LOCAL_STORAGE 1)
 342 else()
 343   set(HAVE_THREAD_LOCAL_STORAGE 0)
 344 endif()
 345
 346 # Our usage of mmap is Linux-specific (flag MAP_ANONYMOUS), but kFreeBSD uses a GNU libc
 347 IF(HAVE_MMAP AND
 348    NOT "${CMAKE_SYSTEM}" MATCHES "Linux" AND
 349    NOT "${CMAKE_SYSTEM}" MATCHES "kFreeBSD" AND
 350    NOT "${CMAKE_SYSTEM}" MATCHES "GNU" AND
 351    NOT  "${CMAKE_SYSTEM}" MATCHES "Darwin")
 352   SET(HAVE_MMAP 0)
 353   message(STATUS "Warning: MMAP is thought as non functional on this architecture (${CMAKE_SYSTEM})")
 354 ENDIF()
 355
 356 if(HAVE_MMAP AND HAVE_THREAD_LOCAL_STORAGE)
 357   SET(HAVE_MMALLOC 1)
 358 else()
 359   SET(HAVE_MMALLOC 0)
 360 endif()
 361
 362 if(enable_jedule)
 363   set(HAVE_JEDULE 1)
 364 else()
 365   set(HAVE_JEDULE 0)
 366 endif()
 367
 368 if(enable_mallocators)
 369   SET(HAVE_MALLOCATOR 1)
 370 else()
 371   SET(HAVE_MALLOCATOR 0)
 372 endif()
 373
 374 if(enable_model-checking AND HAVE_MMALLOC)
 375   SET(HAVE_MC 1)
 376   include(FindLibunwind)
 377   include(FindLibdw)
 378 else()
 379   if(enable_model-checking)
 380     message(STATUS "Warning: support for model-checking has been disabled because you are missing either mmap or __thread.")
 381   endif()
 382   SET(HAVE_MC 0)
 383   SET(HAVE_MMALLOC 0)
 384 endif()
 385
 386 if(enable_smpi)
 387   include(FindGFortran)
 388   SET(HAVE_SMPI 1)
 389   if("${CMAKE_SYSTEM}" MATCHES "Linux")
 390     SET(USE_LIBUTIL 0)
 391     SET(HAVE_PRIVATIZATION 1)
 392   elseif("${CMAKE_SYSTEM}" MATCHES "^FreeBSD")
 393     SET(USE_LIBUTIL 0)
 394     SET(HAVE_PRIVATIZATION 0)
 395   else()
 396     message (STATUS "Warning:  no support for SMPI automatic privatization on this platform")
 397     SET(HAVE_PRIVATIZATION 0)
 398   endif()
 399 else()
 400   SET(HAVE_SMPI 0)
 401 endif()
 402
 403 #--------------------------------------------------------------------------------------------------
 404 ### Check for GNU dynamic linker
 405 CHECK_INCLUDE_FILE("dlfcn.h" HAVE_DLFCN_H)
 406 if (HAVE_DLFCN_H)
 407     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_gnu_dynlinker.c -ldl -o test_gnu_ld
 408       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 409       OUTPUT_VARIABLE HAVE_GNU_LD_compil
 410     )
 411     if(HAVE_GNU_LD_compil)
 412       set(HAVE_GNU_LD 0)
 413       message(STATUS "Warning: test program toward GNU ld failed to compile:")
 414       message(STATUS "${HAVE_GNU_LD_comp_output}")
 415     else()
 416
 417       execute_process(COMMAND ./test_gnu_ld
 418           WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 419           RESULT_VARIABLE HAVE_GNU_LD_run
 420           OUTPUT_VARIABLE var_exec
 421       )
 422
 423       if(NOT HAVE_GNU_LD_run)
 424         set(HAVE_GNU_LD 1)
 425         message(STATUS "We are using GNU dynamic linker")
 426       else()
 427         set(HAVE_GNU_LD 0)
 428         message(STATUS "Warning: error while checking for GNU ld:")
 429         message(STATUS "Test output: '${var_exec}'")
 430         message(STATUS "Exit status: ${HAVE_GNU_LD_run}")
 431       endif()
 432       file(REMOVE test_gnu_ld)
 433     endif()
 434 endif()
 435
 436
 437 #--------------------------------------------------------------------------------------------------
 438 ### Initialize of CONTEXT THREADS
 439
 440 set(HAVE_THREAD_CONTEXTS 0)
 441
 442 if(HAVE_PTHREAD)
 443   ### Test that we have a way to create semaphores
 444
 445   if(HAVE_SEM_OPEN_LIB)
 446     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_open.c -lpthread -o sem_open
 447       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 448       OUTPUT_VARIABLE HAVE_SEM_OPEN_compil
 449     )
 450
 451     # Test sem_open by compiling:
 452     if(HAVE_SEM_OPEN_compil)
 453       set(HAVE_SEM_OPEN 0)
 454       message(STATUS "Warning: sem_open not compilable")
 455       message(STATUS "HAVE_SEM_OPEN_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 456     else()
 457       set(HAVE_SEM_OPEN 1)
 458       message(STATUS "sem_open is compilable")
 459     endif()
 460
 461     # If we're not crosscompiling, we check by executing the program:
 462     if (HAVE_SEM_OPEN AND NOT CMAKE_CROSSCOMPILING)
 463       execute_process(COMMAND ./sem_open
 464         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 465         RESULT_VARIABLE HAVE_SEM_OPEN_run
 466         OUTPUT_VARIABLE var_compil
 467       )
 468       if (NOT HAVE_SEM_OPEN_run)
 469         set(HAVE_SEM_OPEN 1)
 470         message(STATUS "sem_open is executable")
 471       else()
 472         set(HAVE_SEM_OPEN 0)
 473         if(EXISTS "${CMAKE_BINARY_DIR}/sem_open")
 474           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open exists!")
 475         else()
 476           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_open not exists!")
 477         endif()
 478         message(STATUS "Warning: sem_open not executable")
 479         message(STATUS "Compilation output: '${var_compil}'")
 480         message(STATUS "Exit result of sem_open: ${HAVE_SEM_OPEN_run}")
 481       endif()
 482     endif()
 483     file(REMOVE sem_open)
 484
 485   else()
 486     set(HAVE_SEM_OPEN 0)
 487   endif()
 488
 489   if(HAVE_SEM_INIT_LIB)
 490     execute_process(COMMAND ${CMAKE_C_COMPILER} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_sem_init.c -lpthread -o sem_init
 491       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 492       RESULT_VARIABLE HAVE_SEM_INIT_run
 493       OUTPUT_VARIABLE HAVE_SEM_INIT_compil)
 494
 495     # Test sem_init by compiling:
 496     if(HAVE_SEM_INIT_compil)
 497       set(HAVE_SEM_INIT 0)
 498       message(STATUS "Warning: sem_init not compilable")
 499       message(STATUS "HAVE_SEM_INIT_comp_output: ${HAVE_SEM_OPEN_comp_output}")
 500     else()
 501       set(HAVE_SEM_INIT 1)
 502       message(STATUS "sem_init is compilable")
 503     endif()
 504
 505     # If we're not crosscompiling, we check by executing the program:
 506     if (HAVE_SEM_INIT AND NOT CMAKE_CROSSCOMPILING)
 507       execute_process(COMMAND ./sem_init
 508         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 509         RESULT_VARIABLE HAVE_SEM_INIT_run
 510         OUTPUT_VARIABLE var_compil
 511       )
 512       if (NOT HAVE_SEM_INIT_run)
 513         set(HAVE_SEM_INIT 1)
 514         message(STATUS "sem_init is executable")
 515       else()
 516         set(HAVE_SEM_INIT 0)
 517         if(EXISTS "${CMAKE_BINARY_DIR}/sem_init")
 518           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init exists!")
 519         else()
 520           message(STATUS "Bin ${CMAKE_BINARY_DIR}/sem_init not exists!")
 521         endif()
 522         message(STATUS "Warning: sem_init not executable")
 523         message(STATUS "Compilation output: '${var_compil}'")
 524         message(STATUS "Exit result of sem_init: ${HAVE_SEM_INIT_run}")
 525       endif()
 526     endif()
 527     file(REMOVE sem_init)
 528   endif()
 529
 530   if(NOT HAVE_SEM_OPEN AND NOT HAVE_SEM_INIT)
 531     message(FATAL_ERROR "Semaphores are not usable (neither sem_open nor sem_init is both compilable and executable), but they are mandatory to threads (you may need to mount /dev).")
 532   endif()
 533
 534   set(HAVE_THREAD_CONTEXTS 1)
 535   message("-- Support for thread context factory ok.")
 536 endif()
 537
 538
 539 set(HAVE_UCONTEXT_CONTEXTS 0)
 540 if(NOT HAVE_UCONTEXT_H)
 541   message("-- No ucontext factory: <ucontext.h> not found.")
 542 elseif(APPLE)
 543   message("-- No ucontext factory: Apple don't want us to use them.")
 544   set(HAVE_UCONTEXT_H 0)
 545 else()
 546   try_compile(compile_makecontext ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_makecontext.c
 547     OUTPUT_VARIABLE compile_makecontext_output)
 548
 549   #If can have both context
 550   if(compile_makecontext)
 551     set(HAVE_UCONTEXT_CONTEXTS 1)
 552     message("-- Support for ucontext factory ok.")
 553   else()
 554     message("-- Error: <ucontext.h> exists, but makecontext is not compilable. Compilation output:\n ${compile_makecontext_output}")
 555     message("-- No ucontext factory: makecontext() is not compilable.")
 556   endif()
 557
 558   # Stack setup (size and address)
 559   try_run(RUN_makecontext_VAR COMPILE_makecontext_VAR
 560     ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stacksetup.c
 561     RUN_OUTPUT_VARIABLE stack_setup)
 562
 563   LIST(LENGTH stack_setup stack_setup_len)
 564   if("${stack_setup_len}" STREQUAL "2")
 565     LIST(GET stack_setup 0 makecontext_addr)
 566     LIST(GET stack_setup 1 makecontext_size)
 567     set(sg_makecontext_stack_addr "#define sg_makecontext_stack_addr(skaddr) (${makecontext_addr})")
 568     set(sg_makecontext_stack_size "#define sg_makecontext_stack_size(sksize) (${makecontext_size})")
 569   else()
 570     message(FATAL_ERROR "Could not figure out the stack setup. Compil: ${RUN_makecontext_VAR}. Exec: ${COMPILE_makecontext_VAR}. Output: ${stack_setup}")
 571   endif()
 572 endif()
 573
 574 # Stack growth direction (upward or downward). Used for the following contexts: SysV, raw, Boost
 575 try_run(RUN_stackgrowth_VAR COMPILE_stackgrowth_VAR
 576   ${CMAKE_BINARY_DIR}
 577   ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_stackgrowth.c
 578   RUN_OUTPUT_VARIABLE stack
 579   COPY_FILE test_stackgrowth)
 580
 581 if("${stack}" STREQUAL "down")
 582   set(PTH_STACKGROWTH "-1")
 583 elseif("${stack}" STREQUAL "up")
 584   set(PTH_STACKGROWTH "1")
 585 else()
 586   if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
 587     set(PTH_STACKGROWTH "-1")
 588   elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "i686")
 589     set(PTH_STACKGROWTH "-1")
 590   else()
 591     message(FATAL_ERROR "Could not figure out the stack direction. Test prog returned: ${stack}; CMAKE_SYSTEM_PROCESSOR: ${CMAKE_SYSTEM_PROCESSOR}.")
 592   endif()
 593 endif()
 594 # If the test ran well, remove the test binary
 595 file(REMOVE test_stackgrowth)
 596 #--------------------------------------------------------------------------------------------------
 597
 598 ### check for addr2line
 599 find_path(ADDR2LINE NAMES addr2line     PATHS NO_DEFAULT_PATHS)
 600 if(ADDR2LINE)
 601   set(ADDR2LINE "${ADDR2LINE}/addr2line")
 602 endif()
 603
 604 ###############
 605 ## GIT version check
 606 ##
 607 if(EXISTS ${CMAKE_HOME_DIRECTORY}/.git/)
 608   execute_process(
 609      COMMAND git remote
 610      COMMAND head -n 1
 611      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 612      OUTPUT_VARIABLE remote
 613      OUTPUT_STRIP_TRAILING_WHITESPACE)
 614   #message(STATUS "Git remote: ${remote}")
 615   execute_process(COMMAND git config --get remote.${remote}.url
 616      WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 617      OUTPUT_VARIABLE url
 618      OUTPUT_STRIP_TRAILING_WHITESPACE)
 619   #message(STATUS "Git url: ${url}")
 620   if(url)
 621     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=oneline --abbrev-commit -1
 622        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 623        OUTPUT_VARIABLE GIT_VERSION
 624        OUTPUT_STRIP_TRAILING_WHITESPACE)
 625     message(STATUS "Git version: ${GIT_VERSION}")
 626
 627     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log -n 1 --pretty=format:%ai .
 628        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 629        OUTPUT_VARIABLE GIT_DATE
 630        OUTPUT_STRIP_TRAILING_WHITESPACE)
 631     message(STATUS "Git date: ${GIT_DATE}")
 632     string(REGEX REPLACE " .*" "" GIT_VERSION "${GIT_VERSION}")
 633
 634     execute_process(COMMAND git --git-dir=${CMAKE_HOME_DIRECTORY}/.git log --pretty=format:%H -1
 635        WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/.git/
 636        OUTPUT_VARIABLE SIMGRID_GITHASH
 637        OUTPUT_STRIP_TRAILING_WHITESPACE)
 638   endif()
 639 elseif(EXISTS ${CMAKE_HOME_DIRECTORY}/.gitversion)
 640   FILE(STRINGS ${CMAKE_HOME_DIRECTORY}/.gitversion GIT_VERSION)
 641 endif()
 642
 643 if(GIT_VERSION)
 644   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} at commit ${GIT_VERSION}")
 645 endif()
 646 if(GIT_DATE)
 647   set(SIMGRID_VERSION_BANNER "${SIMGRID_VERSION_BANNER} (${GIT_DATE})")
 648 endif()
 649
 650 ### Generate the required headers and scripts
 651 #############################################
 652 # Avoid triggering a (full) rebuild by touching the files if they did not really change
 653 configure_file("${CMAKE_HOME_DIRECTORY}/tools/cmake/src/internal_config.h.in" "${CMAKE_BINARY_DIR}/src/internal_config.h.generated"    @ONLY IMMEDIATE)
 654 configure_file("${CMAKE_HOME_DIRECTORY}/include/simgrid_config.h.in"          "${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated" @ONLY IMMEDIATE)
 655 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/src/internal_config.h.generated ${CMAKE_BINARY_DIR}/src/internal_config.h)
 656 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated ${CMAKE_BINARY_DIR}/include/simgrid_config.h)
 657 file(REMOVE ${CMAKE_BINARY_DIR}/src/internal_config.h.generated)
 658 file(REMOVE ${CMAKE_BINARY_DIR}/include/simgrid_config.h.generated)
 659
 660 # We need two versions of the SMPI scripts because they contain the path to the library
 661 # so, it depends of whether SimGrid is installed, or run from the sources (during the build)
 662
 663 file(READ ${CMAKE_HOME_DIRECTORY}/src/smpi/smpitools.sh SMPITOOLS_SH) # Definitions shared amongst all SMPI scripts, inlined in each of them
 664
 665 ### SMPI script used when simgrid is installed
 666 set(exec_prefix ${CMAKE_INSTALL_PREFIX})
 667 set(includeflag "-I${CMAKE_INSTALL_PREFIX}/include -I${CMAKE_INSTALL_PREFIX}/include/smpi")
 668 set(includedir "${CMAKE_INSTALL_PREFIX}/include")
 669 set(libdir ${exec_prefix}/lib)
 670 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_INSTALL_PREFIX}/lib")
 671 if(NS3_LIBRARY_PATH)
 672   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 673 endif()
 674 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 675
 676 configure_file(${CMAKE_HOME_DIRECTORY}/include/smpi/mpif.h.in ${CMAKE_BINARY_DIR}/include/smpi/mpif.h @ONLY)
 677 foreach(script cc cxx ff f90 run)
 678   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/bin/smpi${script} @ONLY)
 679 endforeach()
 680
 681 ### SMPI scripts used when compiling simgrid
 682 set(exec_prefix "${CMAKE_BINARY_DIR}/smpi_script/")
 683 set(includeflag "-I${CMAKE_HOME_DIRECTORY}/include -I${CMAKE_HOME_DIRECTORY}/include/smpi")
 684 set(includeflag "${includeflag} -I${CMAKE_BINARY_DIR}/include -I${CMAKE_BINARY_DIR}/include/smpi")
 685 set(includedir "${CMAKE_HOME_DIRECTORY}/include")
 686 set(libdir "${CMAKE_BINARY_DIR}/lib")
 687 set(CMAKE_SMPI_COMMAND "export LD_LIBRARY_PATH=\"${CMAKE_BINARY_DIR}/lib")
 688 if(NS3_LIBRARY_PATH)
 689   set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:${NS3_LIBRARY_PATH}")
 690 endif()
 691 set(CMAKE_SMPI_COMMAND "${CMAKE_SMPI_COMMAND}:\${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}\"")
 692
 693 foreach(script cc cxx ff f90 run)
 694   configure_file(${CMAKE_HOME_DIRECTORY}/src/smpi/smpi${script}.in ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script} @ONLY)
 695 endforeach()
 696
 697 if(NOT WIN32)
 698   foreach(script cc cxx ff f90 run)
 699     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpi${script})
 700     execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/smpi_script/bin/smpi${script})
 701   endforeach()
 702 endif()
 703
 704 set(generated_headers_to_install
 705   ${CMAKE_CURRENT_BINARY_DIR}/include/smpi/mpif.h
 706   ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h
 707   )
 708
 709 set(generated_headers
 710   ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h
 711   )
 712
 713 set(generated_files_to_clean
 714   ${generated_headers}
 715   ${generated_headers_to_install}
 716   ${CMAKE_BINARY_DIR}/bin/smpicc
 717   ${CMAKE_BINARY_DIR}/bin/smpicxx
 718   ${CMAKE_BINARY_DIR}/bin/smpiff
 719   ${CMAKE_BINARY_DIR}/bin/smpif90
 720   ${CMAKE_BINARY_DIR}/bin/smpirun
 721   ${CMAKE_BINARY_DIR}/bin/colorize
 722   ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
 723   ${CMAKE_BINARY_DIR}/examples/smpi/tracing/smpi_traced.trace
 724   )
 725
 726 if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_HOME_DIRECTORY}")
 727   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt COPYONLY)
 728   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt COPYONLY)
 729   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allReduce.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt COPYONLY)
 730   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_barrier.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt COPYONLY)
 731   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_bcast.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt COPYONLY)
 732   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_with_isend.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt COPYONLY)
 733   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt COPYONLY)
 734   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_alltoallv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt COPYONLY)
 735   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_waitall.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt COPYONLY)
 736   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_reducescatter.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt COPYONLY)
 737   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_gather.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt COPYONLY)
 738   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay/actions_allgatherv.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt COPYONLY)
 739   configure_file(${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/hostfile ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile COPYONLY)
 740
 741   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/description_file ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file COPYONLY)
 742   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/README ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README COPYONLY)
 743   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/smpi_replay.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt COPYONLY)
 744   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt COPYONLY)
 745   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt COPYONLY)
 746   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt COPYONLY)
 747   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt COPYONLY)
 748   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt COPYONLY)
 749   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt COPYONLY)
 750   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt COPYONLY)
 751   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt COPYONLY)
 752   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt COPYONLY)
 753   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt COPYONLY)
 754   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt COPYONLY)
 755   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt COPYONLY)
 756   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt COPYONLY)
 757   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt COPYONLY)
 758   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt COPYONLY)
 759   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt COPYONLY)
 760   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt COPYONLY)
 761   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt COPYONLY)
 762   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt COPYONLY)
 763   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt COPYONLY)
 764   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt COPYONLY)
 765   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt COPYONLY)
 766   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt COPYONLY)
 767   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt COPYONLY)
 768   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt COPYONLY)
 769   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt COPYONLY)
 770   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt COPYONLY)
 771   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt COPYONLY)
 772   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt COPYONLY)
 773   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt COPYONLY)
 774   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt COPYONLY)
 775   configure_file(${CMAKE_HOME_DIRECTORY}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt COPYONLY)
 776
 777   set(generated_files_to_clean
 778     ${generated_files_to_clean}
 779     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions0.txt
 780     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions1.txt
 781     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allReduce.txt
 782     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_barrier.txt
 783     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_bcast.txt
 784     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_with_isend.txt
 785     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoall.txt
 786     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_alltoallv.txt
 787     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_waitall.txt
 788     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_gather.txt
 789     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_allgatherv.txt
 790     ${CMAKE_BINARY_DIR}/examples/smpi/replay/actions_reducescatter.txt
 791     ${CMAKE_BINARY_DIR}/teshsuite/smpi/hostfile
 792     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/description_file
 793     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/README
 794     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/smpi_replay.txt
 795     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace0.txt
 796     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace1.txt
 797     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace2.txt
 798     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace3.txt
 799     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace4.txt
 800     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace5.txt
 801     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace6.txt
 802     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace7.txt
 803     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace8.txt
 804     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace9.txt
 805     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace10.txt
 806     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace11.txt
 807     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace12.txt
 808     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace13.txt
 809     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace14.txt
 810     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace15.txt
 811     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace16.txt
 812     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace17.txt
 813     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace18.txt
 814     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace19.txt
 815     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace20.txt
 816     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace21.txt
 817     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace22.txt
 818     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace23.txt
 819     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace24.txt
 820     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace25.txt
 821     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace26.txt
 822     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace27.txt
 823     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace28.txt
 824     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace29.txt
 825     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace30.txt
 826     ${CMAKE_BINARY_DIR}/examples/smpi/replay_multiple/ti_traces_32_1/ti_trace31.txt
 827     )
 828 endif()
 829
 830 SET_DIRECTORY_PROPERTIES(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES
 831   "${generated_files_to_clean}")
 832
 833 ### Define source packages for Libs
 834 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/DefinePackages.cmake)
 835
 836 ### Build some Maintainer files
 837 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MaintainerMode.cmake)
 838 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/UnitTesting.cmake)
 839
 840 ### Setup gcc & clang flags
 841 if (NOT MSVC)
 842   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/GCCFlags.cmake)
 843 endif()
 844
 845 ### Make Libs
 846 if(NOT WIN32)
 847   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLib.cmake)
 848 else()
 849   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/MakeLibWin.cmake)
 850 endif()
 851
 852 if(enable_java)
 853   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Java.cmake)
 854 endif()
 855
 856 ### Make tests
 857 if(enable_memcheck_xml)
 858   set(enable_memcheck true)
 859 endif()
 860
 861 INCLUDE(CTest)
 862 ENABLE_TESTING()
 863 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Tests.cmake)
 864 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/CTestConfig.cmake)
 865
 866 ### Define subdirectories
 867 foreach(cmakefile ${CMAKEFILES_TXT})
 868   string(REPLACE "/CMakeLists.txt" "" repository ${cmakefile})
 869   add_subdirectory("${CMAKE_HOME_DIRECTORY}/${repository}")
 870 endforeach()
 871
 872 ### Setup the distrib
 873 include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Distrib.cmake)
 874
 875 ### Build the doc (Windows downloads the doc instead of regenerating)
 876 #
 877 if(NOT WIN32)
 878   include(${CMAKE_HOME_DIRECTORY}/tools/cmake/Documentation.cmake)
 879 else()
 880   find_program(WGET_PROGRAM  NAMES wget)
 881   message(STATUS "wget: ${WGET_PROGRAM}")
 882   if(WGET_PROGRAM)
 883     ADD_CUSTOM_TARGET(documentation
 884       COMMENT "Downloading the SimGrid documentation..."
 885       COMMAND ${WGET_PROGRAM} -r -np -nH -nd http://simgrid.gforge.inria.fr/simgrid/${release_version}/doc/
 886       WORKING_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html
 887     )
 888   endif()
 889 endif()
 890
 891 ### Print the result of configuration
 892 message("")
 893 message("##########################################")
 894 message("#### Content of src/internal_config.h ####")
 895 message("##########################################")
 896 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/src/internal_config.h config_output)
 897 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8) # Pass the file header
 898 foreach(line ${config_output})
 899   message("   ${line}")
 900 endforeach()
 901 message("##########################################")
 902 message("####   Content of simgrid_config.h    ####")
 903 message("##########################################")
 904 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/include/simgrid_config.h config_output)
 905 LIST(REMOVE_AT config_output 0 1 2 3 4 5 6 7 8 9 -1) # Pass the file header
 906 foreach(line ${config_output})
 907   message("   ${line}")
 908 endforeach()
 909 message("##########################################")
 910 message("####   End of configuration headers   ####")
 911 message("##########################################")
 912
 913 message("\nConfiguration of package `simgrid':")
 914 message("        Home directory ..............: ${CMAKE_HOME_DIRECTORY}")
 915 message("        Build Name ..................: ${BUILDNAME}")
 916 message("        Cmake Generator .............: ${CMAKE_GENERATOR}")
 917 message("        Site ........................: ${SITE}")
 918 message("        Install prefix ..............: ${CMAKE_INSTALL_PREFIX}")
 919 if(release)
 920   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (release build)")
 921 else()
 922   message("        Release .....................: simgrid-${release_version}${SIMGRID_VERSION_EXTRA} (development build)")
 923 endif()
 924 message("")
 925 message("        Compiler: C .................: ${CMAKE_C_COMPILER} (id: ${CMAKE_C_COMPILER_ID})")
 926 message("                version .............: ${CMAKE_C_COMPILER_VERSION}")
 927 message("                is gnu ..............: ${CMAKE_COMPILER_IS_GNUCC}")
 928 message("        Compiler: C++ ...............: ${CMAKE_CXX_COMPILER} (id: ${CMAKE_CXX_COMPILER_ID})")
 929 message("                version .............: ${CMAKE_CXX_COMPILER_VERSION}")
 930 if(${Java_FOUND})
 931   message("        Compiler: Javac .............: ${Java_JAVAC_EXECUTABLE}")
 932   message("                version .............: ${Java_VERSION_STRING}")
 933 if(${SWIG_FOUND})
 934   message("                SWIG ................: Version ${SWIG_VERSION} found.")
 935 else()
 936   message("                SWIG ................: Missing.")
 937 endif()
 938 endif()
 939 if(CMAKE_Fortran_COMPILER)
 940   message("        Compiler: Fortran ...........: ${CMAKE_Fortran_COMPILER} (id: ${CMAKE_Fortran_COMPILER_ID})")
 941   message("                version .............: ${CMAKE_Fortran_COMPILER_VERSION}")
 942 endif()
 943 message("        Linker: .....................: ${CMAKE_LINKER}")
 944 message("                version .............: ${LINKER_VERSION}")
 945 message("        Make program: ...............: ${CMAKE_MAKE_PROGRAM}")
 946 message("")
 947 message("        CFlags ......................: ${CMAKE_C_FLAGS}")
 948 message("        CXXFlags ....................: ${CMAKE_CXX_FLAGS}")
 949 message("        LDFlags .....................: ${CMAKE_C_LINK_FLAGS}")
 950 message("        with LTO ....................: ${enable_lto}")
 951 message("")
 952
 953 if (HAVE_NS3)
 954   message("        Compile NS-3 ................: yes (path: ${NS3_PATH})")
 955 else()
 956   message("        Compile NS-3 ................: NO  (hint: ${NS3_HINT})")
 957 endif()
 958
 959 if (${Java_FOUND})
 960   message("        Compile Java ................: yes")
 961   message("          Native lib in jar .........: ${enable_lib_in_jar}")
 962 else()
 963   message("        Compile Java ................: NO")
 964 endif()
 965 message("        Compile Lua .................: ${HAVE_LUA}")
 966 message("        Compile Smpi ................: ${HAVE_SMPI}")
 967 message("          Smpi fortran ..............: ${SMPI_FORTRAN}")
 968 message("          MPICH3 testsuite ..........: ${enable_smpi_MPICH3_testsuite}")
 969 message("          Privatization .............: ${HAVE_PRIVATIZATION}")
 970 message("        Compile Boost.Context support: ${HAVE_BOOST_CONTEXTS}")
 971 message("")
 972 message("        Maintainer mode .............: ${enable_maintainer_mode}")
 973 message("        Documentation................: ${enable_documentation}")
 974 message("        Model checking ..............: ${HAVE_MC}")
 975 message("        Jedule  mode ................: ${HAVE_JEDULE}")
 976 message("        Graphviz mode ...............: ${HAVE_GRAPHVIZ}")
 977 message("        Sigc++ mode .................: ${SIMGRID_HAVE_LIBSIG}")
 978 message("        Mallocators .................: ${enable_mallocators}")
 979 message("")
 980 message("        Simgrid dependencies ........: ${SIMGRID_DEP}")
 981 message("")
 982
 983 execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_BINARY_DIR}/Testing/Notes/)
 984 file(WRITE ${PROJECT_BINARY_DIR}/Testing/Notes/Build  "GIT version : ${GIT_VERSION}\n")
 985 file(APPEND ${PROJECT_BINARY_DIR}/Testing/Notes/Build "Release     : simgrid-${release_version}\n")
 986
 987 INCLUDE(Dart)