Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
renaming value of presence state to "presence" (to get a good time-slice value later on)
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.3.5-svn],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision: 6998 $)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AC_PROG_CXX
21 AM_PROG_GCJ
22
23 AM_INIT_AUTOMAKE([gnu -Wno-portability])
24 AC_CONFIG_MACRO_DIR(acmacro) 
25 ACLOCAL="$ACLOCAL -I acmacro"
26
27 dnl Next few lines is a hack to prevent libtool checking for F77
28 m4_undefine([AC_PROG_F77])
29 m4_defun([AC_PROG_F77],[])
30
31 dnl We do build a proper DLL when using win32
32 AC_LIBTOOL_WIN32_DLL
33 AC_PROG_LIBTOOL
34
35 SIMGRID_DEP=""
36 SMPI_DEP=""
37 GRAS_DEP=""
38
39
40 ###############
41 ## SVN version check
42 ##
43 if test -e .svn && echo $VERSION | grep -q svn; then
44   VERSION="$VERSION-r`svnversion`"
45   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
46   PACKAGE_STRING="$PACKAGE_STRING r`svnversion`"
47 else if test -e .git && echo $VERSION | grep -q svn; then
48   ver=`git log --oneline -1 | sed 's| .*||'`
49   VERSION=`echo "$VERSION-r$ver" | sed 's/svn/git/'`
50   PACKAGE_VERSION=`echo "$PACKAGE_VERSION-r$ver" | sed 's/svn/git/'`
51   PACKAGE_STRING=`echo "$PACKAGE_STRING r$ver" | sed 's/svn/git/'`
52 fi fi
53
54 ###############
55 ## System checks
56 ##
57 SG_CONFIGURE_PART([System checks...])
58 AC_PROG_CC(xlC gcc cc)
59 AM_SANITY_CHECK
60 AC_PROG_MAKE_SET
61 AC_CHECK_PRINTF_NULL
62 AC_CHECK_VA_COPY
63
64 # Checks for header files.
65 AC_HEADER_STDC
66 AC_HEADER_TIME
67 AC_CHECK_HEADERS([sys/socket.h \
68                   sys/stat.h \
69                   windows.h winsock.h winsock2.h \
70                   sys/time.h \
71                   errno.h unistd.h \
72                   execinfo.h\
73                   signal.h ])
74 AC_CHECK_FUNCS([gettimeofday usleep \
75                 getdtablesize \
76                 sysconf\
77                 readv\
78                 popen\
79                 signal])           
80   
81 dnl GNU systems before POSIX2008 need the _GNU_SOURCE definition to find getline (and simgrid does pass this)             
82 AC_MSG_CHECKING(a usable getline)
83 AC_LINK_IFELSE([
84     #define _GNU_SOURCE
85     #include <stdio.h>
86     int main(void){
87       FILE * fp;
88       char * line = NULL;
89       size_t len = 0;
90       getline(&line, &len, fp);
91     }
92   ],[
93     AC_MSG_RESULT(found)
94   ],[
95     AC_SUBST(need_getline, ["#define SIMGRID_NEED_GETLINE 1 /* enable the getline replacement*/"])
96     AC_DEFINE(SIMGRID_NEED_GETLINE, 1, enable the getline replacement)
97     AC_MSG_RESULT(not found (activating internal implementation))
98   ])
99
100 dnl AC_MSG_CHECKING(POSIX timer functions)
101 AC_CHECK_LIB(rt, [clock_gettime], [
102     AC_DEFINE(HAVE_POSIX_GETTIME, 1, POSIX timer functions were found)
103     SIMGRID_DEP="$SIMGRID_DEP -lrt"
104     GRAS_DEP="$GRAS_DEP -lrt"
105   ])
106
107 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
108 AC_FUNC_SNPRINTF
109 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
110 AC_CHECK_FUNC(  asprintf, :,[
111     AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf replacement)
112     AC_SUBST(need_asprintf, ["#define SIMGRID_NEED_ASPRINTF 1 /* enable the asprintf replacement */"]) 
113    ])
114 AC_CHECK_FUNC( vasprintf, :,[
115     AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf replacement)
116     AC_SUBST(need_vasprintf, ["#define SIMGRID_NEED_VASPRINTF 1 /*enable the vasprintf replacement */"]) 
117    ])
118
119 # Checks for typedefs, structures, and compiler characteristics.
120 AC_C_CONST
121 AC_C_INLINE
122 AC_TYPE_SIZE_T
123
124 ###################################
125 ## SimGrid and GRAS specific checks
126 ##
127
128 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
129 # Check architecture signature begin
130 GRAS_ARCH
131 # Check architecture signature end
132 GRAS_CHECK_STRUCT_COMPACTION
133
134
135 dnl ##
136 dnl ##  CONTEXT IMPLEMENTATION
137 dnl ##
138
139 SG_CONFIGURE_PART([Checking threads, contexts or assimilated...])
140
141 dnl #
142 dnl #  1. determine possibilities
143 dnl #
144
145 dnl #  check for MCSC method (ucontexts)
146 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
147
148 dnl #  check for pthread method
149 AC_CHECK_HEADERS([pthread.h])
150 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
151
152 if test x$pthread = xyes ; then
153   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
154   if test ${HAVE_SEM_INIT} = yes ; then
155      AC_MSG_CHECKING(if sem_init is compilable)
156      AC_TRY_COMPILE([#include <semaphore.h>],
157                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
158      if test ${HAVE_SEM_INIT} = yes ; then
159         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
160         AC_MSG_RESULT(yes)
161      else
162         AC_MSG_RESULT(no)
163      fi
164   fi
165   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
166   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
167      AC_MSG_CHECKING(if sem_timedwait is compilable)
168      AC_TRY_COMPILE([#include <semaphore.h>],
169                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
170      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
171         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
172         AC_MSG_RESULT(yes)
173      else
174         AC_MSG_RESULT(no)
175      fi
176   fi
177
178   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
179   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
180      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
181      AC_TRY_COMPILE([#include <pthread.h>],
182                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
183      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
184         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
185         AC_MSG_RESULT(yes)
186      else
187         AC_MSG_RESULT(no)
188      fi
189   fi
190 fi
191
192 dnl #
193 dnl #  2. make a general decision
194 dnl #
195
196 if test ".$mcsc" = .yes; then
197    # ucontext found
198    mcsc=yes
199 elif test ".$pthread" = .yes; then
200    # ucontext not found, but pthread found
201    pthread=yes
202 else
203     ac_header=windows.h
204     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
205     if test `eval echo '${'$as_ac_Header'}'` = yes; then
206       windows_context=yes
207     else
208       AC_ERROR([no appropriate backend found])
209     fi
210 fi
211 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
212
213
214 dnl #
215 dnl #  3. allow decision to be overridden by user
216 dnl #
217
218 AC_MSG_CHECKING(what kind of backend should we use)
219
220 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
221 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
222
223 AC_ARG_WITH(context,
224   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
225   with_context=auto)
226
227 if test "x$with_context$mcsc" = "xucontextno" ; then 
228   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
229 fi
230
231 case $with_context in
232  ucontext) ;;
233  pthread) ;;
234  pthreads) ;;
235  windows) ;;
236  auto) with_context=ucontext;;
237  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
238 esac
239
240 if test "x$with_context" = "xucontext" ; then
241   if test ".$mcsc" = .yes; then
242     AC_MSG_RESULT(found working ucontext. Great!)
243     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
244     AC_CHECK_HEADERS([valgrind/valgrind.h])
245   else
246     if test ".$windows_context" = .yes ; then
247       AC_MSG_RESULT(use windows context portability layer.)
248       with_context=windows
249     else
250       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
251       with_context=pthread
252     fi
253   fi
254 fi
255
256 if test "x$with_context" = "xpthread"; then
257   if test x$pthread != xyes ; then # reuse previous checks
258     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
259   fi
260   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
261   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
262 fi
263 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
264
265 dnl #
266 dnl #  4. determine a few additional details
267 dnl #
268
269 if test "x$with_context" = "xucontext" ; then
270 dnl #  direction of stack grow
271   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
272   if test ".$ac_cv_check_stackgrowth" = ".down"; then
273       PTH_STACK_GROWTH="down"
274   else
275       PTH_STACK_GROWTH="up"
276   fi
277   AC_SUBST(PTH_STACK_GROWTH)
278   
279   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
280 fi
281
282 #########################################
283 ## Check for libraries extra-dependencies
284 ##
285
286 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
287
288 if test xpthread=xyes ; then 
289   # if the pthreads are usable
290   if test "x$with_context" = "xpthread" ; then
291     # if we use them to implement the xbt_context
292     SIMGRID_DEP="$SIMGRID_DEP -lpthread"
293   fi
294   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
295   if test "x$with_context" != "xwindows" ; then
296     GRAS_DEP="$GRAS_DEP -lpthread"
297   fi
298 fi
299 AC_SEARCH_LIBS([connect],[socket],[],[],[]) # need -lsocket on solaris
300
301 #########################################
302 ## Build optional modules (gtnets)
303 ##
304 gtnets=no
305 AC_ARG_WITH(gtnets,
306   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
307   gtnets_path="$withval",gtnets_path="no")
308 if test "x$gtnets_path" = "xno" ; then
309   AC_MSG_RESULT(Eventually you will come to GTNetS.)
310 else  
311   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
312   AC_MSG_CHECKING(for gtnets)
313   AC_LANG_PUSH([C++])  
314   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
315   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
316   LDFLAGS_SAV=$LDFLAGS  
317   CPPFLAGS_SAV=$CPPFLAGS
318   CPPFLAGS+=$GTNETS_CPPFLAGS
319   LDFLAGS+=$GTNETS_LDFLAGS
320   AC_TRY_LINK([ #include <simulator.h>
321               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
322   CPPFLAGS=$CPPFLAGS_SAV
323   LDFLAGS=$LDFLAGS_SAV
324   AC_LANG_POP([C++])  
325 fi
326
327 if test "x$gtnets" = "xyes" ; then
328   AC_MSG_RESULT(Enabling GTNETS support.)
329   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
330   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
331   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
332 fi
333 AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
334
335
336
337 AC_SUBST([SIMGRID_DEP])
338 AC_SUBST([SMPI_DEP])
339
340 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
341 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
342
343 AC_MSG_CHECKING(for extra dependencies of libgras)
344 case $host_os in
345   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
346             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
347             AC_DEFINE(CONTEXT_THREADS,1);;
348 esac
349
350
351
352 if test "x$GRAS_DEP" = x; then 
353    AC_MSG_RESULT(none)
354 else
355    AC_MSG_RESULT($GRAS_DEP)
356 fi
357 AC_SUBST([GRAS_DEP])
358
359 ##############################################
360 ## Enhance maintainer mode and SUBST variables
361 ## (must be placed after any compilation tests since our overprotective flags
362 ##  let some tests fail)
363
364 # Check whether we are doing a regular build or a GRAMINE (minimal) one
365 # Next line is modified by sed when building gramine source tree
366 gramine_mode=no
367 if test x$gramine_mode = xyes
368 then
369   USE_MAINTAINER_MODE=no
370 fi
371 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
372
373 AM_MAINTAINER_MODE
374 if test x$USE_MAINTAINER_MODE = xyes 
375 then
376    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
377    force_compile_warnings=yes   
378 fi
379 SG_COMPILE_FLAGS
380
381 ##
382 ## Support for tracing instrumentation
383 ##
384 AC_CONFIG_HEADERS([include/instr/config.h])
385 AC_ARG_ENABLE(tracing,
386               AS_HELP_STRING([--enable-tracing],[Activate the instrumentation so SimGrid can be traced to be visualized]),
387               [tracing=$enableval],
388               [tracing=no])
389 if test x$tracing = xyes ; then
390      AC_DEFINE([HAVE_TRACING],[1], [defines whether instrumentation must be compiled or not])
391 fi
392
393 ##
394 ## Support for the supernovae compilation mode
395 ##
396 AC_ARG_ENABLE(supernovae,
397               AS_HELP_STRING([--enable-supernovae],[Put the whole library in one compilation unit only to help gcc optimizing the code]),
398               [supernovae=$enableval],
399               [supernovae=no])
400 AM_CONDITIONAL(SUPERNOVAE_MODE, test x$supernovae != xno)
401
402 AC_SUBST([CFLAGS])
403 AC_SUBST([CPPFLAGS])
404 AC_SUBST([LDFLAGS])
405 AC_SUBST([AM_CPPFLAGS])
406 AC_SUBST([abs_builddir])
407 AC_SUBST([abs_srcdir])
408 AC_SUBST([abs_top_builddir])
409 AC_SUBST([abs_top_srcdir])
410
411 ##############################################
412 ## Specific mode for build daemons.
413 ## (they compile the SVN without having the autotools installed)
414 AC_ARG_ENABLE(botbuild,
415               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
416               botbuild=$enableval,botbuild=no)
417 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
418
419 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
420   echo "ERROR: "
421   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
422   echo "ERROR: For this, just call configure this way:"
423   echo "ERROR:"
424   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
425   echo "ERROR:"
426   exit 1
427 fi
428
429
430 SG_CONFIGURE_PART(Checking Java bindings...)
431 # Java cruft
432 AC_ARG_ENABLE(java,
433               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
434               disable_java=$enableval,disable_java=yes)
435 if test "x$disable_java" != "xyes" ; then
436    use_java="disabled by user"
437 else
438   AC_PATH_PROG([JAVAC], [javac], `which javac`)
439   AC_PATH_PROG([JAVA],  [java] , `which java`)
440   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
441   AC_CHECK_HEADERS(jni.h)
442   if test -n "$JAVAC" && test -n "$JAVA" && test -n "$JAR" && test "x$ac_cv_header_jni_h" = "xyes" ; then
443      use_java="yes"
444      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
445   else   
446      use_java="no (you may want to install the java-gcj-compat-dev package)"
447   fi
448 fi
449 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
450 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
451
452
453 SG_CONFIGURE_PART(Checking Lua bindings...)
454 AC_ARG_ENABLE(lua,
455               AS_HELP_STRING([--disable-lua], [To not compile the Lua bindings even if the tools are found]),
456               disable_lua=$enableval,disable_lua=yes)
457 if test "x$disable_lua" != "xyes" ; then
458    use_lua="disabled by user"
459 else
460   AC_CHECK_HEADERS(lua5.1/lualib.h)
461   if test "x$ac_cv_header_lua5_1_lualib_h" = "xyes" ; then
462      use_lua="yes"
463      AC_DEFINE(HAVE_LUA,1, [defines whether Lua bindings must be compiled or not])
464      SIMGRID_DEP="${SIMGRID_DEP} -ldl -llua5.1"
465   else   
466      use_lua="no (you may want to install the liblua5.1-0-dev package)"
467   fi
468 fi
469 AC_MSG_RESULT(decide whether to compile lua bindings... $use_lua)
470 AM_CONDITIONAL(HAVE_LUA,test "x$use_lua" = "xyes")
471
472 SG_CONFIGURE_PART(Checking Ruby bindings...)
473 # Ruby cruft
474 AC_ARG_ENABLE(ruby,
475               AS_HELP_STRING([--disable-ruby], [To not compile the Ruby bindings even if the tools are found]),
476               disable_ruby=$enableval,disable_ruby=yes)
477 if test "x$disable_ruby" != "xyes" ; then
478    use_ruby="disabled by user"
479 else
480   CPPFLAGS="-I/usr/lib/ruby/1.8/i486-linux/ $CPPFLAGS"
481   AC_MSG_CHECKING(checking ruby.h usability and presence)
482   AC_COMPILE_IFELSE([
483     #undef PACKAGE_NAME
484     #undef PACKAGE_TARNAME
485     #undef PACKAGE_VERSION
486     #undef PACKAGE_STRING
487     #undef PACKAGE_BUGREPORT
488     #include <ruby.h>
489   ], use_ruby=yes,use_ruby="no (Package ruby1.8-dev missing)")
490   AC_MSG_RESULT($use_ruby)
491   if test "x$use_ruby" = "xyes" ; then
492      AC_DEFINE(HAVE_RUBY,1, [defines whether Ruby bindings must be compiled or not])
493      SIMGRID_DEP="${SIMGRID_DEP} -lruby1.8"
494   else
495      AC_MSG_RESULT(Please install the ruby1.8-dev package (on debian and similar) to get ruby bindings)
496   fi
497 fi
498 AC_MSG_RESULT(decide whether to compile ruby bindings... $use_ruby)
499 AM_CONDITIONAL(HAVE_RUBY,test "x$use_ruby" = "xyes")
500
501
502 #####################
503 ## Check for programs
504 ##
505
506 SG_CONFIGURE_PART(Checking programs...)
507 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
508 WARNING="This file is generated, do not edit"
509 AC_SUBST(WARNING)
510
511
512 # Can we rebuild the parsers?
513 # We really want flex and refuse other lex. So, the parser is portable and
514 # does not induce extra lib dependency
515 AC_PROG_FLEX(2.5.30)
516                 
517 # Can we rebuild the xml-lexers from the XML specification?
518 # if not, simply touch the flex source files (which are distributed in
519 #  tarballs even if generated by flexml) and hope for the best.
520 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
521 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
522
523 # Check for doxygen when in maintainer mode which is helpful to build doc & dist
524 AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
525 AC_PATH_PROG(FIG2DEV,fig2dev,`which fig2dev`)
526 AM_CONDITIONAL(HAVE_DOXYGEN,test x$DOXYGEN != x &&
527                             test x$FIG2DEV != x)
528
529 # Can we rebuild the publication list from the bib file?
530 AC_CHECK_PROG(BIBTEX,bibtex,`which flexml`,NOTFOUND)
531 AC_CHECK_PROG(BIBTOOL,bibtool,`which bibtool`,NOTFOUND)
532 AC_CHECK_PROG(ICONV,iconv,`which iconv`,NOTFOUND)
533 AC_CHECK_PROG(BIBTEX2HTML,bibtex2html,`which bibtex2html`,NOTFOUND)
534
535 BIBTEX2HTML_VER="date"
536 if test "x$BIBTEX2HTML" != "xNOTFOUND" ; then
537    BIBTEX2HTML_VER=`$BIBTEX2HTML --help 2>&1 | grep date`
538 fi;
539
540 AC_MSG_CHECKING(whether you have the right bibtex2html and will be able to build HTML files from the bibtex file)
541 AM_CONDITIONAL(HAVE_BIBTEX2HTML,test "x$BIBTEX2HTML_VER" == "x"     &&
542                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
543                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
544                                 test "x$ICONV" != "xNOTFOUND"         )
545
546 if test "x$BIBTEX2HTML_VER" == "x"     &&
547                                 test "x$BIBTEX2HTML" != "xNOTFOUND" &&
548                                 test "x$BIBTOOL" != "xNOTFOUND"     &&
549                                 test "x$ICONV" != "xNOTFOUND"; then
550    AC_MSG_RESULT(yes)
551 else
552    AC_MSG_RESULT(no)
553 fi
554
555 # Can we extract really usable backtraces? (also need the popen function)
556 AC_PATH_PROG(ADDR2LINE, addr2line)
557 if test x$ADDR2LINE != x ; then
558   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
559 fi
560
561 AC_SUBST(ac_configure_args)
562 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
563 # Can we make status line about the compilation result?
564 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
565 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
566 AC_SUBST(build_id)
567
568 ###################
569 ## Makes the output
570 ##
571
572
573 #
574 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
575 #  src/amok/Makefile
576
577 SG_CONFIGURE_PART(Generating files...)
578
579 # Core of the libraries
580
581 AC_CONFIG_FILES([
582   Makefile
583   include/Makefile
584   include/simgrid_config.h
585   src/Makefile
586   src/context_sysv_config.h
587 ])
588
589 # Tools being embeeded in gramine (stub generator)
590 AC_CONFIG_FILES([
591   tools/Makefile
592     tools/gras/Makefile
593     tools/tesh/Makefile
594 ])
595 #    tools/tesh2/Makefile
596
597
598 # GRAMINE_CUT_BEGIN
599
600 # Tools NOT being embeeded in gramine
601 AC_CONFIG_FILES([
602   tools/graspe-slave
603 ],[
604     for file in                                                 \
605      tools/graspe-slave           tools/graspe-master           \
606      checkall                     examples/java/runtest         \
607      src/mk_supernovae.sh                                       \
608     ; do                                                        \
609       test -e $file && chmod +x $file;                          \
610     done
611 ])
612
613 # build tools && Testsuite
614
615 AC_CONFIG_FILES([  
616   buildtools/Makefile
617   testsuite/Makefile
618   testsuite/run_tests    
619 ],[
620     for file in                                                 \
621      testsuite/run_tests                                        \
622     ; do                                                        \
623       test -e $file && chmod +x $file;                          \
624     done
625 ])
626
627 # Teshsuite (testsuite using tesh)
628 AC_CONFIG_FILES([  
629   teshsuite/Makefile
630 ])
631
632 # Documentation
633 AC_CONFIG_FILES([
634   doc/Makefile
635   doc/Doxyfile
636 ])
637
638 # Examples
639
640 #      examples/gras/p2p/Makefile
641 #      examples/gras/p2p/chord/Makefile
642 #      examples/gras/p2p/can/Makefile
643
644 AC_CONFIG_FILES([
645     examples/java/Makefile
646       examples/java/basic/Makefile
647       examples/java/comm_time/Makefile
648       examples/java/suspend/Makefile
649       examples/java/ping_pong/Makefile
650 ])
651
652 AC_CONFIG_FILES([
653   examples/Makefile 
654     examples/msg/Makefile
655     examples/simdag/Makefile
656     examples/gras/Makefile
657       examples/gras/ping/Makefile   
658       examples/gras/rpc/Makefile
659       examples/gras/spawn/Makefile
660       examples/gras/synchro/Makefile
661       examples/gras/timer/Makefile
662       examples/gras/properties/Makefile
663       examples/gras/chrono/Makefile
664       examples/gras/mutual_exclusion/simple_token/Makefile
665       examples/gras/mmrpc/Makefile
666       examples/gras/pmm/Makefile
667       examples/gras/all2all/Makefile
668     examples/amok/Makefile       
669     examples/smpi/Makefile       
670 ])
671 #      examples/gras/replay/Makefile
672
673 AC_CONFIG_FILES([
674   src/smpi/smpicc
675   src/smpi/smpirun
676 ],[
677     for file in                                                 \
678       src/smpi/smpicc                                           \
679       src/smpi/smpirun                                          \
680     ; do                                                        \
681       test -e $file && chmod +x $file;                          \
682     done
683 ])
684
685 # GRAMINE_CUT_END
686
687 AC_OUTPUT
688
689 echo "
690
691 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
692
693         Compiler:        ${CC} (version: ${GCC_VERSION})
694         
695         CFlags:          ${CFLAGS}
696         CPPFlags:        ${CPPFLAGS}
697         LDFlags:         ${LDFLAGS}
698
699         Context backend: ${with_context}
700         Compile Java:    ${use_java}
701         Compile Lua:     ${use_lua}
702         Compile Ruby:    ${use_ruby}
703         
704         Maintainer mode: ${USE_MAINTAINER_MODE}
705         Supernovae mode: ${supernovae}
706
707 "
708 if test x$botbuild = xyes ; then
709   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
710   echo
711 fi
712
713 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
714   echo "WARNING: "
715   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
716   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
717   echo "WARNING:"
718   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
719   echo "WARNING:"
720 fi
721
722 echo $build_id > stamp.configure
723
724 exit 0;