Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
regenerate the lexer
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[2.97-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15
16 AM_INIT_AUTOMAKE(gnu)
17 AC_CONFIG_MACRO_DIR(acmacro) 
18 ACLOCAL="$ACLOCAL -I acmacro"
19 AC_PROG_LIBTOOL
20
21 ###############
22 ## System checks
23 ##
24 SG_CONFIGURE_PART(System checks...)
25 AC_PROG_CC(xlC gcc cc)
26 AM_SANITY_CHECK
27 AC_PROG_MAKE_SET
28 AC_CHECK_PRINTF_NULL
29 AC_CHECK_VA_COPY
30
31 # Checks for header files.
32 AC_HEADER_STDC
33 AC_HEADER_TIME
34 AC_CHECK_HEADERS([sys/socket.h \
35                   sys/stat.h \
36                   windows.h winsock.h winsock2.h \
37                   sys/time.h \
38                   errno.h unistd.h \
39                   execinfo.h])
40 AC_CHECK_FUNCS([gettimeofday usleep \
41                 getdtablesize \
42                 sysconf])
43                 
44 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
45 AC_FUNC_SNPRINTF
46 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
47 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
48 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
49 # we don't use those:
50 # A C_CHECK_FUNC( asnprintf, :,   A C_DEFINE(NEED_ASNPRINTF,  1, enable the asnprintf  replacement))
51 # A C_CHECK_FUNC(vasnprintf, :,   A C_DEFINE(NEED_VASNPRINTF, 1, enable the vansprintf replacement))
52
53
54 # Checks for typedefs, structures, and compiler characteristics.
55 AC_C_CONST
56 AC_C_INLINE
57 AC_TYPE_SIZE_T
58
59 ###################################
60 ## SimGrid and GRAS specific checks
61 ##
62
63 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
64 # Check architecture signature begin
65 GRAS_ARCH
66 # Check architecture signature end
67 GRAS_CHECK_STRUCT_COMPACTION
68
69
70 dnl ##
71 dnl ##  CONTEXT IMPLEMENTATION
72 dnl ##
73
74 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
75
76 dnl #
77 dnl #  1. determine possibilities
78 dnl #
79
80 dnl #  check for MCSC method
81 AC_MSG_CHECKING(on top of what can we build the contexts)
82 AC_CHECK_HEADER(ucontext.h,,, [#include <sys/types.h>])
83 AC_CHECK_FUNCS(makecontext swapcontext getcontext setcontext)
84 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
85
86 dnl #  check for pthread method
87 AC_CHECK_HEADERS([pthread.h])
88 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
89
90 dnl #
91 dnl #  2. make a general decision
92 dnl #
93
94 if test ".$mcsc" = .yes; then
95    mcsc=yes
96 elif test ".$pthread" = .yes; then
97    pthread=yes
98 else
99     ac_header=windows.h
100     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
101     if test `eval echo '${'$as_ac_Header'}'` = yes; then
102       windows_context=yes
103     else
104       AC_ERROR([no appropriate backend found])
105     fi
106 fi
107
108 dnl #
109 dnl #  3. allow decision to be overridden by user
110 dnl #
111
112 AC_MSG_CHECKING(what kind of backend should we use)
113 AC_ARG_WITH(context,
114   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
115   with_context=auto)
116 case $with_context in
117  ucontext) ;;
118  pthread) ;;
119  windows) ;;
120  auto) with_context=ucontext;;
121  *) AC_MSG_ERROR("--with-context must be either ucontext or pthread") ;;
122 esac
123
124 if test "x$with_context" = "xucontext" ; then
125   if test ".$mcsc" = .yes; then
126     AC_MSG_RESULT(found working ucontext. Great!)
127     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
128   else
129     if test ".$windows_context" = .yes ; then
130       AC_MSG_RESULT(use windows context portability layer.)
131       with_context=windows
132     else
133       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
134       with_context=pthread
135     fi
136   fi
137 fi
138
139 if test "x$with_context" = "xpthread"; then
140   AC_CHECK_HEADERS([pthread.h])
141   AC_CHECK_LIB(pthread,pthread_create,,
142     [AC_MSG_ERROR([[Cannot find pthreads, no way (try --with-context=ucontext if you haven't already tried).]])])
143   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
144   AC_MSG_RESULT(You have pthreads. Let's use them.)
145 fi
146
147 dnl #
148 dnl #  4. determine a few additional details
149 dnl #
150
151 if test "x$with_context" = "xucontext" ; then
152 dnl #  direction of stack grow
153   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
154   if test ".$ac_cv_check_stackgrowth" = ".down"; then
155       PTH_STACK_GROWTH="down"
156   else
157       PTH_STACK_GROWTH="up"
158   fi
159   AC_SUBST(PTH_STACK_GROWTH)
160   
161   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
162 fi
163
164 #########################################
165 ## Check for libraries extra-dependencies
166 ##
167
168 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
169 SIMGRID_DEP=""
170 AC_SUBST([SIMGRID_DEP])
171
172 GRAS_DEP=""
173 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
174 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
175
176 AC_MSG_CHECKING(for extra dependencies of libgras)
177 case $host_os in
178   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32" ;;
179 esac
180            
181 if test "x$GRAS_DEP" = x; then 
182    AC_MSG_RESULT(none)
183 else
184    AC_MSG_RESULT($GRAS_DEP)
185 fi
186 AC_SUBST([GRAS_DEP])
187
188 ##############################################
189 ## Enhance maintainer mode and SUBST variables
190 ## (must be placed after any compilation tests since our overprotective flags
191 ##  let some tests fail)
192
193 AM_MAINTAINER_MODE
194 if test x$USE_MAINTAINER_MODE = xyes 
195 then
196    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
197    enable_compile_warnings=yes
198 fi
199 SG_COMPILE_FLAGS
200
201 AC_SUBST(CFLAGS)
202 AC_SUBST(CPPFLAGS)
203 AC_SUBST(LDFLAGS)
204
205 #####################
206 ## Check for programs
207 ##
208
209 SG_CONFIGURE_PART(Check for programs...)
210 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
211 WARNING="This file is generated, do not edit"
212 AC_SUBST(WARNING)
213
214 # Can we rebuild the parsers?
215 # We really want flex and refuse other lex. So, the parser is portable and
216 # does not induce extra lib dependency
217 AC_PROG_FLEX(2.5.30)
218                 
219 # Can we rebuild the xml-lexers from the XML specification?
220 # if not, simply touch the flex source files (which are distributed in
221 #  tarballs even if generated by flexml) and hope for the best.
222 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
223 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
224
225 ###################
226 ## Makes the output
227 ##
228
229
230 #    examples/pastry/Makefile    examples/pastry/test_sg
231 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
232 #  src/amok/Makefile
233
234 SG_CONFIGURE_PART(Generating files...)
235 AC_CONFIG_FILES([
236   Makefile
237   include/Makefile
238   src/Makefile
239   src/ucontext_stack.h
240   examples/Makefile 
241     examples/msg/Makefile           examples/msg/run_msg_test
242     examples/gras/Makefile 
243       examples/gras/ping/Makefile   examples/gras/ping/test_sg  examples/gras/ping/test_rl
244       examples/gras/timer/Makefile  examples/gras/timer/test_sg examples/gras/timer/test_rl
245       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
246       examples/gras/tokenS/Makefile examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl
247     examples/amok/Makefile       
248       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
249   doc/Makefile
250     doc/Doxyfile
251   tools/graspe-slave            tools/Makefile
252     tools/gras/Makefile
253   testsuite/Makefile
254   testsuite/run_tests    
255   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
256 ],[
257     for file in                                                 \
258      testsuite/run_tests                                        \
259      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
260      tools/graspe-slave           tools/graspe-master           \
261      \
262      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
263      \
264      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
265      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
266      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
267      examples/gras/tokenS/test_sg examples/gras/tokenS/test_rl  \
268      examples/msg/run_msg_test                                  \
269     ; do                                                        \
270       test -e $file && chmod +x $file;                          \
271     done
272 ])
273
274
275 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
276 #    examples/gras/pastry/test_sg   
277
278
279
280 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
281 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
282
283
284
285 AC_OUTPUT
286
287 echo "
288
289 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
290
291         Compiler:        ${CC} (version: ${GCC_VERSION})
292         
293         CFlags:          ${CFLAGS}
294         LDFlags:         ${LDFLAGS}
295
296         Context backend: ${with_context}
297 "
298
299 exit 0;