Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Erm
[simgrid.git] / configure.ac
1
2 ######################
3 ## Setup the autotools
4 ##
5
6 AC_PREREQ(2.59)
7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
8 AC_CONFIG_SRCDIR([include/gras.h])
9 AC_CONFIG_HEADERS([src/gras_config.h])
10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
11
12 AC_REVISION($Revision$)
13 AC_CANONICAL_TARGET
14 AC_LANG([C])
15 AM_PROG_GCJ
16
17 AM_INIT_AUTOMAKE(gnu)
18 AC_CONFIG_MACRO_DIR(acmacro) 
19 ACLOCAL="$ACLOCAL -I acmacro"
20
21 dnl Next few lines is a hack to prevent libtool checking for F77
22 m4_undefine([AC_PROG_F77])
23 m4_defun([AC_PROG_F77],[])
24
25 dnl We do build a proper DLL when using win32
26 AC_LIBTOOL_WIN32_DLL
27 AC_PROG_LIBTOOL
28
29 ###############
30 ## System checks
31 ##
32 SG_CONFIGURE_PART(System checks...)
33 AC_PROG_CC(xlC gcc cc)
34 AM_SANITY_CHECK
35 AC_PROG_MAKE_SET
36 AC_CHECK_PRINTF_NULL
37 AC_CHECK_VA_COPY
38
39 # Checks for header files.
40 AC_HEADER_STDC
41 AC_HEADER_TIME
42 AC_CHECK_HEADERS([sys/socket.h \
43                   sys/stat.h \
44                   windows.h winsock.h winsock2.h \
45                   sys/time.h \
46                   errno.h unistd.h \
47                   execinfo.h\
48                   signal.h ])
49 AC_CHECK_FUNCS([gettimeofday usleep \
50                 getdtablesize \
51                 sysconf\
52                 readv\
53                 popen\
54                 signal\
55                 getline])
56                 
57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
58 AC_FUNC_SNPRINTF
59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
62
63 # Checks for typedefs, structures, and compiler characteristics.
64 AC_C_CONST
65 AC_C_INLINE
66 AC_TYPE_SIZE_T
67
68 ###################################
69 ## SimGrid and GRAS specific checks
70 ##
71
72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
73 # Check architecture signature begin
74 GRAS_ARCH
75 # Check architecture signature end
76 GRAS_CHECK_STRUCT_COMPACTION
77
78
79 dnl ##
80 dnl ##  CONTEXT IMPLEMENTATION
81 dnl ##
82
83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
84
85 dnl #
86 dnl #  1. determine possibilities
87 dnl #
88
89 dnl #  check for MCSC method
90 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
91
92 dnl #  check for pthread method
93 AC_CHECK_HEADERS([pthread.h])
94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
95
96 dnl #
97 dnl #  2. make a general decision
98 dnl #
99
100 if test ".$mcsc" = .yes; then
101    mcsc=yes
102 elif test ".$pthread" = .yes; then
103    pthread=yes
104 else
105     ac_header=windows.h
106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
108       windows_context=yes
109     else
110       AC_ERROR([no appropriate backend found])
111     fi
112 fi
113
114 dnl #
115 dnl #  3. allow decision to be overridden by user
116 dnl #
117
118 AC_MSG_CHECKING(what kind of backend should we use)
119
120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
122
123 AC_ARG_WITH(context,
124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
125   with_context=auto)
126
127 if test "x$with_context$mcsc" = "xucontextno" ; then 
128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
129 fi
130
131 case $with_context in
132  ucontext) ;;
133  pthread) ;;
134  pthreads) ;;
135  windows) ;;
136  auto) with_context=ucontext;;
137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
138 esac
139
140 if test "x$with_context" = "xucontext" ; then
141   if test ".$mcsc" = .yes; then
142     AC_MSG_RESULT(found working ucontext. Great!)
143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
144   else
145     if test ".$windows_context" = .yes ; then
146       AC_MSG_RESULT(use windows context portability layer.)
147       with_context=windows
148     else
149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
150       with_context=pthread
151     fi
152   fi
153 fi
154
155 if test "x$with_context" = "xpthreads"; then
156   with_context=pthread
157 fi
158 if test "x$with_context" = "xpthread"; then
159   AC_CHECK_HEADERS([pthread.h])
160   AC_CHECK_LIB(pthread,pthread_create,,
161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
163   AC_MSG_RESULT(You have pthreads. Let's use them.)
164 fi
165
166 dnl #
167 dnl #  4. determine a few additional details
168 dnl #
169
170 if test "x$with_context" = "xucontext" ; then
171 dnl #  direction of stack grow
172   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
173   if test ".$ac_cv_check_stackgrowth" = ".down"; then
174       PTH_STACK_GROWTH="down"
175   else
176       PTH_STACK_GROWTH="up"
177   fi
178   AC_SUBST(PTH_STACK_GROWTH)
179   
180   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
181 fi
182
183 #########################################
184 ## Check for libraries extra-dependencies
185 ##
186
187 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
188
189 SIMGRID_DEP=""
190 GRAS_DEP=""
191
192 #########################################
193 ## Build optional modules (gtnets)
194 ##
195 AC_ARG_WITH(gtnets,
196   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
197   gtnets_path="$withval",gtnets_path="NO")
198 if test "x$gtnets_path" = "xNO" ; then
199   AC_MSG_RESULT(Eventually you will come to GTNetS.)
200 else  
201   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****)
202   AC_DEFINE(USE_GTNETS, 1, [Indicates whether we should use GTNetS or not])
203   if ! test -e $gtnets_path ; then
204     AC_MSG_ERROR(Provided path to GTNetS include files ($gtnets_path) do not exist!)
205   fi
206   GTNETS_CFLAGS=-I$gtnets_path/include
207   AC_SUBST([GTNETS_CFLAGS])  
208   GTNETS_LDFLAGS=-L$gtnets_path/lib
209   AC_SUBST([GTNETS_LDFLAGS])
210   SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS -lgtnets"
211 fi
212 AM_CONDITIONAL(USE_GTNETS,test "x$gtnets_path" != xNO)
213
214 if test xpthread=xyes ; then 
215   # if the pthreads are usable
216   if test "x$with_context" = "xpthread" ; then
217     # if we use them to implement the xbt_context
218     SIMGRID_DEP="-lpthread"
219   fi
220   # we need them in any case for the gras lib (which is multithreaded)
221   GRAS_DEP="-lpthread"
222 fi
223
224 AC_MSG_CHECKING(for csdp)
225 sdp=no
226 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
227 if test "x$csdp" = xyes; then 
228   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
229   AC_MSG_RESULT(Found working sdp library.)
230   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
231 else
232   AC_MSG_RESULT(Could not find any working sdp library.)
233 fi;
234 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
235
236 AC_SUBST([SIMGRID_DEP])
237
238 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
239 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
240
241 AC_MSG_CHECKING(for extra dependencies of libgras)
242 case $host_os in
243   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
244             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
245             AC_DEFINE(CONTEXT_THREADS,1);;
246 esac
247            
248 if test "x$GRAS_DEP" = x; then 
249    AC_MSG_RESULT(none)
250 else
251    AC_MSG_RESULT($GRAS_DEP)
252 fi
253 AC_SUBST([GRAS_DEP])
254
255 ##############################################
256 ## Enhance maintainer mode and SUBST variables
257 ## (must be placed after any compilation tests since our overprotective flags
258 ##  let some tests fail)
259
260 # Check whether we are doing a regular build or a GRAMINE (minimal) one
261 # Next line is modified by sed when building gramine source tree
262 gramine_mode=no
263 if test x$gramine_mode = xyes
264 then
265   USE_MAINTAINER_MODE=no
266 fi
267 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
268
269
270 AM_MAINTAINER_MODE
271 if test x$USE_MAINTAINER_MODE = xyes 
272 then
273    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
274    enable_compile_warnings=yes   
275 fi
276 SG_COMPILE_FLAGS
277
278 AC_SUBST(CFLAGS)
279 AC_SUBST(CPPFLAGS)
280 AC_SUBST(LDFLAGS)
281 AC_SUBST([abs_builddir])
282 AC_SUBST([abs_srcdir])
283 AC_SUBST([abs_top_builddir])
284 AC_SUBST([abs_top_srcdir])
285
286
287
288 SG_CONFIGURE_PART(Check for Java bindings...)
289 # Java cruft
290 AC_PATH_PROG([JAVAC], [javac], `which javac`)
291 AC_PATH_PROG([JAVA],  [java] , `which java`)
292 AC_PATH_PROG([JAR],   [jar]  , `which jar`)
293 AC_CHECK_HEADERS(jni.h)
294 AC_MSG_CHECKING(whether to compile java bindings)
295 if test -n "$JAVAC"   \
296    && test -n "$JAVA" \
297    && test -n "$JAR"  \
298    && test "x$ac_cv_header_jni_h"="xyes" ; then
299    
300    use_java="yes"
301 else   
302    use_java="no"
303 fi
304 AC_MSG_RESULT($use_java)
305 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java"="xyes")
306
307 #####################
308 ## Check for programs
309 ##
310
311 SG_CONFIGURE_PART(Check for programs...)
312 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
313 WARNING="This file is generated, do not edit"
314 AC_SUBST(WARNING)
315
316
317 # Can we rebuild the parsers?
318 # We really want flex and refuse other lex. So, the parser is portable and
319 # does not induce extra lib dependency
320 AC_PROG_FLEX(2.5.30)
321                 
322 # Can we rebuild the xml-lexers from the XML specification?
323 # if not, simply touch the flex source files (which are distributed in
324 #  tarballs even if generated by flexml) and hope for the best.
325 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
326 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
327
328 if test x$USE_MAINTAINER_MODE = xyes 
329 then
330    # Check for doxygen when in maintainer mode since dist* targets fail
331    # without it
332    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
333    if test x$DOXYGEN = x ; then 
334      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
335    fi
336 fi
337
338 # Can we extract really usable backtraces? (also need the popen function)
339 AC_PATH_PROG(ADDR2LINE, addr2line)
340 if test x$ADDR2LINE != x ; then
341   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
342 fi
343
344 AC_SUBST(ac_configure_args)
345 # Can we make status line about the compilation result?
346 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
347 if test x$MD5SUM != xno ; then
348   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
349                  xargs cat| $MD5SUM | sed 's/ .*$//'`
350 else 
351   build_version="no_md5sum_binary"
352 fi
353 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
354 AC_SUBST(build_id)
355
356 ###################
357 ## Makes the output
358 ##
359
360
361 #
362 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
363 #  src/amok/Makefile
364
365 SG_CONFIGURE_PART(Generating files...)
366
367 # Core of the libraries
368
369 AC_CONFIG_FILES([
370   Makefile
371   include/Makefile
372   src/Makefile
373   src/ucontext_stack.h
374 ])
375
376 # Tools being embeeded in gramine (stub generator)
377 AC_CONFIG_FILES([
378   tools/Makefile
379     tools/gras/Makefile
380     tools/tesh/Makefile
381 ])
382
383
384 # GRAMINE_CUT_BEGIN
385
386 # Tools NOT being embeeded in gramine
387 AC_CONFIG_FILES([
388   tools/graspe-slave
389 ],[
390     for file in                                                 \
391      tools/graspe-slave           tools/graspe-master           \
392     ; do                                                        \
393       test -e $file && chmod +x $file;                          \
394     done
395 ])
396
397 # Testsuite
398
399 AC_CONFIG_FILES([  
400   testsuite/Makefile
401   testsuite/run_tests    
402   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
403 ],[
404     for file in                                                 \
405      testsuite/run_tests                                        \
406      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
407     ; do                                                        \
408       test -e $file && chmod +x $file;                          \
409     done
410 ])
411
412 # Documentation
413 AC_CONFIG_FILES([
414   doc/Makefile
415   doc/Doxyfile
416 ])
417
418 # Examples
419
420 #      examples/gras/p2p/Makefile
421 #      examples/gras/p2p/chord/Makefile
422 #      examples/gras/p2p/can/Makefile
423
424
425 AC_CONFIG_FILES([
426   examples/Makefile 
427     examples/msg/Makefile
428       examples/msg/basic.tesh         examples/msg/small_plat.tesh 
429       examples/msg/suspend.tesh       examples/msg/flexml_bypass.tesh 
430     examples/simdag/Makefile        examples/simdag/test_simdag
431     examples/gras/Makefile
432       examples/gras/ping/Makefile   
433       examples/gras/rpc/Makefile
434       examples/gras/timer/Makefile
435       examples/gras/chrono/Makefile
436       examples/gras/mutual_exclusion/simple_token/Makefile
437       examples/gras/mmrpc/Makefile
438       examples/gras/pmm/Makefile
439       examples/gras/all2all/Makefile
440     examples/amok/Makefile       
441       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
442       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
443     examples/java/Makefile
444       examples/java/basic/Makefile
445       examples/java/comm_time/Makefile
446       examples/java/suspend/Makefile
447       examples/java/ping_pong/Makefile
448 ],[
449     for file in                                                 \
450      \
451      examples/msg/run_msg_test                                  \
452      examples/simdag/test_simdag                                \
453      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
454      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
455     ; do                                                        \
456       test -e $file && chmod +x $file;                          \
457     done
458 ])
459
460
461 # GRAMINE_CUT_END
462
463 AC_OUTPUT
464
465 echo "
466
467 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
468
469         Compiler:        ${CC} (version: ${GCC_VERSION})
470         
471         CFlags:          ${CFLAGS}
472         CPPFlags:        ${CPPFLAGS}
473         LDFlags:         ${LDFLAGS}
474
475         Context backend: ${with_context}
476 "
477
478 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
479   echo "WARNING:"
480   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
481   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
482   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
483   echo "WARNING:"
484   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
485   echo "WARNING:"
486 fi
487 echo $build_id > stamp.configure
488
489 exit 0;