configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.2-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal\
  48                 getline])
  49
  50 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  51 AC_FUNC_SNPRINTF
  52 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  53 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  54 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_CONST
  58 AC_C_INLINE
  59 AC_TYPE_SIZE_T
  60
  61 ###################################
  62 ## SimGrid and GRAS specific checks
  63 ##
  64
  65 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  66 # Check architecture signature begin
  67 GRAS_ARCH
  68 # Check architecture signature end
  69 GRAS_CHECK_STRUCT_COMPACTION
  70
  71
  72 dnl ##
  73 dnl ##  CONTEXT IMPLEMENTATION
  74 dnl ##
  75
  76 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  77
  78 dnl #
  79 dnl #  1. determine possibilities
  80 dnl #
  81
  82 dnl #  check for MCSC method
  83 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  84
  85 dnl #  check for pthread method
  86 AC_CHECK_HEADERS([pthread.h])
  87 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  88
  89 dnl #
  90 dnl #  2. make a general decision
  91 dnl #
  92
  93 if test ".$mcsc" = .yes; then
  94    mcsc=yes
  95 elif test ".$pthread" = .yes; then
  96    pthread=yes
  97 else
  98     ac_header=windows.h
  99     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 100     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 101       windows_context=yes
 102     else
 103       AC_ERROR([no appropriate backend found])
 104     fi
 105 fi
 106
 107 dnl #
 108 dnl #  3. allow decision to be overridden by user
 109 dnl #
 110
 111 AC_MSG_CHECKING(what kind of backend should we use)
 112
 113 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 114
 115 AC_ARG_WITH(context,
 116   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 117   with_context=auto)
 118
 119 if test "x$with_context$mcsc" = "xucontextno" ; then
 120   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 121 fi
 122
 123 case $with_context in
 124  ucontext) ;;
 125  pthread) ;;
 126  windows) ;;
 127  auto) with_context=ucontext;;
 128  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 129 esac
 130
 131 if test "x$with_context" = "xucontext" ; then
 132   if test ".$mcsc" = .yes; then
 133     AC_MSG_RESULT(found working ucontext. Great!)
 134     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 135   else
 136     if test ".$windows_context" = .yes ; then
 137       AC_MSG_RESULT(use windows context portability layer.)
 138       with_context=windows
 139     else
 140       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 141       with_context=pthread
 142     fi
 143   fi
 144 fi
 145
 146 if test "x$with_context" = "xpthread"; then
 147   AC_CHECK_HEADERS([pthread.h])
 148   AC_CHECK_LIB(pthread,pthread_create,,
 149     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 150   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 151   AC_MSG_RESULT(You have pthreads. Let's use them.)
 152 fi
 153
 154 dnl #
 155 dnl #  4. determine a few additional details
 156 dnl #
 157
 158 if test "x$with_context" = "xucontext" ; then
 159 dnl #  direction of stack grow
 160   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 161   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 162       PTH_STACK_GROWTH="down"
 163   else
 164       PTH_STACK_GROWTH="up"
 165   fi
 166   AC_SUBST(PTH_STACK_GROWTH)
 167
 168   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 169 fi
 170
 171
 172 #########################################
 173 ## Build optional modules (simix)
 174 ##
 175 SG_CONFIGURE_PART(Optional modules)
 176 AC_ARG_ENABLE(simix,
 177   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
 178   enable_simix=$enableval,enable_simix=no)
 179 if test "x$enable_simix" = "xyes" ; then
 180   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
 181   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
 182 else
 183   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
 184 fi
 185 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
 186
 187 #########################################
 188 ## Check for libraries extra-dependencies
 189 ##
 190
 191 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 192
 193 SIMGRID_DEP=""
 194 GRAS_DEP=""
 195 AC_CHECK_LIB(pthread,pthread_create,SIMGRID_DEP="-lpthread"; GRAS_DEP="-lpthread")
 196
 197 AC_MSG_CHECKING(for csdp)
 198 sdp=no
 199 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 200 if test "x$csdp" = xyes; then
 201   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 202   AC_MSG_RESULT(Found working sdp library.)
 203   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 204 else
 205   AC_MSG_RESULT(Could not find any working sdp library.)
 206 fi;
 207 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 208
 209 AC_SUBST([SIMGRID_DEP])
 210
 211 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 212 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 213
 214 AC_MSG_CHECKING(for extra dependencies of libgras)
 215 case $host_os in
 216   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 217             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT);;
 218 esac
 219
 220 if test "x$GRAS_DEP" = x; then
 221    AC_MSG_RESULT(none)
 222 else
 223    AC_MSG_RESULT($GRAS_DEP)
 224 fi
 225 AC_SUBST([GRAS_DEP])
 226
 227
 228 ##############################################
 229 ## Enhance maintainer mode and SUBST variables
 230 ## (must be placed after any compilation tests since our overprotective flags
 231 ##  let some tests fail)
 232
 233 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 234 # Next line is modified by sed when building gramine source tree
 235 gramine_mode=no
 236 if test x$gramine_mode = xyes
 237 then
 238   USE_MAINTAINER_MODE=no
 239 fi
 240 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 241
 242
 243 AM_MAINTAINER_MODE
 244 if test x$USE_MAINTAINER_MODE = xyes
 245 then
 246    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 247    enable_compile_warnings=yes
 248 fi
 249 SG_COMPILE_FLAGS
 250
 251 AC_SUBST(CFLAGS)
 252 AC_SUBST(CPPFLAGS)
 253 AC_SUBST(LDFLAGS)
 254 AC_SUBST([abs_builddir])
 255 AC_SUBST([abs_srcdir])
 256 AC_SUBST([abs_top_builddir])
 257 AC_SUBST([abs_top_srcdir])
 258
 259 #####################
 260 ## Check for programs
 261 ##
 262
 263 SG_CONFIGURE_PART(Check for programs...)
 264 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 265 WARNING="This file is generated, do not edit"
 266 AC_SUBST(WARNING)
 267
 268
 269 # Can we rebuild the parsers?
 270 # We really want flex and refuse other lex. So, the parser is portable and
 271 # does not induce extra lib dependency
 272 AC_PROG_FLEX(2.5.30)
 273
 274 # Can we rebuild the xml-lexers from the XML specification?
 275 # if not, simply touch the flex source files (which are distributed in
 276 #  tarballs even if generated by flexml) and hope for the best.
 277 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 278 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 279
 280 if test x$USE_MAINTAINER_MODE = xyes
 281 then
 282    # Check for doxygen when in maintainer mode since dist* targets fail
 283    # without it
 284    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 285    if test x$DOXYGEN = x ; then
 286      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 287    fi
 288 fi
 289
 290 # Can we extract really usable backtraces? (also need the popen function)
 291 AC_PATH_PROG(ADDR2LINE, addr2line)
 292 if test x$ADDR2LINE != x ; then
 293   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 294 fi
 295
 296 AC_SUBST(ac_configure_args)
 297 # Can we make status line about the compilation result?
 298 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 299 if test x$MD5SUM != xno ; then
 300   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 301                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 302 else
 303   build_version="no_md5sum_binary"
 304 fi
 305 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 306 AC_SUBST(build_id)
 307
 308 ###################
 309 ## Makes the output
 310 ##
 311
 312
 313 #
 314 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 315 #  src/amok/Makefile
 316
 317 SG_CONFIGURE_PART(Generating files...)
 318
 319 # Core of the libraries
 320
 321 AC_CONFIG_FILES([
 322   Makefile
 323   include/Makefile
 324   src/Makefile
 325   src/ucontext_stack.h
 326 ])
 327
 328 # Tools being embeeded in gramine (stub generator)
 329 AC_CONFIG_FILES([
 330   tools/Makefile
 331     tools/gras/Makefile
 332 ])
 333 dnl tools/tesh/Makefile
 334
 335
 336 # GRAMINE_CUT_BEGIN
 337
 338 # Tools NOT being embeeded in gramine
 339 AC_CONFIG_FILES([
 340   tools/graspe-slave
 341 ],[
 342     for file in                                                 \
 343      tools/graspe-slave           tools/graspe-master           \
 344     ; do                                                        \
 345       test -e $file && chmod +x $file;                          \
 346     done
 347 ])
 348
 349 # Testsuite
 350
 351 AC_CONFIG_FILES([
 352   testsuite/Makefile
 353   testsuite/run_tests
 354   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 355 ],[
 356     for file in                                                 \
 357      testsuite/run_tests                                        \
 358      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 359     ; do                                                        \
 360       test -e $file && chmod +x $file;                          \
 361     done
 362 ])
 363
 364 # Documentation
 365 AC_CONFIG_FILES([
 366   doc/Makefile
 367   doc/Doxyfile
 368 ])
 369
 370 # Examples
 371
 372 AC_CONFIG_FILES([
 373   examples/Makefile
 374     examples/msg/Makefile           examples/msg/run_msg_test
 375     examples/simdag/Makefile        examples/simdag/test_simdag
 376     examples/gras/Makefile
 377       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 378       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 379       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 380       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 381       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 382       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 383       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 384       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 385
 386       examples/gras/p2p/Makefile
 387       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 388       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 389
 390     examples/amok/Makefile
 391       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 392       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 393 ],[
 394     for file in                                                 \
 395      \
 396      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 397      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 398      \
 399      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 400      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 401      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 402      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 403      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 404      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 405      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 406      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 407      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 408      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 409      examples/msg/run_msg_test                                  \
 410      examples/simdag/test_simdag                                \
 411     ; do                                                        \
 412       test -e $file && chmod +x $file;                          \
 413     done
 414 ])
 415
 416 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 417 #    examples/gras/pastry/test_sg
 418
 419
 420
 421 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 422 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 423
 424
 425 # GRAMINE_CUT_END
 426
 427 AC_OUTPUT
 428
 429 echo "
 430
 431 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 432
 433         Compiler:        ${CC} (version: ${GCC_VERSION})
 434
 435         CFlags:          ${CFLAGS}
 436         CPPFlags:        ${CPPFLAGS}
 437         LDFlags:         ${LDFLAGS}
 438
 439         Context backend: ${with_context}
 440 "
 441
 442 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 443   echo "WARNING:"
 444   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 445   echo "WARNING: You may want to enable this by specifying:"
 446   echo "WARNING:"
 447   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 448   echo "WARNING:"
 449 fi
 450 echo $build_id > stamp.configure
 451
 452 exit 0;